gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 dnl v2.5 needed for --bindir et al
   8 AC_PREREQ(2.13)
   9 AC_INIT(as.h)
  10
  11 AC_CANONICAL_SYSTEM
  12 AC_ISC_POSIX
  13
  14 changequote(,)dnl
  15 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  16 changequote([,])dnl
  17 AM_INIT_AUTOMAKE(gas, ${BFD_VERSION})
  18
  19 AM_PROG_LIBTOOL
  20
  21 user_bfd_gas=
  22 AC_ARG_ENABLE(bfd-assembler,
  23 [  --enable-bfd-assembler  use BFD back end for writing object files],
  24 [case "${enableval}" in
  25   yes) need_bfd=yes user_bfd_gas=yes ;;
  26   no)  user_bfd_gas=no ;;
  27   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  28 esac])dnl
  29 AC_ARG_ENABLE(targets,
  30 [    targets            alternative target configurations besides the primary],
  31 [case "${enableval}" in
  32   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  33             ;;
  34   no)       enable_targets= ;;
  35   *)        enable_targets=$enableval ;;
  36 esac])dnl
  37 AC_ARG_ENABLE(commonbfdlib,
  38 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  39 [case "${enableval}" in
  40   yes) commonbfdlib=true ;;
  41   no)  commonbfdlib=false ;;
  42   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  43 esac])dnl
  44
  45 using_cgen=no
  46
  47 build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
  48 AC_ARG_ENABLE(build-warnings,
  49 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  50 [case "${enableval}" in
  51   yes)  ;;
  52   no)   build_warnings="-w";;
  53   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  54         build_warnings="${build_warnings} ${t}";;
  55   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  56         build_warnings="${t} ${build_warnings}";;
  57   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  58 esac
  59 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  60   echo "Setting warning flags = $build_warnings" 6>&1
  61 fi])dnl
  62 WARN_CFLAGS=""
  63 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  64     WARN_CFLAGS="${build_warnings}"
  65 fi
  66 AC_SUBST(WARN_CFLAGS)
  67
  68 # Generate a header file
  69 AM_CONFIG_HEADER(config.h:config.in)
  70
  71 # If we are on a DOS filesystem, we must use gdb.ini rather than
  72 # .gdbinit.
  73 GDBINIT=".gdbinit"
  74 case "${host}" in
  75   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-windows*)
  76     GDBINIT="gdb.ini"
  77     ;;
  78 esac
  79 AC_SUBST(GDBINIT)
  80
  81 te_file=generic
  82
  83 # Makefile target for installing gas in $(tooldir)/bin.
  84 install_tooldir=install-exec-tooldir
  85
  86 canon_targets=""
  87 all_targets=no
  88 if test -n "$enable_targets" ; then
  89   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  90     if test $t = "all"; then
  91       all_targets=yes
  92       continue
  93     fi
  94     result=`$ac_config_sub $t 2>/dev/null`
  95     if test -n "$result" ; then
  96       canon_targets="$canon_targets $result"
  97 #    else
  98 #      # Permit "all", etc.  We don't support it yet though.
  99 #      canon_targets="$canon_targets $t"
 100     fi
 101   done
 102   GAS_UNIQ(canon_targets)
 103 fi
 104
 105 emulations=""
 106
 107 for this_target in $target $canon_targets ; do
 108
 109 changequote(,)dnl
 110     eval `echo $this_target | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/cpu=\1 vendor=\2 os=\3/'`
 111 changequote([,])dnl
 112
 113     # check for architecture variants
 114     arch=
 115     endian=
 116     case ${cpu} in
 117       alpha*)           cpu_type=alpha ;;
 118       arm*b|xscale*b|strongarm*b) cpu_type=arm endian=big ;;
 119       arm*|xscale*|strongarm*)    cpu_type=arm endian=little ;;
 120       hppa*)            cpu_type=hppa ;;
 121 changequote(,)dnl
 122       i[3456]86)        cpu_type=i386 arch=i386;;
 123       x86_64)           cpu_type=i386 arch=x86_64;;
 124       ia64)             cpu_type=ia64 ;;
 125       ip2k)             cpu_type=ip2k endian=big ;;
 126       m6811|m6812|m68hc12) cpu_type=m68hc11 ;;
 127       m680[012346]0)    cpu_type=m68k ;;
 128 changequote([,])dnl
 129       m68008)           cpu_type=m68k ;;
 130       m683??)           cpu_type=m68k ;;
 131       m5200)            cpu_type=m68k ;;
 132       m8*)              cpu_type=m88k ;;
 133       mips*el)          cpu_type=mips endian=little ;;
 134       mips*)            cpu_type=mips endian=big ;;
 135       or32*)            cpu_type=or32 endian=big ;;
 136       pjl*)             cpu_type=pj endian=little ;;
 137       pj*)              cpu_type=pj endian=big ;;
 138       powerpc*le*)      cpu_type=ppc endian=little ;;
 139       powerpc*)         cpu_type=ppc endian=big ;;
 140       rs6000*)          cpu_type=ppc ;;
 141       s390x*)           cpu_type=s390 arch=s390x ;;
 142       s390*)            cpu_type=s390 arch=s390 ;;
 143       sh5*)             cpu_type=sh64 endian=big ;;
 144       sh5le*)           cpu_type=sh64 endian=little ;;
 145       sh64*)            cpu_type=sh64 endian=big ;;
 146       sh64le*)          cpu_type=sh64 endian=little ;;
 147       sh*le)            cpu_type=sh endian=little ;;
 148       sh*)              cpu_type=sh endian=big ;;
 149       sparclite*)       cpu_type=sparc arch=sparclite ;;
 150       sparclet*)        cpu_type=sparc arch=sparclet ;;
 151       sparc64*)         cpu_type=sparc arch=v9-64 ;;
 152       sparc86x*)        cpu_type=sparc arch=sparc86x  ;;
 153       sparc*)           cpu_type=sparc arch=sparclite ;; # ??? See tc-sparc.c.
 154       v850*)            cpu_type=v850 ;;
 155       *)                cpu_type=${cpu} ;;
 156     esac
 157
 158     if test ${this_target} = $target ; then
 159       target_cpu_type=${cpu_type}
 160     elif test ${target_cpu_type} != ${cpu_type} ; then
 161       continue
 162     fi
 163
 164     generic_target=${cpu_type}-$vendor-$os
 165     dev=no
 166     bfd_gas=no
 167     em=generic
 168
 169     # assign object format
 170     case ${generic_target} in
 171       a29k-*-coff)                      fmt=coff ;;
 172       a29k-amd-udi)                     fmt=coff ;;
 173       a29k-amd-ebmon)                   fmt=coff ;;
 174       a29k-nyu-sym1)                    fmt=coff ;;
 175       a29k-*-rtems*)                    fmt=coff ;;
 176       a29k-*-vxworks*)                  fmt=coff ;;
 177
 178       alpha*-*-*vms*)                   fmt=evax ;;
 179       alpha*-*-netware*)                fmt=ecoff ;;
 180       alpha*-*-osf*)                    fmt=ecoff ;;
 181       alpha*-*-linuxecoff*)             fmt=ecoff ;;
 182       alpha*-*-linux-gnu*)              fmt=elf em=linux ;;
 183       alpha*-*-netbsd*)                 fmt=elf em=nbsd ;;
 184       alpha*-*-openbsd*)                fmt=elf em=obsd ;;
 185
 186       arc-*-elf*)                       fmt=elf ;;
 187
 188       arm-*-aout)                       fmt=aout ;;
 189       arm-*-coff | thumb-*-coff)        fmt=coff ;;
 190       arm-*-rtems | thumb-*-rtems)      fmt=elf ;;
 191       arm-*-elf | thumb-*-elf)          fmt=elf ;;
 192       arm*-*-conix*)                    fmt=elf ;;
 193       arm-*-linux*aout*)                fmt=aout em=linux ;;
 194       arm*-*-linux-gnu*)                fmt=elf  em=linux ;;
 195       arm*-*-uclinux*)                  fmt=elf  em=linux ;;
 196       arm-*-netbsdelf*)                 fmt=elf  em=nbsd ;;
 197       arm-*-*n*bsd*)                    fmt=aout em=nbsd ;;
 198       arm-**-nto*)                      fmt=elf ;;
 199       arm-*-oabi | thumb-*-oabi)        fmt=elf ;;
 200       arm-epoc-pe | thumb-epoc-pe)      fmt=coff em=epoc-pe ;;
 201       arm-*-wince)                      fmt=coff em=wince-pe ;;
 202       arm-*-pe | thumb-*-pe)            fmt=coff em=pe ;;
 203       arm-*-riscix*)                    fmt=aout em=riscix ;;
 204       arm-*-vxworks)                    fmt=coff ;;
 205
 206       avr-*-*)                          fmt=elf ;;
 207
 208       cris-*-*)                         fmt=multi bfd_gas=yes ;;
 209
 210       d10v-*-*)                         fmt=elf ;;
 211       d30v-*-*)                         fmt=elf ;;
 212       dlx-*-*)                          fmt=elf ;;
 213
 214       fr30-*-*)                         fmt=elf ;;
 215       frv-*-*)                          fmt=elf ;;
 216
 217       hppa-*-linux*)    case ${cpu} in
 218                             hppa*64*)   fmt=elf em=hppalinux64;;
 219                             hppa*)      fmt=elf em=linux;;
 220                         esac ;;
 221       hppa-*-*elf*)                     fmt=elf em=hppa ;;
 222       hppa-*-lites*)                    fmt=elf em=hppa ;;
 223       hppa-*-netbsd*)                   fmt=elf em=nbsd ;;
 224       hppa-*-openbsd*)                  fmt=elf em=hppa ;;
 225       hppa-*-osf*)                      fmt=som em=hppa ;;
 226       hppa-*-rtems*)                    fmt=elf em=hppa ;;
 227       hppa-*-hpux11*)   case ${cpu} in
 228                             hppa*64*)   fmt=elf em=hppa64 ;;
 229                             hppa*)      fmt=som em=hppa ;;
 230                         esac ;;
 231       hppa-*-hpux*)                     fmt=som em=hppa ;;
 232       hppa-*-mpeix*)                    fmt=som em=hppa ;;
 233       hppa-*-bsd*)                      fmt=som em=hppa ;;
 234       hppa-*-hiux*)                     fmt=som em=hppa ;;
 235
 236       h8300-*-rtems*)                   fmt=coff ;;
 237       h8300-*-coff)                     fmt=coff ;;
 238       h8300-*-elf)                      fmt=elf ;;
 239       h8500-*-rtems*)                   fmt=coff ;;
 240       h8500-*-coff)                     fmt=coff ;;
 241
 242       i370-*-elf* | i370-*-linux*)      fmt=elf ;;
 243       i386-ibm-aix*)                    fmt=coff em=i386aix ;;
 244       i386-sequent-bsd*)                fmt=aout em=dynix ;;
 245       i386-*-beospe*)                   fmt=coff em=pe ;;
 246       i386-*-beos*)                     fmt=elf ;;
 247       i386-*-coff)                      fmt=coff ;;
 248       i386-*-elf)                       fmt=elf ;;
 249       i386-*-bsd*)                      fmt=aout em=386bsd ;;
 250       i386-*-netbsd0.8)                 fmt=aout em=386bsd ;;
 251       i386-*-netbsdpe*)                 fmt=coff em=pe ;;
 252       i386-*-netbsdelf*)                fmt=elf em=nbsd ;;
 253       i386-*-*n*bsd*)   case ${cpu} in
 254                             x86_64)     fmt=elf em=nbsd ;;
 255                             *)          fmt=aout em=nbsd ;;
 256                         esac ;;
 257       i386-*-linux*aout*)               fmt=aout em=linux ;;
 258       i386-*-linux*oldld)               fmt=aout em=linux ;;
 259       i386-*-linux*coff*)               fmt=coff em=linux ;;
 260       i386-*-linux-gnu*)                fmt=elf em=linux ;;
 261       x86_64-*-linux-gnu*)              fmt=elf em=linux ;;
 262       i386-*-lynxos*)                   fmt=coff em=lynx ;;
 263 changequote(,)dnl
 264       i386-*-sysv[45]*)                 fmt=elf ;;
 265       i386-*-solaris*)                  fmt=elf ;;
 266       i386-*-freebsdaout*)              fmt=aout em=386bsd ;;
 267       i386-*-freebsd[12].*)             fmt=aout em=386bsd ;;
 268       i386-*-freebsd[12])               fmt=aout em=386bsd ;;
 269 changequote([,])dnl
 270       i386-*-sysv*)                     fmt=coff ;;
 271       i386-*-sco3.2v5*coff)             fmt=coff ;;
 272       i386-*-isc*)                      fmt=coff ;;
 273       i386-*-sco3.2v5*)                 fmt=elf
 274           if test ${this_target} = $target; then
 275             AC_DEFINE(SCO_ELF, 1, [Define if defaulting to ELF on SCO 5.])
 276           fi ;;
 277       i386-*-sco3.2*)                   fmt=coff ;;
 278       i386-*-vsta)                      fmt=aout ;;
 279       i386-*-msdosdjgpp* \
 280       | i386-*-go32* \
 281       | i386-go32-rtems*)               fmt=coff em=go32
 282             AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?]) ;;
 283       i386-*-rtemself*)                 fmt=elf ;;
 284       i386-*-rtemscoff*)                fmt=coff ;;
 285       i386-*-rtems*)                    fmt=elf ;;
 286       i386-*-gnu*)                      fmt=elf ;;
 287       i386-*-mach*)                     fmt=aout em=mach ;;
 288       i386-*-msdos*)                    fmt=aout ;;
 289       i386-*-moss*)                     fmt=elf ;;
 290       i386-*-pe)                        fmt=coff em=pe ;;
 291       i386-*-cygwin*)                   fmt=coff em=pe ;;
 292       i386-*-interix*)                  fmt=coff em=interix ;;
 293       i386-*-mingw32*)                  fmt=coff em=pe ;;
 294       i386-*-nto-qnx*)                  fmt=elf ;;
 295       i386-*-*nt*)                      fmt=coff em=pe ;;
 296       i386-*-vxworks*)                  fmt=aout ;;
 297       i386-*-chaos)                     fmt=elf ;;
 298
 299       i860-*-*)                         fmt=elf endian=little
 300                 AC_MSG_WARN(GAS support for ${generic_target} is preliminary and a work in progress) ;;
 301       i960-*-bout)                      fmt=bout ;;
 302       i960-*-coff)                      fmt=coff em=ic960 ;;
 303       i960-*-rtems*)                    fmt=coff em=ic960 ;;
 304       i960-*-nindy*)                    fmt=bout ;;
 305       i960-*-vxworks5.0)                fmt=bout ;;
 306       i960-*-vxworks5.*)                fmt=coff em=ic960 ;;
 307       i960-*-vxworks*)                  fmt=bout ;;
 308       i960-*-elf*)                      fmt=elf ;;
 309
 310       ia64-*-elf*)                      fmt=elf ;;
 311       ia64-*-aix*)                      fmt=elf em=ia64aix ;;
 312       ia64-*-linux-gnu*)                fmt=elf em=linux ;;
 313       ia64-*-hpux*)                     fmt=elf em=hpux ;;
 314       ia64-*-netbsd*)                   fmt=elf em=nbsd ;;
 315
 316       ip2k-*-*)                         fmt=elf ;;
 317
 318       m32r-*-*)                         fmt=elf ;;
 319
 320       m68hc11-*-* | m6811-*-*)          fmt=elf ;;
 321       m68hc12-*-* | m6812-*-*)          fmt=elf ;;
 322
 323       m68k-*-vxworks*)                  fmt=aout em=sun3 ;;
 324       m68k-ericsson-ose)                fmt=aout em=sun3 ;;
 325       m68k-*-sunos*)                    fmt=aout em=sun3 ;;
 326       m68k-motorola-sysv*)              fmt=coff em=delta ;;
 327       m68k-bull-sysv3*)                 fmt=coff em=dpx2 ;;
 328       m68k-apollo-*)                    fmt=coff em=apollo ;;
 329       m68k-*-elf*)                      fmt=elf ;;
 330       m68k-*-sysv4*)                    fmt=elf em=svr4 ;;
 331       m68k-*-sysv*)                     fmt=coff ;;
 332       m68k-*-coff | m68k-*-rtemscoff*)  fmt=coff ;;
 333       m68k-*-rtems*)                    fmt=elf ;;
 334       m68k-*-hpux*)                     fmt=hp300 em=hp300 ;;
 335       m68k-*-linux*aout*)               fmt=aout em=linux ;;
 336       m68k-*-linux-gnu*)                fmt=elf em=linux ;;
 337       m68k-*-gnu*)                      fmt=elf ;;
 338       m68k-*-lynxos*)                   fmt=coff em=lynx ;;
 339       m68k-*-netbsdelf*)                fmt=elf em=nbsd ;;
 340       m68k-*-netbsd*)                   fmt=aout em=nbsd bfd_gas=yes ;;
 341       m68k-*-openbsd*)                  fmt=aout em=nbsd bfd_gas=yes ;;
 342       m68k-apple-aux*)                  fmt=coff em=aux ;;
 343       m68k-*-psos*)                     fmt=elf em=psos;;
 344
 345       m88k-motorola-sysv3*)             fmt=coff em=delt88 ;;
 346       m88k-*-coff*)                     fmt=coff ;;
 347
 348       mcore-*-elf)                      fmt=elf ;;
 349       mcore-*-pe)                       fmt=coff em=pe bfd_gas=yes ;;
 350
 351       # don't change em like *-*-bsd does
 352       mips-dec-openbsd*)                fmt=elf endian=little ;;
 353       mips-dec-bsd*)                    fmt=aout endian=little ;;
 354       mips-sony-bsd*)                   fmt=ecoff ;;
 355       mips-*-bsd*)
 356             AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.) ;;
 357       mips-*-ultrix*)                   fmt=ecoff endian=little ;;
 358       mips-*-osf*)                      fmt=ecoff endian=little ;;
 359       mips-*-ecoff*)                    fmt=ecoff ;;
 360       mips-*-pe*)                       fmt=coff endian=little em=pe ;;
 361       mips-*-irix6*)                    fmt=elf ;;
 362       mips-*-irix5*)                    fmt=elf ;;
 363       mips-*-irix*)                     fmt=ecoff ;;
 364       mips-*-lnews*)                    fmt=ecoff em=lnews ;;
 365       mips-*-riscos*)                   fmt=ecoff ;;
 366       mips*-*-linux*)                   fmt=elf em=tmips ;;
 367       mips-*-sysv4*MP* | mips-*-gnu*)   fmt=elf em=tmips ;;
 368       mips-*-sysv*)                     fmt=ecoff ;;
 369       mips-*-elf* | mips-*-rtems*)      fmt=elf ;;
 370       mips-*-*n*bsd*)                   fmt=elf ;;
 371       mips-*-vxworks*)                  fmt=elf ;;
 372
 373       mmix-*-*)                         fmt=elf ;;
 374       mn10200-*-*)                      fmt=elf ;;
 375       mn10300-*-*)                      fmt=elf ;;
 376       msp430-*-*)                       fmt=elf ;;
 377       openrisc-*-*)                     fmt=elf ;;
 378       or32-*-rtems*)                    fmt=coff ;;
 379       or32-*-coff)                      fmt=coff ;;
 380       or32-*-elf)                       fmt=elf ;;
 381       pj*)                              fmt=elf ;;
 382
 383       ppc-*-pe | ppc-*-cygwin*)         fmt=coff em=pe ;;
 384       ppc-*-winnt*)                     fmt=coff em=pe ;;
 385       ppc-*-aix5*)                      fmt=coff em=aix5 ;;
 386       ppc-*-aix*)                       fmt=coff ;;
 387       ppc-*-beos*)                      fmt=coff ;;
 388       ppc-*-*n*bsd* | ppc-*-elf*)       fmt=elf ;;
 389       ppc-*-eabi* | ppc-*-sysv4*)       fmt=elf ;;
 390       ppc-*-linux-gnu*)                 fmt=elf
 391             case "$endian" in
 392                 big)  ;;
 393                 *)    AC_MSG_ERROR(GNU/Linux must be configured big endian) ;;
 394             esac ;;
 395       ppc-*-solaris*)                   fmt=elf
 396             if test ${this_target} = $target; then
 397                 AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 398                           [Define if default target is PowerPC Solaris.])
 399             fi
 400             if test x${endian} = xbig; then
 401                 AC_MSG_ERROR(Solaris must be configured little endian)
 402             fi ;;
 403       ppc-*-rtems*)                     fmt=elf ;;
 404       ppc-*-macos* | ppc-*-mpw*)        fmt=coff em=macos ;;
 405       ppc-*-netware*)                   fmt=elf em=ppcnw ;;
 406       ppc-**-nto*)                      fmt=elf ;;
 407       ppc-*-vxworks*)                   fmt=elf ;;
 408       ppc-*-windiss*)                   fmt=elf ;;
 409
 410       s390x-*-linux-gnu*)               fmt=elf em=linux ;;
 411       s390-*-linux-gnu*)                fmt=elf em=linux ;;
 412
 413       sh*-*-linux*)                     fmt=elf em=linux
 414             case ${cpu} in
 415                 sh*eb)  endian=big ;;
 416                 *)      endian=little ;;
 417             esac ;;
 418       sh5*-*-netbsd*)                   fmt=elf em=nbsd ;;
 419       sh64*-*-netbsd*)                  fmt=elf em=nbsd ;;
 420       sh*-*-netbsdelf*)                 fmt=elf em=nbsd ;;
 421       sh-*-elf*)                        fmt=elf ;;
 422       sh-*-coff*)                       fmt=coff ;;
 423       sh-*-nto*)                        fmt=elf ;;
 424       sh-*-pe*)                         fmt=coff em=pe bfd_gas=yes endian=little ;;
 425       sh-*-rtemself*)                   fmt=elf ;;
 426       sh-*-rtems*)                      fmt=coff ;;
 427       sh64-*-elf*)                      fmt=elf ;;
 428
 429       ns32k-pc532-mach*)                fmt=aout em=pc532mach ;;
 430       ns32k-pc532-ux*)                  fmt=aout em=pc532mach ;;
 431       ns32k-pc532-lites*)               fmt=aout em=nbsd532 ;;
 432       ns32k-*-*n*bsd*)                  fmt=aout em=nbsd532 ;;
 433
 434       sparc-*-rtemsaout*)               fmt=aout ;;
 435       sparc-*-rtemself*)                fmt=elf ;;
 436       sparc-*-rtems*)                   fmt=elf ;;
 437       sparc-*-sunos4*)                  fmt=aout em=sun3 ;;
 438       sparc-*-aout | sparc*-*-vxworks*) fmt=aout em=sparcaout ;;
 439       sparc-*-coff)                     fmt=coff ;;
 440       sparc-*-linux*aout*)              fmt=aout em=linux ;;
 441       sparc-*-linux-gnu*)               fmt=elf em=linux ;;
 442       sparc-*-lynxos*)                  fmt=coff em=lynx ;;
 443       sparc-fujitsu-none)               fmt=aout ;;
 444       sparc-*-elf)                      fmt=elf ;;
 445       sparc-*-sysv4*)                   fmt=elf ;;
 446       sparc-*-solaris*)                 fmt=elf ;;
 447       sparc-*-netbsdelf*)               fmt=elf em=nbsd ;;
 448       sparc-*-*n*bsd*)  case ${cpu} in
 449                             sparc64)    fmt=elf em=nbsd ;;
 450                             *)          fmt=aout em=nbsd ;;
 451                         esac ;;
 452       strongarm-*-coff)                 fmt=coff ;;
 453       strongarm-*-elf)                  fmt=elf ;;
 454       xscale-*-coff)                    fmt=coff ;;
 455       xscale-*-elf)                     fmt=elf ;;
 456
 457       tic30-*-*aout*)                   fmt=aout bfd_gas=yes ;;
 458       tic30-*-*coff*)                   fmt=coff bfd_gas=yes ;;
 459       tic4x-*-* | c4x-*-*)              fmt=coff bfd_gas=yes ;;
 460       tic54x-*-* | c54x*-*-*)           fmt=coff bfd_gas=yes need_libm=yes;;
 461       tic80-*-*)                        fmt=coff ;;
 462
 463       v850-*-*)                         fmt=elf ;;
 464       v850e-*-*)                        fmt=elf ;;
 465       v850ea-*-*)                       fmt=elf ;;
 466
 467       vax-*-netbsdelf*)                 fmt=elf em=nbsd ;;
 468       vax-*-netbsd*)                    fmt=aout em=nbsd ;;
 469       vax-*-bsd* | vax-*-ultrix*)       fmt=aout ;;
 470       vax-*-vms)                        fmt=vms ;;
 471
 472       w65-*-*)                          fmt=coff ;;
 473
 474       xstormy16-*-*)                    fmt=elf ;;
 475
 476       z8k-*-coff | z8k-*-sim)           fmt=coff ;;
 477
 478       *-*-aout | *-*-scout)             fmt=aout ;;
 479       *-*-freebsd*)                     fmt=elf em=freebsd ;;
 480       *-*-nindy*)                       fmt=bout ;;
 481       *-*-bsd*)                         fmt=aout em=sun3 ;;
 482       *-*-generic)                      fmt=generic ;;
 483       *-*-xray | *-*-hms)               fmt=coff ;;
 484       *-*-sim)                          fmt=coff ;;
 485       *-*-elf | *-*-sysv4* | *-*-solaris*) fmt=elf dev=yes ;;
 486       *-*-vxworks)                      fmt=aout ;;
 487       *-*-netware)                      fmt=elf ;;
 488     esac
 489
 490     if test ${this_target} = $target ; then
 491       endian_def=
 492       if test x${endian} = xbig; then
 493         endian_def=1
 494       elif test x${endian} = xlittle; then
 495         endian_def=0
 496       fi
 497       if test x${endian_def} != x; then
 498         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 499                            [Define as 1 if big endian.])
 500       fi
 501     fi
 502
 503     case ${cpu_type}-${fmt} in
 504         alpha*-* | arm-* | i386-* | ia64*-* | mips-* | ns32k-* \
 505                 | pdp11-* | ppc-* | sparc-* | strongarm-* | xscale-* \
 506                 | *-elf | *-ecoff | *-som)
 507             bfd_gas=yes ;;
 508     esac
 509
 510 # Other random stuff.
 511
 512     case ${cpu_type} in
 513       mips)
 514         # Set mips_cpu to the name of the default CPU.
 515         case ${target_cpu} in
 516           mips | mipsbe | mipseb | mipsle | mipsel | mips64 | mips64el)
 517             mips_cpu=from-abi
 518             ;;
 519           mipsisa32 | mipsisa32el)
 520             mips_cpu=mips32
 521             ;;
 522           mipsisa32r2 | mipsisa32r2el)
 523             mips_cpu=mips32r2
 524             ;;
 525           mipsisa64 | mipsisa64el)
 526             mips_cpu=mips64
 527             ;;
 528           mipstx39 | mipstx39el)
 529             mips_cpu=r3900
 530             ;;
 531           mips64vr | mips64vrel)
 532             mips_cpu=vr4100
 533             ;;
 534           mipsisa32r2*)
 535 changequote(,)dnl
 536             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r2//' -e 's/el$//'`
 537 changequote([,])dnl
 538             ;;
 539           mips64* | mipsisa64* | mipsisa32*)
 540 changequote(,)dnl
 541             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..//' -e 's/el$//'`
 542 changequote([,])dnl
 543             ;;
 544           *)
 545             AC_ERROR($target_cpu isn't a supported MIPS CPU name)
 546             ;;
 547         esac
 548         # See whether it's appropriate to set E_MIPS_ABI_O32 for o32
 549         # binaries.  It's a GNU extension that some OSes don't understand.
 550         # The value only matters on ELF targets.
 551         case ${target} in
 552           *-*-irix*)
 553             use_e_mips_abi_o32=0
 554             ;;
 555           *)
 556             use_e_mips_abi_o32=1
 557             ;;
 558         esac
 559         # Decide whether to generate 32-bit or 64-bit code by default.
 560         # Used to resolve -march=from-abi when an embedded ABI is selected.
 561         case ${target} in
 562           mips64*-*-* | mipsisa64*-*-*)
 563             mips_default_64bit=1
 564             ;;
 565           *)
 566             mips_default_64bit=0
 567             ;;
 568         esac
 569         AC_DEFINE_UNQUOTED(MIPS_CPU_STRING_DEFAULT, "$mips_cpu",
 570                            [Default CPU for MIPS targets. ])
 571         AC_DEFINE_UNQUOTED(USE_E_MIPS_ABI_O32, $use_e_mips_abi_o32,
 572                            [Allow use of E_MIPS_ABI_O32 on MIPS targets. ])
 573         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_64BIT, $mips_default_64bit,
 574                            [Generate 64-bit code by default on MIPS targets. ])
 575         ;;
 576     esac
 577
 578     # Do we need the opcodes library?
 579     case ${cpu_type} in
 580       vax | i386 | tic30)
 581         ;;
 582
 583       *)
 584         need_opcodes=yes
 585
 586         case "${enable_shared}" in
 587         yes) shared_opcodes=true ;;
 588         *opcodes*) shared_opcodes=true ;;
 589         *) shared_opcodes=false ;;
 590         esac
 591         if test "${shared_opcodes}" = "true"; then
 592           # A shared libopcodes must be linked against libbfd.
 593           need_bfd=yes
 594         fi
 595         ;;
 596     esac
 597
 598     # Any other special object files needed ?
 599     case ${cpu_type} in
 600       fr30 | ip2k | m32r | openrisc)
 601         using_cgen=yes
 602         ;;
 603
 604       frv)
 605         using_cgen=yes
 606         ;;
 607       m68k)
 608         case ${extra_objects} in
 609         *m68k-parse.o*) ;;
 610         *) extra_objects="$extra_objects m68k-parse.o" ;;
 611         esac
 612         ;;
 613
 614       mips)
 615         echo ${extra_objects} | grep -s "itbl-parse.o"
 616         if test $? -ne 0 ; then
 617           extra_objects="$extra_objects itbl-parse.o"
 618         fi
 619
 620         echo ${extra_objects} | grep -s "itbl-lex.o"
 621         if test $? -ne 0 ; then
 622           extra_objects="$extra_objects itbl-lex.o"
 623         fi
 624
 625         echo ${extra_objects} | grep -s "itbl-ops.o"
 626         if test $? -ne 0 ; then
 627           extra_objects="$extra_objects itbl-ops.o"
 628         fi
 629         ;;
 630
 631       i386 | s390 | sparc)
 632         if test $this_target = $target ; then
 633           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 634         fi
 635         ;;
 636
 637       xstormy16)
 638         using_cgen=yes
 639         ;;
 640
 641       *)
 642         ;;
 643     esac
 644
 645     if test $using_cgen = yes ; then
 646         case "x${extra_objects}" in
 647         *cgen.o*) ;;
 648         *) extra_objects="$extra_objects cgen.o" ;;
 649         esac
 650     fi
 651
 652 # See if we really can support this configuration with the emulation code.
 653
 654     if test $this_target = $target ; then
 655       primary_bfd_gas=$bfd_gas
 656       obj_format=$fmt
 657       te_file=$em
 658
 659       if test $bfd_gas = no ; then
 660         # Can't support other configurations this way.
 661         break
 662       fi
 663     elif test $bfd_gas = no ; then
 664       # Can't support this configuration.
 665       break
 666     fi
 667
 668 # From target name and format, produce a list of supported emulations.
 669
 670     case ${generic_target}-${fmt} in
 671       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 672       mips*-*-linux*-*) case "$endian" in
 673                         big)    emulation="mipsbelf mipslelf mipself" ;;
 674                         *)      emulation="mipslelf mipsbelf mipself" ;;
 675                         esac ;;
 676       mips-*-lnews*-ecoff) ;;
 677       mips-*-*-ecoff)   case "$endian" in
 678                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 679                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 680                         esac ;;
 681       mips-*-*-elf)     case "$endian" in
 682                         big)    emulation="mipsbelf mipslelf mipself" ;;
 683                         *)      emulation="mipslelf mipsbelf mipself" ;;
 684                         esac ;;
 685       mips-*-sysv4*MP*-*) emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 686       # i386-pc-pe-coff != i386-pc-coff.
 687       i386-*-pe-coff)   ;;
 688       # Uncommenting the next line will turn on support for i386 AOUT
 689       # for the default linux configuration
 690       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 691       #
 692       i386-*-aout)      emulation="i386aout" ;;
 693       i386-*-coff)      emulation="i386coff" ;;
 694       i386-*-elf)       emulation="i386elf" ;;
 695
 696       # Always all formats.  The first stated emulation becomes the default.
 697       cris-*-*aout*)    emulation="crisaout criself" ;;
 698       cris-*-*)         emulation="criself crisaout" ;;
 699     esac
 700
 701     emulations="$emulations $emulation"
 702
 703 done
 704
 705 # Turn on all targets if possible
 706 if test ${all_targets} = "yes"; then
 707   case ${target_cpu_type} in
 708   i386)
 709     case ${obj_format} in
 710     aout)
 711       emulations="$emulations i386coff i386elf"
 712       ;;
 713     coff)
 714       emulations="$emulations i386aout i386elf"
 715     ;;
 716     elf)
 717       emulations="$emulations i386aout i386coff"
 718       ;;
 719     esac
 720   ;;
 721   esac
 722 fi
 723
 724 # Assign floating point type.  Most processors with FP support
 725 # IEEE FP.  On those that don't support FP at all, usually IEEE
 726 # is emulated.
 727 case ${target_cpu} in
 728   vax | tahoe ) atof=${target_cpu} ;;
 729   pdp11)        atof=vax ;;
 730   *)            atof=ieee ;;
 731 esac
 732
 733 case "${obj_format}" in
 734   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 735 esac
 736
 737 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 738 cgen_cpu_prefix=""
 739 if test $using_cgen = yes ; then
 740   case ${target_cpu} in
 741     *) cgen_cpu_prefix=${target_cpu} ;;
 742   esac
 743   AC_SUBST(cgen_cpu_prefix)
 744   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 745 fi
 746
 747 dnl
 748 dnl Make sure the desired support files exist.
 749 dnl
 750
 751 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 752   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 753 fi
 754
 755 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 756   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 757 fi
 758
 759 case ${user_bfd_gas}-${primary_bfd_gas} in
 760   yes-yes | no-no)
 761     # We didn't override user's choice.
 762     ;;
 763   no-yes)
 764     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 765     ;;
 766   no-preferred)
 767     primary_bfd_gas=no
 768     ;;
 769   *-preferred)
 770     primary_bfd_gas=yes
 771     ;;
 772   yes-*)
 773     primary_bfd_gas=yes
 774     ;;
 775   -*)
 776     # User specified nothing.
 777     ;;
 778 esac
 779
 780 # Some COFF configurations want these random other flags set.
 781 case ${obj_format} in
 782   coff)
 783     case ${target_cpu_type} in
 784       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 785       m68k) AC_DEFINE(M68KCOFF, 1, [Using m68k COFF?]) ;;
 786       m88k) AC_DEFINE(M88KCOFF, 1, [Using m88k COFF?]) ;;
 787     esac
 788     ;;
 789 esac
 790
 791 # Getting this done right is going to be a bitch.  Each configuration specified
 792 # with --enable-targets=... should be checked for environment, format, cpu, and
 793 # bfd_gas setting.
 794 #
 795 # For each configuration, the necessary object file support code must be linked
 796 # in.  This might be only one, it might be up to four.  The necessary emulation
 797 # code needs to be provided, too.
 798 #
 799 # And then there's "--enable-targets=all"....
 800 #
 801 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 802
 803 formats="${obj_format}"
 804 emfiles=""
 805 EMULATIONS=""
 806 GAS_UNIQ(emulations)
 807 for em in . $emulations ; do
 808   case $em in
 809     .)  continue ;;
 810     mipsbelf | mipslelf | mipself)
 811         fmt=elf   file=mipself ;;
 812     mipsbecoff | mipslecoff | mipsecoff)
 813         fmt=ecoff file=mipsecoff ;;
 814     *coff)
 815         fmt=coff  file=$em ;;
 816     *aout)
 817         fmt=aout file=$em ;;
 818     *elf)
 819         fmt=elf file=$em ;;
 820   esac
 821   formats="$formats $fmt"
 822   emfiles="$emfiles e-$file.o"
 823   EMULATIONS="$EMULATIONS &$em,"
 824 done
 825 GAS_UNIQ(formats)
 826 GAS_UNIQ(emfiles)
 827 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 828   for fmt in $formats ; do
 829     case $fmt in
 830       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 831       bout)     AC_DEFINE(OBJ_MAYBE_BOUT, 1,    [b.out support?])   ;;
 832       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 833       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 834       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 835       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 836       hp300)    AC_DEFINE(OBJ_MAYBE_HP300, 1,   [HP300 support?])   ;;
 837       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE, 1,    [IEEE support?])    ;;
 838       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 839       vms)      AC_DEFINE(OBJ_MAYBE_VMS, 1,     [VMS support?])     ;;
 840     esac
 841     extra_objects="$extra_objects obj-$fmt.o"
 842   done
 843   obj_format=multi
 844 fi
 845 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 846   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 847   # e-mips* has more than one emulation per file, e-i386* has just one at the
 848   # moment.  If only one emulation is specified, then don't define
 849   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 850   case "${obj_format}${emfiles}" in
 851     multi* | *mips*)
 852       extra_objects="$extra_objects $emfiles"
 853       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 854   esac
 855 fi
 856 AC_SUBST(extra_objects)
 857 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 858 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 859                    [Default emulation.])
 860
 861 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 862   yes-*-coff)   need_bfd=yes ;;
 863   no-*-coff)    need_bfd=yes
 864                 AC_DEFINE(MANY_SEGMENTS, 1, [old COFF support?]) ;;
 865 esac
 866
 867 reject_dev_configs=yes
 868
 869 case ${reject_dev_configs}-${dev} in
 870   yes-yes) # Oops.
 871     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 872     ;;
 873 esac
 874
 875 AC_SUBST(target_cpu_type)
 876 AC_SUBST(obj_format)
 877 AC_SUBST(te_file)
 878 AC_SUBST(install_tooldir)
 879 AC_SUBST(atof)
 880 dnl AC_SUBST(emulation)
 881
 882 case "${primary_bfd_gas}" in
 883   yes)  AC_DEFINE(BFD_ASSEMBLER, 1, [Use BFD interface?])
 884         need_bfd=yes ;;
 885 esac
 886
 887 # do we need the opcodes library?
 888 case "${need_opcodes}" in
 889 yes)
 890   OPCODES_LIB=../opcodes/libopcodes.la
 891   ;;
 892 esac
 893
 894 case "${need_bfd}" in
 895 yes)
 896   BFDLIB=../bfd/libbfd.la
 897   BFDVER_H=../bfd/bfdver.h
 898   ALL_OBJ_DEPS="$ALL_OBJ_DEPS"' ../bfd/bfd.h $(INCDIR)/symcat.h'
 899   ;;
 900 esac
 901
 902 AC_SUBST(BFDLIB)
 903 AC_SUBST(OPCODES_LIB)
 904
 905 AC_SUBST(BFDVER_H)
 906 AC_SUBST(ALL_OBJ_DEPS)
 907
 908 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 909 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 910 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 911 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 912 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 913
 914 AC_PROG_CC
 915
 916 AC_PROG_YACC
 917 AM_PROG_LEX
 918
 919 ALL_LINGUAS="fr tr es"
 920 CY_GNU_GETTEXT
 921
 922 AM_MAINTAINER_MODE
 923 AC_EXEEXT
 924
 925 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 926
 927 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 928 # people who are not cross-compiling but are compiling cross-assemblers.
 929 AC_MSG_CHECKING(whether compiling a cross-assembler)
 930 if test "${host}" = "${target}"; then
 931   cross_gas=no
 932 else
 933   cross_gas=yes
 934   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 935 fi
 936 AC_MSG_RESULT($cross_gas)
 937
 938 dnl ansidecl.h will deal with const
 939 dnl AC_CONST
 940 AC_FUNC_ALLOCA
 941 AC_C_INLINE
 942
 943 # VMS doesn't have unlink.
 944 AC_CHECK_FUNCS(unlink remove, break)
 945
 946 # Some systems don't have sbrk().
 947 AC_CHECK_FUNCS(sbrk)
 948
 949 # do we need the math library?
 950 case "${need_libm}" in
 951 yes)
 952   AC_CHECK_LIBM
 953   AC_SUBST(LIBM)
 954   ;;
 955 esac
 956
 957 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 958 # enough, but on some of those systems, the assert macro relies on requoting
 959 # working properly!
 960 GAS_WORKING_ASSERT
 961
 962 # On some systems, the system header files may not declare malloc, realloc,
 963 # and free.  There are places where gas needs these functions to have been
 964 # declared -- such as when taking their addresses.
 965 gas_test_headers="
 966 #ifdef HAVE_MEMORY_H
 967 #include <memory.h>
 968 #endif
 969 #ifdef HAVE_STRING_H
 970 #include <string.h>
 971 #else
 972 #ifdef HAVE_STRINGS_H
 973 #include <strings.h>
 974 #endif
 975 #endif
 976 #ifdef HAVE_STDLIB_H
 977 #include <stdlib.h>
 978 #endif
 979 #ifdef HAVE_UNISTD_H
 980 #include <unistd.h>
 981 #endif
 982 "
 983 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
 984 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 985 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 986 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
 987 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
 988
 989 # Does errno.h declare errno, or do we have to add a separate declaration
 990 # for it?
 991 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 992 #ifdef HAVE_ERRNO_H
 993 #include <errno.h>
 994 #endif
 995 ])
 996
 997 dnl This must come last.
 998
 999 dnl We used to make symlinks to files in the source directory, but now
1000 dnl we just use the right name for .c files, and create .h files in
1001 dnl the build directory which include the right .h file.  Make sure
1002 dnl the old symlinks don't exist, so that a reconfigure in an existing
1003 dnl directory behaves reasonably.
1004
1005 AC_OUTPUT(Makefile doc/Makefile ${GDBINIT}:gdbinit.in po/Makefile.in:po/Make-in,
1006 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
1007  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
1008  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
1009  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
1010  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
1011  if test "x$cgen_cpu_prefix" != x ; then
1012    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
1013  fi
1014
1015  sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile],
1016 [target_cpu_type=${target_cpu_type}
1017  cgen_cpu_prefix=${cgen_cpu_prefix}
1018  obj_format=${obj_format}
1019  te_file=${te_file}])