bfd/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT
   6 AC_CONFIG_SRCDIR([libbfd.c])
   7
   8 AC_CANONICAL_TARGET
   9 AC_ISC_POSIX
  10
  11 AM_INIT_AUTOMAKE(bfd, 2.16.90)
  12
  13 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  14 dnl to call AC_CHECK_PROG.
  15 AC_CHECK_TOOL(AR, ar)
  16 AC_CHECK_TOOL(RANLIB, ranlib, :)
  17
  18 dnl Default to a non shared library.  This may be overridden by the
  19 dnl configure option --enable-shared.
  20 AM_DISABLE_SHARED
  21
  22 AM_PROG_LIBTOOL
  23
  24 AC_ARG_ENABLE(64-bit-bfd,
  25 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  26 [case "${enableval}" in
  27   yes)  want64=true  ;;
  28   no)   want64=false ;;
  29   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  30 esac],[want64=false])dnl
  31 AC_ARG_ENABLE(targets,
  32 [  --enable-targets        alternative target configurations],
  33 [case "${enableval}" in
  34   yes | "") AC_MSG_ERROR([enable-targets option must specify target names or 'all'])
  35             ;;
  36   no)       enable_targets= ;;
  37   *)        enable_targets=$enableval ;;
  38 esac])dnl
  39 AC_ARG_ENABLE(commonbfdlib,
  40 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  41 [case "${enableval}" in
  42   yes) commonbfdlib=true ;;
  43   no)  commonbfdlib=false ;;
  44   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  45 esac])dnl
  46 AC_ARG_WITH(mmap,
  47 [  --with-mmap             try using mmap for BFD input files if available],
  48 [case "${withval}" in
  49   yes)  want_mmap=true ;;
  50   no)   want_mmap=false ;;
  51   *)    AC_MSG_ERROR(bad value ${withval} for BFD with-mmap option) ;;
  52 esac],[want_mmap=false])dnl
  53
  54 AM_BINUTILS_WARNINGS
  55
  56 AM_CONFIG_HEADER(config.h:config.in)
  57
  58 if test -z "$target" ; then
  59     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  60 fi
  61
  62 AM_MAINTAINER_MODE
  63 AM_INSTALL_LIBBFD
  64 AC_EXEEXT
  65
  66 host64=false
  67 target64=false
  68 bfd_default_target_size=32
  69
  70 # host stuff:
  71
  72 AC_PROG_CC
  73
  74 ALL_LINGUAS="fr tr ja es sv da zh_CN ro rw"
  75 CY_GNU_GETTEXT
  76
  77 # Permit host specific settings.
  78 . ${srcdir}/configure.host
  79
  80 AC_SUBST(HDEFINES)
  81 AC_PROG_INSTALL
  82
  83 BFD_HOST_64BIT_LONG=0
  84 BFD_HOST_LONG_LONG=0
  85 BFD_HOST_64_BIT_DEFINED=0
  86 BFD_HOST_64_BIT=
  87 BFD_HOST_U_64_BIT=
  88
  89 AC_MSG_CHECKING([for long long])
  90 AC_CACHE_VAL(bfd_cv_has_long_long,
  91 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[unsigned long long ll = 18446744073709551615ULL;]])],[bfd_cv_has_long_long=yes],[bfd_cv_has_long_long=no])])
  92 AC_MSG_RESULT($bfd_cv_has_long_long)
  93 if test $bfd_cv_has_long_long = yes; then
  94   BFD_HOST_LONG_LONG=1
  95   AC_COMPILE_CHECK_SIZEOF(long long)
  96 fi
  97
  98 AC_COMPILE_CHECK_SIZEOF(long)
  99 if test "x${ac_cv_sizeof_long}" = "x8"; then
 100   host64=true
 101   BFD_HOST_64BIT_LONG=1
 102   test -n "${HOST_64BIT_TYPE}" || HOST_64BIT_TYPE="long"
 103   test -n "${HOST_U_64BIT_TYPE}" || HOST_U_64BIT_TYPE="unsigned long"
 104 elif test "x${ac_cv_sizeof_long_long}" = "x8"; then
 105   test -n "${HOST_64BIT_TYPE}" || HOST_64BIT_TYPE="long long"
 106   test -n "${HOST_U_64BIT_TYPE}" || HOST_U_64BIT_TYPE="unsigned long long"
 107 fi
 108
 109 if test -n "${HOST_64BIT_TYPE}" -a -n "${HOST_U_64BIT_TYPE}"; then
 110   BFD_HOST_64_BIT_DEFINED=1
 111   BFD_HOST_64_BIT="${HOST_64BIT_TYPE}"
 112   BFD_HOST_U_64_BIT="${HOST_U_64BIT_TYPE}"
 113 fi
 114
 115 AC_SUBST(BFD_HOST_64BIT_LONG)
 116 AC_SUBST(BFD_HOST_LONG_LONG)
 117 AC_SUBST(BFD_HOST_64_BIT_DEFINED)
 118 AC_SUBST(BFD_HOST_64_BIT)
 119 AC_SUBST(BFD_HOST_U_64_BIT)
 120
 121 BFD_CC_FOR_BUILD
 122
 123 AC_CHECK_HEADERS(stddef.h string.h strings.h stdlib.h time.h unistd.h)
 124 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h)
 125 AC_HEADER_TIME
 126 AC_HEADER_DIRENT
 127 AC_CHECK_FUNCS(fcntl getpagesize setitimer sysconf fdopen getuid getgid)
 128 AC_CHECK_FUNCS(strtoull)
 129
 130 AC_CHECK_DECLS(basename)
 131 AC_CHECK_DECLS(ftello)
 132 AC_CHECK_DECLS(ftello64)
 133 AC_CHECK_DECLS(fseeko)
 134 AC_CHECK_DECLS(fseeko64)
 135
 136 BFD_BINARY_FOPEN
 137
 138 AC_CHECK_DECLS(ffs)
 139 AC_CHECK_DECLS(free)
 140 AC_CHECK_DECLS(getenv)
 141 AC_CHECK_DECLS(malloc)
 142 AC_CHECK_DECLS(realloc)
 143 AC_CHECK_DECLS(strstr)
 144
 145 # If we are configured native, pick a core file support file.
 146 COREFILE=
 147 COREFLAG=
 148 TRAD_HEADER=
 149 if test "${target}" = "${host}"; then
 150   case "${host}" in
 151   alpha*-*-freebsd* | alpha*-*-kfreebsd*-gnu)
 152         COREFILE=''
 153         ;;
 154   alpha*-*-linux-*)
 155         COREFILE=trad-core.lo
 156         TRAD_HEADER='"hosts/alphalinux.h"'
 157         ;;
 158   alpha*-*-netbsd* | alpha*-*-openbsd*)
 159         COREFILE=netbsd-core.lo
 160         ;;
 161   alpha*-*-*)           COREFILE=osf-core.lo ;;
 162   arm-*-freebsd* | arm-*-kfreebsd*-gnu)
 163                         COREFILE='' ;;
 164   arm-*-netbsd*)        COREFILE=netbsd-core.lo ;;
 165   arm-*-riscix)         COREFILE=trad-core.lo ;;
 166   hppa*-*-hpux*)        COREFILE=hpux-core.lo ;;
 167   hppa*-*-hiux*)        COREFILE=hpux-core.lo ;;
 168   hppa*-*-mpeix*)       COREFILE=hpux-core.lo ;;
 169   hppa*-*-bsd*)         COREFILE="hpux-core.lo hppabsd-core.lo"
 170                         COREFLAG="-DHPUX_CORE -DHPPABSD_CORE" ;;
 171   hppa*-*-netbsd* | hppa*-*-openbsd*)
 172         COREFILE=netbsd-core.lo
 173         ;;
 174
 175   i370-*-*)
 176         COREFILE=trad-core.lo
 177         TRAD_HEADER='"hosts/i370linux.h"'
 178         ;;
 179
 180 changequote(,)dnl
 181   i[3-7]86-sequent-bsd*)
 182 changequote([,])dnl
 183         COREFILE=trad-core.lo
 184         TRAD_HEADER='"hosts/symmetry.h"'
 185         ;;
 186 changequote(,)dnl
 187   i[3-7]86-sequent-sysv4*) ;;
 188   i[3-7]86-sequent-sysv*)
 189 changequote([,])dnl
 190         COREFILE=trad-core.lo
 191         TRAD_HEADER='"hosts/symmetry.h"'
 192         ;;
 193 changequote(,)dnl
 194   i[3-7]86-*-bsdi)
 195 changequote([,])dnl
 196         COREFILE=
 197         ;;
 198 changequote(,)dnl
 199   i[3-7]86-*-bsd* | i[3-7]86-*-freebsd[123] | i[3-7]86-*-freebsd[123]\.* | i[3-7]86-*-freebsd4\.[01234] | i[3-7]86-*-freebsd4\.[01234]\.* | i[3-7]86-*-freebsd*aout*)
 200 changequote([,])dnl
 201         COREFILE=trad-core.lo
 202         TRAD_HEADER='"hosts/i386bsd.h"'
 203         ;;
 204 changequote(,)dnl
 205   i[3-7]86-*-freebsd* | i[3-7]86-*-kfreebsd*-gnu)
 206 changequote([,])dnl
 207         COREFILE=''
 208         TRAD_HEADER='"hosts/i386bsd.h"'
 209         ;;
 210 changequote(,)dnl
 211   i[3-7]86-*-netbsd* | i[3-7]86-*-knetbsd*-gnu | i[3-7]86-*-openbsd*)
 212 changequote([,])dnl
 213         COREFILE=netbsd-core.lo
 214         ;;
 215 changequote(,)dnl
 216   i[3-7]86-esix-sysv3*)
 217 changequote([,])dnl
 218         COREFILE=trad-core.lo
 219         TRAD_HEADER='"hosts/esix.h"'
 220         ;;
 221 changequote(,)dnl
 222   i[3-7]86-*-sco3.2v5*)
 223 changequote([,])dnl
 224         COREFILE=sco5-core.lo
 225         ;;
 226 changequote(,)dnl
 227   i[3-7]86-*-sco* | i[3-7]86-*-isc*)
 228 changequote([,])dnl
 229         COREFILE=trad-core.lo
 230         TRAD_HEADER='"hosts/i386sco.h"'
 231         ;;
 232 changequote(,)dnl
 233   i[3-7]86-*-mach3*)
 234 changequote([,])dnl
 235         COREFILE=trad-core.lo
 236         TRAD_HEADER='"hosts/i386mach3.h"'
 237         ;;
 238 changequote(,)dnl
 239   i[3-7]86-*-linux-*)
 240 changequote([,])dnl
 241         COREFILE=trad-core.lo
 242         TRAD_HEADER='"hosts/i386linux.h"'
 243         ;;
 244 changequote(,)dnl
 245   i[3-7]86-*-isc*)      COREFILE=trad-core.lo ;;
 246   i[3-7]86-*-aix*)      COREFILE=aix386-core.lo ;;
 247 changequote([,])dnl
 248   i860-*-mach3* | i860-*-osf1*)
 249         COREFILE=trad-core.lo
 250         TRAD_HEADER='"hosts/i860mach3.h"'
 251         ;;
 252   mips-*-netbsd* | mips*-*-openbsd*)
 253         COREFILE=netbsd-core.lo
 254         ;;
 255   mips-dec-*)
 256         COREFILE=trad-core.lo
 257         TRAD_HEADER='"hosts/decstation.h"'
 258         ;;
 259   mips-sgi-irix4*)      COREFILE=irix-core.lo ;;
 260   mips-sgi-irix5*)      COREFILE=irix-core.lo ;;
 261   mips-sgi-irix6*)      COREFILE=irix-core.lo ;;
 262   mips-*-sysv4*)        ;;
 263   mips-*-sysv* | mips-*-riscos*)
 264         COREFILE=trad-core.lo
 265         TRAD_HEADER='"hosts/riscos.h"'
 266         ;;
 267   mips-sony-bsd*)
 268         COREFILE=trad-core.lo
 269         TRAD_HEADER='"hosts/news-mips.h"'
 270         ;;
 271   m68*-bull*-sysv*)
 272         COREFILE=trad-core.lo
 273         TRAD_HEADER='"hosts/dpx2.h"'
 274         ;;
 275   m68*-hp-hpux*)        COREFILE=hpux-core.lo ;;
 276   m68*-hp-bsd*)
 277         COREFILE=trad-core.lo
 278         TRAD_HEADER='"hosts/hp300bsd.h"'
 279         ;;
 280   m68*-*-linux-*)
 281         COREFILE=trad-core.lo
 282         TRAD_HEADER='"hosts/m68klinux.h"'
 283         ;;
 284   m68*-motorola-sysv*)
 285         COREFILE=trad-core.lo
 286         TRAD_HEADER='"hosts/delta68.h"'
 287         ;;
 288   m68*-sony-*)
 289         COREFILE=trad-core.lo
 290         TRAD_HEADER='"hosts/news.h"'
 291         ;;
 292   m68*-*-netbsd* | m68*-*-openbsd*)
 293         COREFILE=netbsd-core.lo
 294         ;;
 295   m68*-apple-aux*)
 296         COREFILE=trad-core.lo
 297         TRAD_HEADER='"hosts/m68kaux.h"'
 298         ;;
 299   m88*-*-sysv4*)
 300         ;;
 301   m88*-motorola-sysv*)
 302         COREFILE=ptrace-core.lo
 303         ;;
 304   m88*-*-mach3*)
 305         COREFILE=trad-core.lo
 306         TRAD_HEADER='"hosts/m88kmach3.h"'
 307         ;;
 308   m88*-*-openbsd*)
 309         COREFILE=netbsd-core.lo
 310         ;;
 311   ns32k-pc532-mach)
 312         COREFILE=trad-core.lo
 313         TRAD_HEADER='"hosts/pc532mach.h"'
 314         ;;
 315   ns32k-*-netbsd* | ns32k-*-openbsd*)
 316         COREFILE=netbsd-core.lo
 317         ;;
 318   rs6000-*-lynx*)
 319         COREFILE=lynx-core.lo
 320         ;;
 321   rs6000-*-aix5.* | powerpc-*-aix5.*)
 322         COREFILE=rs6000-core.lo
 323         COREFLAG="$COREFLAG -DAIX_5_CORE -DAIX_CORE_DUMPX_CORE"
 324         ;;
 325 changequote(,)dnl
 326   rs6000-*-aix4.[3-9]* | powerpc-*-aix4.[3-9]*)
 327 changequote([,])dnl
 328         COREFILE=rs6000-core.lo
 329         COREFLAG="$COREFLAG -DAIX_CORE_DUMPX_CORE"
 330         # Not all versions of AIX with -DAIX_CORE_DUMPX_CORE
 331         # have c_impl as a member of struct core_dumpx
 332         AC_MSG_CHECKING([for c_impl in struct core_dumpx])
 333         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <core.h>]], [[struct core_dumpx c; c.c_impl = 0;]])],[AC_DEFINE(HAVE_ST_C_IMPL, 1,
 334             [Define if struct core_dumpx has member c_impl])
 335           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 336         ;;
 337   rs6000-*-aix4*)       COREFILE=rs6000-core.lo ;;
 338   rs6000-*-*)           COREFILE=rs6000-core.lo ;;
 339   powerpc-*-aix4*)      COREFILE=rs6000-core.lo ;;
 340   powerpc-*-aix*)       COREFILE=rs6000-core.lo ;;
 341   powerpc-*-beos*)      ;;
 342   powerpc-*-freebsd* | powerpc-*-kfreebsd*-gnu)
 343                         COREFILE='' ;;
 344   powerpc-*-netbsd*)    COREFILE=netbsd-core.lo ;;
 345   powerpc-*-*bsd*)      COREFILE=netbsd-core.lo ;;
 346   s390*-*-*)            COREFILE=trad-core.lo ;;
 347   sh*-*-netbsd*)        COREFILE=netbsd-core.lo ;;
 348   sparc-*-netbsd* | sparc*-*-openbsd*)
 349         COREFILE=netbsd-core.lo
 350         ;;
 351   tahoe-*-*)
 352         COREFILE=trad-core.lo
 353         TRAD_HEADER='"hosts/tahoe.h"'
 354         ;;
 355   vax-*-netbsd* | vax-*-openbsd*)
 356         COREFILE=netbsd-core.lo
 357         ;;
 358   vax-*-ultrix2*)
 359         COREFILE=trad-core.lo
 360         TRAD_HEADER='"hosts/vaxult2.h"'
 361         ;;
 362   vax-*-ultrix*)
 363         COREFILE=trad-core.lo
 364         TRAD_HEADER='"hosts/vaxult2.h"'
 365         ;;
 366   vax-*-linux-*)
 367         COREFILE=trad-core.lo
 368         TRAD_HEADER='"hosts/vaxlinux.h"'
 369         ;;
 370   vax-*-*)
 371         COREFILE=trad-core.lo
 372         TRAD_HEADER='"hosts/vaxbsd.h"'
 373         ;;
 374   x86_64-*-netbsd* | x86_64-*-openbsd*)
 375         COREFILE=netbsd-core.lo
 376         ;;
 377   esac
 378
 379   case "$COREFILE" in
 380   aix386-core.lo)       COREFLAG=-DAIX386_CORE ;;
 381   hppabsd-core.lo)      COREFLAG=-DHPPABSD_CORE ;;
 382   hpux-core.lo)         COREFLAG=-DHPUX_CORE ;;
 383   irix-core.lo)         COREFLAG=-DIRIX_CORE ;;
 384   lynx-core.lo)         COREFLAG=-DLYNX_CORE ;;
 385   netbsd-core.lo)       COREFLAG=-DNETBSD_CORE ;;
 386   osf-core.lo)          COREFLAG=-DOSF_CORE ;;
 387   ptrace-core.lo)       COREFLAG=-DPTRACE_CORE ;;
 388   rs6000-core.lo)       COREFLAG="$COREFLAG -DAIX_CORE" ;;
 389   sco5-core.lo)         COREFLAG="$COREFLAG -DSCO5_CORE" ;;
 390   trad-core.lo)         COREFLAG="$COREFLAG -DTRAD_CORE" ;;
 391   esac
 392
 393   # ELF corefile support has several flavors, but all of
 394   # them use something called <sys/procfs.h>
 395   AC_CHECK_HEADERS(sys/procfs.h)
 396   if test "$ac_cv_header_sys_procfs_h" = yes; then
 397     BFD_HAVE_SYS_PROCFS_TYPE(prstatus_t)
 398     BFD_HAVE_SYS_PROCFS_TYPE(prstatus32_t)
 399     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(prstatus_t, pr_who)
 400     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(prstatus32_t, pr_who)
 401     BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 402     BFD_HAVE_SYS_PROCFS_TYPE(pxstatus_t)
 403     BFD_HAVE_SYS_PROCFS_TYPE(pstatus32_t)
 404     BFD_HAVE_SYS_PROCFS_TYPE(prpsinfo_t)
 405     BFD_HAVE_SYS_PROCFS_TYPE(prpsinfo32_t)
 406     BFD_HAVE_SYS_PROCFS_TYPE(psinfo_t)
 407     BFD_HAVE_SYS_PROCFS_TYPE(psinfo32_t)
 408     BFD_HAVE_SYS_PROCFS_TYPE(lwpstatus_t)
 409     BFD_HAVE_SYS_PROCFS_TYPE(lwpxstatus_t)
 410     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_context)
 411     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_reg)
 412     BFD_HAVE_SYS_PROCFS_TYPE(win32_pstatus_t)
 413   fi
 414 fi
 415 AC_SUBST(COREFILE)
 416 AC_SUBST(COREFLAG)
 417 if test -n "$TRAD_HEADER"; then
 418   AC_DEFINE_UNQUOTED(TRAD_HEADER, $TRAD_HEADER,
 419     [Name of host specific header file to include in trad-core.c.])
 420 fi
 421
 422 # Horrible hacks to build DLLs on Windows.
 423 WIN32LDFLAGS=
 424 WIN32LIBADD=
 425 case "${host}" in
 426 *-*-cygwin*)
 427   if test "$enable_shared" = "yes"; then
 428     WIN32LDFLAGS="-no-undefined"
 429     WIN32LIBADD="-L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin -lkernel32"
 430   fi
 431   ;;
 432 *-*-linux*)
 433   # We borrow WIN32LIBADD so that the shared libbfd won't depend on
 434   # libiberty.a.
 435   case "${host}" in
 436   mips*-*-linux*)
 437     # Linux/MIPS uses PIC by default.
 438     if test "$enable_shared" = "yes"; then
 439       WIN32LIBADD="-L../libiberty -liberty"
 440     fi
 441     ;;
 442   *)
 443 changequote(,)dnl
 444     x=`sed -n -e 's/^[  ]*PICFLAG[      ]*=[    ]*//p' < ../libiberty/Makefile | sed -n '$p'`
 445 changequote([,])dnl
 446     if test -n "$x"; then
 447       WIN32LIBADD="-L../libiberty/pic -liberty"
 448     fi
 449   ;;
 450   esac
 451   ;;
 452 esac
 453 AC_SUBST(WIN32LDFLAGS)
 454 AC_SUBST(WIN32LIBADD)
 455
 456 # target stuff:
 457
 458 # Canonicalize the secondary target names.
 459 if test -n "$enable_targets" ; then
 460     for targ in `echo $enable_targets | sed 's/,/ /g'`
 461     do
 462         result=`$ac_config_sub $targ 2>/dev/null`
 463         if test -n "$result" ; then
 464             canon_targets="$canon_targets $result"
 465         else
 466             # Allow targets that config.sub doesn't recognize, like "all".
 467             canon_targets="$canon_targets $targ"
 468         fi
 469     done
 470 fi
 471
 472 all_targets=false
 473 defvec=
 474 selvecs=
 475 assocvecs=
 476 selarchs=
 477 TDEFINES=
 478 for targ in $target $canon_targets
 479 do
 480     if test "x$targ" = "xall"; then
 481         all_targets=true
 482         assocvecs="$assocvecs $targ_defvec $targ_selvecs"
 483     else
 484         . $srcdir/config.bfd
 485         if test "x$targ" = "x$target"; then
 486             defvec=$targ_defvec
 487         fi
 488         selvecs="$selvecs $targ_defvec $targ_selvecs"
 489         selarchs="$selarchs $targ_archs"
 490         TDEFINES="$TDEFINES $targ_cflags"
 491     fi
 492 done
 493 AC_SUBST(TDEFINES)
 494
 495 # This processing still needs to be done if we're to decide properly whether
 496 # 64-bit support needs to be compiled in.  Currently, it will be included if
 497 # the default or any other explicitly requested target requires it; it
 498 # will not be included on a 32-bit host if no 64-bit target is requested, and
 499 # no "--with-64-bit-bfd" option is given, even if "--enable-targets=all" is
 500 # used.
 501
 502 # uniq the default and selected vectors in all the configured targets.
 503 f=""
 504 for i in $selvecs ; do
 505     case " $f " in
 506     *" $i "*) ;;
 507     *) f="$f $i" ;;
 508     esac
 509 done
 510 selvecs="$f"
 511
 512
 513 # uniq the associated vectors in all the configured targets.
 514 f=""
 515 for i in $assocvecs ; do
 516     case " $f " in
 517     *" $i "*) ;;
 518     *) f="$f $i" ;;
 519     esac
 520 done
 521 assocvecs="$f"
 522
 523
 524 # uniq the architectures in all the configured targets.
 525 f=""
 526 for i in $selarchs ; do
 527     case " $f " in
 528     *" $i "*) ;;
 529     *) f="$f $i" ;;
 530     esac
 531 done
 532 selarchs="$f"
 533
 534 # Target backend .o files.
 535 tb=
 536
 537 elf="elf.lo elflink.lo elf-strtab.lo elf-eh-frame.lo dwarf1.lo"
 538
 539 for vec in $selvecs
 540 do
 541     target_size=32
 542     case "$vec" in
 543     # This list is alphabetized to make it easy to compare
 544     # with the two vector lists in targets.c.  For the same reason,
 545     # use one entry per line, even though this leads to long lines.
 546     a29kcoff_big_vec)           tb="$tb coff-a29k.lo cofflink.lo" ;;
 547     a_out_adobe_vec)            tb="$tb aout-adobe.lo aout32.lo" ;;
 548     aix5coff64_vec)             tb="$tb coff64-rs6000.lo xcofflink.lo aix5ppc-core.lo"; target_size=64 ;;
 549     aout0_big_vec)              tb="$tb aout0.lo aout32.lo" ;;
 550     aout_arm_big_vec)           tb="$tb aout-arm.lo aout32.lo" ;;
 551     aout_arm_little_vec)        tb="$tb aout-arm.lo aout32.lo" ;;
 552     apollocoff_vec)             tb="$tb coff-apollo.lo" ;;
 553     arm_epoc_pe_big_vec)        tb="$tb epoc-pe-arm.lo peigen.lo cofflink.lo " ;;
 554     arm_epoc_pe_little_vec)     tb="$tb epoc-pe-arm.lo peigen.lo cofflink.lo " ;;
 555     arm_epoc_pei_big_vec)       tb="$tb epoc-pei-arm.lo peigen.lo cofflink.lo " ;;
 556     arm_epoc_pei_little_vec)    tb="$tb epoc-pei-arm.lo peigen.lo cofflink.lo " ;;
 557     armcoff_big_vec)            tb="$tb coff-arm.lo cofflink.lo " ;;
 558     armcoff_little_vec)         tb="$tb coff-arm.lo cofflink.lo " ;;
 559     armnetbsd_vec)              tb="$tb armnetbsd.lo aout32.lo" ;;
 560     armpe_big_vec)              tb="$tb pe-arm.lo peigen.lo cofflink.lo " ;;
 561     armpe_little_vec)           tb="$tb pe-arm.lo peigen.lo cofflink.lo " ;;
 562     armpei_big_vec)             tb="$tb pei-arm.lo peigen.lo cofflink.lo " ;;
 563     armpei_little_vec)          tb="$tb pei-arm.lo peigen.lo cofflink.lo " ;;
 564     b_out_vec_big_host)         tb="$tb bout.lo aout32.lo" ;;
 565     b_out_vec_little_host)      tb="$tb bout.lo aout32.lo" ;;
 566     bfd_efi_app_ia32_vec)       tb="$tb efi-app-ia32.lo peigen.lo cofflink.lo" ;;
 567     bfd_efi_app_ia64_vec)       tb="$tb efi-app-ia64.lo pepigen.lo cofflink.lo"; target_size=64 ;;
 568     bfd_elf32_am33lin_vec)      tb="$tb elf32-am33lin.lo elf32.lo $elf" ;;
 569     bfd_elf32_avr_vec)          tb="$tb elf32-avr.lo elf32.lo $elf" ;;
 570     bfd_elf32_big_generic_vec)  tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 571     bfd_elf32_bigarc_vec)       tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 572     bfd_elf32_bigarm_vec)       tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 573     bfd_elf32_bigarm_symbian_vec)
 574                                 tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 575     bfd_elf32_bigarm_vxworks_vec)
 576                                 tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 577     bfd_elf32_bigmips_vec)      tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 578     bfd_elf32_cr16c_vec)        tb="$tb elf32-cr16c.lo elf32.lo $elf" ;;
 579     bfd_elf32_cris_vec)         tb="$tb elf32-cris.lo elf32.lo $elf" ;;
 580     bfd_elf32_crx_vec)          tb="$tb elf32-crx.lo elf32.lo $elf" ;;
 581     bfd_elf32_d10v_vec)         tb="$tb elf32-d10v.lo elf32.lo $elf" ;;
 582     bfd_elf32_d30v_vec)         tb="$tb elf32-d30v.lo elf32.lo $elf" ;;
 583     bfd_elf32_dlx_big_vec)      tb="$tb elf32-dlx.lo elf32.lo $elf" ;;
 584     bfd_elf32_fr30_vec)         tb="$tb elf32-fr30.lo elf32.lo $elf" ;;
 585     bfd_elf32_frv_vec)          tb="$tb elf32-frv.lo elf32.lo $elf" ;;
 586     bfd_elf32_frvfdpic_vec)     tb="$tb elf32-frv.lo elf32.lo $elf" ;;
 587     bfd_elf32_h8300_vec)        tb="$tb elf32-h8300.lo elf32.lo $elf" ;;
 588     bfd_elf32_hppa_linux_vec)   tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 589     bfd_elf32_hppa_nbsd_vec)    tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 590     bfd_elf32_hppa_vec)         tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 591     bfd_elf32_i370_vec)         tb="$tb elf32-i370.lo elf32.lo $elf" ;;
 592     bfd_elf32_i386_freebsd_vec) tb="$tb elf32-i386.lo elf32.lo $elf" ;;
 593     bfd_elf32_i386_vec)         tb="$tb elf32-i386.lo elf32.lo $elf" ;;
 594     bfd_elf32_i860_little_vec)  tb="$tb elf32-i860.lo elf32.lo $elf" ;;
 595     bfd_elf32_i860_vec)         tb="$tb elf32-i860.lo elf32.lo $elf" ;;
 596     bfd_elf32_i960_vec)         tb="$tb elf32-i960.lo elf32.lo $elf" ;;
 597     bfd_elf32_ia64_big_vec)     tb="$tb elf32-ia64.lo elf32.lo $elf" ;;
 598     bfd_elf32_ia64_hpux_big_vec) tb="$tb elf32-ia64.lo elf32.lo $elf";;
 599     bfd_elf32_ip2k_vec)         tb="$tb elf32-ip2k.lo elf32.lo $elf" ;;
 600     bfd_elf32_iq2000_vec)       tb="$tb elf32-iq2000.lo elf32.lo $elf" ;;
 601     bfd_elf32_little_generic_vec) tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 602     bfd_elf32_littlearc_vec)    tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 603     bfd_elf32_littlearm_symbian_vec)
 604                                 tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 605     bfd_elf32_littlearm_vxworks_vec)
 606                                 tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 607     bfd_elf32_littlearm_vec)    tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 608     bfd_elf32_littlemips_vec)   tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 609     bfd_elf32_m32r_vec)         tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 610     bfd_elf32_m32rle_vec)       tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 611     bfd_elf32_m32rlin_vec)      tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 612     bfd_elf32_m32rlelin_vec)    tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 613     bfd_elf32_m68hc11_vec)      tb="$tb elf32-m68hc11.lo elf32-m68hc1x.lo elf32.lo $elf" ;;
 614     bfd_elf32_m68hc12_vec)      tb="$tb elf32-m68hc12.lo elf32-m68hc1x.lo elf32.lo $elf" ;;
 615     bfd_elf32_m68k_vec)         tb="$tb elf32-m68k.lo elf32.lo $elf" ;;
 616     bfd_elf32_m88k_vec)         tb="$tb elf32-m88k.lo elf32.lo $elf" ;;
 617     bfd_elf32_mcore_big_vec)    tb="$tb elf32-mcore.lo elf32.lo $elf" ;;
 618     bfd_elf32_mcore_little_vec) tb="$tb elf32-mcore.lo elf32.lo $elf" ;;
 619     bfd_elf32_mn10200_vec)      tb="$tb elf-m10200.lo elf32.lo $elf" ;;
 620     bfd_elf32_mn10300_vec)      tb="$tb elf-m10300.lo elf32.lo $elf" ;;
 621     bfd_elf32_msp430_vec)       tb="$tb elf32-msp430.lo elf32.lo $elf" ;;
 622     bfd_elf32_nbigmips_vec)     tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 623     bfd_elf32_nlittlemips_vec)  tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 624     bfd_elf32_ntradbigmips_vec) tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 625     bfd_elf32_ntradlittlemips_vec) tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 626     bfd_elf32_openrisc_vec)     tb="$tb elf32-openrisc.lo elf32.lo $elf" ;;
 627     bfd_elf32_or32_big_vec)     tb="$tb elf32-or32.lo elf32.lo $elf" ;;
 628     bfd_elf32_pj_vec)           tb="$tb elf32-pj.lo elf32.lo $elf";;
 629     bfd_elf32_pjl_vec)          tb="$tb elf32-pj.lo elf32.lo $elf";;
 630     bfd_elf32_powerpc_vec)      tb="$tb elf32-ppc.lo elf32.lo $elf" ;;
 631     bfd_elf32_powerpcle_vec)    tb="$tb elf32-ppc.lo elf32.lo $elf" ;;
 632     bfd_elf32_s390_vec)         tb="$tb elf32-s390.lo elf32.lo $elf" ;;
 633     # FIXME: We include cofflink.lo not because it's needed for
 634     # bfd_elf32_sh64[l]_vec, but because we include bfd_elf32_sh[l]_vec
 635     # which needs it but does not list it.  Should be fixed in right place.
 636     bfd_elf32_sh64_vec)         tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 637     bfd_elf32_sh64l_vec)        tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 638     bfd_elf32_sh64lin_vec)      tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 639     bfd_elf32_sh64blin_vec)     tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 640     bfd_elf32_sh64lnbsd_vec)    tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" ;;
 641     bfd_elf32_sh64nbsd_vec)     tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" ;;
 642     bfd_elf32_sh_vec)           tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
 643     bfd_elf32_shblin_vec)       tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 644     bfd_elf32_shl_vec)          tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
 645     bfd_elf32_shl_symbian_vec)  tb="$tb elf32-sh-symbian.lo elf32-sh64-com.lo elf32.lo $elf coff-sh.lo" ;;
 646     bfd_elf32_shlin_vec)        tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 647     bfd_elf32_shlnbsd_vec)      tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 648     bfd_elf32_shnbsd_vec)       tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 649     bfd_elf32_sparc_vec)        tb="$tb elf32-sparc.lo elfxx-sparc.lo elf32.lo $elf" ;;
 650     bfd_elf32_tradbigmips_vec)  tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 651     bfd_elf32_tradlittlemips_vec) tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 652     bfd_elf32_us_cris_vec)      tb="$tb elf32-cris.lo elf32.lo $elf" ;;
 653     bfd_elf32_v850_vec)         tb="$tb elf32-v850.lo elf32.lo $elf" ;;
 654     bfd_elf32_vax_vec)          tb="$tb elf32-vax.lo elf32.lo $elf" ;;
 655     bfd_elf32_xstormy16_vec)    tb="$tb elf32-xstormy16.lo elf32.lo $elf" ;;
 656     bfd_elf32_xtensa_le_vec)    tb="$tb xtensa-isa.lo xtensa-modules.lo elf32-xtensa.lo elf32.lo $elf" ;;
 657     bfd_elf32_xtensa_be_vec)    tb="$tb xtensa-isa.lo xtensa-modules.lo elf32-xtensa.lo elf32.lo $elf" ;;
 658     bfd_elf64_alpha_freebsd_vec) tb="$tb elf64-alpha.lo elf64.lo $elf"; target_size=64 ;;
 659     bfd_elf64_alpha_vec)        tb="$tb elf64-alpha.lo elf64.lo $elf"; target_size=64 ;;
 660     bfd_elf64_big_generic_vec)  tb="$tb elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 661     bfd_elf64_bigmips_vec)      tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 662     bfd_elf64_hppa_linux_vec)   tb="$tb elf64-hppa.lo elf64.lo $elf"; target_size=64 ;;
 663     bfd_elf64_hppa_vec)         tb="$tb elf64-hppa.lo elf64.lo $elf"; target_size=64 ;;
 664     bfd_elf64_ia64_big_vec)     tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 665     bfd_elf64_ia64_hpux_big_vec) tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 666     bfd_elf64_ia64_little_vec)  tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 667     bfd_elf64_little_generic_vec) tb="$tb elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 668     bfd_elf64_littlemips_vec)   tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 669     bfd_elf64_mmix_vec)         tb="$tb elf64-mmix.lo elf64.lo $elf" target_size=64 ;;
 670     bfd_elf64_powerpc_vec)      tb="$tb elf64-ppc.lo elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 671     bfd_elf64_powerpcle_vec)    tb="$tb elf64-ppc.lo elf64-gen.lo elf64.lo $elf" target_size=64 ;;
 672     bfd_elf64_s390_vec)         tb="$tb elf64-s390.lo elf64.lo $elf"; target_size=64 ;;
 673     bfd_elf64_sh64_vec)         tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 674     bfd_elf64_sh64l_vec)        tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 675     bfd_elf64_sh64lin_vec)      tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 676     bfd_elf64_sh64blin_vec)     tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 677     bfd_elf64_sh64lnbsd_vec)    tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 678     bfd_elf64_sh64nbsd_vec)     tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 679     bfd_elf64_sparc_vec)        tb="$tb elf64-sparc.lo elfxx-sparc.lo elf64.lo $elf"; target_size=64 ;;
 680     bfd_elf64_tradbigmips_vec)  tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 681     bfd_elf64_tradlittlemips_vec) tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 682     bfd_elf64_x86_64_vec)       tb="$tb elf64-x86-64.lo elf64.lo $elf"; target_size=64 ;;
 683     bfd_mmo_vec)                tb="$tb mmo.lo" target_size=64 ;;
 684     bfd_powerpc_pe_vec)         tb="$tb pe-ppc.lo peigen.lo cofflink.lo" ;;
 685     bfd_powerpc_pei_vec)        tb="$tb pei-ppc.lo peigen.lo cofflink.lo" ;;
 686     bfd_powerpcle_pe_vec)       tb="$tb pe-ppc.lo peigen.lo cofflink.lo" ;;
 687     bfd_powerpcle_pei_vec)      tb="$tb pei-ppc.lo peigen.lo cofflink.lo" ;;
 688     cris_aout_vec)              tb="$tb aout-cris.lo" ;;
 689     demo_64_vec)                tb="$tb demo64.lo aout64.lo"; target_size=64 ;;
 690     ecoff_big_vec)              tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 691     ecoff_biglittle_vec)        tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 692     ecoff_little_vec)           tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 693     ecoffalpha_little_vec)      tb="$tb coff-alpha.lo ecoff.lo ecofflink.lo"; target_size=64 ;;
 694     go32coff_vec)               tb="$tb coff-go32.lo cofflink.lo" ;;
 695     go32stubbedcoff_vec)        tb="$tb coff-stgo32.lo cofflink.lo" ;;
 696     h8300coff_vec)              tb="$tb coff-h8300.lo reloc16.lo" ;;
 697     h8500coff_vec)              tb="$tb coff-h8500.lo reloc16.lo" ;;
 698     host_aout_vec)              tb="$tb host-aout.lo aout32.lo" ;;
 699     hp300bsd_vec)               tb="$tb hp300bsd.lo aout32.lo" ;;
 700     hp300hpux_vec)              tb="$tb hp300hpux.lo aout32.lo" ;;
 701     i386aout_vec)               tb="$tb i386aout.lo aout32.lo" ;;
 702     i386bsd_vec)                tb="$tb i386bsd.lo aout32.lo" ;;
 703     i386coff_vec)               tb="$tb coff-i386.lo cofflink.lo" ;;
 704     i386dynix_vec)              tb="$tb i386dynix.lo aout32.lo" ;;
 705     i386freebsd_vec)            tb="$tb i386freebsd.lo aout32.lo" ;;
 706     i386linux_vec)              tb="$tb i386linux.lo aout32.lo" ;;
 707     i386lynx_aout_vec)          tb="$tb i386lynx.lo lynx-core.lo aout32.lo" ;;
 708     i386lynx_coff_vec)          tb="$tb cf-i386lynx.lo cofflink.lo lynx-core.lo" ;;
 709     i386mach3_vec)              tb="$tb i386mach3.lo aout32.lo" ;;
 710     i386msdos_vec)              tb="$tb i386msdos.lo" ;;
 711     i386netbsd_vec)             tb="$tb i386netbsd.lo aout32.lo" ;;
 712     i386os9k_vec)               tb="$tb i386os9k.lo aout32.lo" ;;
 713     i386pe_vec)                 tb="$tb pe-i386.lo peigen.lo cofflink.lo" ;;
 714     i386pei_vec)                tb="$tb pei-i386.lo peigen.lo cofflink.lo" ;;
 715     i860coff_vec)               tb="$tb coff-i860.lo cofflink.lo" ;;
 716     icoff_big_vec)              tb="$tb coff-i960.lo cofflink.lo" ;;
 717     icoff_little_vec)           tb="$tb coff-i960.lo cofflink.lo" ;;
 718     ieee_vec)                   tb="$tb ieee.lo" ;;
 719     m68k4knetbsd_vec)           tb="$tb m68k4knetbsd.lo aout32.lo" ;;
 720     m68kaux_coff_vec)           tb="$tb coff-aux.lo coff-m68k.lo cofflink.lo" ;;
 721     m68kcoff_vec)               tb="$tb coff-m68k.lo cofflink.lo" ;;
 722     m68kcoffun_vec)             tb="$tb coff-u68k.lo coff-m68k.lo cofflink.lo" ;;
 723     m68klinux_vec)              tb="$tb m68klinux.lo aout32.lo" ;;
 724     m68klynx_aout_vec)          tb="$tb m68klynx.lo lynx-core.lo aout32.lo" ;;
 725     m68klynx_coff_vec)          tb="$tb cf-m68klynx.lo coff-m68k.lo cofflink.lo lynx-core.lo" ;;
 726     m68knetbsd_vec)             tb="$tb m68knetbsd.lo aout32.lo" ;;
 727     m68ksysvcoff_vec)           tb="$tb coff-svm68k.lo cofflink.lo" ;;
 728     m88kbcs_vec)                tb="$tb coff-m88k.lo" ;;
 729     m88kmach3_vec)              tb="$tb m88kmach3.lo aout32.lo" ;;
 730     m88kopenbsd_vec)            tb="$tb m88kopenbsd.lo aout32.lo" ;;
 731     maxqcoff_vec)               tb="$tb coff-maxq.lo" ;;
 732     mach_o_be_vec)              tb="$tb mach-o.lo" ;;
 733     mach_o_le_vec)              tb="$tb mach-o.lo" ;;
 734     mach_o_fat_vec)             tb="$tb mach-o.lo" ;;
 735     mcore_pe_big_vec)           tb="$tb pe-mcore.lo peigen.lo cofflink.lo" ;;
 736     mcore_pe_little_vec)        tb="$tb pe-mcore.lo peigen.lo cofflink.lo" ;;
 737     mcore_pei_big_vec)          tb="$tb pei-mcore.lo peigen.lo cofflink.lo" ;;
 738     mcore_pei_little_vec)       tb="$tb pei-mcore.lo peigen.lo cofflink.lo" ;;
 739     mipslpe_vec)                tb="$tb pe-mips.lo peigen.lo cofflink.lo" ;;
 740     mipslpei_vec)               tb="$tb pei-mips.lo peigen.lo cofflink.lo" ;;
 741     newsos3_vec)                tb="$tb newsos3.lo aout32.lo" ;;
 742     nlm32_alpha_vec)            tb="$tb nlm32-alpha.lo nlm32.lo nlm.lo"; target_size=64 ;;
 743     nlm32_i386_vec)             tb="$tb nlm32-i386.lo nlm32.lo nlm.lo" ;;
 744     nlm32_powerpc_vec)          tb="$tb nlm32-ppc.lo nlm32.lo nlm.lo" ;;
 745     nlm32_sparc_vec)            tb="$tb nlm32-sparc.lo nlm32.lo nlm.lo" ;;
 746     or32coff_big_vec)           tb="$tb coff-or32.lo cofflink.lo" ;;
 747     pc532machaout_vec)          tb="$tb pc532-mach.lo aout-ns32k.lo" ;;
 748     pc532netbsd_vec)            tb="$tb ns32knetbsd.lo aout-ns32k.lo" ;;
 749     pef_vec)                    tb="$tb pef.lo" ;;
 750     pef_xlib_vec)               tb="$tb pef.lo" ;;
 751     pdp11_aout_vec)             tb="$tb pdp11.lo" ;;
 752     pmac_xcoff_vec)             tb="$tb coff-rs6000.lo xcofflink.lo" ;;
 753     ppcboot_vec)                tb="$tb ppcboot.lo" ;;
 754     riscix_vec)                 tb="$tb aout32.lo riscix.lo" ;;
 755     rs6000coff64_vec)           tb="$tb coff64-rs6000.lo xcofflink.lo aix5ppc-core.lo"; target_size=64 ;;
 756     rs6000coff_vec)             tb="$tb coff-rs6000.lo xcofflink.lo" ;;
 757     shcoff_small_vec)           tb="$tb coff-sh.lo cofflink.lo" ;;
 758     shcoff_vec)                 tb="$tb coff-sh.lo cofflink.lo" ;;
 759     shlcoff_small_vec)          tb="$tb coff-sh.lo cofflink.lo" ;;
 760     shlcoff_vec)                tb="$tb coff-sh.lo cofflink.lo" ;;
 761     shlpe_vec)                  tb="$tb pe-sh.lo coff-sh.lo peigen.lo cofflink.lo" ;;
 762     shlpei_vec)                 tb="$tb pei-sh.lo coff-sh.lo peigen.lo cofflink.lo" ;;
 763     som_vec)                    tb="$tb som.lo" ;;
 764     sparccoff_vec)              tb="$tb coff-sparc.lo" ;;
 765     sparcle_aout_vec)           tb="$tb aout-sparcle.lo aout32.lo" ;;
 766     sparclinux_vec)             tb="$tb sparclinux.lo aout32.lo" ;;
 767     sparclynx_aout_vec)         tb="$tb sparclynx.lo lynx-core.lo aout32.lo" ;;
 768     sparclynx_coff_vec)         tb="$tb cf-sparclynx.lo lynx-core.lo" ;;
 769     sparcnetbsd_vec)            tb="$tb sparcnetbsd.lo aout32.lo" ;;
 770     sunos_big_vec)              tb="$tb sunos.lo aout32.lo" ;;
 771     sym_vec)                    tb="$tb xsym.lo" ;;
 772     tic30_aout_vec)             tb="$tb aout-tic30.lo" ;;
 773     tic30_coff_vec)             tb="$tb coff-tic30.lo" ;;
 774     tic4x_coff0_vec)            tb="$tb coff-tic4x.lo" ;;
 775     tic4x_coff0_beh_vec)        tb="$tb coff-tic4x.lo" ;;
 776     tic4x_coff1_vec)            tb="$tb coff-tic4x.lo" ;;
 777     tic4x_coff1_beh_vec)        tb="$tb coff-tic4x.lo" ;;
 778     tic4x_coff2_vec)            tb="$tb coff-tic4x.lo" ;;
 779     tic4x_coff2_beh_vec)        tb="$tb coff-tic4x.lo" ;;
 780     tic54x_coff0_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 781     tic54x_coff0_vec)           tb="$tb coff-tic54x.lo" ;;
 782     tic54x_coff1_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 783     tic54x_coff1_vec)           tb="$tb coff-tic54x.lo" ;;
 784     tic54x_coff2_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 785     tic54x_coff2_vec)           tb="$tb coff-tic54x.lo" ;;
 786     tic80coff_vec)              tb="$tb coff-tic80.lo cofflink.lo" ;;
 787     vaxnetbsd_vec)              tb="$tb vaxnetbsd.lo aout32.lo" ;;
 788     vax1knetbsd_vec)            tb="$tb vax1knetbsd.lo aout32.lo" ;;
 789     vaxbsd_vec)                 tb="$tb vaxbsd.lo aout32.lo" ;;
 790     versados_vec)               tb="$tb versados.lo" ;;
 791     vms_alpha_vec)              tb="$tb vms.lo vms-hdr.lo vms-gsd.lo vms-tir.lo vms-misc.lo"; target_size=64 ;;
 792     vms_vax_vec)                tb="$tb vms.lo vms-hdr.lo vms-gsd.lo vms-tir.lo vms-misc.lo" ;;
 793     w65_vec)                    tb="$tb coff-w65.lo reloc16.lo" ;;
 794     we32kcoff_vec)              tb="$tb coff-we32k.lo" ;;
 795     z8kcoff_vec)                tb="$tb coff-z8k.lo reloc16.lo" ;;
 796
 797     # These appear out of order in targets.c
 798     srec_vec)                   tb="$tb srec.lo" ;;
 799     symbolsrec_vec)             tb="$tb srec.lo" ;;
 800     tekhex_vec)                 tb="$tb tekhex.lo" ;;
 801     cisco_core_big_vec)         tb="$tb cisco-core.lo" ;;
 802     cisco_core_little_vec)      tb="$tb cisco-core.lo" ;;
 803
 804     "")                 ;;
 805     *) AC_MSG_ERROR(*** unknown target vector $vec) ;;
 806     esac
 807
 808     if test ${target_size} = 64; then
 809         target64=true
 810     fi
 811     if test x"${vec}" = x"${defvec}"; then
 812         bfd_default_target_size=${target_size}
 813     fi
 814 done
 815
 816 # Target architecture .o files.
 817 # A couple of CPUs use shorter file names to avoid problems on DOS
 818 # filesystems.
 819 ta=`echo $selarchs | sed -e s/bfd_/cpu-/g -e s/_arch/.lo/g -e s/mn10200/m10200/ -e s/mn10300/m10300/`
 820
 821 # Weed out duplicate .o files.
 822 f=""
 823 for i in $tb ; do
 824     case " $f " in
 825     *" $i "*) ;;
 826     *) f="$f $i" ;;
 827     esac
 828 done
 829 tb="$f"
 830
 831 f=""
 832 for i in $ta ; do
 833     case " $f " in
 834     *" $i "*) ;;
 835     *) f="$f $i" ;;
 836     esac
 837 done
 838 ta="$f"
 839
 840 bfd_backends="$tb"
 841 bfd_machines="$ta"
 842
 843 if test x${all_targets} = xtrue ; then
 844   bfd_backends="${bfd_backends}"' $(ALL_BACKENDS)'
 845   bfd_machines="${bfd_machines}"' $(ALL_MACHINES)'
 846   selvecs=
 847   havevecs=
 848   selarchs=
 849   test -n "$assocvecs" &&
 850     assocvecs=`echo $assocvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 851 else    # all_targets is true
 852   # Only set these if they will be nonempty, for the clever echo.
 853   havevecs=
 854   assocvecs=
 855   test -n "$selvecs" &&
 856     havevecs=`echo $selvecs | sed -e 's/^/-DHAVE_/' -e 's/ \(.\)/ -DHAVE_\1/g'`
 857   test -n "$selvecs" &&
 858     selvecs=`echo $selvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 859   test -n "$selarchs" &&
 860     selarchs=`echo $selarchs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 861 fi      # all_targets is true
 862
 863 case ${host64}-${target64}-${want64} in
 864   *true*)
 865     wordsize=64
 866     bfd_libs='$(BFD64_LIBS) $(BFD32_LIBS)'
 867     all_backends='$(BFD64_BACKENDS) $(BFD32_BACKENDS)'
 868     if test $BFD_HOST_64_BIT_DEFINED = 0; then
 869       AC_MSG_WARN([You have requested a 64 bit BFD configuration, but])
 870       AC_MSG_WARN([your compiler may not have a 64 bit integral type])
 871     fi
 872     if test -n "$GCC" ; then
 873        bad_64bit_gcc=no;
 874        AC_MSG_CHECKING([for gcc version with buggy 64-bit support])
 875        # Add more tests for gcc versions with non-working 64-bit support here.
 876        AC_EGREP_CPP([: 2 : 91 : 1 :],[:__GNUC__:__GNUC_MINOR__:__i386__:],
 877                     bad_64bit_gcc=yes;
 878                     AC_MSG_RESULT([yes: egcs-1.1.2 on ix86 spotted]),
 879                     AC_MSG_RESULT(no))
 880        if test $bad_64bit_gcc = yes ; then
 881          AC_MSG_ERROR([A newer version of gcc is needed for the requested 64-bit BFD configuration])
 882        fi
 883     fi
 884     ;;
 885   false-false-false)
 886     wordsize=32
 887     bfd_libs='$(BFD32_LIBS)'
 888     all_backends='$(BFD32_BACKENDS)'
 889     ;;
 890 esac
 891
 892 AC_SUBST(wordsize)
 893 AC_SUBST(bfd_libs)
 894 AC_SUBST(all_backends)
 895 AC_SUBST(bfd_backends)
 896 AC_SUBST(bfd_machines)
 897 AC_SUBST(bfd_default_target_size)
 898
 899 # Determine the host dependant file_ptr a.k.a. off_t type.  In order
 900 # prefer: off64_t - if ftello64 and fseeko64, off_t - if ftello and
 901 # fseeko, long.  This assumes that sizeof off_t is .ge. sizeof long.
 902 # Hopefully a reasonable assumption since fseeko et.al. should be
 903 # upward compatible.
 904 AC_CHECK_FUNCS(ftello ftello64 fseeko fseeko64)
 905 if test x"$ac_cv_func_ftello" = xyes -a x"$ac_cv_func_fseeko" = xyes; then
 906     AC_COMPILE_CHECK_SIZEOF(off_t)
 907 fi
 908 AC_MSG_CHECKING([file_ptr type])
 909 bfd_file_ptr="long"
 910 bfd_ufile_ptr="unsigned long"
 911 if test x"$ac_cv_func_ftello64" = xyes -a x"$ac_cv_func_fseeko64" = xyes \
 912         -o x"${ac_cv_sizeof_off_t}" = x8; then
 913     bfd_file_ptr=BFD_HOST_64_BIT
 914     bfd_ufile_ptr=BFD_HOST_U_64_BIT
 915 fi
 916 AC_MSG_RESULT($bfd_file_ptr)
 917 AC_SUBST(bfd_file_ptr)
 918 AC_SUBST(bfd_ufile_ptr)
 919
 920
 921 tdefaults=""
 922 test -n "${defvec}" && tdefaults="${tdefaults} -DDEFAULT_VECTOR=${defvec}"
 923 test -n "${selvecs}" && tdefaults="${tdefaults} -DSELECT_VECS='${selvecs}'"
 924 test -n "${assocvecs}" && tdefaults="${tdefaults} -DASSOCIATED_VECS='${assocvecs}'"
 925 test -n "${selarchs}" && tdefaults="${tdefaults} -DSELECT_ARCHITECTURES='${selarchs}'"
 926 test -n "${havevecs}" && tdefaults="${tdefaults} ${havevecs}"
 927 AC_SUBST(tdefaults)
 928
 929 dnl AC_CHECK_HEADERS(sys/mman.h)
 930 AC_FUNC_MMAP
 931 AC_CHECK_FUNCS(madvise mprotect)
 932 case ${want_mmap}+${ac_cv_func_mmap_fixed_mapped} in
 933   true+yes )  AC_DEFINE(USE_MMAP, 1, [Use mmap if it's available?]) ;;
 934 esac
 935
 936 rm -f doc/config.status
 937 AC_CONFIG_FILES([Makefile doc/Makefile bfd-in3.h:bfd-in2.h po/Makefile.in:po/Make-in])
 938 AC_CONFIG_COMMANDS([default],[[sed -e '/SRC-POTFILES =/r po/SRC-POTFILES' -e '/BLD-POTFILES =/r po/BLD-POTFILES' po/Makefile.in > po/Makefile]],[[]])
 939 AC_OUTPUT
 940