ld/configure.in

   1 dnl Process this file with autoconf to produce a configure script
   2 dnl
   3 AC_PREREQ(2.59)
   4 AC_INIT
   5 AC_CONFIG_SRCDIR(ldmain.c)
   6
   7 AC_CANONICAL_TARGET
   8 AC_ISC_POSIX
   9
  10 changequote(,)dnl
  11 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  12 changequote([,])dnl
  13 AM_INIT_AUTOMAKE(ld, ${BFD_VERSION})
  14
  15 AC_ARG_WITH(lib-path, [  --with-lib-path=dir1:dir2...  set default LIB_PATH],LIB_PATH=$withval)
  16 AC_ARG_ENABLE(targets,
  17 [  --enable-targets        alternative target configurations],
  18 [case "${enableval}" in
  19   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  20             ;;
  21   no)       enable_targets= ;;
  22   *)        enable_targets=$enableval ;;
  23 esac])dnl
  24 AC_ARG_ENABLE(64-bit-bfd,
  25 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  26 [case "${enableval}" in
  27   yes)  want64=true  ;;
  28   no)   want64=false ;;
  29   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  30 esac],[want64=false])dnl
  31
  32 AC_ARG_WITH(sysroot,
  33 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
  34 [
  35  case ${with_sysroot} in
  36  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
  37  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
  38  esac
  39
  40  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
  41  use_sysroot=yes
  42
  43  if test "x$prefix" = xNONE; then
  44   test_prefix=/usr/local
  45  else
  46   test_prefix=$prefix
  47  fi
  48  if test "x$exec_prefix" = xNONE; then
  49   test_exec_prefix=$test_prefix
  50  else
  51   test_exec_prefix=$exec_prefix
  52  fi
  53  case ${TARGET_SYSTEM_ROOT} in
  54  "${test_prefix}"|"${test_prefix}/"*|\
  55  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
  56  '${prefix}'|'${prefix}/'*|\
  57  '${exec_prefix}'|'${exec_prefix}/'*)
  58    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
  59    TARGET_SYSTEM_ROOT_DEFINE="$t"
  60    ;;
  61  esac
  62 ], [
  63  use_sysroot=no
  64  TARGET_SYSTEM_ROOT=
  65  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
  66 ])
  67 AC_SUBST(use_sysroot)
  68 AC_SUBST(TARGET_SYSTEM_ROOT)
  69 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
  70
  71 AC_ARG_ENABLE([got],
  72 AS_HELP_STRING([--enable-got=<type>],
  73                [GOT handling scheme (target, single, negative, multigot)]),
  74 [case "${enableval}" in
  75   target | single | negative | multigot)  got_handling=$enableval ;;
  76   *)  AC_MSG_ERROR(bad value ${enableval} for --enable-got option) ;;
  77 esac],
  78 [got_handling=target])
  79
  80 case "${got_handling}" in
  81   target)
  82     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_TARGET_DEFAULT],
  83               [Define to choose default GOT handling scheme]) ;;
  84   single)
  85     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_SINGLE],
  86               [Define to choose default GOT handling scheme]) ;;
  87   negative)
  88     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_NEGATIVE],
  89               [Define to choose default GOT handling scheme]) ;;
  90   multigot)
  91     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_MULTIGOT],
  92               [Define to choose default GOT handling scheme]) ;;
  93   *)  AC_MSG_ERROR(bad value ${got_handling} for --enable-got option) ;;
  94 esac
  95
  96 AM_BINUTILS_WARNINGS
  97
  98 AC_CONFIG_HEADERS([config.h:config.in])
  99
 100 if test -z "$target" ; then
 101     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
 102 fi
 103 if test -z "$host" ; then
 104     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
 105 fi
 106
 107 # host-specific stuff:
 108
 109 AC_PROG_CC
 110 AC_GNU_SOURCE
 111 AC_USE_SYSTEM_EXTENSIONS
 112 AC_SYS_LARGEFILE
 113 AC_PROG_INSTALL
 114
 115 LT_INIT
 116
 117 ALL_LINGUAS="fr sv tr es da vi zh_CN zh_TW ga fi id"
 118 ZW_GNU_GETTEXT_SISTER_DIR
 119 AM_PO_SUBDIRS
 120
 121 AC_EXEEXT
 122
 123 AC_PROG_YACC
 124 AM_PROG_LEX
 125
 126 AM_MAINTAINER_MODE
 127 AM_CONDITIONAL(GENINSRC_NEVER, false)
 128 ACX_PROG_CMP_IGNORE_INITIAL
 129
 130 . ${srcdir}/configure.host
 131
 132 AC_SUBST(HDEFINES)
 133 AC_SUBST(HOSTING_CRT0)
 134 AC_SUBST(HOSTING_LIBS)
 135 AC_SUBST(NATIVE_LIB_DIRS)
 136
 137 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h elf-hints.h limits.h sys/param.h)
 138 AC_CHECK_FUNCS(glob mkstemp realpath sbrk waitpid)
 139 AC_HEADER_DIRENT
 140
 141 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 142 AC_CACHE_VAL(ld_cv_decl_getopt_unistd_h,
 143 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 144 ld_cv_decl_getopt_unistd_h=yes, ld_cv_decl_getopt_unistd_h=no)])
 145 AC_MSG_RESULT($ld_cv_decl_getopt_unistd_h)
 146 if test $ld_cv_decl_getopt_unistd_h = yes; then
 147   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 148             [Is the prototype for getopt in <unistd.h> in the expected format?])
 149 fi
 150
 151 BFD_BINARY_FOPEN
 152
 153 AC_CHECK_DECLS([strstr, free, sbrk, getenv, environ])
 154
 155 # Link in zlib if we can.  This is needed only for the bootstrap tests
 156 # right now, since those tests use libbfd, which depends on zlib.
 157 AC_SEARCH_LIBS(zlibVersion, z, [AC_CHECK_HEADERS(zlib.h)])
 158
 159 # When converting linker scripts into strings for use in emulation
 160 # files, use astring.sed if the compiler supports ANSI string
 161 # concatenation, or ostring.sed otherwise.  This is to support the
 162 # broken Microsoft MSVC compiler, which limits the length of string
 163 # constants, while still supporting pre-ANSI compilers which do not
 164 # support string concatenation.
 165 AC_MSG_CHECKING([whether ANSI C string concatenation works])
 166 AC_CACHE_VAL(ld_cv_string_concatenation,
 167 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [char *a = "a" "a";])],
 168   ld_cv_string_concatenation=yes,
 169   ld_cv_string_concatenation=no)])
 170 AC_MSG_RESULT($ld_cv_string_concatenation)
 171 if test "$ld_cv_string_concatenation" = "yes"; then
 172   STRINGIFY=astring.sed
 173 else
 174   STRINGIFY=ostring.sed
 175 fi
 176 AC_SUBST(STRINGIFY)
 177
 178 # target-specific stuff:
 179
 180 all_targets=
 181 EMUL=
 182 all_emuls=
 183 all_emul_extras=
 184 all_libpath=
 185
 186 dnl We need to get an arbitrary number of tdir definitions into
 187 dnl Makefile.  We can't do it using AC_SUBST, because autoconf does
 188 dnl not permit literal newlines in an AC_SUBST variables.  So we use a
 189 dnl file.
 190 rm -f tdirs
 191
 192 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 193 do
 194   if test "$targ_alias" = "all"; then
 195     all_targets=true
 196   else
 197     # Canonicalize the secondary target names.
 198     result=`$ac_config_sub $targ_alias 2>/dev/null`
 199     if test -n "$result"; then
 200         targ=$result
 201     else
 202         targ=$targ_alias
 203     fi
 204
 205     . ${srcdir}/configure.tgt
 206
 207     if test "$targ" = "$target"; then
 208       EMUL=$targ_emul
 209     fi
 210
 211     if test x${want64} = xfalse; then
 212       . ${srcdir}/../bfd/config.bfd
 213     fi
 214
 215     if test x${want64} = xtrue; then
 216       targ_extra_emuls="$targ_extra_emuls $targ64_extra_emuls"
 217       targ_extra_libpath="$targ_extra_libpath $targ64_extra_libpath"
 218     fi
 219
 220     for i in $targ_emul $targ_extra_emuls $targ_extra_libpath; do
 221         case " $all_emuls " in
 222         *" e${i}.o "*) ;;
 223         *)
 224           all_emuls="$all_emuls e${i}.o"
 225           eval result=\$tdir_$i
 226           test -z "$result" && result=$targ_alias
 227           echo tdir_$i=$result >> tdirs
 228           ;;
 229         esac
 230     done
 231
 232     for i in $targ_emul $targ_extra_libpath; do
 233         case " $all_libpath " in
 234         *" ${i} "*) ;;
 235         *)
 236           if test -z "$all_libpath"; then
 237             all_libpath=${i}
 238           else
 239             all_libpath="$all_libpath ${i}"
 240           fi
 241           ;;
 242         esac
 243     done
 244
 245     for i in $targ_extra_ofiles; do
 246         case " $all_emul_extras " in
 247         *" ${i} "*) ;;
 248         *)
 249           all_emul_extras="$all_emul_extras ${i}"
 250           ;;
 251         esac
 252     done
 253   fi
 254 done
 255
 256 AC_SUBST(EMUL)
 257
 258 TDIRS=tdirs
 259 AC_SUBST_FILE(TDIRS)
 260
 261 if test x${all_targets} = xtrue; then
 262   if test x${want64} = xfalse; then
 263     AC_CHECK_SIZEOF(long)
 264     if test "x${ac_cv_sizeof_long}" = "x8"; then
 265       want64=true
 266     fi
 267   fi
 268   if test x${want64} = xtrue; then
 269     EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)'
 270   else
 271     EMULATION_OFILES='$(ALL_EMULATIONS)'
 272   fi
 273   EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)'
 274 else
 275   EMULATION_OFILES=$all_emuls
 276   EMUL_EXTRA_OFILES=$all_emul_extras
 277 fi
 278 AC_SUBST(EMULATION_OFILES)
 279 AC_SUBST(EMUL_EXTRA_OFILES)
 280 AC_SUBST(LIB_PATH)
 281
 282 EMULATION_LIBPATH=$all_libpath
 283 AC_SUBST(EMULATION_LIBPATH)
 284
 285 if test x${enable_static} = xno; then
 286   TESTBFDLIB="--rpath ../bfd/.libs ../bfd/.libs/libbfd.so"
 287 else
 288   TESTBFDLIB="../bfd/.libs/libbfd.a"
 289 fi
 290 AC_SUBST(TESTBFDLIB)
 291
 292 target_vendor=${target_vendor=$host_vendor}
 293 case "$target_vendor" in
 294   hp) EXTRA_SHLIB_EXTENSION=".sl" ;;
 295   *)  EXTRA_SHLIB_EXTENSION= ;;
 296 esac
 297
 298 case "$target_os" in
 299   lynxos) EXTRA_SHLIB_EXTENSION=".a" ;;
 300 esac
 301
 302 if test x${EXTRA_SHLIB_EXTENSION} != x ; then
 303   AC_DEFINE_UNQUOTED(EXTRA_SHLIB_EXTENSION, "$EXTRA_SHLIB_EXTENSION",
 304    [Additional extension a shared object might have.])
 305 fi
 306
 307 dnl Required by html, pdf, install-pdf and install-html
 308 AC_SUBST(datarootdir)
 309 AC_SUBST(docdir)
 310 AC_SUBST(htmldir)
 311 AC_SUBST(pdfdir)
 312
 313 AC_CONFIG_FILES(Makefile po/Makefile.in:po/Make-in)
 314 AC_OUTPUT