opcodes/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3
   4 AC_PREREQ(2.13)
   5 AC_INIT(z8k-dis.c)
   6
   7 AC_CANONICAL_SYSTEM
   8 AC_ISC_POSIX
   9
  10 # We currently only use the version number for the name of any shared
  11 # library.  For user convenience, we always use the same version
  12 # number that BFD is using.
  13 changequote(,)dnl
  14 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  15 changequote([,])dnl
  16
  17 AM_INIT_AUTOMAKE(opcodes, ${BFD_VERSION})
  18
  19 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  20 dnl to call AC_CHECK_PROG.
  21 AC_CHECK_TOOL(AR, ar)
  22 AC_CHECK_TOOL(RANLIB, ranlib, :)
  23
  24 dnl Default to a non shared library.  This may be overridden by the
  25 dnl configure option --enable-shared.
  26 AM_DISABLE_SHARED
  27
  28 AM_PROG_LIBTOOL
  29
  30 AC_ARG_ENABLE(targets,
  31 [  --enable-targets        alternative target configurations],
  32 [case "${enableval}" in
  33   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  34             ;;
  35   no)       enable_targets= ;;
  36   *)        enable_targets=$enableval ;;
  37 esac])dnl
  38 AC_ARG_ENABLE(commonbfdlib,
  39 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  40 [case "${enableval}" in
  41   yes) commonbfdlib=true ;;
  42   no)  commonbfdlib=false ;;
  43   *)   AC_MSG_ERROR([bad value ${enableval} for opcodes commonbfdlib option]) ;;
  44 esac])dnl
  45
  46 build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
  47 AC_ARG_ENABLE(build-warnings,
  48 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  49 [case "${enableval}" in
  50   yes)  ;;
  51   no)   build_warnings="-w";;
  52   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  53         build_warnings="${build_warnings} ${t}";;
  54   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  55         build_warnings="${t} ${build_warnings}";;
  56   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  57 esac
  58 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  59   echo "Setting warning flags = $build_warnings" 6>&1
  60 fi])dnl
  61 WARN_CFLAGS=""
  62 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  63     WARN_CFLAGS="${build_warnings}"
  64 fi
  65 AC_SUBST(WARN_CFLAGS)
  66
  67 AM_CONFIG_HEADER(config.h:config.in)
  68
  69 if test -z "$target" ; then
  70     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  71 fi
  72
  73 AM_MAINTAINER_MODE
  74 AC_EXEEXT
  75
  76 # host-specific stuff:
  77
  78 AC_PROG_CC
  79
  80 ALL_LINGUAS=
  81 CY_GNU_GETTEXT
  82
  83 . ${srcdir}/../bfd/configure.host
  84
  85 AC_SUBST(HDEFINES)
  86 AC_PROG_INSTALL
  87
  88 AC_CHECK_HEADERS(string.h strings.h stdlib.h)
  89
  90 cgen_maint=no
  91 cgendir='$(srcdir)/../cgen'
  92
  93 AC_ARG_ENABLE(cgen-maint,
  94 [  --enable-cgen-maint[=dir]    build cgen generated files],
  95 [case "${enableval}" in
  96   yes)  cgen_maint=yes ;;
  97   no)   cgen_maint=no ;;
  98   *)
  99         # argument is cgen install directory (not implemented yet).
 100         # Having a `share' directory might be more appropriate for the .scm,
 101         # .cpu, etc. files.
 102         cgen_maint=yes
 103         cgendir=${cgen_maint}/lib/cgen
 104         ;;
 105 esac])dnl
 106 AM_CONDITIONAL(CGEN_MAINT, test x${cgen_maint} = xyes)
 107 AC_SUBST(cgendir)
 108
 109 using_cgen=no
 110
 111 # Horrible hacks to build DLLs on Windows.
 112 WIN32LDFLAGS=
 113 WIN32LIBADD=
 114 case "${host}" in
 115 *-*-cygwin*)
 116   if test "$enable_shared" = "yes"; then
 117     WIN32LDFLAGS="-no-undefined"
 118     WIN32LIBADD="-L`pwd`/../bfd -lbfd -L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin"
 119   fi
 120   ;;
 121 esac
 122 AC_SUBST(WIN32LDFLAGS)
 123 AC_SUBST(WIN32LIBADD)
 124
 125 # target-specific stuff:
 126
 127 # Canonicalize the secondary target names.
 128 if test -n "$enable_targets" ; then
 129     for targ in `echo $enable_targets | sed 's/,/ /g'`
 130     do
 131         result=`$ac_config_sub $targ 2>/dev/null`
 132         if test -n "$result" ; then
 133             canon_targets="$canon_targets $result"
 134         else
 135             # Allow targets that config.sub doesn't recognize, like "all".
 136             canon_targets="$canon_targets $targ"
 137         fi
 138     done
 139 fi
 140
 141 all_targets=false
 142 selarchs=
 143 for targ in $target $canon_targets
 144 do
 145     if test "x$targ" = "xall" ; then
 146         all_targets=true
 147     else
 148         . $srcdir/../bfd/config.bfd
 149         selarchs="$selarchs $targ_archs"
 150     fi
 151 done
 152
 153 # Utility var, documents generic cgen support files.
 154
 155 cgen_files="cgen-opc.lo cgen-asm.lo cgen-dis.lo"
 156
 157 # We don't do any links based on the target system, just makefile config.
 158
 159 if test x${all_targets} = xfalse ; then
 160
 161     # Target architecture .o files.
 162     ta=
 163
 164     for arch in $selarchs
 165     do
 166         ad=`echo $arch | sed -e s/bfd_//g -e s/_arch//g`
 167         archdefs="$archdefs -DARCH_$ad"
 168         case "$arch" in
 169         bfd_a29k_arch)          ta="$ta a29k-dis.lo" ;;
 170         bfd_alliant_arch)       ;;
 171         bfd_alpha_arch)         ta="$ta alpha-dis.lo alpha-opc.lo" ;;
 172         bfd_arc_arch)           ta="$ta arc-dis.lo arc-opc.lo arc-ext.lo" ;;
 173         bfd_arm_arch)           ta="$ta arm-dis.lo" ;;
 174         bfd_avr_arch)           ta="$ta avr-dis.lo" ;;
 175         bfd_convex_arch)        ;;
 176         bfd_cris_arch)          ta="$ta cris-dis.lo cris-opc.lo" ;;
 177         bfd_d10v_arch)          ta="$ta d10v-dis.lo d10v-opc.lo" ;;
 178         bfd_d30v_arch)          ta="$ta d30v-dis.lo d30v-opc.lo" ;;
 179         bfd_fr30_arch)          ta="$ta fr30-asm.lo fr30-desc.lo fr30-dis.lo fr30-ibld.lo fr30-opc.lo" using_cgen=yes ;;
 180         bfd_h8300_arch)         ta="$ta h8300-dis.lo" ;;
 181         bfd_h8500_arch)         ta="$ta h8500-dis.lo" ;;
 182         bfd_hppa_arch)          ta="$ta hppa-dis.lo" ;;
 183         bfd_i370_arch)          ta="$ta i370-dis.lo i370-opc.lo" ;;
 184         bfd_i386_arch)          ta="$ta i386-dis.lo" ;;
 185         bfd_i860_arch)          ta="$ta i860-dis.lo" ;;
 186         bfd_i960_arch)          ta="$ta i960-dis.lo" ;;
 187         bfd_ia64_arch)          ta="$ta ia64-dis.lo ia64-opc.lo" ;;
 188         bfd_m32r_arch)          ta="$ta m32r-asm.lo m32r-desc.lo m32r-dis.lo m32r-ibld.lo m32r-opc.lo m32r-opinst.lo" using_cgen=yes ;;
 189         bfd_m68hc11_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 190         bfd_m68hc12_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 191         bfd_m68k_arch)          ta="$ta m68k-dis.lo m68k-opc.lo" ;;
 192         bfd_m88k_arch)          ta="$ta m88k-dis.lo" ;;
 193         bfd_mcore_arch)         ta="$ta mcore-dis.lo" ;;
 194         bfd_mips_arch)          ta="$ta mips-dis.lo mips-opc.lo mips16-opc.lo" ;;
 195         bfd_mn10200_arch)       ta="$ta m10200-dis.lo m10200-opc.lo" ;;
 196         bfd_mn10300_arch)       ta="$ta m10300-dis.lo m10300-opc.lo" ;;
 197         bfd_ns32k_arch)         ta="$ta ns32k-dis.lo" ;;
 198         bfd_openrisc_arch)      ta="$ta openrisc-asm.lo openrisc-desc.lo openrisc-dis.lo openrisc-ibld.lo openrisc-opc.lo" using_cgen=yes ;;
 199         bfd_pdp11_arch)         ta="$ta pdp11-dis.lo pdp11-opc.lo" ;;
 200         bfd_pj_arch)            ta="$ta pj-dis.lo pj-opc.lo" ;;
 201         bfd_powerpc_arch)       ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 202         bfd_powerpc_64_arch)    ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 203         bfd_pyramid_arch)       ;;
 204         bfd_romp_arch)          ;;
 205         bfd_rs6000_arch)        ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 206         bfd_s390_arch)          ta="$ta s390-dis.lo s390-opc.lo" ;;
 207         bfd_sh_arch)
 208                                 ta="$ta sh-dis.lo" ;;
 209         bfd_sparc_arch)         ta="$ta sparc-dis.lo sparc-opc.lo" ;;
 210         bfd_tahoe_arch)         ;;
 211         bfd_tic30_arch)         ta="$ta tic30-dis.lo" ;;
 212         bfd_tic54x_arch)        ta="$ta tic54x-dis.lo tic54x-opc.lo" ;;
 213         bfd_tic80_arch)         ta="$ta tic80-dis.lo tic80-opc.lo" ;;
 214         bfd_v850_arch)          ta="$ta v850-opc.lo v850-dis.lo" ;;
 215         bfd_v850e_arch)         ta="$ta v850-opc.lo v850-dis.lo" ;;
 216         bfd_v850ea_arch)        ta="$ta v850-opc.lo v850-dis.lo" ;;
 217         bfd_vax_arch)           ta="$ta vax-dis.lo" ;;
 218         bfd_w65_arch)           ta="$ta w65-dis.lo" ;;
 219         bfd_we32k_arch)         ;;
 220         bfd_z8k_arch)           ta="$ta z8k-dis.lo" ;;
 221
 222         "")                     ;;
 223         *)              AC_MSG_ERROR(*** unknown target architecture $arch) ;;
 224         esac
 225     done
 226
 227     if test $using_cgen = yes ; then
 228         ta="$ta $cgen_files"
 229     fi
 230
 231     # Weed out duplicate .o files.
 232     f=""
 233     for i in $ta ; do
 234         case " $f " in
 235         *" $i "*) ;;
 236         *) f="$f $i" ;;
 237         esac
 238     done
 239     ta="$f"
 240
 241     # And duplicate -D flags.
 242     f=""
 243     for i in $archdefs ; do
 244         case " $f " in
 245         *" $i "*) ;;
 246         *) f="$f $i" ;;
 247         esac
 248     done
 249     archdefs="$f"
 250
 251     BFD_MACHINES="$ta"
 252
 253 else    # all_targets is true
 254     archdefs=-DARCH_all
 255     BFD_MACHINES='$(ALL_MACHINES)'
 256 fi
 257
 258 AC_SUBST(archdefs)
 259 AC_SUBST(BFD_MACHINES)
 260
 261 AC_OUTPUT(Makefile po/Makefile.in:po/Make-in,
 262 [sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile])