bfd/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3
   4 AC_PREREQ(2.13)
   5 AC_INIT(libbfd.c)
   6
   7 AC_CANONICAL_SYSTEM
   8 AC_ISC_POSIX
   9
  10 AM_INIT_AUTOMAKE(bfd, 2.9.5)
  11
  12 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  13 dnl to call AC_CHECK_PROG.
  14 AC_CHECK_TOOL(AR, ar)
  15 AC_CHECK_TOOL(RANLIB, ranlib, :)
  16
  17 dnl Default to a non shared library.  This may be overridden by the
  18 dnl configure option --enable-shared.
  19 AM_DISABLE_SHARED
  20
  21 AM_PROG_LIBTOOL
  22
  23 AC_ARG_ENABLE(64-bit-bfd,
  24 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  25 [case "${enableval}" in
  26   yes)  want64=true  ;;
  27   no)   want64=false ;;
  28   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  29 esac],[want64=false])dnl
  30 AC_ARG_ENABLE(targets,
  31 [  --enable-targets        alternative target configurations],
  32 [case "${enableval}" in
  33   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  34             ;;
  35   no)       enable_targets= ;;
  36   *)        enable_targets=$enableval ;;
  37 esac])dnl
  38 AC_ARG_ENABLE(commonbfdlib,
  39 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  40 [case "${enableval}" in
  41   yes) commonbfdlib=true ;;
  42   no)  commonbfdlib=false ;;
  43   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  44 esac])dnl
  45 AC_ARG_WITH(mmap,
  46 [  --with-mmap             try using mmap for BFD input files if available],
  47 [case "${withval}" in
  48   yes)  want_mmap=true ;;
  49   no)   want_mmap=false ;;
  50   *)    AC_MSG_ERROR(bad value ${withval} for BFD with-mmap option) ;;
  51 esac],[want_mmap=false])dnl
  52
  53 build_warnings="-W -Wall"
  54 AC_ARG_ENABLE(build-warnings,
  55 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  56 [case "${enableval}" in
  57   yes)  ;;
  58   no)   build_warnings="-w";;
  59   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  60         build_warnings="${build_warnings} ${t}";;
  61   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  62         build_warnings="${t} ${build_warnings}";;
  63   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  64 esac
  65 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  66   echo "Setting warning flags = $build_warnings" 6>&1
  67 fi])dnl
  68 WARN_CFLAGS=""
  69 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  70     WARN_CFLAGS="${build_warnings}"
  71 fi
  72 AC_SUBST(WARN_CFLAGS)
  73
  74 AM_CONFIG_HEADER(config.h:config.in)
  75
  76 if test -z "$target" ; then
  77     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  78 fi
  79 AC_ARG_PROGRAM
  80
  81 AM_MAINTAINER_MODE
  82 AC_EXEEXT
  83
  84 host64=false
  85 target64=false
  86
  87 # host stuff:
  88
  89 AC_PROG_CC
  90
  91 ALL_LINGUAS=
  92 CY_GNU_GETTEXT
  93
  94 # Permit host specific settings.
  95 . ${srcdir}/configure.host
  96
  97 AC_SUBST(HDEFINES)
  98 AC_PROG_INSTALL
  99
 100 BFD_HOST_64BIT_LONG=0
 101 BFD_HOST_64_BIT_DEFINED=0
 102 BFD_HOST_64_BIT=
 103 BFD_HOST_U_64_BIT=
 104 if test "x${HOST_64BIT_TYPE}" = "xlong"; then
 105   BFD_HOST_64BIT_LONG=1
 106 elif test "x${HOST_64BIT_TYPE}" != "x"; then
 107   BFD_HOST_64_BIT_DEFINED=1
 108   BFD_HOST_64_BIT=${HOST_64BIT_TYPE}
 109   BFD_HOST_U_64_BIT=${HOST_U_64BIT_TYPE}
 110 fi
 111 AC_SUBST(BFD_HOST_64BIT_LONG)
 112 AC_SUBST(BFD_HOST_64_BIT_DEFINED)
 113 AC_SUBST(BFD_HOST_64_BIT)
 114 AC_SUBST(BFD_HOST_U_64_BIT)
 115
 116 BFD_CC_FOR_BUILD
 117
 118 AC_CHECK_HEADERS(stddef.h string.h strings.h stdlib.h time.h unistd.h)
 119 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h)
 120 AC_HEADER_TIME
 121 AC_HEADER_DIRENT
 122 AC_CHECK_FUNCS(fcntl getpagesize setitimer sysconf fdopen getuid getgid)
 123
 124 BFD_BINARY_FOPEN
 125
 126 BFD_NEED_DECLARATION(strstr)
 127 BFD_NEED_DECLARATION(malloc)
 128 BFD_NEED_DECLARATION(realloc)
 129 BFD_NEED_DECLARATION(free)
 130 BFD_NEED_DECLARATION(getenv)
 131
 132 # If we are configured native, pick a core file support file.
 133 COREFILE=
 134 COREFLAG=
 135 TRAD_HEADER=
 136 if test "${target}" = "${host}"; then
 137   case "${host}" in
 138   alpha*-*-linux-gnu*)
 139         COREFILE=trad-core.lo
 140         TRAD_HEADER='"hosts/alphalinux.h"'
 141         ;;
 142   alpha*-*-netbsd*)     COREFILE=netbsd-core.lo ;;
 143   alpha*-*-*)           COREFILE=osf-core.lo ;;
 144   arm-*-riscix)         COREFILE=trad-core.lo ;;
 145   hppa*-*-hpux*)        COREFILE=hpux-core.lo ;;
 146   hppa*-*-hiux*)        COREFILE=hpux-core.lo ;;
 147   hppa*-*-mpeix*)       COREFILE=hpux-core.lo ;;
 148   hppa*-*-bsd*)         COREFILE="hpux-core.lo hppabsd-core.lo"
 149                         COREFLAG="-DHPUX_CORE -DHPPABSD_CORE" ;;
 150   i370-*-*)
 151         COREFILE=trad-core.lo
 152         TRAD_HEADER='"hosts/i370linux.h"'
 153         ;;
 154
 155 changequote(,)dnl
 156   i[3456]86-sequent-bsd*)
 157 changequote([,])dnl
 158         COREFILE=trad-core.lo
 159         TRAD_HEADER='"hosts/symmetry.h"'
 160         ;;
 161 changequote(,)dnl
 162   i[3456]86-sequent-sysv4*) ;;
 163   i[3456]86-sequent-sysv*)
 164 changequote([,])dnl
 165         COREFILE=trad-core.lo
 166         TRAD_HEADER='"hosts/symmetry.h"'
 167         ;;
 168 changequote(,)dnl
 169   i[3456]86-*-bsd* | i[3456]86-*-freebsd*)
 170 changequote([,])dnl
 171         COREFILE=trad-core.lo
 172         TRAD_HEADER='"hosts/i386bsd.h"'
 173         ;;
 174 changequote(,)dnl
 175   i[3456]86-*-netbsd* | i[3456]86-*-openbsd*)
 176 changequote([,])dnl
 177         COREFILE=netbsd-core.lo
 178         ;;
 179 changequote(,)dnl
 180   i[3456]86-esix-sysv3*)
 181 changequote([,])dnl
 182         COREFILE=trad-core.lo
 183         TRAD_HEADER='"hosts/esix.h"'
 184         ;;
 185 changequote(,)dnl
 186   i[3456]86-*-sco3.2v5*)
 187 changequote([,])dnl
 188         COREFILE=sco5-core.lo
 189         ;;
 190 changequote(,)dnl
 191   i[3456]86-*-sco* | i[3456]86-*-isc*)
 192 changequote([,])dnl
 193         COREFILE=trad-core.lo
 194         TRAD_HEADER='"hosts/i386sco.h"'
 195         ;;
 196 changequote(,)dnl
 197   i[3456]86-*-mach3*)
 198 changequote([,])dnl
 199         COREFILE=trad-core.lo
 200         TRAD_HEADER='"hosts/i386mach3.h"'
 201         ;;
 202 changequote(,)dnl
 203   i[3456]86-*-linux-gnu*)
 204 changequote([,])dnl
 205         COREFILE=trad-core.lo
 206         TRAD_HEADER='"hosts/i386linux.h"'
 207         ;;
 208 changequote(,)dnl
 209   i[3456]86-*-isc*)     COREFILE=trad-core.lo ;;
 210   i[3456]86-*-aix*)     COREFILE=aix386-core.lo ;;
 211 changequote([,])dnl
 212   i860-*-mach3* | i860-*-osf1*)
 213         COREFILE=trad-core.lo
 214         TRAD_HEADER='"hosts/i860mach3.h"'
 215         ;;
 216   mips-dec-bsd*)
 217         COREFILE=trad-core.lo
 218         TRAD_HEADER='"hosts/mipsbsd.h"'
 219         ;;
 220   mips-dec-mach3*)
 221         COREFILE=trad-core.lo
 222         TRAD_HEADER='"hosts/mipsmach3.h"'
 223         ;;
 224   mips-*-netbsd* | mips*-*-openbsd*)
 225         COREFILE=netbsd-core.lo
 226         ;;
 227   mips-dec-*)
 228         COREFILE=trad-core.lo
 229         TRAD_HEADER='"hosts/decstation.h"'
 230         ;;
 231   mips-sgi-irix4*)      COREFILE=irix-core.lo ;;
 232   mips-sgi-irix5*)      COREFILE=irix-core.lo ;;
 233   mips-sgi-irix6*)      COREFILE=irix-core.lo ;;
 234   mips-*-mach3*)
 235         COREFILE=trad-core.lo
 236         TRAD_HEADER='"hosts/mipsmach3.h"'
 237         ;;
 238   mips-*-sysv4*)        ;;
 239   mips-*-sysv* | mips-*-riscos*)
 240         COREFILE=trad-core.lo
 241         TRAD_HEADER='"hosts/riscos.h"'
 242         ;;
 243   mips-sony-bsd*)
 244         COREFILE=trad-core.lo
 245         TRAD_HEADER='"hosts/news-mips.h"'
 246         ;;
 247   m68*-bull*-sysv*)
 248         COREFILE=trad-core.lo
 249         TRAD_HEADER='"hosts/dpx2.h"'
 250         ;;
 251   m68*-hp-hpux*)        COREFILE=hpux-core.lo ;;
 252   m68*-hp-bsd*)
 253         COREFILE=trad-core.lo
 254         TRAD_HEADER='"hosts/hp300bsd.h"'
 255         ;;
 256   m68*-*-linux-gnu*)
 257         COREFILE=trad-core.lo
 258         TRAD_HEADER='"hosts/m68klinux.h"'
 259         ;;
 260   m68*-motorola-sysv*)
 261         COREFILE=trad-core.lo
 262         TRAD_HEADER='"hosts/delta68.h"'
 263         ;;
 264   m68*-sony-*)
 265         COREFILE=trad-core.lo
 266         TRAD_HEADER='"hosts/news.h"'
 267         ;;
 268   m68*-*-netbsd* | m68*-*-openbsd*)
 269         COREFILE=netbsd-core.lo
 270         ;;
 271   m68*-apple-aux*)
 272         COREFILE=trad-core.lo
 273         TRAD_HEADER='"hosts/m68kaux.h"'
 274         ;;
 275   m88*-*-sysv4*)        ;;
 276   m88*-motorola-sysv*)  COREFILE=ptrace-core.lo ;;
 277   m88*-*-mach3*)
 278         COREFILE=trad-core.lo
 279         TRAD_HEADER='"hosts/m88kmach3.h"'
 280         ;;
 281   ns32k-pc532-mach)
 282         COREFILE=trad-core.lo
 283         TRAD_HEADER='"hosts/pc532mach.h"'
 284         ;;
 285   ns32k-*-netbsd* | ns32k-*-openbsd*)
 286         COREFILE=netbsd-core.lo
 287         ;;
 288   rs6000-*-lynx*)       COREFILE=lynx-core.lo ;;
 289 changequote(,)dnl
 290   rs6000-*-aix4.[3-9]* | powerpc-*-aix4.[3-9]*)
 291 changequote([,])dnl
 292         COREFILE=rs6000-core.lo
 293         COREFLAG="$COREFLAG -DAIX_CORE_DUMPX_CORE"
 294         ;;
 295   rs6000-*-aix4*)       COREFILE=rs6000-core.lo ;;
 296   rs6000-*-*)           COREFILE=rs6000-core.lo ;;
 297   powerpc-*-*bsd*)      COREFILE=netbsd-core.lo ;;
 298   powerpc-*-aix4*)      COREFILE=rs6000-core.lo ;;
 299   powerpc-*-aix*)       COREFILE=rs6000-core.lo ;;
 300   powerpc-*-beos*)      ;;
 301   powerpc-*-netbsd*)    COREFILE=netbsd-core.lo ;;
 302   sparc-*-netbsd* | sparc-*-openbsd*)
 303         COREFILE=netbsd-core.lo
 304         ;;
 305   tahoe-*-*)
 306         COREFILE=trad-core.lo
 307         TRAD_HEADER='"hosts/tahoe.h"'
 308         ;;
 309   vax-*-ultrix2*)
 310         COREFILE=trad-core.lo
 311         TRAD_HEADER='"hosts/vaxult2.h"'
 312         ;;
 313   vax-*-ultrix*)
 314         COREFILE=trad-core.lo
 315         TRAD_HEADER='"hosts/vaxult2.h"'
 316         ;;
 317   vax-*-*)
 318         COREFILE=trad-core.lo
 319         TRAD_HEADER='"hosts/vaxbsd.h"'
 320         ;;
 321   esac
 322
 323   case "$COREFILE" in
 324   aix386-core.lo)       COREFLAG=-DAIX386_CORE ;;
 325   hppabsd-core.lo)      COREFLAG=-DHPPABSD_CORE ;;
 326   hpux-core.lo)         COREFLAG=-DHPUX_CORE ;;
 327   irix-core.lo)         COREFLAG=-DIRIX_CORE ;;
 328   lynx-core.lo)         COREFLAG=-DLYNX_CORE ;;
 329   netbsd-core.lo)       COREFLAG=-DNETBSD_CORE ;;
 330   osf-core.lo)          COREFLAG=-DOSF_CORE ;;
 331   ptrace-core.lo)       COREFLAG=-DPTRACE_CORE ;;
 332   rs6000-core.lo)       COREFLAG="$COREFLAG -DAIX_CORE" ;;
 333   sco5-core.lo)         COREFLAG="$COREFLAG -DSCO5_CORE" ;;
 334   trad-core.lo)         COREFLAG="$COREFLAG -DTRAD_CORE" ;;
 335   esac
 336
 337   # ELF corefile support has several flavors, but all of
 338   # them use something called <sys/procfs.h>
 339   AC_CHECK_HEADERS(sys/procfs.h)
 340   if test "$ac_cv_header_sys_procfs_h" = yes; then
 341     BFD_HAVE_SYS_PROCFS_TYPE(prstatus_t)
 342     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(prstatus_t, pr_who)
 343     BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 344     BFD_HAVE_SYS_PROCFS_TYPE(prpsinfo_t)
 345     BFD_HAVE_SYS_PROCFS_TYPE(psinfo_t)
 346     BFD_HAVE_SYS_PROCFS_TYPE(lwpstatus_t)
 347     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_context)
 348     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_reg)
 349     BFD_HAVE_SYS_PROCFS_TYPE(win32_pstatus_t)
 350   fi
 351 fi
 352 AC_SUBST(COREFILE)
 353 AC_SUBST(COREFLAG)
 354 if test -n "$TRAD_HEADER"; then
 355   AC_DEFINE_UNQUOTED(TRAD_HEADER, $TRAD_HEADER,
 356     [Name of host specific header file to include in trad-core.c.])
 357 fi
 358
 359 # Horrible hacks to build DLLs on Windows.
 360 WIN32LDFLAGS=
 361 WIN32LIBADD=
 362 case "${host}" in
 363 *-*-cygwin*)
 364   if test "$enable_shared" = "yes"; then
 365     WIN32LDFLAGS="-no-undefined"
 366     WIN32LIBADD="-L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin -lkernel32"
 367   fi
 368   ;;
 369 esac
 370 AC_SUBST(WIN32LDFLAGS)
 371 AC_SUBST(WIN32LIBADD)
 372
 373 # target stuff:
 374
 375 # Canonicalize the secondary target names.
 376 if test -n "$enable_targets" ; then
 377     for targ in `echo $enable_targets | sed 's/,/ /g'`
 378     do
 379         result=`$ac_config_sub $targ 2>/dev/null`
 380         if test -n "$result" ; then
 381             canon_targets="$canon_targets $result"
 382         else
 383             # Allow targets that config.sub doesn't recognize, like "all".
 384             canon_targets="$canon_targets $targ"
 385         fi
 386     done
 387 fi
 388
 389 all_targets=false
 390 defvec=
 391 selvecs=
 392 selarchs=
 393 TDEFINES=
 394 for targ in $target $canon_targets
 395 do
 396     if test "x$targ" = "xall"; then
 397         all_targets=true
 398     else
 399         . $srcdir/config.bfd
 400         if test "x$targ" = "x$target"; then
 401             defvec=$targ_defvec
 402         fi
 403         selvecs="$selvecs $targ_defvec $targ_selvecs"
 404         selarchs="$selarchs $targ_archs"
 405         TDEFINES="$TDEFINES $targ_cflags"
 406     fi
 407 done
 408 AC_SUBST(TDEFINES)
 409
 410 # This processing still needs to be done if we're to decide properly whether
 411 # 64-bit support needs to be compiled in.  Currently, it will be included if
 412 # the default or any other explicitly requested target requires it; it
 413 # will not be included on a 32-bit host if no 64-bit target is requested, and
 414 # no "--with-64-bit-bfd" option is given, even if "--enable-targets=all" is
 415 # used.
 416
 417 # uniq the default and selected vectors in all the configured targets.
 418 f=""
 419 for i in $selvecs ; do
 420     case " $f " in
 421     *" $i "*) ;;
 422     *) f="$f $i" ;;
 423     esac
 424 done
 425 selvecs="$f"
 426
 427
 428 # uniq the architectures in all the configured targets.
 429 f=""
 430 for i in $selarchs ; do
 431     case " $f " in
 432     *" $i "*) ;;
 433     *) f="$f $i" ;;
 434     esac
 435 done
 436 selarchs="$f"
 437
 438 # Target backend .o files.
 439 tb=
 440
 441 elf="elf.lo elflink.lo dwarf2.lo dwarf1.lo"
 442
 443 for vec in $selvecs
 444 do
 445     case "$vec" in
 446     # This list is alphabetized to make it easy to compare
 447     # with the two vector lists in targets.c.
 448     a29kcoff_big_vec)           tb="$tb coff-a29k.lo cofflink.lo" ;;
 449     a_out_adobe_vec)            tb="$tb aout-adobe.lo aout32.lo" ;;
 450     armcoff_little_vec)         tb="$tb coff-arm.lo cofflink.lo " ;;
 451     armcoff_big_vec)            tb="$tb coff-arm.lo cofflink.lo " ;;
 452     armnetbsd_vec)              tb="$tb armnetbsd.lo aout32.lo" ;;
 453     armpe_little_vec)           tb="$tb pe-arm.lo peigen.lo cofflink.lo " ;;
 454     armpe_big_vec)              tb="$tb pe-arm.lo peigen.lo cofflink.lo " ;;
 455     armpei_little_vec)          tb="$tb pei-arm.lo peigen.lo cofflink.lo " ;;
 456     armpei_big_vec)             tb="$tb pei-arm.lo peigen.lo cofflink.lo " ;;
 457     arm_epoc_pe_little_vec)     tb="$tb epoc-pe-arm.lo peigen.lo cofflink.lo " ;;
 458     arm_epoc_pe_big_vec)        tb="$tb epoc-pe-arm.lo peigen.lo cofflink.lo " ;;
 459     arm_epoc_pei_little_vec)    tb="$tb epoc-pei-arm.lo peigen.lo cofflink.lo " ;;
 460     arm_epoc_pei_big_vec)       tb="$tb epoc-pei-arm.lo peigen.lo cofflink.lo " ;;
 461     aout0_big_vec)              tb="$tb aout0.lo aout32.lo" ;;
 462     aout_arm_big_vec)           tb="$tb aout-arm.lo aout32.lo" ;;
 463     aout_arm_little_vec)        tb="$tb aout-arm.lo aout32.lo" ;;
 464     aout_mips_big_vec)          tb="$tb mipsbsd.lo aout32.lo" ;;
 465     aout_mips_little_vec)       tb="$tb mipsbsd.lo aout32.lo" ;;
 466     apollocoff_vec)             tb="$tb coff-apollo.lo" ;;
 467     b_out_vec_big_host)         tb="$tb bout.lo aout32.lo" ;;
 468     b_out_vec_little_host)      tb="$tb bout.lo aout32.lo" ;;
 469     bfd_efi_app_ia32_vec)       tb="$tb efi-app-ia32.lo peigen.lo cofflink.lo" ;;
 470     bfd_efi_app_ia64_vec)       tb="$tb efi-app-ia64.lo peigen.lo cofflink.lo"
 471                                 target64=true ;;
 472     bfd_elf64_alpha_vec)        tb="$tb elf64-alpha.lo elf64.lo $elf"
 473                                 target64=true ;;
 474     bfd_elf64_hppa_vec)         tb="$tb elf64-hppa.lo elf64.lo $elf"
 475                                 target64=true ;;
 476     bfd_elf64_ia64_little_vec)  tb="$tb elf64-ia64.lo elf64.lo $elf"
 477                                 target64=true ;;
 478     bfd_elf64_ia64_big_vec)     tb="$tb elf64-ia64.lo elf64.lo $elf"
 479                                 target64=true ;;
 480     bfd_elf32_avr_vec)          tb="$tb elf32-avr.lo elf32.lo $elf" ;;
 481     bfd_elf32_littlearc_vec)    tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 482     bfd_elf32_littlearm_vec)    tb="$tb elfarm-nabi.lo elf32.lo $elf" ;;
 483     bfd_elf32_littlearm_oabi_vec) tb="$tb elfarm-oabi.lo elf32.lo $elf" ;;
 484     bfd_elf32_bigarc_vec)       tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 485     bfd_elf32_bigarm_vec)       tb="$tb elfarm-nabi.lo elf32.lo $elf" ;;
 486     bfd_elf32_bigarm_oabi_vec)  tb="$tb elfarm-oabi.lo elf32.lo $elf" ;;
 487     bfd_elf32_big_generic_vec)  tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 488     bfd_elf32_bigmips_vec)      tb="$tb elf32-mips.lo elf32.lo $elf ecofflink.lo" ;;
 489     bfd_elf64_bigmips_vec)      tb="$tb elf64-mips.lo elf64.lo elf32-mips.lo elf32.lo $elf ecofflink.lo"
 490                                 target64=true ;;
 491     bfd_elf32_d10v_vec)         tb="$tb elf32-d10v.lo elf32.lo $elf" ;;
 492     bfd_elf32_d30v_vec)         tb="$tb elf32-d30v.lo elf32.lo $elf" ;;
 493     bfd_elf32_fr30_vec)         tb="$tb elf32-fr30.lo elf32.lo $elf" ;;
 494     bfd_elf32_hppa_vec)         tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 495     bfd_elf32_i370_vec)         tb="$tb elf32-i370.lo elf32.lo $elf" ;;
 496     bfd_elf32_i386_vec)         tb="$tb elf32-i386.lo elf32.lo $elf" ;;
 497     bfd_elf32_i860_vec)         tb="$tb elf32-i860.lo elf32.lo $elf" ;;
 498     bfd_elf32_i960_vec)         tb="$tb elf32-i960.lo elf32.lo $elf" ;;
 499     bfd_elf32_little_generic_vec) tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 500     bfd_elf32_littlemips_vec)   tb="$tb elf32-mips.lo elf32.lo $elf ecofflink.lo" ;;
 501     bfd_elf64_littlemips_vec)   tb="$tb elf64-mips.lo elf64.lo elf32-mips.lo elf32.lo $elf ecofflink.lo"
 502                                 target64=true ;;
 503     bfd_elf32_m32r_vec)         tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 504     bfd_elf32_m68k_vec)         tb="$tb elf32-m68k.lo elf32.lo $elf" ;;
 505     bfd_elf32_m88k_vec)         tb="$tb elf32-m88k.lo elf32.lo $elf" ;;
 506     bfd_elf32_mcore_big_vec)    tb="$tb elf32-mcore.lo elf32.lo $elf" ;;
 507     bfd_elf32_mcore_little_vec) tb="$tb elf32-mcore.lo elf32.lo $elf" ;;
 508     bfd_elf32_mn10200_vec)      tb="$tb elf-m10200.lo elf32.lo $elf" ;;
 509     bfd_elf32_mn10300_vec)      tb="$tb elf-m10300.lo elf32.lo $elf" ;;
 510     bfd_elf32_pj_vec)           tb="$tb elf32-pj.lo elf32.lo $elf";;
 511     bfd_elf32_pjl_vec)          tb="$tb elf32-pj.lo elf32.lo $elf";;
 512     bfd_elf32_powerpc_vec)      tb="$tb elf32-ppc.lo elf32.lo $elf" ;;
 513     bfd_elf32_powerpcle_vec)    tb="$tb elf32-ppc.lo elf32.lo $elf" ;;
 514     bfd_elf32_sh_vec)           tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
 515     bfd_elf32_shl_vec)          tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
 516     bfd_elf32_sparc_vec)        tb="$tb elf32-sparc.lo elf32.lo $elf" ;;
 517     bfd_elf32_v850_vec)         tb="$tb elf32-v850.lo elf32.lo $elf" ;;
 518     bfd_elf64_big_generic_vec)  tb="$tb elf64-gen.lo elf64.lo $elf"
 519                                 target64=true ;;
 520     bfd_elf64_little_generic_vec) tb="$tb elf64-gen.lo elf64.lo $elf"
 521                                 target64=true ;;
 522     bfd_elf64_sparc_vec)        tb="$tb elf64-sparc.lo elf64.lo $elf"
 523                                 target64=true ;;
 524     cisco_core_big_vec)         tb="$tb cisco-core.lo" ;;
 525     cisco_core_little_vec)      tb="$tb cisco-core.lo" ;;
 526     demo_64_vec)                tb="$tb demo64.lo aout64.lo"
 527                                 target64=true ;;
 528     ecoff_big_vec)              tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 529     ecoff_little_vec)           tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 530     ecoff_biglittle_vec)        tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 531     ecoffalpha_little_vec)      tb="$tb coff-alpha.lo ecoff.lo ecofflink.lo"
 532                                 target64=true ;;
 533     go32coff_vec)               tb="$tb coff-go32.lo cofflink.lo" ;;
 534     go32stubbedcoff_vec)        tb="$tb coff-stgo32.lo cofflink.lo" ;;
 535     h8300coff_vec)              tb="$tb coff-h8300.lo reloc16.lo" ;;
 536     h8500coff_vec)              tb="$tb coff-h8500.lo reloc16.lo" ;;
 537     host_aout_vec)              tb="$tb host-aout.lo aout32.lo" ;;
 538     hp300bsd_vec)               tb="$tb hp300bsd.lo aout32.lo" ;;
 539     hp300hpux_vec)              tb="$tb hp300hpux.lo aout32.lo" ;;
 540     i386aout_vec)               tb="$tb i386aout.lo aout32.lo" ;;
 541     i386bsd_vec)                tb="$tb i386bsd.lo aout32.lo" ;;
 542     i386coff_vec)               tb="$tb coff-i386.lo cofflink.lo" ;;
 543     i386dynix_vec)              tb="$tb i386dynix.lo aout32.lo" ;;
 544     i386freebsd_vec)            tb="$tb i386freebsd.lo aout32.lo" ;;
 545     i386msdos_vec)              tb="$tb i386msdos.lo" ;;
 546     i386pe_vec)                 tb="$tb pe-i386.lo peigen.lo cofflink.lo" ;;
 547     i386pei_vec)                tb="$tb pei-i386.lo peigen.lo cofflink.lo" ;;
 548     i386linux_vec)              tb="$tb i386linux.lo aout32.lo" ;;
 549     i386lynx_aout_vec)          tb="$tb i386lynx.lo lynx-core.lo aout32.lo" ;;
 550     i386lynx_coff_vec)          tb="$tb cf-i386lynx.lo cofflink.lo lynx-core.lo" ;;
 551     i386mach3_vec)              tb="$tb i386mach3.lo aout32.lo" ;;
 552     i386netbsd_vec)             tb="$tb i386netbsd.lo aout32.lo" ;;
 553     i386os9k_vec)               tb="$tb i386os9k.lo aout32.lo" ;;
 554     i860coff_vec)               tb="$tb coff-i860.lo cofflink.lo" ;;
 555     icoff_big_vec)              tb="$tb coff-i960.lo cofflink.lo" ;;
 556     icoff_little_vec)           tb="$tb coff-i960.lo cofflink.lo" ;;
 557     ieee_vec)                   tb="$tb ieee.lo" ;;
 558     m68kcoff_vec)               tb="$tb coff-m68k.lo cofflink.lo" ;;
 559     m68kcoffun_vec)             tb="$tb coff-u68k.lo coff-m68k.lo cofflink.lo" ;;
 560     m68klinux_vec)              tb="$tb m68klinux.lo aout32.lo" ;;
 561     m68klynx_aout_vec)          tb="$tb m68klynx.lo lynx-core.lo aout32.lo" ;;
 562     m68klynx_coff_vec)          tb="$tb cf-m68klynx.lo coff-m68k.lo cofflink.lo lynx-core.lo" ;;
 563     m68knetbsd_vec)             tb="$tb m68knetbsd.lo aout32.lo" ;;
 564     m68k4knetbsd_vec)           tb="$tb m68k4knetbsd.lo aout32.lo" ;;
 565     m68kaux_coff_vec)           tb="$tb coff-aux.lo coff-m68k.lo cofflink.lo" ;;
 566     m68ksysvcoff_vec)           tb="$tb coff-svm68k.lo cofflink.lo" ;;
 567     m88kbcs_vec)                tb="$tb coff-m88k.lo" ;;
 568     mipslpe_vec)                tb="$tb pe-mips.lo peigen.lo cofflink.lo" ;;
 569     mipslpei_vec)               tb="$tb pei-mips.lo peigen.lo cofflink.lo" ;;
 570     mcore_pe_big_vec)           tb="$tb pe-mcore.lo peigen.lo cofflink.lo" ;;
 571     mcore_pe_little_vec)        tb="$tb pe-mcore.lo peigen.lo cofflink.lo" ;;
 572     mcore_pei_big_vec)          tb="$tb pei-mcore.lo peigen.lo cofflink.lo" ;;
 573     mcore_pei_little_vec)       tb="$tb pei-mcore.lo peigen.lo cofflink.lo" ;;
 574     newsos3_vec)                tb="$tb newsos3.lo aout32.lo" ;;
 575     nlm32_i386_vec)             tb="$tb nlm32-i386.lo nlm32.lo nlm.lo" ;;
 576     rs6000coff64_vec)           tb="$tb coff64-rs6000.lo xcofflink.lo"
 577                                 target64=true ;;
 578     nlm32_sparc_vec)            tb="$tb nlm32-sparc.lo nlm32.lo nlm.lo" ;;
 579     nlm32_alpha_vec)            tb="$tb nlm32-alpha.lo nlm32.lo nlm.lo"
 580                                 target64=true ;;
 581     riscix_vec)                 tb="$tb aout32.lo riscix.lo" ;;
 582     nlm32_powerpc_vec)          tb="$tb nlm32-ppc.lo nlm32.lo nlm.lo" ;;
 583     pc532netbsd_vec)            tb="$tb ns32knetbsd.lo aout-ns32k.lo" ;;
 584     pc532machaout_vec)          tb="$tb pc532-mach.lo aout-ns32k.lo" ;;
 585     pmac_xcoff_vec)             tb="$tb coff-pmac.lo xcofflink.lo" ;;
 586     rs6000coff_vec)             tb="$tb coff-rs6000.lo xcofflink.lo" ;;
 587     bfd_powerpc_pe_vec)         tb="$tb pe-ppc.lo peigen.lo cofflink.lo" ;;
 588     bfd_powerpcle_pe_vec)       tb="$tb pe-ppc.lo peigen.lo cofflink.lo" ;;
 589     bfd_powerpc_pei_vec)        tb="$tb pei-ppc.lo peigen.lo cofflink.lo" ;;
 590     bfd_powerpcle_pei_vec)      tb="$tb pei-ppc.lo peigen.lo cofflink.lo" ;;
 591     ppcboot_vec)                tb="$tb ppcboot.lo" ;;
 592     shcoff_vec)                 tb="$tb coff-sh.lo cofflink.lo" ;;
 593     shlcoff_vec)                tb="$tb coff-sh.lo cofflink.lo" ;;
 594     shcoff_small_vec)           tb="$tb coff-sh.lo cofflink.lo" ;;
 595     shlcoff_small_vec)          tb="$tb coff-sh.lo cofflink.lo" ;;
 596     shlpe_vec)                  tb="$tb pe-sh.lo coff-sh.lo cofflink.lo" ;;
 597     shlpei_vec)                 tb="$tb pei-sh.lo coff-sh.lo cofflink.lo" ;;
 598     som_vec)                    tb="$tb som.lo" ;;
 599     sparcle_aout_vec)           tb="$tb aout-sparcle.lo aout32.lo" ;;
 600     sparclinux_vec)             tb="$tb sparclinux.lo aout32.lo" ;;
 601     sparclynx_aout_vec)         tb="$tb sparclynx.lo lynx-core.lo aout32.lo" ;;
 602     sparclynx_coff_vec)         tb="$tb cf-sparclynx.lo lynx-core.lo" ;;
 603     sparcnetbsd_vec)            tb="$tb sparcnetbsd.lo aout32.lo" ;;
 604     sparccoff_vec)              tb="$tb coff-sparc.lo" ;;
 605     srec_vec)                   tb="$tb srec.lo" ;;
 606     sunos_big_vec)              tb="$tb sunos.lo aout32.lo" ;;
 607     symbolsrec_vec)             tb="$tb srec.lo" ;;
 608     tekhex_vec)                 tb="$tb tekhex.lo" ;;
 609     tic30_aout_vec)             tb="$tb aout-tic30.lo" ;;
 610     tic30_coff_vec)             tb="$tb coff-tic30.lo" ;;
 611     tic54x_coff0_vec)           tb="$tb coff-tic54x.lo" ;;
 612     tic54x_coff0_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 613     tic54x_coff1_vec)           tb="$tb coff-tic54x.lo" ;;
 614     tic54x_coff1_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 615     tic54x_coff2_vec)           tb="$tb coff-tic54x.lo" ;;
 616     tic54x_coff2_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 617     tic80coff_vec)              tb="$tb coff-tic80.lo cofflink.lo" ;;
 618     versados_vec)               tb="$tb versados.lo" ;;
 619     vms_alpha_vec)              tb="$tb vms.lo vms-hdr.lo vms-gsd.lo vms-tir.lo vms-misc.lo"
 620                                 target64=true ;;
 621     vms_vax_vec)                tb="$tb vms.lo vms-hdr.lo vms-gsd.lo vms-tir.lo vms-misc.lo" ;;
 622     w65_vec)                    tb="$tb coff-w65.lo reloc16.lo" ;;
 623     we32kcoff_vec)              tb="$tb coff-we32k.lo" ;;
 624     z8kcoff_vec)                tb="$tb coff-z8k.lo reloc16.lo" ;;
 625
 626     "")                 ;;
 627     *) AC_MSG_ERROR(*** unknown target vector $vec) ;;
 628     esac
 629 done
 630
 631 # Target architecture .o files.
 632 # A couple of CPUs use shorter file names to avoid problems on DOS
 633 # filesystems.
 634 ta=`echo $selarchs | sed -e s/bfd_/cpu-/g -e s/_arch/.lo/g -e s/mn10200/m10200/ -e s/mn10300/m10300/`
 635
 636 # Weed out duplicate .o files.
 637 f=""
 638 for i in $tb ; do
 639     case " $f " in
 640     *" $i "*) ;;
 641     *) f="$f $i" ;;
 642     esac
 643 done
 644 tb="$f"
 645
 646 f=""
 647 for i in $ta ; do
 648     case " $f " in
 649     *" $i "*) ;;
 650     *) f="$f $i" ;;
 651     esac
 652 done
 653 ta="$f"
 654
 655 bfd_backends="$tb"
 656 bfd_machines="$ta"
 657
 658 if test x${all_targets} = xtrue ; then
 659   bfd_backends="${bfd_backends}"' $(ALL_BACKENDS)'
 660   bfd_machines="${bfd_machines}"' $(ALL_MACHINES)'
 661   selvecs=
 662   havevecs=
 663   selarchs=
 664 else    # all_targets is true
 665   # Only set these if they will be nonempty, for the clever echo.
 666   havevecs=
 667   test -n "$selvecs" &&
 668     havevecs=`echo $selvecs | sed -e 's/^/-DHAVE_/' -e 's/ \(.\)/ -DHAVE_\1/g'`
 669   test -n "$selvecs" &&
 670     selvecs=`echo $selvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 671   test -n "$selarchs" &&
 672     selarchs=`echo $selarchs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 673 fi      # all_targets is true
 674
 675 case ${host64}-${target64}-${want64} in
 676   *true*)
 677     wordsize=64
 678     all_backends='$(BFD64_BACKENDS) $(BFD32_BACKENDS)'
 679     if test -z "$GCC" && test "$BFD_HOST_64BIT_LONG" = "0" && test "$BFD_HOST_64_BIT_DEFINED" = "0"; then
 680       AC_MSG_WARN([You have requested a 64 bit BFD configuration, but])
 681       AC_MSG_WARN([your compiler may not have a 64 bit integral type])
 682     fi
 683     ;;
 684   false-false-false)
 685     wordsize=32
 686     all_backends='$(BFD32_BACKENDS)'
 687     ;;
 688 esac
 689
 690 AC_SUBST(wordsize)
 691 AC_SUBST(all_backends)
 692 AC_SUBST(bfd_backends)
 693 AC_SUBST(bfd_machines)
 694
 695 tdefaults=""
 696 test -n "${defvec}" && tdefaults="${tdefaults} -DDEFAULT_VECTOR=${defvec}"
 697 test -n "${selvecs}" && tdefaults="${tdefaults} -DSELECT_VECS='${selvecs}'"
 698 test -n "${selarchs}" && tdefaults="${tdefaults} -DSELECT_ARCHITECTURES='${selarchs}'"
 699 test -n "${havevecs}" && tdefaults="${tdefaults} ${havevecs}"
 700 AC_SUBST(tdefaults)
 701
 702 dnl AC_CHECK_HEADERS(sys/mman.h)
 703 AC_FUNC_MMAP
 704 AC_CHECK_FUNCS(madvise mprotect)
 705 case ${want_mmap}+${ac_cv_func_mmap_fixed_mapped} in
 706   true+yes )  AC_DEFINE(USE_MMAP, 1, [Use mmap if it's available?]) ;;
 707 esac
 708
 709 rm -f doc/config.status
 710 AC_OUTPUT(Makefile doc/Makefile bfd-in3.h:bfd-in2.h po/Makefile.in:po/Make-in,
 711 [sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile])