gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 dnl v2.5 needed for --bindir et al
   8 AC_PREREQ(2.57)
   9 AC_INIT(as.h)
  10
  11 dnl Autoconf 2.57 will find the aux dir without this.  However, unless
  12 dnl we specify this explicitly, automake-1.7 will assume that ylwrap is in
  13 dnl gas/ instead of gas/../.
  14 AC_CONFIG_AUX_DIR(..)
  15 AC_CANONICAL_SYSTEM
  16 AC_ISC_POSIX
  17
  18 changequote(,)dnl
  19 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  20 changequote([,])dnl
  21 AM_INIT_AUTOMAKE(gas, ${BFD_VERSION})
  22
  23 AM_PROG_LIBTOOL
  24
  25 user_bfd_gas=
  26 AC_ARG_ENABLE(bfd-assembler,
  27 [  --enable-bfd-assembler  use BFD back end for writing object files],
  28 [case "${enableval}" in
  29   yes) need_bfd=yes user_bfd_gas=yes ;;
  30   no)  user_bfd_gas=no ;;
  31   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  32 esac])dnl
  33 AC_ARG_ENABLE(targets,
  34 [    targets            alternative target configurations besides the primary],
  35 [case "${enableval}" in
  36   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  37             ;;
  38   no)       enable_targets= ;;
  39   *)        enable_targets=$enableval ;;
  40 esac])dnl
  41 AC_ARG_ENABLE(commonbfdlib,
  42 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  43 [case "${enableval}" in
  44   yes) commonbfdlib=true ;;
  45   no)  commonbfdlib=false ;;
  46   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  47 esac])dnl
  48
  49 using_cgen=no
  50
  51 build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
  52 AC_ARG_ENABLE(build-warnings,
  53 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  54 [case "${enableval}" in
  55   yes)  ;;
  56   no)   build_warnings="-w";;
  57   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  58         build_warnings="${build_warnings} ${t}";;
  59   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  60         build_warnings="${t} ${build_warnings}";;
  61   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  62 esac
  63 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  64   echo "Setting warning flags = $build_warnings" 6>&1
  65 fi])dnl
  66 WARN_CFLAGS=""
  67 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  68     WARN_CFLAGS="${build_warnings}"
  69 fi
  70 AC_SUBST(WARN_CFLAGS)
  71
  72 # Generate a header file
  73 AM_CONFIG_HEADER(config.h:config.in)
  74
  75 # If we are on a DOS filesystem, we must use gdb.ini rather than
  76 # .gdbinit.
  77 case "${host}" in
  78   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-windows*)
  79     GDBINIT="gdb.ini"
  80     AC_CONFIG_FILES(gdb.ini:gdbinit.in)
  81     ;;
  82   *)
  83     GDBINIT=".gdbinit"
  84     AC_CONFIG_FILES(.gdbinit:gdbinit.in)
  85     ;;
  86 esac
  87 AC_SUBST(GDBINIT)
  88
  89 te_file=generic
  90
  91 # Makefile target for installing gas in $(tooldir)/bin.
  92 install_tooldir=install-exec-tooldir
  93
  94 canon_targets=""
  95 all_targets=no
  96 if test -n "$enable_targets" ; then
  97   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  98     if test $t = "all"; then
  99       all_targets=yes
 100       continue
 101     fi
 102     result=`$ac_config_sub $t 2>/dev/null`
 103     if test -n "$result" ; then
 104       canon_targets="$canon_targets $result"
 105 #    else
 106 #      # Permit "all", etc.  We don't support it yet though.
 107 #      canon_targets="$canon_targets $t"
 108     fi
 109   done
 110   GAS_UNIQ(canon_targets)
 111 fi
 112
 113 emulations=""
 114
 115 for this_target in $target $canon_targets ; do
 116
 117 changequote(,)dnl
 118     eval `echo $this_target | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/cpu=\1 vendor=\2 os=\3/'`
 119 changequote([,])dnl
 120
 121     # Check for architecture variants.
 122     # Note: This table is alpha-sorted, please try to keep it that way.
 123     arch=
 124     endian=
 125     case ${cpu} in
 126       am33_2.0)         cpu_type=mn10300 endian=little ;;
 127       alpha*)           cpu_type=alpha ;;
 128       arm*be|xscale*be|strongarm*be | \
 129       arm*b|xscale*b|strongarm*b) cpu_type=arm endian=big ;;
 130       arm*|xscale*|strongarm*)    cpu_type=arm endian=little ;;
 131       c4x*)             cpu_type=tic4x ;;
 132       crx*)             cpu_type=crx endian=little ;;
 133       hppa*)            cpu_type=hppa ;;
 134 changequote(,)dnl
 135       i[3-7]86)         cpu_type=i386 arch=i386;;
 136       ia64)             cpu_type=ia64 ;;
 137       ip2k)             cpu_type=ip2k endian=big ;;
 138       iq2000)           cpu_type=iq2000 endian=big ;;
 139       m32r)             cpu_type=m32r target_cpu=m32r endian=big ;;
 140       m32rle)           cpu_type=m32r target_cpu=m32r endian=little ;;
 141       m6811|m6812|m68hc12) cpu_type=m68hc11 ;;
 142       m680[012346]0)    cpu_type=m68k ;;
 143 changequote([,])dnl
 144       m68008)           cpu_type=m68k ;;
 145       m683??)           cpu_type=m68k ;;
 146       m5200)            cpu_type=m68k ;;
 147       m8*)              cpu_type=m88k ;;
 148       mips*el)          cpu_type=mips endian=little ;;
 149       mips*)            cpu_type=mips endian=big ;;
 150       or32*)            cpu_type=or32 endian=big ;;
 151       pjl*)             cpu_type=pj endian=little ;;
 152       pj*)              cpu_type=pj endian=big ;;
 153       powerpc*le*)      cpu_type=ppc endian=little ;;
 154       powerpc*)         cpu_type=ppc endian=big ;;
 155       rs6000*)          cpu_type=ppc ;;
 156       s390x*)           cpu_type=s390 arch=s390x ;;
 157       s390*)            cpu_type=s390 arch=s390 ;;
 158       sh5*)             cpu_type=sh64 endian=big ;;
 159       sh5le*)           cpu_type=sh64 endian=little ;;
 160       sh64*)            cpu_type=sh64 endian=big ;;
 161       sh64le*)          cpu_type=sh64 endian=little ;;
 162       sh*le)            cpu_type=sh endian=little ;;
 163       sh*)              cpu_type=sh endian=big ;;
 164       sparclite*)       cpu_type=sparc arch=sparclite ;;
 165       sparclet*)        cpu_type=sparc arch=sparclet ;;
 166       sparc64*)         cpu_type=sparc arch=v9-64 ;;
 167       sparc86x*)        cpu_type=sparc arch=sparc86x  ;;
 168       sparc*)           cpu_type=sparc arch=sparclite ;; # ??? See tc-sparc.c.
 169       v850*)            cpu_type=v850 ;;
 170       x86_64)           cpu_type=i386 arch=x86_64;;
 171       xtensa*)          cpu_type=xtensa arch=xtensa ;;
 172       *)                cpu_type=${cpu} ;;
 173     esac
 174
 175     if test ${this_target} = $target ; then
 176       target_cpu_type=${cpu_type}
 177     elif test ${target_cpu_type} != ${cpu_type} ; then
 178       continue
 179     fi
 180
 181     generic_target=${cpu_type}-$vendor-$os
 182     dev=no
 183     bfd_gas=no
 184     em=generic
 185
 186     # Assign object format.
 187     # Note: This table is alpha-sorted, please try to keep it that way.
 188     case ${generic_target} in
 189       a29k-*-coff)                      fmt=coff ;;
 190       a29k-amd-udi)                     fmt=coff ;;
 191       a29k-amd-ebmon)                   fmt=coff ;;
 192       a29k-nyu-sym1)                    fmt=coff ;;
 193       a29k-*-rtems*)                    fmt=coff ;;
 194       a29k-*-vxworks*)                  fmt=coff ;;
 195
 196       alpha*-*-*vms*)                   fmt=evax ;;
 197       alpha*-*-osf*)                    fmt=ecoff ;;
 198       alpha*-*-linuxecoff*)             fmt=ecoff ;;
 199       alpha*-*-linux-gnu*)              fmt=elf em=linux ;;
 200       alpha*-*-netbsd*)                 fmt=elf em=nbsd ;;
 201       alpha*-*-openbsd*)                fmt=elf em=obsd ;;
 202
 203       arc-*-elf*)                       fmt=elf ;;
 204
 205       arm-*-aout)                       fmt=aout ;;
 206       arm-*-coff | thumb-*-coff)        fmt=coff ;;
 207       arm-*-rtems* | thumb-*-rtems*)    fmt=elf ;;
 208       arm-*-elf | thumb-*-elf)          fmt=elf ;;
 209       arm*-*-eabi*)                     fmt=elf ;;
 210       arm*-*-symbianelf*)               fmt=elf em=symbian ;;
 211       arm-*-kaos*)                      fmt=elf ;;
 212       arm*-*-conix*)                    fmt=elf ;;
 213       arm-*-linux*aout*)                fmt=aout em=linux ;;
 214       arm*-*-linux-gnu*)                fmt=elf  em=linux ;;
 215       arm*-*-uclinux*)                  fmt=elf  em=linux ;;
 216       arm-*-netbsdelf*)                 fmt=elf  em=nbsd ;;
 217       arm-*-*n*bsd*)                    fmt=aout em=nbsd ;;
 218       arm-**-nto*)                      fmt=elf ;;
 219       arm-*-oabi | thumb-*-oabi)        fmt=elf ;;
 220       arm-epoc-pe | thumb-epoc-pe)      fmt=coff em=epoc-pe ;;
 221       arm-wince-pe | arm-*-wince)       fmt=coff em=wince-pe ;;
 222       arm-*-pe | thumb-*-pe)            fmt=coff em=pe ;;
 223       arm-*-riscix*)                    fmt=aout em=riscix ;;
 224
 225       avr-*-*)                          fmt=elf ;;
 226
 227       cris-*-linux-gnu*)                fmt=multi bfd_gas=yes em=linux ;;
 228       cris-*-*)                         fmt=multi bfd_gas=yes ;;
 229
 230       crx-*-elf*)                       fmt=elf ;;
 231
 232       d10v-*-*)                         fmt=elf ;;
 233       d30v-*-*)                         fmt=elf ;;
 234       dlx-*-*)                          fmt=elf ;;
 235
 236       fr30-*-*)                         fmt=elf ;;
 237       frv-*-*linux*)                    fmt=elf em=linux;;
 238       frv-*-*)                          fmt=elf ;;
 239
 240       hppa-*-linux*)    case ${cpu} in
 241                             hppa*64*)   fmt=elf em=hppalinux64;;
 242                             hppa*)      fmt=elf em=linux;;
 243                         esac ;;
 244       hppa-*-*elf*)                     fmt=elf em=hppa ;;
 245       hppa-*-lites*)                    fmt=elf em=hppa ;;
 246       hppa-*-netbsd*)                   fmt=elf em=nbsd ;;
 247       hppa-*-openbsd*)                  fmt=elf em=hppa ;;
 248       hppa-*-osf*)                      fmt=som em=hppa ;;
 249       hppa-*-rtems*)                    fmt=elf em=hppa ;;
 250       hppa-*-hpux11*)   case ${cpu} in
 251                             hppa*64*)   fmt=elf em=hppa64 ;;
 252                             hppa*)      fmt=som em=hppa ;;
 253                         esac ;;
 254       hppa-*-hpux*)                     fmt=som em=hppa ;;
 255       hppa-*-mpeix*)                    fmt=som em=hppa ;;
 256       hppa-*-bsd*)                      fmt=som em=hppa ;;
 257       hppa-*-hiux*)                     fmt=som em=hppa ;;
 258
 259       h8300-*-rtems*)                   fmt=coff ;;
 260       h8300-*-coff)                     fmt=coff ;;
 261       h8300-*-elf)                      fmt=elf ;;
 262       h8500-*-rtems*)                   fmt=coff ;;
 263       h8500-*-coff)                     fmt=coff ;;
 264
 265       i370-*-elf* | i370-*-linux*)      fmt=elf ;;
 266       i386-ibm-aix*)                    fmt=coff em=i386aix ;;
 267       i386-sequent-bsd*)                fmt=aout em=dynix ;;
 268       i386-*-beospe*)                   fmt=coff em=pe ;;
 269       i386-*-beos*)                     fmt=elf ;;
 270       i386-*-coff)                      fmt=coff ;;
 271       i386-*-elf)                       fmt=elf ;;
 272       i386-*-kaos*)                     fmt=elf ;;
 273       i386-*-bsd*)                      fmt=aout em=386bsd ;;
 274       i386-*-netbsd0.8)                 fmt=aout em=386bsd ;;
 275       i386-*-netbsdpe*)                 fmt=coff em=pe ;;
 276       i386-*-netbsd*-gnu* | \
 277       i386-*-knetbsd*-gnu | \
 278       i386-*-netbsdelf*)                fmt=elf em=nbsd ;;
 279       i386-*-*n*bsd*)   case ${cpu} in
 280                             x86_64)     fmt=elf em=nbsd ;;
 281                             *)          fmt=aout em=nbsd ;;
 282                         esac ;;
 283       i386-*-linux*aout*)               fmt=aout em=linux ;;
 284       i386-*-linux*oldld)               fmt=aout em=linux ;;
 285       i386-*-linux*coff*)               fmt=coff em=linux ;;
 286       i386-*-linux-gnu*)                fmt=elf em=linux ;;
 287       x86_64-*-linux-gnu*)              fmt=elf em=linux ;;
 288       i386-*-lynxos*)                   fmt=elf em=lynx bfd_gas=yes ;;
 289 changequote(,)dnl
 290       i386-*-sysv[45]*)                 fmt=elf ;;
 291       i386-*-solaris*)                  fmt=elf ;;
 292       i386-*-freebsdaout*)              fmt=aout em=386bsd ;;
 293       i386-*-freebsd[12].*)             fmt=aout em=386bsd ;;
 294       i386-*-freebsd[12])               fmt=aout em=386bsd ;;
 295 changequote([,])dnl
 296       i386-*-freebsd* | i386-*-kfreebsd*-gnu)
 297                                         fmt=elf em=freebsd ;;
 298       i386-*-sysv*)                     fmt=coff ;;
 299       i386-*-sco3.2v5*coff)             fmt=coff ;;
 300       i386-*-isc*)                      fmt=coff ;;
 301       i386-*-sco3.2v5*)                 fmt=elf
 302           if test ${this_target} = $target; then
 303             AC_DEFINE(SCO_ELF, 1, [Define if defaulting to ELF on SCO 5.])
 304           fi ;;
 305       i386-*-sco3.2*)                   fmt=coff ;;
 306       i386-*-vsta)                      fmt=aout ;;
 307       i386-*-msdosdjgpp* \
 308       | i386-*-go32* \
 309       | i386-go32-rtems*)               fmt=coff em=go32
 310             AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?]) ;;
 311       i386-*-rtemself*)                 fmt=elf ;;
 312       i386-*-rtemscoff*)                fmt=coff ;;
 313       i386-*-rtems*)                    fmt=elf ;;
 314       i386-*-gnu*)                      fmt=elf ;;
 315       i386-*-mach*)                     fmt=aout em=mach ;;
 316       i386-*-msdos*)                    fmt=aout ;;
 317       i386-*-moss*)                     fmt=elf ;;
 318       i386-*-pe)                        fmt=coff em=pe ;;
 319       i386-*-cygwin*)                   fmt=coff em=pe ;;
 320       i386-*-interix*)                  fmt=coff em=interix ;;
 321       i386-*-mingw32*)                  fmt=coff em=pe ;;
 322       i386-*-nto-qnx*)                  fmt=elf ;;
 323       i386-*-*nt*)                      fmt=coff em=pe ;;
 324       i386-*-chaos)                     fmt=elf ;;
 325
 326       i860-*-*)                         fmt=elf endian=little
 327                 AC_MSG_WARN(GAS support for ${generic_target} is preliminary and a work in progress) ;;
 328       i960-*-bout)                      fmt=bout ;;
 329       i960-*-coff)                      fmt=coff em=ic960 ;;
 330       i960-*-rtems*)                    fmt=coff em=ic960 ;;
 331       i960-*-nindy*)                    fmt=bout ;;
 332       i960-*-vxworks5.0)                fmt=bout ;;
 333       i960-*-vxworks5.*)                fmt=coff em=ic960 ;;
 334       i960-*-vxworks*)                  fmt=bout ;;
 335       i960-*-elf*)                      fmt=elf ;;
 336
 337       ia64-*-elf*)                      fmt=elf ;;
 338       ia64-*-aix*)                      fmt=elf em=ia64aix ;;
 339       ia64-*-linux-gnu*)                fmt=elf em=linux ;;
 340       ia64-*-hpux*)                     fmt=elf em=hpux ;;
 341       ia64-*-netbsd*)                   fmt=elf em=nbsd ;;
 342
 343       ip2k-*-*)                         fmt=elf ;;
 344
 345       iq2000-*-elf)                     fmt=elf bfd_gas=yes ;;
 346
 347       m32r-*-elf*)                      fmt=elf ;;
 348       m32r-*-linux*)                    fmt=elf em=linux;;
 349
 350       m68hc11-*-* | m6811-*-*)          fmt=elf ;;
 351       m68hc12-*-* | m6812-*-*)          fmt=elf ;;
 352
 353       m68k-*-vxworks*)                  fmt=aout em=sun3 ;;
 354       m68k-ericsson-ose)                fmt=aout em=sun3 ;;
 355       m68k-*-sunos*)                    fmt=aout em=sun3 ;;
 356       m68k-motorola-sysv*)              fmt=coff em=delta ;;
 357       m68k-bull-sysv3*)                 fmt=coff em=dpx2 ;;
 358       m68k-apollo-*)                    fmt=coff em=apollo ;;
 359       m68k-*-elf*)                      fmt=elf ;;
 360       m68k-*-sysv4*)                    fmt=elf em=svr4 ;;
 361       m68k-*-sysv*)                     fmt=coff ;;
 362       m68k-*-coff | m68k-*-rtemscoff*)  fmt=coff ;;
 363       m68k-*-rtems*)                    fmt=elf ;;
 364       m68k-*-hpux*)                     fmt=hp300 em=hp300 ;;
 365       m68k-*-linux*aout*)               fmt=aout em=linux ;;
 366       m68k-*-linux-gnu*)                fmt=elf em=linux ;;
 367       m68k-*-uclinux*)                  fmt=elf ;;
 368       m68k-*-gnu*)                      fmt=elf ;;
 369       m68k-*-lynxos*)                   fmt=coff em=lynx ;;
 370       m68k-*-netbsdelf*)                fmt=elf em=nbsd ;;
 371       m68k-*-netbsd*)                   fmt=aout em=nbsd bfd_gas=yes ;;
 372       m68k-*-openbsd*)                  fmt=aout em=nbsd bfd_gas=yes ;;
 373       m68k-apple-aux*)                  fmt=coff em=aux ;;
 374       m68k-*-psos*)                     fmt=elf em=psos;;
 375
 376       m88k-motorola-sysv3*)             fmt=coff em=delt88 ;;
 377       m88k-*-coff*)                     fmt=coff ;;
 378
 379       mcore-*-elf)                      fmt=elf ;;
 380       mcore-*-pe)                       fmt=coff em=pe bfd_gas=yes ;;
 381
 382       # don't change em like *-*-bsd does
 383       mips-dec-openbsd*)                fmt=elf endian=little ;;
 384       mips-sony-bsd*)                   fmt=ecoff ;;
 385       mips-*-bsd*)
 386             AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.) ;;
 387       mips-*-ultrix*)                   fmt=ecoff endian=little ;;
 388       mips-*-osf*)                      fmt=ecoff endian=little ;;
 389       mips-*-ecoff*)                    fmt=ecoff ;;
 390       mips-*-pe*)                       fmt=coff endian=little em=pe ;;
 391       mips-*-irix6*)                    fmt=elf em=irix ;;
 392       mips-*-irix5*)                    fmt=elf em=irix ;;
 393       mips-*-irix*)                     fmt=ecoff em=irix ;;
 394       mips-*-lnews*)                    fmt=ecoff em=lnews ;;
 395       mips-*-riscos*)                   fmt=ecoff ;;
 396       mips*-*-linux*)                   fmt=elf em=tmips ;;
 397       mips-*-sysv4*MP* | mips-*-gnu*)   fmt=elf em=tmips ;;
 398       mips-*-sysv*)                     fmt=ecoff ;;
 399       mips-*-elf* | mips-*-rtems*)      fmt=elf ;;
 400       mips-*-netbsd*)                   fmt=elf ;;
 401       mips-*-openbsd*)                  fmt=elf ;;
 402
 403       mmix-*-*)                         fmt=elf ;;
 404       mn10200-*-*)                      fmt=elf ;;
 405       # cpu_type for am33_2.0 is set to mn10300
 406       mn10300-*-linux*)                 fmt=elf bfd_gas=yes em=linux ;;
 407       mn10300-*-*)                      fmt=elf ;;
 408
 409       msp430-*-*)                       fmt=elf ;;
 410
 411       ns32k-pc532-mach*)                fmt=aout em=pc532mach ;;
 412       ns32k-pc532-ux*)                  fmt=aout em=pc532mach ;;
 413       ns32k-pc532-lites*)               fmt=aout em=nbsd532 ;;
 414       ns32k-*-*n*bsd*)                  fmt=aout em=nbsd532 ;;
 415
 416       openrisc-*-*)                     fmt=elf ;;
 417       or32-*-rtems*)                    fmt=elf ;;
 418       or32-*-coff)                      fmt=coff ;;
 419       or32-*-elf)                       fmt=elf ;;
 420
 421       pj*)                              fmt=elf ;;
 422
 423       ppc-*-pe | ppc-*-cygwin*)         fmt=coff em=pe ;;
 424       ppc-*-winnt*)                     fmt=coff em=pe ;;
 425 changequote(,)dnl
 426       ppc-*-aix5.[01])                  fmt=coff em=aix5 ;;
 427 changequote([,])dnl
 428       ppc-*-aix5.*)                     fmt=coff em=aix5
 429         AC_DEFINE(AIX_WEAK_SUPPORT, 1,
 430                   [Define if using AIX 5.2 value for C_WEAKEXT.])
 431       ;;
 432       ppc-*-aix*)                       fmt=coff ;;
 433       ppc-*-beos*)                      fmt=coff ;;
 434       ppc-*-*n*bsd* | ppc-*-elf*)       fmt=elf ;;
 435       ppc-*-eabi* | ppc-*-sysv4*)       fmt=elf ;;
 436       ppc-*-linux-gnu*)                 fmt=elf em=linux
 437             case "$endian" in
 438                 big)  ;;
 439                 *)    AC_MSG_ERROR(GNU/Linux must be configured big endian) ;;
 440             esac ;;
 441       ppc-*-solaris*)                   fmt=elf
 442             if test ${this_target} = $target; then
 443                 AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 444                           [Define if default target is PowerPC Solaris.])
 445             fi
 446             if test x${endian} = xbig; then
 447                 AC_MSG_ERROR(Solaris must be configured little endian)
 448             fi ;;
 449       ppc-*-rtems*)                     fmt=elf ;;
 450       ppc-*-macos*)                     fmt=coff em=macos ;;
 451       ppc-*-nto*)                       fmt=elf ;;
 452       ppc-*-kaos*)                      fmt=elf ;;
 453       ppc-*-lynxos*)                    fmt=elf em=lynx bfd_gas=yes ;;
 454
 455       s390x-*-linux-gnu*)               fmt=elf em=linux ;;
 456       s390-*-linux-gnu*)                fmt=elf em=linux ;;
 457
 458       sh*-*-linux*)                     fmt=elf em=linux
 459             case ${cpu} in
 460                 sh*eb)  endian=big ;;
 461                 *)      endian=little ;;
 462             esac ;;
 463       sh5*-*-netbsd*)                   fmt=elf em=nbsd ;;
 464       sh64*-*-netbsd*)                  fmt=elf em=nbsd ;;
 465       sh*-*-netbsdelf*)                 fmt=elf em=nbsd ;;
 466       sh*-*-symbianelf*)                fmt=elf endian=little
 467                 AC_DEFINE(TARGET_SYMBIAN, 1, [Define if target is Symbian OS.])
 468                 ;;
 469       sh-*-elf*)                        fmt=elf ;;
 470       sh-*-coff*)                       fmt=coff ;;
 471       sh-*-nto*)                        fmt=elf ;;
 472       sh-*-pe*)                         fmt=coff em=pe bfd_gas=yes endian=little ;;
 473       sh-*-rtemscoff*)                  fmt=coff ;;
 474       sh-*-rtems*)                      fmt=elf ;;
 475       sh-*-kaos*)                       fmt=elf ;;
 476       shle*-*-kaos*)                    fmt=elf ;;
 477       sh64-*-elf*)                      fmt=elf ;;
 478
 479       sparc-*-rtemsaout*)               fmt=aout ;;
 480       sparc-*-rtemself*)                fmt=elf ;;
 481       sparc-*-rtems*)                   fmt=elf ;;
 482       sparc-*-sunos4*)                  fmt=aout em=sun3 ;;
 483       sparc-*-aout | sparc*-*-vxworks*) fmt=aout em=sparcaout ;;
 484       sparc-*-coff)                     fmt=coff ;;
 485       sparc-*-linux*aout*)              fmt=aout em=linux ;;
 486       sparc-*-linux-gnu*)               fmt=elf em=linux ;;
 487       sparc-*-lynxos*)                  fmt=coff em=lynx ;;
 488       sparc-fujitsu-none)               fmt=aout ;;
 489       sparc-*-elf)                      fmt=elf ;;
 490       sparc-*-sysv4*)                   fmt=elf ;;
 491       sparc-*-solaris*)                 fmt=elf ;;
 492       sparc-*-netbsdelf*)               fmt=elf em=nbsd ;;
 493       sparc-*-*n*bsd*)  case ${cpu} in
 494                             sparc64)    fmt=elf em=nbsd ;;
 495                             *)          fmt=aout em=nbsd ;;
 496                         esac ;;
 497       strongarm-*-coff)                 fmt=coff ;;
 498       strongarm-*-elf)                  fmt=elf ;;
 499       strongarm-*-kaos*)                fmt=elf ;;
 500
 501       tic30-*-*aout*)                   fmt=aout bfd_gas=yes ;;
 502       tic30-*-*coff*)                   fmt=coff bfd_gas=yes ;;
 503       tic4x-*-* | c4x-*-*)              fmt=coff bfd_gas=yes ;;
 504       tic54x-*-* | c54x*-*-*)           fmt=coff bfd_gas=yes need_libm=yes;;
 505       tic80-*-*)                        fmt=coff ;;
 506
 507       v850-*-*)                         fmt=elf ;;
 508       v850e-*-*)                        fmt=elf ;;
 509       v850ea-*-*)                       fmt=elf ;;
 510
 511       vax-*-netbsdelf*)                 fmt=elf em=nbsd ;;
 512       vax-*-netbsd*)                    fmt=aout em=nbsd ;;
 513       vax-*-bsd* | vax-*-ultrix*)       fmt=aout ;;
 514       vax-*-linux-gnu*)                 fmt=elf em=linux bfd_gas=yes ;;
 515       vax-*-vms)                        fmt=vms ;;
 516
 517       w65-*-*)                          fmt=coff ;;
 518
 519       xscale-*-coff)                    fmt=coff ;;
 520       xscale-*-elf)                     fmt=elf ;;
 521
 522       xstormy16-*-*)                    fmt=elf ;;
 523
 524       xtensa-*-*)                       fmt=elf ;;
 525
 526       z8k-*-coff | z8k-*-sim)           fmt=coff ;;
 527
 528       *-*-aout | *-*-scout)             fmt=aout ;;
 529       *-*-freebsd* | *-*-kfreebsd*-gnu) fmt=elf em=freebsd ;;
 530       *-*-nindy*)                       fmt=bout ;;
 531       *-*-bsd*)                         fmt=aout em=sun3 ;;
 532       *-*-generic)                      fmt=generic ;;
 533       *-*-xray | *-*-hms)               fmt=coff ;;
 534       *-*-sim)                          fmt=coff ;;
 535       *-*-elf | *-*-sysv4* | *-*-solaris*) fmt=elf dev=yes ;;
 536       *-*-aros*)                        fmt=elf em=linux bfd_gas=yes ;;
 537       *-*-vxworks | *-*-windiss)        fmt=elf ;;
 538       *-*-netware)                      fmt=elf em=netware ;;
 539     esac
 540
 541     if test ${this_target} = $target ; then
 542       endian_def=
 543       if test x${endian} = xbig; then
 544         endian_def=1
 545       elif test x${endian} = xlittle; then
 546         endian_def=0
 547       fi
 548       if test x${endian_def} != x; then
 549         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 550                            [Define as 1 if big endian.])
 551       fi
 552     fi
 553
 554     case ${cpu_type}-${fmt} in
 555         alpha*-* | arm-* | i386-* | ia64*-* | mips-* | ns32k-* \
 556                 | pdp11-* | ppc-* | sparc-* | strongarm-* | xscale-* \
 557                 | *-elf | *-ecoff | *-som)
 558             bfd_gas=yes ;;
 559     esac
 560
 561 # Other random stuff.
 562
 563     case ${cpu_type} in
 564       mips)
 565         # Set mips_cpu to the name of the default CPU.
 566         case ${target_cpu} in
 567           mips | mipsbe | mipseb | mipsle | mipsel | mips64 | mips64el)
 568             mips_cpu=from-abi
 569             ;;
 570           mipsisa32 | mipsisa32el)
 571             mips_cpu=mips32
 572             ;;
 573           mipsisa32r2 | mipsisa32r2el)
 574             mips_cpu=mips32r2
 575             ;;
 576           mipsisa64 | mipsisa64el)
 577             mips_cpu=mips64
 578             ;;
 579           mipsisa64r2 | mipsisa64r2el)
 580             mips_cpu=mips64r2
 581             ;;
 582           mipstx39 | mipstx39el)
 583             mips_cpu=r3900
 584             ;;
 585           mips64vr | mips64vrel)
 586             mips_cpu=vr4100
 587             ;;
 588           mipsisa32r2* | mipsisa64r2*)
 589 changequote(,)dnl
 590             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r2//' -e 's/el$//'`
 591 changequote([,])dnl
 592             ;;
 593           mips64* | mipsisa64* | mipsisa32*)
 594 changequote(,)dnl
 595             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..//' -e 's/el$//'`
 596 changequote([,])dnl
 597             ;;
 598           *)
 599             AC_ERROR($target_cpu isn't a supported MIPS CPU name)
 600             ;;
 601         esac
 602         # See whether it's appropriate to set E_MIPS_ABI_O32 for o32
 603         # binaries.  It's a GNU extension that some OSes don't understand.
 604         # The value only matters on ELF targets.
 605         case ${target} in
 606           *-*-irix*)
 607             use_e_mips_abi_o32=0
 608             ;;
 609           *)
 610             use_e_mips_abi_o32=1
 611             ;;
 612         esac
 613         # Decide whether to generate 32-bit or 64-bit code by default.
 614         # Used to resolve -march=from-abi when an embedded ABI is selected.
 615         case ${target} in
 616           mips64*-*-* | mipsisa64*-*-*)
 617             mips_default_64bit=1
 618             ;;
 619           *)
 620             mips_default_64bit=0
 621             ;;
 622         esac
 623         # Decide which ABI to target by default.
 624         case ${target} in
 625           mips64*-linux* | mips-sgi-irix6*)
 626             mips_default_abi=N32_ABI
 627             ;;
 628           mips*-linux*)
 629             mips_default_abi=O32_ABI
 630             ;;
 631           *)
 632             mips_default_abi=NO_ABI
 633             ;;
 634         esac
 635         AC_DEFINE_UNQUOTED(MIPS_CPU_STRING_DEFAULT, "$mips_cpu",
 636                            [Default CPU for MIPS targets. ])
 637         AC_DEFINE_UNQUOTED(USE_E_MIPS_ABI_O32, $use_e_mips_abi_o32,
 638                            [Allow use of E_MIPS_ABI_O32 on MIPS targets. ])
 639         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_64BIT, $mips_default_64bit,
 640                            [Generate 64-bit code by default on MIPS targets. ])
 641         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_ABI, $mips_default_abi,
 642                            [Choose a default ABI for MIPS targets. ])
 643         ;;
 644     esac
 645
 646     # Do we need the opcodes library?
 647     case ${cpu_type} in
 648       vax | i386 | tic30)
 649         ;;
 650
 651       *)
 652         need_opcodes=yes
 653
 654         case "${enable_shared}" in
 655         yes) shared_opcodes=true ;;
 656         *opcodes*) shared_opcodes=true ;;
 657         *) shared_opcodes=false ;;
 658         esac
 659         if test "${shared_opcodes}" = "true"; then
 660           # A shared libopcodes must be linked against libbfd.
 661           need_bfd=yes
 662         fi
 663         ;;
 664     esac
 665
 666     # Any other special object files needed ?
 667     case ${cpu_type} in
 668       fr30 | ip2k | iq2000 | m32r | openrisc)
 669         using_cgen=yes
 670         ;;
 671
 672       frv)
 673         using_cgen=yes
 674         ;;
 675       m68k)
 676         case ${extra_objects} in
 677         *m68k-parse.o*) ;;
 678         *) extra_objects="$extra_objects m68k-parse.o" ;;
 679         esac
 680         ;;
 681
 682       mips)
 683         echo ${extra_objects} | grep -s "itbl-parse.o"
 684         if test $? -ne 0 ; then
 685           extra_objects="$extra_objects itbl-parse.o"
 686         fi
 687
 688         echo ${extra_objects} | grep -s "itbl-lex.o"
 689         if test $? -ne 0 ; then
 690           extra_objects="$extra_objects itbl-lex.o"
 691         fi
 692
 693         echo ${extra_objects} | grep -s "itbl-ops.o"
 694         if test $? -ne 0 ; then
 695           extra_objects="$extra_objects itbl-ops.o"
 696         fi
 697         ;;
 698
 699       i386 | s390 | sparc)
 700         if test $this_target = $target ; then
 701           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 702         fi
 703         ;;
 704
 705       xstormy16)
 706         using_cgen=yes
 707         ;;
 708
 709       xtensa)
 710         echo ${extra_objects} | grep -s "xtensa-relax.o"
 711         if test $? -ne 0 ; then
 712           extra_objects="$extra_objects xtensa-relax.o"
 713         fi
 714         ;;
 715
 716       *)
 717         ;;
 718     esac
 719
 720     if test $using_cgen = yes ; then
 721         case "x${extra_objects}" in
 722         *cgen.o*) ;;
 723         *) extra_objects="$extra_objects cgen.o" ;;
 724         esac
 725     fi
 726
 727 # See if we really can support this configuration with the emulation code.
 728
 729     if test $this_target = $target ; then
 730       primary_bfd_gas=$bfd_gas
 731       obj_format=$fmt
 732       te_file=$em
 733
 734       if test $bfd_gas = no ; then
 735         # Can't support other configurations this way.
 736         break
 737       fi
 738     elif test $bfd_gas = no ; then
 739       # Can't support this configuration.
 740       break
 741     fi
 742
 743 # From target name and format, produce a list of supported emulations.
 744
 745     case ${generic_target}-${fmt} in
 746       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 747       mips*-*-linux*-*) case "$endian" in
 748                         big)    emulation="mipsbelf mipslelf mipself" ;;
 749                         *)      emulation="mipslelf mipsbelf mipself" ;;
 750                         esac ;;
 751       mips-*-lnews*-ecoff) ;;
 752       mips-*-*-ecoff)   case "$endian" in
 753                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 754                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 755                         esac ;;
 756       mips-*-*-elf)     case "$endian" in
 757                         big)    emulation="mipsbelf mipslelf mipself" ;;
 758                         *)      emulation="mipslelf mipsbelf mipself" ;;
 759                         esac ;;
 760       mips-*-sysv4*MP*-*) emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 761       # i386-pc-pe-coff != i386-pc-coff.
 762       i386-*-pe-coff)   ;;
 763       # Uncommenting the next line will turn on support for i386 AOUT
 764       # for the default linux configuration
 765       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 766       #
 767       i386-*-aout)      emulation="i386aout" ;;
 768       i386-*-coff)      emulation="i386coff" ;;
 769       i386-*-elf)       emulation="i386elf" ;;
 770
 771       # Always all formats.  The first stated emulation becomes the default.
 772       cris-*-*aout*)    emulation="crisaout criself" ;;
 773       cris-*-*)         emulation="criself crisaout" ;;
 774     esac
 775
 776     emulations="$emulations $emulation"
 777
 778 done
 779
 780 # Turn on all targets if possible
 781 if test ${all_targets} = "yes"; then
 782   case ${target_cpu_type} in
 783   i386)
 784     case ${obj_format} in
 785     aout)
 786       emulations="$emulations i386coff i386elf"
 787       ;;
 788     coff)
 789       emulations="$emulations i386aout i386elf"
 790     ;;
 791     elf)
 792       emulations="$emulations i386aout i386coff"
 793       ;;
 794     esac
 795   ;;
 796   esac
 797 fi
 798
 799 # Assign floating point type.  Most processors with FP support
 800 # IEEE FP.  On those that don't support FP at all, usually IEEE
 801 # is emulated.
 802 case ${target_cpu} in
 803   vax | tahoe ) atof=${target_cpu} ;;
 804   pdp11)        atof=vax ;;
 805   *)            atof=ieee ;;
 806 esac
 807
 808 case "${obj_format}" in
 809   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 810 esac
 811
 812 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 813 cgen_cpu_prefix=""
 814 if test $using_cgen = yes ; then
 815   case ${target_cpu} in
 816     *) cgen_cpu_prefix=${target_cpu} ;;
 817   esac
 818   AC_SUBST(cgen_cpu_prefix)
 819   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 820 fi
 821
 822 dnl
 823 dnl Make sure the desired support files exist.
 824 dnl
 825
 826 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 827   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 828 fi
 829
 830 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 831   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 832 fi
 833
 834 case ${user_bfd_gas}-${primary_bfd_gas} in
 835   yes-yes | no-no)
 836     # We didn't override user's choice.
 837     ;;
 838   no-yes)
 839     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 840     ;;
 841   no-preferred)
 842     primary_bfd_gas=no
 843     ;;
 844   *-preferred)
 845     primary_bfd_gas=yes
 846     ;;
 847   yes-*)
 848     primary_bfd_gas=yes
 849     ;;
 850   -*)
 851     # User specified nothing.
 852     ;;
 853 esac
 854
 855 # Some COFF configurations want these random other flags set.
 856 case ${obj_format} in
 857   coff)
 858     case ${target_cpu_type} in
 859       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 860       m68k) AC_DEFINE(M68KCOFF, 1, [Using m68k COFF?]) ;;
 861       m88k) AC_DEFINE(M88KCOFF, 1, [Using m88k COFF?]) ;;
 862     esac
 863     ;;
 864 esac
 865
 866 # Getting this done right is going to be a bitch.  Each configuration specified
 867 # with --enable-targets=... should be checked for environment, format, cpu, and
 868 # bfd_gas setting.
 869 #
 870 # For each configuration, the necessary object file support code must be linked
 871 # in.  This might be only one, it might be up to four.  The necessary emulation
 872 # code needs to be provided, too.
 873 #
 874 # And then there's "--enable-targets=all"....
 875 #
 876 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 877
 878 formats="${obj_format}"
 879 emfiles=""
 880 EMULATIONS=""
 881 GAS_UNIQ(emulations)
 882 for em in . $emulations ; do
 883   case $em in
 884     .)  continue ;;
 885     mipsbelf | mipslelf | mipself)
 886         fmt=elf   file=mipself ;;
 887     mipsbecoff | mipslecoff | mipsecoff)
 888         fmt=ecoff file=mipsecoff ;;
 889     *coff)
 890         fmt=coff  file=$em ;;
 891     *aout)
 892         fmt=aout file=$em ;;
 893     *elf)
 894         fmt=elf file=$em ;;
 895   esac
 896   formats="$formats $fmt"
 897   emfiles="$emfiles e-$file.o"
 898   EMULATIONS="$EMULATIONS &$em,"
 899 done
 900 GAS_UNIQ(formats)
 901 GAS_UNIQ(emfiles)
 902 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 903   for fmt in $formats ; do
 904     case $fmt in
 905       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 906       bout)     AC_DEFINE(OBJ_MAYBE_BOUT, 1,    [b.out support?])   ;;
 907       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 908       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 909       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 910       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 911       hp300)    AC_DEFINE(OBJ_MAYBE_HP300, 1,   [HP300 support?])   ;;
 912       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE, 1,    [IEEE support?])    ;;
 913       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 914       vms)      AC_DEFINE(OBJ_MAYBE_VMS, 1,     [VMS support?])     ;;
 915     esac
 916     extra_objects="$extra_objects obj-$fmt.o"
 917   done
 918   obj_format=multi
 919 fi
 920 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 921   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 922   # e-mips* has more than one emulation per file, e-i386* has just one at the
 923   # moment.  If only one emulation is specified, then don't define
 924   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 925   case "${obj_format}${emfiles}" in
 926     multi* | *mips*)
 927       extra_objects="$extra_objects $emfiles"
 928       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 929   esac
 930 fi
 931 AC_SUBST(extra_objects)
 932 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 933 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 934                    [Default emulation.])
 935
 936 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 937   yes-*-coff)   need_bfd=yes ;;
 938   no-*-coff)    need_bfd=yes
 939                 AC_DEFINE(MANY_SEGMENTS, 1, [old COFF support?]) ;;
 940 esac
 941
 942 reject_dev_configs=yes
 943
 944 case ${reject_dev_configs}-${dev} in
 945   yes-yes) # Oops.
 946     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 947     ;;
 948 esac
 949
 950 AC_SUBST(target_cpu_type)
 951 AC_SUBST(obj_format)
 952 AC_SUBST(te_file)
 953 AC_SUBST(install_tooldir)
 954 AC_SUBST(atof)
 955 dnl AC_SUBST(emulation)
 956
 957 case "${primary_bfd_gas}" in
 958   yes)  AC_DEFINE(BFD_ASSEMBLER, 1, [Use BFD interface?])
 959         need_bfd=yes ;;
 960 esac
 961
 962 # do we need the opcodes library?
 963 case "${need_opcodes}" in
 964 yes)
 965   OPCODES_LIB=../opcodes/libopcodes.la
 966   ;;
 967 esac
 968
 969 case "${need_bfd}" in
 970 yes)
 971   BFDLIB=../bfd/libbfd.la
 972   BFDVER_H=../bfd/bfdver.h
 973   ALL_OBJ_DEPS="$ALL_OBJ_DEPS"' ../bfd/bfd.h $(INCDIR)/symcat.h'
 974   ;;
 975 esac
 976
 977 AC_SUBST(BFDLIB)
 978 AC_SUBST(OPCODES_LIB)
 979
 980 AC_SUBST(BFDVER_H)
 981 AC_SUBST(ALL_OBJ_DEPS)
 982
 983 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 984 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 985 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 986 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 987 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 988
 989 AC_PROG_CC
 990
 991 AC_PROG_YACC
 992 AM_PROG_LEX
 993
 994 ALL_LINGUAS="fr tr es"
 995 CY_GNU_GETTEXT
 996
 997 AM_MAINTAINER_MODE
 998 AC_EXEEXT
 999
