gold/testsuite/script_test_2.t

   1 /* script_test_2.t -- linker script test 2 for gold
   2
   3    Copyright 2008 Free Software Foundation, Inc.
   4    Written by Ian Lance Taylor <iant@google.com>.
   5
   6    This file is part of gold.
   7
   8    This program is free software; you can redistribute it and/or modify
   9    it under the terms of the GNU General Public License as published by
  10    the Free Software Foundation; either version 3 of the License, or
  11    (at your option) any later version.
  12
  13    This program is distributed in the hope that it will be useful,
  14    but WITHOUT ANY WARRANTY; without even the implied warranty of
  15    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16    GNU General Public License for more details.
  17
  18    You should have received a copy of the GNU General Public License
  19    along with this program; if not, write to the Free Software
  20    Foundation, Inc., 51 Franklin Street - Fifth Floor, Boston,
  21    MA 02110-1301, USA.  */
  22
  23 SECTIONS
  24 {
  25   /* With luck this will work everywhere.  */
  26   . = 0x10000000;
  27
  28   /* With luck this will be enough to get the program working.  */
  29   .text : { *(.text) }
  30   . += 0x100000;
  31   . = ALIGN(0x100);
  32   .data : { *(.data) }
  33   .bss : { *(.bss) }
  34
  35   /* Now the real test.  */
  36   . = 0x20000001;
  37   start_test_area = .;
  38   .gold_test ALIGN(16) : SUBALIGN(32) {
  39     start_test_area_1 = .;
  40
  41     /* No sections should wind up here, because of the EXCLUDE_FILE.  */
  42     *( EXCLUDE_FILE(script_test*) .gold_test)
  43
  44     /* This should match only script_test_2b.o.  */
  45     script_test_2b.o(.gold_test)
  46
  47     /* This should match the remaining sections.  */
  48     *(.gold_test)
  49
  50     . = . + 4;
  51     start_data = .;
  52     BYTE(1)
  53     SHORT(2)
  54     LONG(4)
  55     QUAD(8)
  56     end_data = .;
  57
  58     start_fill = .;
  59     FILL(0x12345678);
  60     . = . + 7;
  61     BYTE(0)
  62     end_fill = .;
  63   }
  64   end_test_area = .;
  65 }