gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 dnl v2.5 needed for --bindir et al
   8 AC_PREREQ(2.57)
   9 AC_INIT(as.h)
  10
  11 dnl Autoconf 2.57 will find the aux dir without this.  However, unless
  12 dnl we specify this explicitly, automake-1.7 will assume that ylwrap is in
  13 dnl gas/ instead of gas/../.
  14 AC_CONFIG_AUX_DIR(..)
  15 AC_CANONICAL_SYSTEM
  16 AC_ISC_POSIX
  17
  18 changequote(,)dnl
  19 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  20 changequote([,])dnl
  21 AM_INIT_AUTOMAKE(gas, ${BFD_VERSION})
  22
  23 AM_PROG_LIBTOOL
  24
  25 user_bfd_gas=
  26 AC_ARG_ENABLE(bfd-assembler,
  27 [  --enable-bfd-assembler  use BFD back end for writing object files],
  28 [case "${enableval}" in
  29   yes) need_bfd=yes user_bfd_gas=yes ;;
  30   no)  user_bfd_gas=no ;;
  31   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  32 esac])dnl
  33 AC_ARG_ENABLE(targets,
  34 [    targets            alternative target configurations besides the primary],
  35 [case "${enableval}" in
  36   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  37             ;;
  38   no)       enable_targets= ;;
  39   *)        enable_targets=$enableval ;;
  40 esac])dnl
  41 AC_ARG_ENABLE(commonbfdlib,
  42 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  43 [case "${enableval}" in
  44   yes) commonbfdlib=true ;;
  45   no)  commonbfdlib=false ;;
  46   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  47 esac])dnl
  48
  49 using_cgen=no
  50
  51 build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
  52 AC_ARG_ENABLE(build-warnings,
  53 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  54 [case "${enableval}" in
  55   yes)  ;;
  56   no)   build_warnings="-w";;
  57   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  58         build_warnings="${build_warnings} ${t}";;
  59   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  60         build_warnings="${t} ${build_warnings}";;
  61   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  62 esac
  63 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  64   echo "Setting warning flags = $build_warnings" 6>&1
  65 fi])dnl
  66 WARN_CFLAGS=""
  67 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  68     WARN_CFLAGS="${build_warnings}"
  69 fi
  70 AC_SUBST(WARN_CFLAGS)
  71
  72 # Generate a header file
  73 AM_CONFIG_HEADER(config.h:config.in)
  74
  75 # If we are on a DOS filesystem, we must use gdb.ini rather than
  76 # .gdbinit.
  77 case "${host}" in
  78   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-windows*)
  79     GDBINIT="gdb.ini"
  80     AC_CONFIG_FILES(gdb.ini:gdbinit.in)
  81     ;;
  82   *)
  83     GDBINIT=".gdbinit"
  84     AC_CONFIG_FILES(.gdbinit:gdbinit.in)
  85     ;;
  86 esac
  87 AC_SUBST(GDBINIT)
  88
  89 te_file=generic
  90
  91 # Makefile target for installing gas in $(tooldir)/bin.
  92 install_tooldir=install-exec-tooldir
  93
  94 canon_targets=""
  95 all_targets=no
  96 if test -n "$enable_targets" ; then
  97   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  98     if test $t = "all"; then
  99       all_targets=yes
 100       continue
 101     fi
 102     result=`$ac_config_sub $t 2>/dev/null`
 103     if test -n "$result" ; then
 104       canon_targets="$canon_targets $result"
 105 #    else
 106 #      # Permit "all", etc.  We don't support it yet though.
 107 #      canon_targets="$canon_targets $t"
 108     fi
 109   done
 110   GAS_UNIQ(canon_targets)
 111 fi
 112
 113 emulations=""
 114
 115 for this_target in $target $canon_targets ; do
 116
 117 changequote(,)dnl
 118     eval `echo $this_target | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/cpu=\1 vendor=\2 os=\3/'`
 119 changequote([,])dnl
 120
 121     # check for architecture variants
 122     arch=
 123     endian=
 124     case ${cpu} in
 125       am33_2.0)         cpu_type=mn10300 endian=little ;;
 126       alpha*)           cpu_type=alpha ;;
 127       arm*b|xscale*b|strongarm*b) cpu_type=arm endian=big ;;
 128       arm*|xscale*|strongarm*)    cpu_type=arm endian=little ;;
 129       c4x*)             cpu_type=tic4x ;;
 130       hppa*)            cpu_type=hppa ;;
 131 changequote(,)dnl
 132       i[3-7]86)         cpu_type=i386 arch=i386;;
 133       x86_64)           cpu_type=i386 arch=x86_64;;
 134       ia64)             cpu_type=ia64 ;;
 135       ip2k)             cpu_type=ip2k endian=big ;;
 136       iq2000)           cpu_type=iq2000 endian=big ;;
 137       m6811|m6812|m68hc12) cpu_type=m68hc11 ;;
 138       m680[012346]0)    cpu_type=m68k ;;
 139 changequote([,])dnl
 140       m68008)           cpu_type=m68k ;;
 141       m683??)           cpu_type=m68k ;;
 142       m5200)            cpu_type=m68k ;;
 143       m8*)              cpu_type=m88k ;;
 144       mips*el)          cpu_type=mips endian=little ;;
 145       mips*)            cpu_type=mips endian=big ;;
 146       or32*)            cpu_type=or32 endian=big ;;
 147       pjl*)             cpu_type=pj endian=little ;;
 148       pj*)              cpu_type=pj endian=big ;;
 149       powerpc*le*)      cpu_type=ppc endian=little ;;
 150       powerpc*)         cpu_type=ppc endian=big ;;
 151       rs6000*)          cpu_type=ppc ;;
 152       s390x*)           cpu_type=s390 arch=s390x ;;
 153       s390*)            cpu_type=s390 arch=s390 ;;
 154       sh5*)             cpu_type=sh64 endian=big ;;
 155       sh5le*)           cpu_type=sh64 endian=little ;;
 156       sh64*)            cpu_type=sh64 endian=big ;;
 157       sh64le*)          cpu_type=sh64 endian=little ;;
 158       sh*le)            cpu_type=sh endian=little ;;
 159       sh*)              cpu_type=sh endian=big ;;
 160       sparclite*)       cpu_type=sparc arch=sparclite ;;
 161       sparclet*)        cpu_type=sparc arch=sparclet ;;
 162       sparc64*)         cpu_type=sparc arch=v9-64 ;;
 163       sparc86x*)        cpu_type=sparc arch=sparc86x  ;;
 164       sparc*)           cpu_type=sparc arch=sparclite ;; # ??? See tc-sparc.c.
 165       v850*)            cpu_type=v850 ;;
 166       xtensa*)          cpu_type=xtensa arch=xtensa ;;
 167       *)                cpu_type=${cpu} ;;
 168     esac
 169
 170     if test ${this_target} = $target ; then
 171       target_cpu_type=${cpu_type}
 172     elif test ${target_cpu_type} != ${cpu_type} ; then
 173       continue
 174     fi
 175
 176     generic_target=${cpu_type}-$vendor-$os
 177     dev=no
 178     bfd_gas=no
 179     em=generic
 180
 181     # assign object format
 182     case ${generic_target} in
 183       a29k-*-coff)                      fmt=coff ;;
 184       a29k-amd-udi)                     fmt=coff ;;
 185       a29k-amd-ebmon)                   fmt=coff ;;
 186       a29k-nyu-sym1)                    fmt=coff ;;
 187       a29k-*-rtems*)                    fmt=coff ;;
 188       a29k-*-vxworks*)                  fmt=coff ;;
 189
 190       alpha*-*-*vms*)                   fmt=evax ;;
 191       alpha*-*-netware*)                fmt=ecoff ;;
 192       alpha*-*-osf*)                    fmt=ecoff ;;
 193       alpha*-*-linuxecoff*)             fmt=ecoff ;;
 194       alpha*-*-linux-gnu*)              fmt=elf em=linux ;;
 195       alpha*-*-netbsd*)                 fmt=elf em=nbsd ;;
 196       alpha*-*-openbsd*)                fmt=elf em=obsd ;;
 197
 198       # cpu_type for am33_2.0 is set to mn10300
 199       mn10300-*-linux*)                 fmt=elf bfd_gas=yes em=linux ;;
 200
 201       arc-*-elf*)                       fmt=elf ;;
 202
 203       arm-*-aout)                       fmt=aout ;;
 204       arm-*-coff | thumb-*-coff)        fmt=coff ;;
 205       arm-*-rtems* | thumb-*-rtems*)    fmt=elf ;;
 206       arm-*-elf | thumb-*-elf)          fmt=elf ;;
 207       arm-*-kaos*)                      fmt=elf ;;
 208       arm*-*-conix*)                    fmt=elf ;;
 209       arm-*-linux*aout*)                fmt=aout em=linux ;;
 210       arm*-*-linux-gnu*)                fmt=elf  em=linux ;;
 211       arm*-*-uclinux*)                  fmt=elf  em=linux ;;
 212       arm-*-netbsdelf*)                 fmt=elf  em=nbsd ;;
 213       arm-*-*n*bsd*)                    fmt=aout em=nbsd ;;
 214       arm-**-nto*)                      fmt=elf ;;
 215       arm-*-oabi | thumb-*-oabi)        fmt=elf ;;
 216       arm-epoc-pe | thumb-epoc-pe)      fmt=coff em=epoc-pe ;;
 217       arm-*-wince)                      fmt=coff em=wince-pe ;;
 218       arm-*-pe | thumb-*-pe)            fmt=coff em=pe ;;
 219       arm-*-riscix*)                    fmt=aout em=riscix ;;
 220
 221       avr-*-*)                          fmt=elf ;;
 222
 223       cris-*-linux-gnu*)                fmt=multi bfd_gas=yes em=linux ;;
 224       cris-*-*)                         fmt=multi bfd_gas=yes ;;
 225
 226       d10v-*-*)                         fmt=elf ;;
 227       d30v-*-*)                         fmt=elf ;;
 228       dlx-*-*)                          fmt=elf ;;
 229
 230       fr30-*-*)                         fmt=elf ;;
 231       frv-*-*)                          fmt=elf ;;
 232
 233       hppa-*-linux*)    case ${cpu} in
 234                             hppa*64*)   fmt=elf em=hppalinux64;;
 235                             hppa*)      fmt=elf em=linux;;
 236                         esac ;;
 237       hppa-*-*elf*)                     fmt=elf em=hppa ;;
 238       hppa-*-lites*)                    fmt=elf em=hppa ;;
 239       hppa-*-netbsd*)                   fmt=elf em=nbsd ;;
 240       hppa-*-openbsd*)                  fmt=elf em=hppa ;;
 241       hppa-*-osf*)                      fmt=som em=hppa ;;
 242       hppa-*-rtems*)                    fmt=elf em=hppa ;;
 243       hppa-*-hpux11*)   case ${cpu} in
 244                             hppa*64*)   fmt=elf em=hppa64 ;;
 245                             hppa*)      fmt=som em=hppa ;;
 246                         esac ;;
 247       hppa-*-hpux*)                     fmt=som em=hppa ;;
 248       hppa-*-mpeix*)                    fmt=som em=hppa ;;
 249       hppa-*-bsd*)                      fmt=som em=hppa ;;
 250       hppa-*-hiux*)                     fmt=som em=hppa ;;
 251
 252       h8300-*-rtems*)                   fmt=coff ;;
 253       h8300-*-coff)                     fmt=coff ;;
 254       h8300-*-elf)                      fmt=elf ;;
 255       h8500-*-rtems*)                   fmt=coff ;;
 256       h8500-*-coff)                     fmt=coff ;;
 257
 258       i370-*-elf* | i370-*-linux*)      fmt=elf ;;
 259       i386-ibm-aix*)                    fmt=coff em=i386aix ;;
 260       i386-sequent-bsd*)                fmt=aout em=dynix ;;
 261       i386-*-beospe*)                   fmt=coff em=pe ;;
 262       i386-*-beos*)                     fmt=elf ;;
 263       i386-*-coff)                      fmt=coff ;;
 264       i386-*-elf)                       fmt=elf ;;
 265       i386-*-kaos*)                     fmt=elf ;;
 266       i386-*-bsd*)                      fmt=aout em=386bsd ;;
 267       i386-*-netbsd0.8)                 fmt=aout em=386bsd ;;
 268       i386-*-netbsdpe*)                 fmt=coff em=pe ;;
 269       i386-*-netbsd*-gnu* | \
 270       i386-*-knetbsd*-gnu | \
 271       i386-*-netbsdelf*)                fmt=elf em=nbsd ;;
 272       i386-*-*n*bsd*)   case ${cpu} in
 273                             x86_64)     fmt=elf em=nbsd ;;
 274                             *)          fmt=aout em=nbsd ;;
 275                         esac ;;
 276       i386-*-linux*aout*)               fmt=aout em=linux ;;
 277       i386-*-linux*oldld)               fmt=aout em=linux ;;
 278       i386-*-linux*coff*)               fmt=coff em=linux ;;
 279       i386-*-linux-gnu*)                fmt=elf em=linux ;;
 280       x86_64-*-linux-gnu*)              fmt=elf em=linux ;;
 281       i386-*-lynxos*)                   fmt=coff em=lynx ;;
 282 changequote(,)dnl
 283       i386-*-sysv[45]*)                 fmt=elf ;;
 284       i386-*-solaris*)                  fmt=elf ;;
 285       i386-*-freebsdaout*)              fmt=aout em=386bsd ;;
 286       i386-*-freebsd[12].*)             fmt=aout em=386bsd ;;
 287       i386-*-freebsd[12])               fmt=aout em=386bsd ;;
 288 changequote([,])dnl
 289       i386-*-freebsd* | i386-*-kfreebsd*-gnu)
 290                                         fmt=elf em=freebsd ;;
 291       i386-*-sysv*)                     fmt=coff ;;
 292       i386-*-sco3.2v5*coff)             fmt=coff ;;
 293       i386-*-isc*)                      fmt=coff ;;
 294       i386-*-sco3.2v5*)                 fmt=elf
 295           if test ${this_target} = $target; then
 296             AC_DEFINE(SCO_ELF, 1, [Define if defaulting to ELF on SCO 5.])
 297           fi ;;
 298       i386-*-sco3.2*)                   fmt=coff ;;
 299       i386-*-vsta)                      fmt=aout ;;
 300       i386-*-msdosdjgpp* \
 301       | i386-*-go32* \
 302       | i386-go32-rtems*)               fmt=coff em=go32
 303             AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?]) ;;
 304       i386-*-rtemself*)                 fmt=elf ;;
 305       i386-*-rtemscoff*)                fmt=coff ;;
 306       i386-*-rtems*)                    fmt=elf ;;
 307       i386-*-gnu*)                      fmt=elf ;;
 308       i386-*-mach*)                     fmt=aout em=mach ;;
 309       i386-*-msdos*)                    fmt=aout ;;
 310       i386-*-moss*)                     fmt=elf ;;
 311       i386-*-pe)                        fmt=coff em=pe ;;
 312       i386-*-cygwin*)                   fmt=coff em=pe ;;
 313       i386-*-interix*)                  fmt=coff em=interix ;;
 314       i386-*-mingw32*)                  fmt=coff em=pe ;;
 315       i386-*-nto-qnx*)                  fmt=elf ;;
 316       i386-*-*nt*)                      fmt=coff em=pe ;;
 317       i386-*-chaos)                     fmt=elf ;;
 318
 319       i860-*-*)                         fmt=elf endian=little
 320                 AC_MSG_WARN(GAS support for ${generic_target} is preliminary and a work in progress) ;;
 321       i960-*-bout)                      fmt=bout ;;
 322       i960-*-coff)                      fmt=coff em=ic960 ;;
 323       i960-*-rtems*)                    fmt=coff em=ic960 ;;
 324       i960-*-nindy*)                    fmt=bout ;;
 325       i960-*-vxworks5.0)                fmt=bout ;;
 326       i960-*-vxworks5.*)                fmt=coff em=ic960 ;;
 327       i960-*-vxworks*)                  fmt=bout ;;
 328       i960-*-elf*)                      fmt=elf ;;
 329
 330       ia64-*-elf*)                      fmt=elf ;;
 331       ia64-*-aix*)                      fmt=elf em=ia64aix ;;
 332       ia64-*-linux-gnu*)                fmt=elf em=linux ;;
 333       ia64-*-hpux*)                     fmt=elf em=hpux ;;
 334       ia64-*-netbsd*)                   fmt=elf em=nbsd ;;
 335
 336       ip2k-*-*)                         fmt=elf ;;
 337
 338       iq2000-*-elf)                     fmt=elf bfd_gas=yes ;;
 339
 340       m32r-*-*)                         fmt=elf ;;
 341
 342       m68hc11-*-* | m6811-*-*)          fmt=elf ;;
 343       m68hc12-*-* | m6812-*-*)          fmt=elf ;;
 344
 345       m68k-*-vxworks*)                  fmt=aout em=sun3 ;;
 346       m68k-ericsson-ose)                fmt=aout em=sun3 ;;
 347       m68k-*-sunos*)                    fmt=aout em=sun3 ;;
 348       m68k-motorola-sysv*)              fmt=coff em=delta ;;
 349       m68k-bull-sysv3*)                 fmt=coff em=dpx2 ;;
 350       m68k-apollo-*)                    fmt=coff em=apollo ;;
 351       m68k-*-elf*)                      fmt=elf ;;
 352       m68k-*-sysv4*)                    fmt=elf em=svr4 ;;
 353       m68k-*-sysv*)                     fmt=coff ;;
 354       m68k-*-coff | m68k-*-rtemscoff*)  fmt=coff ;;
 355       m68k-*-rtems*)                    fmt=elf ;;
 356       m68k-*-hpux*)                     fmt=hp300 em=hp300 ;;
 357       m68k-*-linux*aout*)               fmt=aout em=linux ;;
 358       m68k-*-linux-gnu*)                fmt=elf em=linux ;;
 359       m68k-*-gnu*)                      fmt=elf ;;
 360       m68k-*-lynxos*)                   fmt=coff em=lynx ;;
 361       m68k-*-netbsdelf*)                fmt=elf em=nbsd ;;
 362       m68k-*-netbsd*)                   fmt=aout em=nbsd bfd_gas=yes ;;
 363       m68k-*-openbsd*)                  fmt=aout em=nbsd bfd_gas=yes ;;
 364       m68k-apple-aux*)                  fmt=coff em=aux ;;
 365       m68k-*-psos*)                     fmt=elf em=psos;;
 366
 367       m88k-motorola-sysv3*)             fmt=coff em=delt88 ;;
 368       m88k-*-coff*)                     fmt=coff ;;
 369
 370       mcore-*-elf)                      fmt=elf ;;
 371       mcore-*-pe)                       fmt=coff em=pe bfd_gas=yes ;;
 372
 373       # don't change em like *-*-bsd does
 374       mips-dec-openbsd*)                fmt=elf endian=little ;;
 375       mips-dec-bsd*)                    fmt=aout endian=little ;;
 376       mips-sony-bsd*)                   fmt=ecoff ;;
 377       mips-*-bsd*)
 378             AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.) ;;
 379       mips-*-ultrix*)                   fmt=ecoff endian=little ;;
 380       mips-*-osf*)                      fmt=ecoff endian=little ;;
 381       mips-*-ecoff*)                    fmt=ecoff ;;
 382       mips-*-pe*)                       fmt=coff endian=little em=pe ;;
 383       mips-*-irix6*)                    fmt=elf em=irix ;;
 384       mips-*-irix5*)                    fmt=elf em=irix ;;
 385       mips-*-irix*)                     fmt=ecoff em=irix ;;
 386       mips-*-lnews*)                    fmt=ecoff em=lnews ;;
 387       mips-*-riscos*)                   fmt=ecoff ;;
 388       mips*-*-linux*)                   fmt=elf em=tmips ;;
 389       mips-*-sysv4*MP* | mips-*-gnu*)   fmt=elf em=tmips ;;
 390       mips-*-sysv*)                     fmt=ecoff ;;
 391       mips-*-elf* | mips-*-rtems*)      fmt=elf ;;
 392       mips-*-netbsd*)                   fmt=elf ;;
 393       mips-*-openbsd*)                  fmt=elf ;;
 394
 395       mmix-*-*)                         fmt=elf ;;
 396       mn10200-*-*)                      fmt=elf ;;
 397       mn10300-*-*)                      fmt=elf ;;
 398       msp430-*-*)                       fmt=elf ;;
 399       openrisc-*-*)                     fmt=elf ;;
 400       or32-*-rtems*)                    fmt=coff ;;
 401       or32-*-coff)                      fmt=coff ;;
 402       or32-*-elf)                       fmt=elf ;;
 403       pj*)                              fmt=elf ;;
 404
 405       ppc-*-pe | ppc-*-cygwin*)         fmt=coff em=pe ;;
 406       ppc-*-winnt*)                     fmt=coff em=pe ;;
 407       ppc-*-aix5*)                      fmt=coff em=aix5 ;;
 408       ppc-*-aix*)                       fmt=coff ;;
 409       ppc-*-beos*)                      fmt=coff ;;
 410       ppc-*-*n*bsd* | ppc-*-elf*)       fmt=elf ;;
 411       ppc-*-eabi* | ppc-*-sysv4*)       fmt=elf ;;
 412       ppc-*-linux-gnu*)                 fmt=elf em=linux
 413             case "$endian" in
 414                 big)  ;;
 415                 *)    AC_MSG_ERROR(GNU/Linux must be configured big endian) ;;
 416             esac ;;
 417       ppc-*-solaris*)                   fmt=elf
 418             if test ${this_target} = $target; then
 419                 AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 420                           [Define if default target is PowerPC Solaris.])
 421             fi
 422             if test x${endian} = xbig; then
 423                 AC_MSG_ERROR(Solaris must be configured little endian)
 424             fi ;;
 425       ppc-*-rtems*)                     fmt=elf ;;
 426       ppc-*-macos* | ppc-*-mpw*)        fmt=coff em=macos ;;
 427       ppc-*-netware*)                   fmt=elf em=ppcnw ;;
 428       ppc-**-nto*)                      fmt=elf ;;
 429       ppc-*-kaos*)                      fmt=elf ;;
 430
 431       s390x-*-linux-gnu*)               fmt=elf em=linux ;;
 432       s390-*-linux-gnu*)                fmt=elf em=linux ;;
 433
 434       sh*-*-linux*)                     fmt=elf em=linux
 435             case ${cpu} in
 436                 sh*eb)  endian=big ;;
 437                 *)      endian=little ;;
 438             esac ;;
 439       sh5*-*-netbsd*)                   fmt=elf em=nbsd ;;
 440       sh64*-*-netbsd*)                  fmt=elf em=nbsd ;;
 441       sh*-*-netbsdelf*)                 fmt=elf em=nbsd ;;
 442       sh-*-elf*)                        fmt=elf ;;
 443       sh-*-coff*)                       fmt=coff ;;
 444       sh-*-nto*)                        fmt=elf ;;
 445       sh-*-pe*)                         fmt=coff em=pe bfd_gas=yes endian=little ;;
 446       sh-*-rtemself*)                   fmt=elf ;;
 447       sh-*-rtems*)                      fmt=coff ;;
 448       sh-*-kaos*)                       fmt=elf ;;
 449       shle*-*-kaos*)                    fmt=elf ;;
 450       sh64-*-elf*)                      fmt=elf ;;
 451
 452       ns32k-pc532-mach*)                fmt=aout em=pc532mach ;;
 453       ns32k-pc532-ux*)                  fmt=aout em=pc532mach ;;
 454       ns32k-pc532-lites*)               fmt=aout em=nbsd532 ;;
 455       ns32k-*-*n*bsd*)                  fmt=aout em=nbsd532 ;;
 456
 457       sparc-*-rtemsaout*)               fmt=aout ;;
 458       sparc-*-rtemself*)                fmt=elf ;;
 459       sparc-*-rtems*)                   fmt=elf ;;
 460       sparc-*-sunos4*)                  fmt=aout em=sun3 ;;
 461       sparc-*-aout | sparc*-*-vxworks*) fmt=aout em=sparcaout ;;
 462       sparc-*-coff)                     fmt=coff ;;
 463       sparc-*-linux*aout*)              fmt=aout em=linux ;;
 464       sparc-*-linux-gnu*)               fmt=elf em=linux ;;
 465       sparc-*-lynxos*)                  fmt=coff em=lynx ;;
 466       sparc-fujitsu-none)               fmt=aout ;;
 467       sparc-*-elf)                      fmt=elf ;;
 468       sparc-*-sysv4*)                   fmt=elf ;;
 469       sparc-*-solaris*)                 fmt=elf ;;
 470       sparc-*-netbsdelf*)               fmt=elf em=nbsd ;;
 471       sparc-*-*n*bsd*)  case ${cpu} in
 472                             sparc64)    fmt=elf em=nbsd ;;
 473                             *)          fmt=aout em=nbsd ;;
 474                         esac ;;
 475       strongarm-*-coff)                 fmt=coff ;;
 476       strongarm-*-elf)                  fmt=elf ;;
 477       strongarm-*-kaos*)                fmt=elf ;;
 478       xscale-*-coff)                    fmt=coff ;;
 479       xscale-*-elf)                     fmt=elf ;;
 480
 481       tic30-*-*aout*)                   fmt=aout bfd_gas=yes ;;
 482       tic30-*-*coff*)                   fmt=coff bfd_gas=yes ;;
 483       tic4x-*-* | c4x-*-*)              fmt=coff bfd_gas=yes ;;
 484       tic54x-*-* | c54x*-*-*)           fmt=coff bfd_gas=yes need_libm=yes;;
 485       tic80-*-*)                        fmt=coff ;;
 486
 487       v850-*-*)                         fmt=elf ;;
 488       v850e-*-*)                        fmt=elf ;;
 489       v850ea-*-*)                       fmt=elf ;;
 490
 491       vax-*-netbsdelf*)                 fmt=elf em=nbsd ;;
 492       vax-*-netbsd*)                    fmt=aout em=nbsd ;;
 493       vax-*-bsd* | vax-*-ultrix*)       fmt=aout ;;
 494       vax-*-vms)                        fmt=vms ;;
 495
 496       w65-*-*)                          fmt=coff ;;
 497
 498       xstormy16-*-*)                    fmt=elf ;;
 499
 500       xtensa-*-*)                       fmt=elf ;;
 501
 502       z8k-*-coff | z8k-*-sim)           fmt=coff ;;
 503
 504       *-*-aout | *-*-scout)             fmt=aout ;;
 505       *-*-freebsd* | *-*-kfreebsd*-gnu) fmt=elf em=freebsd ;;
 506       *-*-nindy*)                       fmt=bout ;;
 507       *-*-bsd*)                         fmt=aout em=sun3 ;;
 508       *-*-generic)                      fmt=generic ;;
 509       *-*-xray | *-*-hms)               fmt=coff ;;
 510       *-*-sim)                          fmt=coff ;;
 511       *-*-elf | *-*-sysv4* | *-*-solaris*) fmt=elf dev=yes ;;
 512       *-*-aros*)                        fmt=elf em=linux bfd_gas=yes ;;
 513       *-*-vxworks | *-*-windiss)        fmt=elf ;;
 514       *-*-netware)                      fmt=elf ;;
 515     esac
 516
 517     if test ${this_target} = $target ; then
 518       endian_def=
 519       if test x${endian} = xbig; then
 520         endian_def=1
 521       elif test x${endian} = xlittle; then
 522         endian_def=0
 523       fi
 524       if test x${endian_def} != x; then
 525         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 526                            [Define as 1 if big endian.])
 527       fi
 528     fi
 529
 530     case ${cpu_type}-${fmt} in
 531         alpha*-* | arm-* | i386-* | ia64*-* | mips-* | ns32k-* \
 532                 | pdp11-* | ppc-* | sparc-* | strongarm-* | xscale-* \
 533                 | *-elf | *-ecoff | *-som)
 534             bfd_gas=yes ;;
 535     esac
 536
 537 # Other random stuff.
 538
 539     case ${cpu_type} in
 540       mips)
 541         # Set mips_cpu to the name of the default CPU.
 542         case ${target_cpu} in
 543           mips | mipsbe | mipseb | mipsle | mipsel | mips64 | mips64el)
 544             mips_cpu=from-abi
 545             ;;
 546           mipsisa32 | mipsisa32el)
 547             mips_cpu=mips32
 548             ;;
 549           mipsisa32r2 | mipsisa32r2el)
 550             mips_cpu=mips32r2
 551             ;;
 552           mipsisa64 | mipsisa64el)
 553             mips_cpu=mips64
 554             ;;
 555           mipsisa64r2 | mipsisa64r2el)
 556             mips_cpu=mips64r2
 557             ;;
 558           mipstx39 | mipstx39el)
 559             mips_cpu=r3900
 560             ;;
 561           mips64vr | mips64vrel)
 562             mips_cpu=vr4100
 563             ;;
 564           mipsisa32r2* | mipsisa64r2*)
 565 changequote(,)dnl
 566             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r2//' -e 's/el$//'`
 567 changequote([,])dnl
 568             ;;
 569           mips64* | mipsisa64* | mipsisa32*)
 570 changequote(,)dnl
 571             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..//' -e 's/el$//'`
 572 changequote([,])dnl
 573             ;;
 574           *)
 575             AC_ERROR($target_cpu isn't a supported MIPS CPU name)
 576             ;;
 577         esac
 578         # See whether it's appropriate to set E_MIPS_ABI_O32 for o32
 579         # binaries.  It's a GNU extension that some OSes don't understand.
 580         # The value only matters on ELF targets.
 581         case ${target} in
 582           *-*-irix*)
 583             use_e_mips_abi_o32=0
 584             ;;
 585           *)
 586             use_e_mips_abi_o32=1
 587             ;;
 588         esac
 589         # Decide whether to generate 32-bit or 64-bit code by default.
 590         # Used to resolve -march=from-abi when an embedded ABI is selected.
 591         case ${target} in
 592           mips64*-*-* | mipsisa64*-*-*)
 593             mips_default_64bit=1
 594             ;;
 595           *)
 596             mips_default_64bit=0
 597             ;;
 598         esac
 599         # Decide which ABI to target by default.
 600         case ${target} in
 601           mips64*-linux* | mips-sgi-irix6*)
 602             mips_default_abi=N32_ABI
 603             ;;
 604           mips*-linux*)
 605             mips_default_abi=O32_ABI
 606             ;;
 607           *)
 608             mips_default_abi=NO_ABI
 609             ;;
 610         esac
 611         AC_DEFINE_UNQUOTED(MIPS_CPU_STRING_DEFAULT, "$mips_cpu",
 612                            [Default CPU for MIPS targets. ])
 613         AC_DEFINE_UNQUOTED(USE_E_MIPS_ABI_O32, $use_e_mips_abi_o32,
 614                            [Allow use of E_MIPS_ABI_O32 on MIPS targets. ])
 615         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_64BIT, $mips_default_64bit,
 616                            [Generate 64-bit code by default on MIPS targets. ])
 617         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_ABI, $mips_default_abi,
 618                            [Choose a default ABI for MIPS targets. ])
 619         ;;
 620     esac
 621
 622     # Do we need the opcodes library?
 623     case ${cpu_type} in
 624       vax | i386 | tic30)
 625         ;;
 626
 627       *)
 628         need_opcodes=yes
 629
 630         case "${enable_shared}" in
 631         yes) shared_opcodes=true ;;
 632         *opcodes*) shared_opcodes=true ;;
 633         *) shared_opcodes=false ;;
 634         esac
 635         if test "${shared_opcodes}" = "true"; then
 636           # A shared libopcodes must be linked against libbfd.
 637           need_bfd=yes
 638         fi
 639         ;;
 640     esac
 641
 642     # Any other special object files needed ?
 643     case ${cpu_type} in
 644       fr30 | ip2k | iq2000 | m32r | openrisc)
 645         using_cgen=yes
 646         ;;
 647
 648       frv)
 649         using_cgen=yes
 650         ;;
 651       m68k)
 652         case ${extra_objects} in
 653         *m68k-parse.o*) ;;
 654         *) extra_objects="$extra_objects m68k-parse.o" ;;
 655         esac
 656         ;;
 657
 658       mips)
 659         echo ${extra_objects} | grep -s "itbl-parse.o"
 660         if test $? -ne 0 ; then
 661           extra_objects="$extra_objects itbl-parse.o"
 662         fi
 663
 664         echo ${extra_objects} | grep -s "itbl-lex.o"
 665         if test $? -ne 0 ; then
 666           extra_objects="$extra_objects itbl-lex.o"
 667         fi
 668
 669         echo ${extra_objects} | grep -s "itbl-ops.o"
 670         if test $? -ne 0 ; then
 671           extra_objects="$extra_objects itbl-ops.o"
 672         fi
 673         ;;
 674
 675       i386 | s390 | sparc)
 676         if test $this_target = $target ; then
 677           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 678         fi
 679         ;;
 680
 681       xstormy16)
 682         using_cgen=yes
 683         ;;
 684
 685       xtensa)
 686         echo ${extra_objects} | grep -s "xtensa-relax.o"
 687         if test $? -ne 0 ; then
 688           extra_objects="$extra_objects xtensa-relax.o"
 689         fi
 690         ;;
 691
 692       *)
 693         ;;
 694     esac
 695
 696     if test $using_cgen = yes ; then
 697         case "x${extra_objects}" in
 698         *cgen.o*) ;;
 699         *) extra_objects="$extra_objects cgen.o" ;;
 700         esac
 701     fi
 702
 703 # See if we really can support this configuration with the emulation code.
 704
 705     if test $this_target = $target ; then
 706       primary_bfd_gas=$bfd_gas
 707       obj_format=$fmt
 708       te_file=$em
 709
 710       if test $bfd_gas = no ; then
 711         # Can't support other configurations this way.
 712         break
 713       fi
 714     elif test $bfd_gas = no ; then
 715       # Can't support this configuration.
 716       break
 717     fi
 718
 719 # From target name and format, produce a list of supported emulations.
 720
 721     case ${generic_target}-${fmt} in
 722       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 723       mips*-*-linux*-*) case "$endian" in
 724                         big)    emulation="mipsbelf mipslelf mipself" ;;
 725                         *)      emulation="mipslelf mipsbelf mipself" ;;
 726                         esac ;;
 727       mips-*-lnews*-ecoff) ;;
 728       mips-*-*-ecoff)   case "$endian" in
 729                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 730                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 731                         esac ;;
 732       mips-*-*-elf)     case "$endian" in
 733                         big)    emulation="mipsbelf mipslelf mipself" ;;
 734                         *)      emulation="mipslelf mipsbelf mipself" ;;
 735                         esac ;;
 736       mips-*-sysv4*MP*-*) emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 737       # i386-pc-pe-coff != i386-pc-coff.
 738       i386-*-pe-coff)   ;;
 739       # Uncommenting the next line will turn on support for i386 AOUT
 740       # for the default linux configuration
 741       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 742       #
 743       i386-*-aout)      emulation="i386aout" ;;
 744       i386-*-coff)      emulation="i386coff" ;;
 745       i386-*-elf)       emulation="i386elf" ;;
 746
 747       # Always all formats.  The first stated emulation becomes the default.
 748       cris-*-*aout*)    emulation="crisaout criself" ;;
 749       cris-*-*)         emulation="criself crisaout" ;;
 750     esac
 751
 752     emulations="$emulations $emulation"
 753
 754 done
 755
 756 # Turn on all targets if possible
 757 if test ${all_targets} = "yes"; then
 758   case ${target_cpu_type} in
 759   i386)
 760     case ${obj_format} in
 761     aout)
 762       emulations="$emulations i386coff i386elf"
 763       ;;
 764     coff)
 765       emulations="$emulations i386aout i386elf"
 766     ;;
 767     elf)
 768       emulations="$emulations i386aout i386coff"
 769       ;;
 770     esac
 771   ;;
 772   esac
 773 fi
 774
 775 # Assign floating point type.  Most processors with FP support
 776 # IEEE FP.  On those that don't support FP at all, usually IEEE
 777 # is emulated.
 778 case ${target_cpu} in
 779   vax | tahoe ) atof=${target_cpu} ;;
 780   pdp11)        atof=vax ;;
 781   *)            atof=ieee ;;
 782 esac
 783
 784 case "${obj_format}" in
 785   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 786 esac
 787
 788 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 789 cgen_cpu_prefix=""
 790 if test $using_cgen = yes ; then
 791   case ${target_cpu} in
 792     *) cgen_cpu_prefix=${target_cpu} ;;
 793   esac
 794   AC_SUBST(cgen_cpu_prefix)
 795   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 796 fi
 797
 798 dnl
 799 dnl Make sure the desired support files exist.
 800 dnl
 801
 802 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 803   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 804 fi
 805
 806 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 807   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 808 fi
 809
 810 case ${user_bfd_gas}-${primary_bfd_gas} in
 811   yes-yes | no-no)
 812     # We didn't override user's choice.
 813     ;;
 814   no-yes)
 815     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 816     ;;
 817   no-preferred)
 818     primary_bfd_gas=no
 819     ;;
 820   *-preferred)
 821     primary_bfd_gas=yes
 822     ;;
 823   yes-*)
 824     primary_bfd_gas=yes
 825     ;;
 826   -*)
 827     # User specified nothing.
 828     ;;
 829 esac
 830
 831 # Some COFF configurations want these random other flags set.
 832 case ${obj_format} in
 833   coff)
 834     case ${target_cpu_type} in
 835       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 836       m68k) AC_DEFINE(M68KCOFF, 1, [Using m68k COFF?]) ;;
 837       m88k) AC_DEFINE(M88KCOFF, 1, [Using m88k COFF?]) ;;
 838     esac
 839     ;;
 840 esac
 841
 842 # Getting this done right is going to be a bitch.  Each configuration specified
 843 # with --enable-targets=... should be checked for environment, format, cpu, and
 844 # bfd_gas setting.
 845 #
 846 # For each configuration, the necessary object file support code must be linked
 847 # in.  This might be only one, it might be up to four.  The necessary emulation
 848 # code needs to be provided, too.
 849 #
 850 # And then there's "--enable-targets=all"....
 851 #
 852 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 853
 854 formats="${obj_format}"
 855 emfiles=""
 856 EMULATIONS=""
 857 GAS_UNIQ(emulations)
 858 for em in . $emulations ; do
 859   case $em in
 860     .)  continue ;;
 861     mipsbelf | mipslelf | mipself)
 862         fmt=elf   file=mipself ;;
 863     mipsbecoff | mipslecoff | mipsecoff)
 864         fmt=ecoff file=mipsecoff ;;
 865     *coff)
 866         fmt=coff  file=$em ;;
 867     *aout)
 868         fmt=aout file=$em ;;
 869     *elf)
 870         fmt=elf file=$em ;;
 871   esac
 872   formats="$formats $fmt"
 873   emfiles="$emfiles e-$file.o"
 874   EMULATIONS="$EMULATIONS &$em,"
 875 done
 876 GAS_UNIQ(formats)
 877 GAS_UNIQ(emfiles)
 878 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 879   for fmt in $formats ; do
 880     case $fmt in
 881       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 882       bout)     AC_DEFINE(OBJ_MAYBE_BOUT, 1,    [b.out support?])   ;;
 883       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 884       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 885       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 886       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 887       hp300)    AC_DEFINE(OBJ_MAYBE_HP300, 1,   [HP300 support?])   ;;
 888       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE, 1,    [IEEE support?])    ;;
 889       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 890       vms)      AC_DEFINE(OBJ_MAYBE_VMS, 1,     [VMS support?])     ;;
 891     esac
 892     extra_objects="$extra_objects obj-$fmt.o"
 893   done
 894   obj_format=multi
 895 fi
 896 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 897   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 898   # e-mips* has more than one emulation per file, e-i386* has just one at the
 899   # moment.  If only one emulation is specified, then don't define
 900   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 901   case "${obj_format}${emfiles}" in
 902     multi* | *mips*)
 903       extra_objects="$extra_objects $emfiles"
 904       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 905   esac
 906 fi
 907 AC_SUBST(extra_objects)
 908 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 909 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 910                    [Default emulation.])
 911
 912 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 913   yes-*-coff)   need_bfd=yes ;;
 914   no-*-coff)    need_bfd=yes
 915                 AC_DEFINE(MANY_SEGMENTS, 1, [old COFF support?]) ;;
 916 esac
 917
 918 reject_dev_configs=yes
 919
 920 case ${reject_dev_configs}-${dev} in
 921   yes-yes) # Oops.
 922     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 923     ;;
 924 esac
 925
 926 AC_SUBST(target_cpu_type)
 927 AC_SUBST(obj_format)
 928 AC_SUBST(te_file)
 929 AC_SUBST(install_tooldir)
 930 AC_SUBST(atof)
 931 dnl AC_SUBST(emulation)
 932
 933 case "${primary_bfd_gas}" in
 934   yes)  AC_DEFINE(BFD_ASSEMBLER, 1, [Use BFD interface?])
 935         need_bfd=yes ;;
 936 esac
 937
 938 # do we need the opcodes library?
 939 case "${need_opcodes}" in
 940 yes)
 941   OPCODES_LIB=../opcodes/libopcodes.la
 942   ;;
 943 esac
 944
 945 case "${need_bfd}" in
 946 yes)
 947   BFDLIB=../bfd/libbfd.la
 948   BFDVER_H=../bfd/bfdver.h
 949   ALL_OBJ_DEPS="$ALL_OBJ_DEPS"' ../bfd/bfd.h $(INCDIR)/symcat.h'
 950   ;;
 951 esac
 952
 953 AC_SUBST(BFDLIB)
 954 AC_SUBST(OPCODES_LIB)
 955
 956 AC_SUBST(BFDVER_H)
 957 AC_SUBST(ALL_OBJ_DEPS)
 958
 959 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 960 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 961 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 962 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 963 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 964
 965 AC_PROG_CC
 966
 967 AC_PROG_YACC
 968 AM_PROG_LEX
 969
 970 ALL_LINGUAS="fr tr es"
 971 CY_GNU_GETTEXT
 972
 973 AM_MAINTAINER_MODE
 974 AC_EXEEXT
 975
 976 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 977
 978 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 979 # people who are not cross-compiling but are compiling cross-assemblers.
 980 AC_MSG_CHECKING(whether compiling a cross-assembler)
 981 if test "${host}" = "${target}"; then
 982   cross_gas=no
 983 else
 984   cross_gas=yes
 985   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 986 fi
 987 AC_MSG_RESULT($cross_gas)
 988
 989 dnl ansidecl.h will deal with const
 990 dnl AC_CONST
 991 AC_FUNC_ALLOCA
 992 AC_C_INLINE
 993
 994 # VMS doesn't have unlink.
 995 AC_CHECK_FUNCS(unlink remove, break)
 996
 997 # Some systems don't have sbrk().
 998 AC_CHECK_FUNCS(sbrk)
 999
