libiberty/configure.in

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 AC_PREREQ(2.13)
   4 AC_INIT(xmalloc.c)
   5
   6 # This works around the fact that libtool configuration may change LD
   7 # for this particular configuration, but some shells, instead of
   8 # keeping the changes in LD private, export them just because LD is
   9 # exported.  We don't use libtool yet, but some day we might, so...
  10 ORIGINAL_LD_FOR_MULTILIBS=$LD
  11
  12 dnl We use these options to decide which functions to include.
  13 AC_ARG_WITH(target-subdir,
  14 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  15 AC_ARG_WITH(build-subdir,
  16 [  --with-build-subdir=SUBDIR       Configuring in a subdirectory for build])
  17 AC_ARG_WITH(cross-host,
  18 [  --with-cross-host=HOST           Configuring with a cross compiler])
  19 AC_ARG_WITH(newlib,
  20 [  --with-newlib                    Configuring with newlib])
  21
  22 if test "${srcdir}" = "."; then
  23   if test -n "${with_build_subdir}"; then
  24     libiberty_topdir="${srcdir}/../.."
  25     with_target_subdir=
  26   elif test -z "${with_target_subdir}"; then
  27     libiberty_topdir="${srcdir}/.."
  28   else
  29     if test "${with_target_subdir}" != "."; then
  30       libiberty_topdir="${srcdir}/${with_multisrctop}../.."
  31     else
  32       libiberty_topdir="${srcdir}/${with_multisrctop}.."
  33     fi
  34   fi
  35 else
  36   libiberty_topdir="${srcdir}/.."
  37 fi
  38 AC_SUBST(libiberty_topdir)
  39 AC_CONFIG_AUX_DIR($libiberty_topdir)
  40
  41 dnl Very limited version of automake's enable-maintainer-mode
  42
  43 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
  44   dnl maintainer-mode is disabled by default
  45   AC_ARG_ENABLE(maintainer-mode,
  46 [  --enable-maintainer-mode
  47                           enable make rules and dependencies not useful
  48                           (and sometimes confusing) to the casual installer],
  49       maintainer_mode=$enableval,
  50       maintainer_mode=no)
  51
  52 AC_MSG_RESULT($maintainer_mode)
  53
  54 if test "$maintainer_mode" = "yes"; then
  55   MAINT=''
  56   NOTMAINT='#'
  57 else
  58   MAINT='#'
  59   NOTMAINT=''
  60 fi
  61 AC_SUBST(MAINT)dnl
  62 AC_SUBST(NOTMAINT)dnl
  63
  64 # Do we have a single-tree copy of texinfo?  Even if we do, we can't
  65 # rely on it - libiberty is built before texinfo.
  66 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
  67 if test "x$MAKEINFO" = "x"; then
  68     MAKEINFO="@echo makeinfo missing; true"
  69     BUILD_INFO=
  70 else
  71     BUILD_INFO=info
  72     case x"`$MAKEINFO --version | grep 'GNU texinfo'`" in
  73       x*\ [[1-3]].* )
  74         MAKEINFO="@echo $MAKEINFO is too old, 4.0 or newer required; true"
  75         BUILD_INFO=
  76         AC_MSG_WARN([
  77 *** Makeinfo is too old. Info documentation will not be built.])
  78         ;;
  79     esac
  80 fi
  81 AC_SUBST(MAKEINFO)
  82 AC_SUBST(BUILD_INFO)
  83
  84 AC_CHECK_PROG(PERL, perl, perl, )
  85 if test x"$PERL" = x""; then
  86   HAVE_PERL='#'
  87 else
  88   HAVE_PERL=''
  89 fi
  90 AC_SUBST(HAVE_PERL)
  91
  92 AC_CANONICAL_HOST
  93
  94 dnl When we start using automake:
  95 dnl AM_INIT_AUTOMAKE(libiberty, 1.0)
  96
  97 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  98 dnl to call AC_CHECK_PROG.
  99 AC_CHECK_TOOL(AR, ar)
 100 AC_CHECK_TOOL(RANLIB, ranlib, :)
 101
 102 LIB_AC_PROG_CC
 103
 104 AC_PROG_CC_C_O
 105 # autoconf is lame and doesn't give us any substitution variable for this.
 106 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 107   NO_MINUS_C_MINUS_O=yes
 108 else
 109   OUTPUT_OPTION='-o $@'
 110 fi
 111 AC_SUBST(NO_MINUS_C_MINUS_O)
 112 AC_SUBST(OUTPUT_OPTION)
 113
 114 AC_ISC_POSIX
 115 AC_C_CONST
 116 AC_C_INLINE
 117
 118 dnl When we start using libtool:
 119 dnl Default to a non shared library.  This may be overridden by the
 120 dnl configure option --enable-shared.
 121 dnl AM_DISABLE_SHARED
 122
 123 dnl When we start using libtool:
 124 dnl AM_PROG_LIBTOOL
 125
 126 dnl When we start using automake:
 127 dnl AM_CONFIG_HEADER(config.h:config.in)
 128 AC_CONFIG_HEADER(config.h:config.in)
 129
 130 dnl When we start using automake:
 131 dnl AM_MAINTAINER_MODE
 132 dnl AC_EXEEXT
 133
 134 dnl When we start using automake:
 135 dnl AM_PROG_INSTALL
 136 AC_PROG_INSTALL
 137
 138 . ${srcdir}/config.table
 139 host_makefile_frag=${frag}
 140 AC_SUBST_FILE(host_makefile_frag)
 141
 142 # It's OK to check for header files.  Although the compiler may not be
 143 # able to link anything, it had better be able to at least compile
 144 # something.
 145 AC_CHECK_HEADERS(sys/file.h sys/param.h limits.h stdlib.h string.h unistd.h strings.h sys/time.h time.h sys/resource.h sys/stat.h sys/mman.h fcntl.h alloca.h sys/pstat.h sys/sysmp.h sys/sysinfo.h machine/hal_sysinfo.h sys/table.h)
 146 AC_HEADER_SYS_WAIT
 147 AC_HEADER_TIME
 148
 149 libiberty_AC_DECLARE_ERRNO
 150
 151 AC_CHECK_TYPE(uintptr_t, unsigned long)
 152
 153 if test $ac_cv_type_uintptr_t = yes
 154 then
 155   AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if you have the \`uintptr_t' type.])
 156 fi
 157
 158 AC_TYPE_PID_T
 159
 160 # This is the list of functions which libiberty will provide if they
 161 # are not available on the host.
 162
 163 funcs="asprintf"
 164 funcs="$funcs atexit"
 165 funcs="$funcs basename"
 166 funcs="$funcs bcmp"
 167 funcs="$funcs bcopy"
 168 funcs="$funcs bsearch"
 169 funcs="$funcs bzero"
 170 funcs="$funcs calloc"
 171 funcs="$funcs clock"
 172 funcs="$funcs ffs"
 173 funcs="$funcs getcwd"
 174 funcs="$funcs getpagesize"
 175 funcs="$funcs index"
 176 funcs="$funcs insque"
 177 funcs="$funcs memchr"
 178 funcs="$funcs memcmp"
 179 funcs="$funcs memcpy"
 180 funcs="$funcs memmove"
 181 funcs="$funcs memset"
 182 funcs="$funcs mkstemps"
 183 funcs="$funcs putenv"
 184 funcs="$funcs random"
 185 funcs="$funcs rename"
 186 funcs="$funcs rindex"
 187 funcs="$funcs setenv"
 188 funcs="$funcs sigsetmask"
 189 funcs="$funcs strcasecmp"
 190 funcs="$funcs strchr"
 191 funcs="$funcs strdup"
 192 funcs="$funcs strncasecmp"
 193 funcs="$funcs strrchr"
 194 funcs="$funcs strstr"
 195 funcs="$funcs strtod"
 196 funcs="$funcs strtol"
 197 funcs="$funcs strtoul"
 198 funcs="$funcs tmpnam"
 199 funcs="$funcs vasprintf"
 200 funcs="$funcs vfprintf"
 201 funcs="$funcs vprintf"
 202 funcs="$funcs vsprintf"
 203 funcs="$funcs waitpid"
 204
 205 # Also in the old function.def file: alloca, vfork, getopt.
 206
 207 vars="sys_errlist sys_nerr sys_siglist"
 208
 209 checkfuncs="getrusage on_exit psignal strerror strsignal sysconf times sbrk gettimeofday"
 210 checkfuncs="$checkfuncs realpath canonicalize_file_name pstat_getstatic pstat_getdynamic sysmp"
 211 checkfuncs="$checkfuncs getsysinfo table"
 212
 213 # These are neither executed nor required, but they help keep
 214 # autoheader happy without adding a bunch of text to acconfig.h.
 215 if test "x" = "y"; then
 216   AC_CHECK_FUNCS(asprintf atexit basename bcmp bcopy bsearch bzero calloc clock)
 217   AC_CHECK_FUNCS(getcwd getpagesize index insque mkstemps memchr memcmp memcpy)
 218   AC_CHECK_FUNCS(memmove memset putenv random rename rindex sigsetmask)
 219   AC_CHECK_FUNCS(strcasecmp setenv strchr strdup strncasecmp strrchr strstr)
 220   AC_CHECK_FUNCS(strtod strtol strtoul tmpnam vasprintf vfprintf vprintf)
 221   AC_CHECK_FUNCS(vsprintf waitpid getrusage on_exit psignal strerror strsignal)
 222   AC_CHECK_FUNCS(sysconf times sbrk gettimeofday ffs)
 223   AC_CHECK_FUNCS(pstat_getstatic pstat_getdynamic sysmp getsysinfo table)
 224   AC_CHECK_FUNCS(realpath canonicalize_file_name)
 225   AC_DEFINE(HAVE_SYS_ERRLIST, 1, [Define if you have the sys_errlist variable.])
 226   AC_DEFINE(HAVE_SYS_NERR,    1, [Define if you have the sys_nerr variable.])
 227   AC_DEFINE(HAVE_SYS_SIGLIST, 1, [Define if you have the sys_siglist variable.])
 228 fi
 229
 230 # For each of these functions, if the host does not provide the
 231 # function we want to put FN.o in LIBOBJS, and if the host does
 232 # provide the function, we want to define HAVE_FN in config.h.
 233
 234 setobjs=
 235 CHECK=
 236 target_header_dir=
 237 if test -n "${with_target_subdir}"; then
 238
 239   # We are being configured as a target library.  AC_REPLACE_FUNCS
 240   # may not work correctly, because the compiler may not be able to
 241   # link executables.  Note that we may still be being configured
 242   # native.
 243
 244   # If we are being configured for newlib, we know which functions
 245   # newlib provide and which ones we will be expected to provide.
 246
 247   if test "x${with_newlib}" = "xyes"; then
 248     LIBOBJS="asprintf.o basename.o insque.o random.o strdup.o vasprintf.o"
 249
 250     for f in $funcs; do
 251       case "$f" in
 252         asprintf | basename | insque | random | strdup | vasprintf)
 253           ;;
 254         *)
 255           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 256           AC_DEFINE_UNQUOTED($n)
 257           ;;
 258       esac
 259     done
 260
 261     # newlib doesnt provide any of the variables in $vars, so we
 262     # dont have to check them here.
 263
 264     # Of the functions in $checkfuncs, newlib only has strerror.
 265     AC_DEFINE_NOAUTOHEADER(HAVE_STRERROR)
 266
 267     setobjs=yes
 268
 269   fi
 270
 271   # We may wish to install the target headers somewhere.
 272   AC_ARG_ENABLE(install-libiberty,
 273   [  --enable-install-libiberty       Install headers for end users],
 274   enable_install_libiberty=$enableval,
 275   enable_install_libiberty=no)dnl
 276
 277   # Option parsed, now set things appropriately.
 278   case x"$enable_install_libiberty" in
 279     xyes|x)
 280       target_header_dir=libiberty
 281       ;;
 282     xno)
 283       target_header_dir=
 284       ;;
 285     *)
 286       # This could be sanity-checked in various ways...
 287       target_header_dir="${enable_install_libiberty}"
 288       ;;
 289   esac
 290
 291
 292 else
 293
 294    # Not a target library, so we set things up to run the test suite.
 295    CHECK=check-cplus-dem
 296
 297 fi
 298
 299 AC_SUBST(CHECK)
 300 AC_SUBST(target_header_dir)
 301
 302 case "${host}" in
 303   *-*-cygwin* | *-*-mingw*)
 304     AC_DEFINE_NOAUTOHEADER(HAVE_SYS_ERRLIST)
 305     AC_DEFINE_NOAUTOHEADER(HAVE_SYS_NERR)
 306     ;;
 307 esac
 308
 309 if test -z "${setobjs}"; then
 310   case "${host}" in
 311
 312   *-*-vxworks*)
 313     # Handle VxWorks configuration specially, since on VxWorks the
 314     # libraries are actually on the target board, not in the file
 315     # system.
 316     LIBOBJS="basename.o getpagesize.o insque.o random.o strcasecmp.o"
 317     LIBOBJS="$LIBOBJS strncasecmp.o strdup.o vfork.o waitpid.o vasprintf.o"
 318     for f in $funcs; do
 319       case "$f" in
 320         basename | getpagesize | insque | random | strcasecmp)
 321           ;;
 322         strncasecmp | strdup | vfork | waitpid | vasprintf)
 323           ;;
 324         *)
 325           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 326           AC_DEFINE_UNQUOTED($n)
 327           ;;
 328       esac
 329     done
 330
 331     # VxWorks doesn't provide any of the variables in $vars, so we
 332     # don't have to check them here.
 333
 334     # Of the functions in $checkfuncs, VxWorks only has strerror.
 335     AC_DEFINE_NOAUTOHEADER(HAVE_STRERROR)
 336
 337     setobjs=yes
 338     ;;
 339
 340   esac
 341 fi
 342
 343 if test -z "${setobjs}"; then
 344
 345   case "${host}" in
 346
 347   *-*-cygwin*)
 348     # The Cygwin library actually uses a couple of files from
 349     # libiberty when it is built.  If we are building a native
 350     # Cygwin, and we run the tests, we will appear to have these
 351     # files.  However, when we go on to build winsup, we will wind up
 352     # with a library which does not have the files, since they should
 353     # have come from libiberty.
 354
 355     # We handle this by removing the functions the winsup library
 356     # provides from our shell variables, so that they appear to be
 357     # missing.
 358
 359     # DJ - only if we're *building* cygwin, not just building *with* cygwin
 360
 361     if test -n "${with_target_subdir}"
 362     then
 363       funcs="`echo $funcs | sed -e 's/random//'`"
 364       LIBOBJS="$LIBOBJS random.o"
 365       vars="`echo $vars | sed -e 's/sys_siglist//'`"
 366       checkfuncs="`echo $checkfuncs | sed -e 's/strsignal//' -e 's/psignal//'`"
 367     fi
 368     ;;
 369
 370   *-*-mingw32*)
 371     # Under mingw32, sys_nerr and sys_errlist exist, but they are
 372     # macros, so the test below won't find them.
 373     libiberty_cv_var_sys_nerr=yes
 374     libiberty_cv_var_sys_errlist=yes
 375     ;;
 376
 377   *-*-uwin*)
 378     # Under some versions of uwin, vfork is notoriously buggy and the test
 379     # can hang configure; on other versions, vfork exists just as a stub.
 380     # FIXME: This should be removed once vfork in uwin's runtime is fixed.
 381     ac_cv_func_vfork_works=no
 382     # Under uwin 2.0+, sys_nerr and sys_errlist exist, but they are
 383     # macros (actually, these are imported from a DLL, but the end effect
 384     # is the same), so the test below won't find them.
 385     libiberty_cv_var_sys_nerr=yes
 386     libiberty_cv_var_sys_errlist=yes
 387     ;;
 388
 389   *-*-*vms*)
 390     # Under VMS, vfork works very different than on Unix. The standard test
 391     # won't work, and it isn't easily adaptable. It makes more sense to
 392     # just force it.
 393     ac_cv_func_vfork_works=yes
 394     ;;
 395
 396   esac
 397
 398   # We haven't set the list of objects yet.  Use the standard autoconf
 399   # tests.  This will only work if the compiler works.
 400   AC_PROG_CC_WORKS
 401   AC_REPLACE_FUNCS($funcs)
 402   libiberty_AC_FUNC_C_ALLOCA
 403   AC_FUNC_VFORK
 404   if test $ac_cv_func_vfork_works = no; then
 405     LIBOBJS="$LIBOBJS vfork.o"
 406   fi
 407   # We only need _doprnt if we might use it to implement v*printf.
 408   if test $ac_cv_func_vprintf != yes \
 409      || test $ac_cv_func_vfprintf != yes \
 410      || test $ac_cv_func_vsprintf != yes; then
 411     AC_REPLACE_FUNCS(_doprnt)
 412   else
 413     AC_CHECK_FUNCS(_doprnt)
 414   fi
 415
 416   for v in $vars; do
 417     AC_MSG_CHECKING([for $v])
 418     AC_CACHE_VAL(libiberty_cv_var_$v,
 419       [AC_TRY_LINK([int *p;], [extern int $v []; p = $v;],
 420                    [eval "libiberty_cv_var_$v=yes"],
 421                    [eval "libiberty_cv_var_$v=no"])])
 422     if eval "test \"`echo '$libiberty_cv_var_'$v`\" = yes"; then
 423       AC_MSG_RESULT(yes)
 424       n=HAVE_`echo $v | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 425       AC_DEFINE_UNQUOTED($n)
 426     else
 427       AC_MSG_RESULT(no)
 428     fi
 429   done
 430   AC_CHECK_FUNCS($checkfuncs)
 431   libiberty_NEED_DECLARATION(canonicalize_file_name)
 432 fi
 433
 434 # Figure out which version of pexecute to use.
 435 case "${host}" in
 436      *-*-mingw* | *-*-winnt*)   pexecute=pex-win32.o  ;;
 437      *-*-msdosdjgpp*)           pexecute=pex-djgpp.o  ;;
 438      *-*-msdos*)                pexecute=pex-msdos.o  ;;
 439      *-*-os2-emx*)              pexecute=pex-os2.o    ;;
 440      *)                         pexecute=pex-unix.o   ;;
 441 esac
 442 AC_SUBST(pexecute)
 443
 444 libiberty_AC_FUNC_STRNCMP
 445
 446 # Install a library built with a cross compiler in $(tooldir) rather
 447 # than $(libdir).
 448 if test -z "${with_cross_host}"; then
 449   INSTALL_DEST=libdir
 450 else
 451   INSTALL_DEST=tooldir
 452 fi
 453 AC_SUBST(INSTALL_DEST)
 454
 455 # We need multilib support, but only if configuring for the target.
 456 AC_OUTPUT(Makefile testsuite/Makefile,
 457 [test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 458 if test -n "$CONFIG_FILES"; then
 459   if test -n "${with_build_subdir}" || test -n "${with_target_subdir}"; then
 460     # FIXME: We shouldn't need to set ac_file
 461     ac_file=Makefile
 462     LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 463     . ${libiberty_topdir}/config-ml.in
 464   fi
 465 fi],
 466 srcdir=${srcdir}
 467 host=${host}
 468 target=${target}
 469 with_target_subdir=${with_target_subdir}
 470 with_build_subdir=${with_build_subdir}
 471 with_multisubdir=${with_multisubdir}
 472 ac_configure_args="--enable-multilib ${ac_configure_args}"
 473 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 474 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
 475 libiberty_topdir=${libiberty_topdir}
 476 )