bfd/acinclude.m4

   1 sinclude(../config/accross.m4)
   2 sinclude(../config/acx.m4)
   3 sinclude(../bfd/bfd.m4)
   4 sinclude(../bfd/warning.m4)
   5
   6 dnl See whether we need to use fopen-bin.h rather than fopen-same.h.
   7 AC_DEFUN([BFD_BINARY_FOPEN],
   8 [AC_REQUIRE([AC_CANONICAL_TARGET])
   9 case "${host}" in
  10 changequote(,)dnl
  11 *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-cygwin* | *-*-windows*)
  12 changequote([,])dnl
  13   AC_DEFINE(USE_BINARY_FOPEN, 1, [Use b modifier when opening binary files?]) ;;
  14 esac])dnl
  15
  16 dnl Get a default for CC_FOR_BUILD to put into Makefile.
  17 AC_DEFUN([BFD_CC_FOR_BUILD],
  18 [# Put a plausible default for CC_FOR_BUILD in Makefile.
  19 if test -z "$CC_FOR_BUILD"; then
  20   if test "x$cross_compiling" = "xno"; then
  21     CC_FOR_BUILD='$(CC)'
  22   else
  23     CC_FOR_BUILD=gcc
  24   fi
  25 fi
  26 AC_SUBST(CC_FOR_BUILD)
  27 # Also set EXEEXT_FOR_BUILD.
  28 if test "x$cross_compiling" = "xno"; then
  29   EXEEXT_FOR_BUILD='$(EXEEXT)'
  30 else
  31   AC_CACHE_CHECK([for build system executable suffix], bfd_cv_build_exeext,
  32     [rm -f conftest*
  33      echo 'int main () { return 0; }' > conftest.c
  34      bfd_cv_build_exeext=
  35      ${CC_FOR_BUILD} -o conftest conftest.c 1>&5 2>&5
  36      for file in conftest.*; do
  37        case $file in
  38        *.c | *.o | *.obj | *.ilk | *.pdb) ;;
  39        *) bfd_cv_build_exeext=`echo $file | sed -e s/conftest//` ;;
  40        esac
  41      done
  42      rm -f conftest*
  43      test x"${bfd_cv_build_exeext}" = x && bfd_cv_build_exeext=no])
  44   EXEEXT_FOR_BUILD=""
  45   test x"${bfd_cv_build_exeext}" != xno && EXEEXT_FOR_BUILD=${bfd_cv_build_exeext}
  46 fi
  47 AC_SUBST(EXEEXT_FOR_BUILD)])dnl
  48
  49 sinclude(../libtool.m4)
  50 dnl The lines below arrange for aclocal not to bring libtool.m4
  51 dnl AM_PROG_LIBTOOL into aclocal.m4, while still arranging for automake
  52 dnl to add a definition of LIBTOOL to Makefile.in.
  53 ifelse(yes,no,[
  54 AC_DEFUN([AM_PROG_LIBTOOL],)
  55 AC_DEFUN([AM_DISABLE_SHARED],)
  56 AC_SUBST(LIBTOOL)
  57 ])
  58
  59 sinclude(../gettext.m4)
  60 ifelse(yes,no,[
  61 AC_DEFUN([CY_WITH_NLS],)
  62 AC_SUBST(INTLLIBS)
  63 ])
  64
  65 AC_DEFUN([AM_INSTALL_LIBBFD],
  66 [AC_MSG_CHECKING([whether to install libbfd])
  67   AC_ARG_ENABLE(install-libbfd,
  68 [  --enable-install-libbfd controls installation of libbfd and related headers],
  69       install_libbfd_p=$enableval,
  70       if test "${host}" = "${target}" || test "$enable_shared" = "yes"; then
  71         install_libbfd_p=yes
  72       else
  73         install_libbfd_p=no
  74       fi)
  75   AC_MSG_RESULT($install_libbfd_p)
  76   AM_CONDITIONAL(INSTALL_LIBBFD, test $install_libbfd_p = yes)
  77   # Need _noncanonical variables for this.
  78   ACX_NONCANONICAL_HOST
  79   ACX_NONCANONICAL_TARGET
  80   # libbfd.a is a host library containing target dependent code
  81   bfdlibdir='$(libdir)'
  82   bfdincludedir='$(includedir)'
  83   if test "${host}" != "${target}"; then
  84     bfdlibdir='$(exec_prefix)/$(host_noncanonical)/$(target_noncanonical)/lib'
  85     bfdincludedir='$(exec_prefix)/$(host_noncanonical)/$(target_noncanonical)/include'
  86   fi
  87   AC_SUBST(bfdlibdir)
  88   AC_SUBST(bfdincludedir)
  89 ]
  90 )