gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 dnl v2.5 needed for --bindir et al
   8 AC_PREREQ(2.57)
   9 AC_INIT(as.h)
  10
  11 dnl Autoconf 2.57 will find the aux dir without this.  However, unless
  12 dnl we specify this explicitly, automake-1.7 will assume that ylwrap is in
  13 dnl gas/ instead of gas/../.
  14 AC_CONFIG_AUX_DIR(..)
  15 AC_CANONICAL_SYSTEM
  16 AC_ISC_POSIX
  17
  18 changequote(,)dnl
  19 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  20 changequote([,])dnl
  21 AM_INIT_AUTOMAKE(gas, ${BFD_VERSION})
  22
  23 AM_PROG_LIBTOOL
  24
  25 user_bfd_gas=
  26 AC_ARG_ENABLE(bfd-assembler,
  27 [  --enable-bfd-assembler  use BFD back end for writing object files],
  28 [case "${enableval}" in
  29   yes) need_bfd=yes user_bfd_gas=yes ;;
  30   no)  user_bfd_gas=no ;;
  31   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  32 esac])dnl
  33 AC_ARG_ENABLE(targets,
  34 [    targets            alternative target configurations besides the primary],
  35 [case "${enableval}" in
  36   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  37             ;;
  38   no)       enable_targets= ;;
  39   *)        enable_targets=$enableval ;;
  40 esac])dnl
  41 AC_ARG_ENABLE(commonbfdlib,
  42 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  43 [case "${enableval}" in
  44   yes) commonbfdlib=true ;;
  45   no)  commonbfdlib=false ;;
  46   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  47 esac])dnl
  48
  49 using_cgen=no
  50
  51 AM_BINUTILS_WARNINGS
  52
  53 # Generate a header file
  54 AM_CONFIG_HEADER(config.h:config.in)
  55
  56 # If we are on a DOS filesystem, we must use gdb.ini rather than
  57 # .gdbinit.
  58 case "${host}" in
  59   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-windows*)
  60     GDBINIT="gdb.ini"
  61     AC_CONFIG_FILES(gdb.ini:gdbinit.in)
  62     ;;
  63   *)
  64     GDBINIT=".gdbinit"
  65     AC_CONFIG_FILES(.gdbinit:gdbinit.in)
  66     ;;
  67 esac
  68 AC_SUBST(GDBINIT)
  69
  70 #We need this for the host.  BOUT header is in host order.
  71 AC_C_BIGENDIAN
  72
  73 te_file=generic
  74
  75 # Makefile target for installing gas in $(tooldir)/bin.
  76 install_tooldir=install-exec-tooldir
  77
  78 canon_targets=""
  79 all_targets=no
  80 if test -n "$enable_targets" ; then
  81   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  82     if test $t = "all"; then
  83       all_targets=yes
  84       continue
  85     fi
  86     result=`$ac_config_sub $t 2>/dev/null`
  87     if test -n "$result" ; then
  88       canon_targets="$canon_targets $result"
  89 #    else
  90 #      # Permit "all", etc.  We don't support it yet though.
  91 #      canon_targets="$canon_targets $t"
  92     fi
  93   done
  94   GAS_UNIQ(canon_targets)
  95 fi
  96
  97 emulations=""
  98
  99 for this_target in $target $canon_targets ; do
 100
 101     targ=${this_target}
 102     . ${srcdir}/configure.tgt
 103
 104     case ${target_cpu} in
 105       crisv32)
 106         AC_DEFINE_UNQUOTED(DEFAULT_CRIS_ARCH, $arch,
 107                            [Default CRIS architecture.])
 108         ;;
 109     esac
 110
 111     if test ${this_target} = $target ; then
 112       target_cpu_type=${cpu_type}
 113     elif test ${target_cpu_type} != ${cpu_type} ; then
 114       continue
 115     fi
 116
 117     generic_target=${cpu_type}-${target_vendor}-${target_os}
 118     case ${generic_target} in
 119       i386-*-sco3.2v5*)
 120         if test ${this_target} = $target; then
 121           AC_DEFINE(SCO_ELF, 1, [Define if defaulting to ELF on SCO 5.])
 122         fi
 123         ;;
 124
 125       i386-*-msdosdjgpp* \
 126       | i386-*-go32* \
 127       | i386-go32-rtems*)
 128         AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?])
 129         ;;
 130
 131       i860-*-*)
 132         AC_MSG_WARN(GAS support for ${generic_target} is preliminary and a work in progress)
 133         ;;
 134
 135       mips-sony-bsd*)
 136         ;;
 137       mips-*-bsd*)
 138         AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.)
 139         ;;
 140
 141       ppc-*-aix5.*)
 142         AC_DEFINE(AIX_WEAK_SUPPORT, 1,
 143                   [Define if using AIX 5.2 value for C_WEAKEXT.])
 144         ;;
 145       ppc-*-linux-*)
 146         case "$endian" in
 147           big)  ;;
 148           *)    AC_MSG_ERROR(GNU/Linux must be configured big endian) ;;
 149         esac
 150         ;;
 151       ppc-*-solaris*)
 152         if test ${this_target} = $target; then
 153           AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 154                     [Define if default target is PowerPC Solaris.])
 155         fi
 156         if test x${endian} = xbig; then
 157           AC_MSG_ERROR(Solaris must be configured little endian)
 158         fi
 159         ;;
 160
 161       sh*-*-symbianelf*)
 162         AC_DEFINE(TARGET_SYMBIAN, 1, [Define if target is Symbian OS.])
 163         ;;
 164     esac
 165
 166     if test ${this_target} = $target ; then
 167       endian_def=
 168       if test x${endian} = xbig; then
 169         endian_def=1
 170       elif test x${endian} = xlittle; then
 171         endian_def=0
 172       fi
 173       if test x${endian_def} != x; then
 174         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 175                            [Define as 1 if big endian.])
 176       fi
 177     fi
 178
 179 # Other random stuff.
 180
 181     case ${cpu_type} in
 182       mips)
 183         # Set mips_cpu to the name of the default CPU.
 184         case ${target_cpu} in
 185           mips | mipsbe | mipseb | mipsle | mipsel | mips64 | mips64el)
 186             mips_cpu=from-abi
 187             ;;
 188           mipsisa32 | mipsisa32el)
 189             mips_cpu=mips32
 190             ;;
 191           mipsisa32r2 | mipsisa32r2el)
 192             mips_cpu=mips32r2
 193             ;;
 194           mipsisa64 | mipsisa64el)
 195             mips_cpu=mips64
 196             ;;
 197           mipsisa64r2 | mipsisa64r2el)
 198             mips_cpu=mips64r2
 199             ;;
 200           mipstx39 | mipstx39el)
 201             mips_cpu=r3900
 202             ;;
 203           mips64vr | mips64vrel)
 204             mips_cpu=vr4100
 205             ;;
 206           mipsisa32r2* | mipsisa64r2*)
 207 changequote(,)dnl
 208             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r2//' -e 's/el$//'`
 209 changequote([,])dnl
 210             ;;
 211           mips64* | mipsisa64* | mipsisa32*)
 212 changequote(,)dnl
 213             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..//' -e 's/el$//'`
 214 changequote([,])dnl
 215             ;;
 216           *)
 217             AC_ERROR($target_cpu isn't a supported MIPS CPU name)
 218             ;;
 219         esac
 220         # See whether it's appropriate to set E_MIPS_ABI_O32 for o32
 221         # binaries.  It's a GNU extension that some OSes don't understand.
 222         # The value only matters on ELF targets.
 223         case ${target} in
 224           *-*-irix*)
 225             use_e_mips_abi_o32=0
 226             ;;
 227           *)
 228             use_e_mips_abi_o32=1
 229             ;;
 230         esac
 231         # Decide whether to generate 32-bit or 64-bit code by default.
 232         # Used to resolve -march=from-abi when an embedded ABI is selected.
 233         case ${target} in
 234           mips64*-*-* | mipsisa64*-*-*)
 235             mips_default_64bit=1
 236             ;;
 237           *)
 238             mips_default_64bit=0
 239             ;;
 240         esac
 241         # Decide which ABI to target by default.
 242         case ${target} in
 243           mips64*-linux* | mips-sgi-irix6*)
 244             mips_default_abi=N32_ABI
 245             ;;
 246           mips*-linux*)
 247             mips_default_abi=O32_ABI
 248             ;;
 249           mips64*-openbsd*)
 250             mips_default_abi=N64_ABI
 251             ;;
 252           *)
 253             mips_default_abi=NO_ABI
 254             ;;
 255         esac
 256         AC_DEFINE_UNQUOTED(MIPS_CPU_STRING_DEFAULT, "$mips_cpu",
 257                            [Default CPU for MIPS targets. ])
 258         AC_DEFINE_UNQUOTED(USE_E_MIPS_ABI_O32, $use_e_mips_abi_o32,
 259                            [Allow use of E_MIPS_ABI_O32 on MIPS targets. ])
 260         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_64BIT, $mips_default_64bit,
 261                            [Generate 64-bit code by default on MIPS targets. ])
 262         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_ABI, $mips_default_abi,
 263                            [Choose a default ABI for MIPS targets. ])
 264         ;;
 265     esac
 266
 267     # Do we need the opcodes library?
 268     case ${cpu_type} in
 269       vax | i386 | tic30)
 270         ;;
 271
 272       *)
 273         need_opcodes=yes
 274
 275         case "${enable_shared}" in
 276         yes) shared_opcodes=true ;;
 277         *opcodes*) shared_opcodes=true ;;
 278         *) shared_opcodes=false ;;
 279         esac
 280         if test "${shared_opcodes}" = "true"; then
 281           # A shared libopcodes must be linked against libbfd.
 282           need_bfd=yes
 283         fi
 284         ;;
 285     esac
 286
 287     # Any other special object files needed ?
 288     case ${cpu_type} in
 289       fr30 | ip2k | iq2000 | m32r | openrisc)
 290         using_cgen=yes
 291         ;;
 292
 293       m32c)
 294         using_cgen=yes
 295         ;;
 296       frv)
 297         using_cgen=yes
 298         ;;
 299       m68k)
 300         case ${extra_objects} in
 301         *m68k-parse.o*) ;;
 302         *) extra_objects="$extra_objects m68k-parse.o" ;;
 303         esac
 304         ;;
 305
 306       mips)
 307         echo ${extra_objects} | grep -s "itbl-parse.o"
 308         if test $? -ne 0 ; then
 309           extra_objects="$extra_objects itbl-parse.o"
 310         fi
 311
 312         echo ${extra_objects} | grep -s "itbl-lex.o"
 313         if test $? -ne 0 ; then
 314           extra_objects="$extra_objects itbl-lex.o"
 315         fi
 316
 317         echo ${extra_objects} | grep -s "itbl-ops.o"
 318         if test $? -ne 0 ; then
 319           extra_objects="$extra_objects itbl-ops.o"
 320         fi
 321         ;;
 322
 323       ms1)
 324         using_cgen=yes
 325         ;;
 326
 327       i386 | s390 | sparc)
 328         if test $this_target = $target ; then
 329           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 330         fi
 331         ;;
 332
 333       xstormy16)
 334         using_cgen=yes
 335         ;;
 336
 337       xtensa)
 338         echo ${extra_objects} | grep -s "xtensa-relax.o"
 339         if test $? -ne 0 ; then
 340           extra_objects="$extra_objects xtensa-relax.o"
 341         fi
 342         ;;
 343
 344       *)
 345         ;;
 346     esac
 347
 348     if test $using_cgen = yes ; then
 349         case "x${extra_objects}" in
 350         *cgen.o*) ;;
 351         *) extra_objects="$extra_objects cgen.o" ;;
 352         esac
 353     fi
 354
 355 # See if we really can support this configuration with the emulation code.
 356
 357     if test $this_target = $target ; then
 358       primary_bfd_gas=$bfd_gas
 359       obj_format=$fmt
 360       te_file=$em
 361
 362       if test $bfd_gas = no ; then
 363         # Can't support other configurations this way.
 364         break
 365       fi
 366     elif test $bfd_gas = no ; then
 367       # Can't support this configuration.
 368       break
 369     fi
 370
 371 # From target name and format, produce a list of supported emulations.
 372
 373     case ${generic_target}-${fmt} in
 374       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 375       mips*-*-linux*-*) case "$endian" in
 376                         big)    emulation="mipsbelf mipslelf mipself" ;;
 377                         *)      emulation="mipslelf mipsbelf mipself" ;;
 378                         esac ;;
 379       mips-*-lnews*-ecoff) ;;
 380       mips-*-*-ecoff)   case "$endian" in
 381                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 382                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 383                         esac ;;
 384       mips-*-*-elf)     case "$endian" in
 385                         big)    emulation="mipsbelf mipslelf mipself" ;;
 386                         *)      emulation="mipslelf mipsbelf mipself" ;;
 387                         esac ;;
 388       mips-*-sysv4*MP*-*) emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 389       # i386-pc-pe-coff != i386-pc-coff.
 390       i386-*-pe-coff)   ;;
 391       # Uncommenting the next line will turn on support for i386 AOUT
 392       # for the default linux configuration
 393       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 394       #
 395       i386-*-aout)      emulation="i386aout" ;;
 396       i386-*-coff)      emulation="i386coff" ;;
 397       i386-*-elf)       emulation="i386elf" ;;
 398
 399       # Always all formats.  The first stated emulation becomes the default.
 400       cris-*-*aout*)    emulation="crisaout criself" ;;
 401       cris-*-*)         emulation="criself crisaout" ;;
 402     esac
 403
 404     emulations="$emulations $emulation"
 405
 406 done
 407
 408 # Turn on all targets if possible
 409 if test ${all_targets} = "yes"; then
 410   case ${target_cpu_type} in
 411   i386)
 412     case ${obj_format} in
 413     aout)
 414       emulations="$emulations i386coff i386elf"
 415       ;;
 416     coff)
 417       emulations="$emulations i386aout i386elf"
 418     ;;
 419     elf)
 420       emulations="$emulations i386aout i386coff"
 421       ;;
 422     esac
 423   ;;
 424   esac
 425 fi
 426
 427 # Assign floating point type.  Most processors with FP support
 428 # IEEE FP.  On those that don't support FP at all, usually IEEE
 429 # is emulated.
 430 case ${target_cpu} in
 431   vax | tahoe ) atof=${target_cpu} ;;
 432   pdp11)        atof=vax ;;
 433   *)            atof=ieee ;;
 434 esac
 435
 436 case "${obj_format}" in
 437   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 438 esac
 439
 440 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 441 cgen_cpu_prefix=""
 442 if test $using_cgen = yes ; then
 443   case ${target_cpu} in
 444     *) cgen_cpu_prefix=${target_cpu} ;;
 445   esac
 446   AC_SUBST(cgen_cpu_prefix)
 447   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 448 fi
 449
 450 dnl
 451 dnl Make sure the desired support files exist.
 452 dnl
 453
 454 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 455   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 456 fi
 457
 458 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 459   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 460 fi
 461
 462 case ${user_bfd_gas}-${primary_bfd_gas} in
 463   yes-yes | no-no)
 464     # We didn't override user's choice.
 465     ;;
 466   no-yes)
 467     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 468     ;;
 469   no-preferred)
 470     primary_bfd_gas=no
 471     ;;
 472   *-preferred)
 473     primary_bfd_gas=yes
 474     ;;
 475   yes-*)
 476     primary_bfd_gas=yes
 477     ;;
 478   -*)
 479     # User specified nothing.
 480     ;;
 481 esac
 482
 483 # Some COFF configurations want these random other flags set.
 484 case ${obj_format} in
 485   coff)
 486     case ${target_cpu_type} in
 487       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 488       m68k) AC_DEFINE(M68KCOFF, 1, [Using m68k COFF?]) ;;
 489       m88k) AC_DEFINE(M88KCOFF, 1, [Using m88k COFF?]) ;;
 490     esac
 491     ;;
 492 esac
 493
 494 # Getting this done right is going to be a bitch.  Each configuration specified
 495 # with --enable-targets=... should be checked for environment, format, cpu, and
 496 # bfd_gas setting.
 497 #
 498 # For each configuration, the necessary object file support code must be linked
 499 # in.  This might be only one, it might be up to four.  The necessary emulation
 500 # code needs to be provided, too.
 501 #
 502 # And then there's "--enable-targets=all"....
 503 #
 504 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 505
 506 formats="${obj_format}"
 507 emfiles=""
 508 EMULATIONS=""
 509 GAS_UNIQ(emulations)
 510 for em in . $emulations ; do
 511   case $em in
 512     .)  continue ;;
 513     mipsbelf | mipslelf | mipself)
 514         fmt=elf   file=mipself ;;
 515     mipsbecoff | mipslecoff | mipsecoff)
 516         fmt=ecoff file=mipsecoff ;;
 517     *coff)
 518         fmt=coff  file=$em ;;
 519     *aout)
 520         fmt=aout file=$em ;;
 521     *elf)
 522         fmt=elf file=$em ;;
 523   esac
 524   formats="$formats $fmt"
 525   emfiles="$emfiles e-$file.o"
 526   EMULATIONS="$EMULATIONS &$em,"
 527 done
 528 GAS_UNIQ(formats)
 529 GAS_UNIQ(emfiles)
 530 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 531   for fmt in $formats ; do
 532     case $fmt in
 533       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 534       bout)     AC_DEFINE(OBJ_MAYBE_BOUT, 1,    [b.out support?])   ;;
 535       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 536       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 537       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 538       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 539       hp300)    AC_DEFINE(OBJ_MAYBE_HP300, 1,   [HP300 support?])   ;;
 540       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE, 1,    [IEEE support?])    ;;
 541       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 542     esac
 543     extra_objects="$extra_objects obj-$fmt.o"
 544   done
 545   obj_format=multi
 546 fi
 547 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 548   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 549   # e-mips* has more than one emulation per file, e-i386* has just one at the
 550   # moment.  If only one emulation is specified, then don't define
 551   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 552   case "${obj_format}${emfiles}" in
 553     multi* | *mips*)
 554       extra_objects="$extra_objects $emfiles"
 555       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 556   esac
 557 fi
 558 AC_SUBST(extra_objects)
 559 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 560 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 561                    [Default emulation.])
 562
 563 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 564   yes-*-coff)   need_bfd=yes ;;
 565   no-*-coff)    need_bfd=yes
 566                 AC_DEFINE(MANY_SEGMENTS, 1, [old COFF support?]) ;;
 567 esac
 568
 569 reject_dev_configs=yes
 570
 571 case ${reject_dev_configs}-${dev} in
 572   yes-yes) # Oops.
 573     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 574     ;;
 575 esac
 576
 577 AC_SUBST(target_cpu_type)
 578 AC_SUBST(obj_format)
 579 AC_SUBST(te_file)
 580 AC_SUBST(install_tooldir)
 581 AC_SUBST(atof)
 582 dnl AC_SUBST(emulation)
 583
 584 case "${primary_bfd_gas}" in
 585   yes)  AC_DEFINE(BFD_ASSEMBLER, 1, [Use BFD interface?])
 586         need_bfd=yes ;;
 587 esac
 588
 589 # do we need the opcodes library?
 590 case "${need_opcodes}" in
 591 yes)
 592   OPCODES_LIB=../opcodes/libopcodes.la
 593   ;;
 594 esac
 595
 596 case "${need_bfd}" in
 597 yes)
 598   BFDLIB=../bfd/libbfd.la
 599   BFDVER_H=../bfd/bfdver.h
 600   ALL_OBJ_DEPS="$ALL_OBJ_DEPS"' ../bfd/bfd.h $(INCDIR)/symcat.h'
 601   ;;
 602 esac
 603
 604 AC_SUBST(BFDLIB)
 605 AC_SUBST(OPCODES_LIB)
 606
 607 AC_SUBST(BFDVER_H)
 608 AC_SUBST(ALL_OBJ_DEPS)
 609
 610 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 611 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 612 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 613 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 614 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 615
 616 AC_PROG_CC
 617
 618 AC_PROG_YACC
 619 AM_PROG_LEX
 620
 621 ALL_LINGUAS="fr tr es rw"
 622 CY_GNU_GETTEXT
 623
 624 AM_MAINTAINER_MODE
 625 AC_EXEEXT
 626
 627 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 628
 629 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 630 # people who are not cross-compiling but are compiling cross-assemblers.
 631 AC_MSG_CHECKING(whether compiling a cross-assembler)
 632 if test "${host}" = "${target}"; then
 633   cross_gas=no
 634 else
 635   cross_gas=yes
 636   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 637 fi
 638 AC_MSG_RESULT($cross_gas)
 639
 640 dnl ansidecl.h will deal with const
 641 dnl AC_CONST
 642 AC_FUNC_ALLOCA
 643 AC_C_INLINE
 644
 645 # VMS doesn't have unlink.
 646 AC_CHECK_FUNCS(unlink remove, break)
 647
 648 # Some systems don't have sbrk().
 649 AC_CHECK_FUNCS(sbrk)
 650
 651 # do we need the math library?
 652 case "${need_libm}" in
 653 yes)
 654   AC_CHECK_LIBM
 655   AC_SUBST(LIBM)
 656   ;;
 657 esac
 658
 659 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 660 # enough, but on some of those systems, the assert macro relies on requoting
 661 # working properly!
 662 GAS_WORKING_ASSERT
 663
 664 # On some systems, the system header files may not declare malloc, realloc,
 665 # and free.  There are places where gas needs these functions to have been
 666 # declared -- such as when taking their addresses.
 667 gas_test_headers="
 668 #ifdef HAVE_MEMORY_H
 669 #include <memory.h>
 670 #endif
 671 #ifdef HAVE_STRING_H
 672 #include <string.h>
 673 #else
 674 #ifdef HAVE_STRINGS_H
 675 #include <strings.h>
 676 #endif
 677 #endif
 678 #ifdef HAVE_STDLIB_H
 679 #include <stdlib.h>
 680 #endif
 681 #ifdef HAVE_UNISTD_H
 682 #include <unistd.h>
 683 #endif
 684 "
 685
 686 # Does errno.h declare errno, or do we have to add a separate declaration
 687 # for it?
 688 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 689 #ifdef HAVE_ERRNO_H
 690 #include <errno.h>
 691 #endif
 692 ])
 693
 694 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 695 AC_CACHE_VAL(gas_cv_decl_getopt_unistd_h,
 696 [AC_TRY_COMPILE([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);],
 697 gas_cv_decl_getopt_unistd_h=yes, gas_cv_decl_getopt_unistd_h=no)])
 698 AC_MSG_RESULT($gas_cv_decl_getopt_unistd_h)
 699 if test $gas_cv_decl_getopt_unistd_h = yes; then
 700   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 701             [Is the prototype for getopt in <unistd.h> in the expected format?])
 702 fi
 703
 704 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
 705 GAS_CHECK_DECL_NEEDED(ffs, f, int (*f)(int), $gas_test_headers)
 706 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 707 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 708 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
 709 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
 710
 711 dnl This must come last.
 712
 713 dnl We used to make symlinks to files in the source directory, but now
 714 dnl we just use the right name for .c files, and create .h files in
 715 dnl the build directory which include the right .h file.  Make sure
 716 dnl the old symlinks don't exist, so that a reconfigure in an existing
 717 dnl directory behaves reasonably.
 718
 719 AC_CONFIG_FILES(Makefile doc/Makefile po/Makefile.in:po/Make-in)
 720 AC_CONFIG_COMMANDS([default],
 721 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
 722  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
 723  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
 724  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
 725  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
 726  if test "x$cgen_cpu_prefix" != x ; then
 727    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
 728  fi
 729
 730  sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile],
 731 [target_cpu_type=${target_cpu_type}
 732  cgen_cpu_prefix=${cgen_cpu_prefix}
 733  obj_format=${obj_format}
 734  te_file=${te_file}])
 735
 736 AC_OUTPUT