1000 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
1001
1002 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
1003 # people who are not cross-compiling but are compiling cross-assemblers.
1004 AC_MSG_CHECKING(whether compiling a cross-assembler)
1005 if test "${host}" = "${target}"; then
1006   cross_gas=no
1007 else
1008   cross_gas=yes
1009   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
1010 fi
1011 AC_MSG_RESULT($cross_gas)
1012
1013 dnl ansidecl.h will deal with const
1014 dnl AC_CONST
1015 AC_FUNC_ALLOCA
1016 AC_C_INLINE
1017
1018 # VMS doesn't have unlink.
1019 AC_CHECK_FUNCS(unlink remove, break)
1020
1021 # Some systems don't have sbrk().
1022 AC_CHECK_FUNCS(sbrk)
1023
1024 # do we need the math library?
1025 case "${need_libm}" in
1026 yes)
1027   AC_CHECK_LIBM
1028   AC_SUBST(LIBM)
1029   ;;
1030 esac
1031
1032 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
1033 # enough, but on some of those systems, the assert macro relies on requoting
1034 # working properly!
1035 GAS_WORKING_ASSERT
1036
1037 # On some systems, the system header files may not declare malloc, realloc,
1038 # and free.  There are places where gas needs these functions to have been
1039 # declared -- such as when taking their addresses.
1040 gas_test_headers="
1041 #ifdef HAVE_MEMORY_H
1042 #include <memory.h>
1043 #endif
1044 #ifdef HAVE_STRING_H
1045 #include <string.h>
1046 #else
1047 #ifdef HAVE_STRINGS_H
1048 #include <strings.h>
1049 #endif
1050 #endif
1051 #ifdef HAVE_STDLIB_H
1052 #include <stdlib.h>
1053 #endif
1054 #ifdef HAVE_UNISTD_H
1055 #include <unistd.h>
1056 #endif
1057 "
1058 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
1059 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
1060 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
1061 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
1062 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
1063
1064 # Does errno.h declare errno, or do we have to add a separate declaration
1065 # for it?
1066 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
1067 #ifdef HAVE_ERRNO_H
1068 #include <errno.h>
1069 #endif
1070 ])
1071
1072 dnl This must come last.
1073
1074 dnl We used to make symlinks to files in the source directory, but now
1075 dnl we just use the right name for .c files, and create .h files in
1076 dnl the build directory which include the right .h file.  Make sure
1077 dnl the old symlinks don't exist, so that a reconfigure in an existing
1078 dnl directory behaves reasonably.
1079
1080 AC_CONFIG_FILES(Makefile doc/Makefile po/Makefile.in:po/Make-in)
1081 AC_CONFIG_COMMANDS([default],
1082 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
1083  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
1084  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
1085  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
1086  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
1087  if test "x$cgen_cpu_prefix" != x ; then
1088    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
1089  fi
1090
1091  sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile],
1092 [target_cpu_type=${target_cpu_type}
1093  cgen_cpu_prefix=${cgen_cpu_prefix}
1094  obj_format=${obj_format}
1095  te_file=${te_file}])
1096
1097 AC_OUTPUT