ld/configure.in

   1 dnl Process this file with autoconf to produce a configure script
   2 dnl
   3 AC_PREREQ(2.57)
   4 AC_INIT(ldmain.c)
   5
   6 AC_CANONICAL_SYSTEM
   7 AC_ISC_POSIX
   8
   9 changequote(,)dnl
  10 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  11 changequote([,])dnl
  12 AM_INIT_AUTOMAKE(ld, ${BFD_VERSION})
  13
  14 AM_PROG_LIBTOOL
  15
  16 AC_ARG_WITH(lib-path, [  --with-lib-path=dir1:dir2...  set default LIB_PATH],LIB_PATH=$withval)
  17 AC_ARG_ENABLE(targets,
  18 [  --enable-targets        alternative target configurations],
  19 [case "${enableval}" in
  20   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  21             ;;
  22   no)       enable_targets= ;;
  23   *)        enable_targets=$enableval ;;
  24 esac])dnl
  25 AC_ARG_ENABLE(64-bit-bfd,
  26 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  27 [case "${enableval}" in
  28   yes)  want64=true  ;;
  29   no)   want64=false ;;
  30   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  31 esac],[want64=false])dnl
  32
  33 AC_ARG_WITH(sysroot,
  34 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
  35 [
  36  case ${with_sysroot} in
  37  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
  38  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
  39  esac
  40
  41  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
  42  use_sysroot=yes
  43
  44  if test "x$exec_prefix" = xNONE; then
  45   if test "x$prefix" = xNONE; then
  46    test_prefix=/usr/local
  47   else
  48    test_prefix=$prefix
  49   fi
  50  else
  51   test_prefix=$exec_prefix
  52  fi
  53  case ${TARGET_SYSTEM_ROOT} in
  54  "${test_prefix}"|"${test_prefix}/"*|\
  55  '${exec_prefix}'|'${exec_prefix}/'*)
  56    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
  57    TARGET_SYSTEM_ROOT_DEFINE="$t"
  58    ;;
  59  esac
  60 ], [
  61  use_sysroot=no
  62  TARGET_SYSTEM_ROOT=
  63  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
  64 ])
  65 AC_SUBST(use_sysroot)
  66 AC_SUBST(TARGET_SYSTEM_ROOT)
  67 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
  68
  69 # The location to which bugs should be reported.
  70 AC_ARG_WITH(bugurl,
  71   AS_HELP_STRING([--with-bugurl=URL],
  72                  [Direct users to URL to report a bug]),
  73   [case "$withval" in
  74     yes) AC_MSG_ERROR([bug URL not specified]) ;;
  75     no)  REPORT_BUGS_TO="";
  76          REPORT_BUGS_TEXI=""
  77          ;;
  78     *)   REPORT_BUGS_TO="<URL:$withval>"
  79          REPORT_BUGS_TEXI="@uref{`echo $withval | sed 's/@/@@/g'`}"
  80          ;;
  81    esac],
  82    REPORT_BUGS_TO="<URL:http://www.sourceware.org/bugzilla/>"
  83    REPORT_BUGS_TEXI="@uref{http://www.sourceware.org/bugzilla/}"
  84 )
  85 AC_SUBST(REPORT_BUGS_TO)
  86 AC_SUBST(REPORT_BUGS_TEXI)
  87
  88 AM_BINUTILS_WARNINGS
  89
  90 AM_CONFIG_HEADER(config.h:config.in)
  91
  92 if test -z "$target" ; then
  93     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  94 fi
  95 if test -z "$host" ; then
  96     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
  97 fi
  98
  99 # host-specific stuff:
 100
 101 AC_PROG_CC
 102 AC_PROG_INSTALL
 103
 104 ALL_LINGUAS="fr sv tr es da vi zh_CN zh_TW ga"
 105 ZW_GNU_GETTEXT_SISTER_DIR
 106 AM_PO_SUBDIRS
 107
 108 AC_EXEEXT
 109
 110 AC_PROG_YACC
 111 AM_PROG_LEX
 112
 113 AM_MAINTAINER_MODE
 114 AM_CONDITIONAL(GENINSRC_NEVER, false)
 115
 116 . ${srcdir}/configure.host
 117
 118 AC_SUBST(HDEFINES)
 119 AC_SUBST(HOSTING_CRT0)
 120 AC_SUBST(HOSTING_LIBS)
 121 AC_SUBST(NATIVE_LIB_DIRS)
 122
 123 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h elf-hints.h limits.h sys/param.h)
 124 AC_CHECK_FUNCS(sbrk realpath glob)
 125 AC_HEADER_DIRENT
 126
 127 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 128 AC_CACHE_VAL(ld_cv_decl_getopt_unistd_h,
 129 [AC_TRY_COMPILE([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);],
 130 ld_cv_decl_getopt_unistd_h=yes, ld_cv_decl_getopt_unistd_h=no)])
 131 AC_MSG_RESULT($ld_cv_decl_getopt_unistd_h)
 132 if test $ld_cv_decl_getopt_unistd_h = yes; then
 133   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 134             [Is the prototype for getopt in <unistd.h> in the expected format?])
 135 fi
 136
 137 BFD_BINARY_FOPEN
 138
 139 AC_CHECK_DECLS([strstr, free, sbrk, getenv, environ])
 140
 141 # When converting linker scripts into strings for use in emulation
 142 # files, use astring.sed if the compiler supports ANSI string
 143 # concatenation, or ostring.sed otherwise.  This is to support the
 144 # broken Microsoft MSVC compiler, which limits the length of string
 145 # constants, while still supporting pre-ANSI compilers which do not
 146 # support string concatenation.
 147 AC_MSG_CHECKING([whether ANSI C string concatenation works])
 148 AC_CACHE_VAL(ld_cv_string_concatenation,
 149 [AC_TRY_COMPILE(,[char *a = "a" "a";],
 150   [ld_cv_string_concatenation=yes],
 151   [ld_cv_string_concatenation=no])])
 152 AC_MSG_RESULT($ld_cv_string_concatenation)
 153 if test "$ld_cv_string_concatenation" = "yes"; then
 154   STRINGIFY=astring.sed
 155 else
 156   STRINGIFY=ostring.sed
 157 fi
 158 AC_SUBST(STRINGIFY)
 159
 160 # target-specific stuff:
 161
 162 all_targets=
 163 EMUL=
 164 all_emuls=
 165 all_emul_extras=
 166 all_libpath=
 167
 168 dnl We need to get an arbitrary number of tdir definitions into
 169 dnl Makefile.  We can't do it using AC_SUBST, because autoconf does
 170 dnl not permit literal newlines in an AC_SUBST variables.  So we use a
 171 dnl file.
 172 rm -f tdirs
 173
 174 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 175 do
 176   if test "$targ_alias" = "all"; then
 177     all_targets=true
 178   else
 179     # Canonicalize the secondary target names.
 180     result=`$ac_config_sub $targ_alias 2>/dev/null`
 181     if test -n "$result"; then
 182         targ=$result
 183     else
 184         targ=$targ_alias
 185     fi
 186
 187     . ${srcdir}/configure.tgt
 188
 189     if test "$targ" = "$target"; then
 190       EMUL=$targ_emul
 191     fi
 192
 193     if test x${want64} = xfalse; then
 194       . ${srcdir}/../bfd/config.bfd
 195     fi
 196
 197     if test x${want64} = xtrue; then
 198       targ_extra_emuls="$targ_extra_emuls $targ64_extra_emuls"
 199       targ_extra_libpath="$targ_extra_libpath $targ64_extra_libpath"
 200     fi
 201
 202     for i in $targ_emul $targ_extra_emuls $targ_extra_libpath; do
 203         case " $all_emuls " in
 204         *" e${i}.o "*) ;;
 205         *)
 206           all_emuls="$all_emuls e${i}.o"
 207           eval result=\$tdir_$i
 208           test -z "$result" && result=$targ_alias
 209           echo tdir_$i=$result >> tdirs
 210           ;;
 211         esac
 212     done
 213
 214     for i in $targ_emul $targ_extra_libpath; do
 215         case " $all_libpath " in
 216         *" ${i} "*) ;;
 217         *)
 218           if test -z "$all_libpath"; then
 219             all_libpath=${i}
 220           else
 221             all_libpath="$all_libpath ${i}"
 222           fi
 223           ;;
 224         esac
 225     done
 226
 227     for i in $targ_extra_ofiles; do
 228         case " $all_emul_extras " in
 229         *" ${i} "*) ;;
 230         *)
 231           all_emul_extras="$all_emul_extras ${i}"
 232           ;;
 233         esac
 234     done
 235   fi
 236 done
 237
 238 AC_SUBST(EMUL)
 239
 240 TDIRS=tdirs
 241 AC_SUBST_FILE(TDIRS)
 242
 243 if test x${all_targets} = xtrue; then
 244   if test x${want64} = xfalse; then
 245     AC_CHECK_SIZEOF(long)
 246     if test "x${ac_cv_sizeof_long}" = "x8"; then
 247       want64=true
 248     fi
 249   fi
 250   if test x${want64} = xtrue; then
 251     EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)'
 252   else
 253     EMULATION_OFILES='$(ALL_EMULATIONS)'
 254   fi
 255   EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)'
 256 else
 257   EMULATION_OFILES=$all_emuls
 258   EMUL_EXTRA_OFILES=$all_emul_extras
 259 fi
 260 AC_SUBST(EMULATION_OFILES)
 261 AC_SUBST(EMUL_EXTRA_OFILES)
 262 AC_SUBST(LIB_PATH)
 263
 264 EMULATION_LIBPATH=$all_libpath
 265 AC_SUBST(EMULATION_LIBPATH)
 266
 267 if test x${enable_static} = xno; then
 268   TESTBFDLIB="--rpath ../bfd/.libs ../bfd/.libs/libbfd.so"
 269 else
 270   TESTBFDLIB="../bfd/.libs/libbfd.a"
 271 fi
 272 AC_SUBST(TESTBFDLIB)
 273
 274 target_vendor=${target_vendor=$host_vendor}
 275 case "$target_vendor" in
 276   hp) EXTRA_SHLIB_EXTENSION=".sl" ;;
 277   *)  EXTRA_SHLIB_EXTENSION= ;;
 278 esac
 279
 280 case "$target_os" in
 281   lynxos) EXTRA_SHLIB_EXTENSION=".a" ;;
 282 esac
 283
 284 if test x${EXTRA_SHLIB_EXTENSION} != x ; then
 285   AC_DEFINE_UNQUOTED(EXTRA_SHLIB_EXTENSION, "$EXTRA_SHLIB_EXTENSION",
 286    [Additional extension a shared object might have.])
 287 fi
 288
 289 dnl Required by html and install-html
 290 AC_SUBST(datarootdir)
 291 AC_SUBST(docdir)
 292 AC_SUBST(htmldir)
 293
 294 AC_OUTPUT(Makefile po/Makefile.in:po/Make-in)