1000 # do we need the math library?
1001 case "${need_libm}" in
1002 yes)
1003   AC_CHECK_LIBM
1004   AC_SUBST(LIBM)
1005   ;;
1006 esac
1007
1008 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
1009 # enough, but on some of those systems, the assert macro relies on requoting
1010 # working properly!
1011 GAS_WORKING_ASSERT
1012
1013 # On some systems, the system header files may not declare malloc, realloc,
1014 # and free.  There are places where gas needs these functions to have been
1015 # declared -- such as when taking their addresses.
1016 gas_test_headers="
1017 #ifdef HAVE_MEMORY_H
1018 #include <memory.h>
1019 #endif
1020 #ifdef HAVE_STRING_H
1021 #include <string.h>
1022 #else
1023 #ifdef HAVE_STRINGS_H
1024 #include <strings.h>
1025 #endif
1026 #endif
1027 #ifdef HAVE_STDLIB_H
1028 #include <stdlib.h>
1029 #endif
1030 #ifdef HAVE_UNISTD_H
1031 #include <unistd.h>
1032 #endif
1033 "
1034 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
1035 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
1036 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
1037 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
1038 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
1039
1040 # Does errno.h declare errno, or do we have to add a separate declaration
1041 # for it?
1042 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
1043 #ifdef HAVE_ERRNO_H
1044 #include <errno.h>
1045 #endif
1046 ])
1047
1048 dnl This must come last.
1049
1050 dnl We used to make symlinks to files in the source directory, but now
1051 dnl we just use the right name for .c files, and create .h files in
1052 dnl the build directory which include the right .h file.  Make sure
1053 dnl the old symlinks don't exist, so that a reconfigure in an existing
1054 dnl directory behaves reasonably.
1055
1056 AC_CONFIG_FILES(Makefile doc/Makefile po/Makefile.in:po/Make-in)
1057 AC_CONFIG_COMMANDS([default],
1058 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
1059  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
1060  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
1061  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
1062  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
1063  if test "x$cgen_cpu_prefix" != x ; then
1064    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
1065  fi
1066
1067  sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile],
1068 [target_cpu_type=${target_cpu_type}
1069  cgen_cpu_prefix=${cgen_cpu_prefix}
1070  obj_format=${obj_format}
1071  te_file=${te_file}])
1072
1073 AC_OUTPUT