opcodes/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3
   4 AC_PREREQ(2.13)
   5 AC_INIT(z8k-dis.c)
   6
   7 AC_CANONICAL_SYSTEM
   8 AC_ISC_POSIX
   9
  10 # We currently only use the version number for the name of any shared
  11 # library.  For user convenience, we always use the same version
  12 # number that BFD is using.
  13 changequote(,)dnl
  14 BFD_VERSION=`grep INIT_AUTOMAKE ${srcdir}/../bfd/configure.in | sed -n -e 's/[  ]//g' -e 's/^.*,\(.*\)).*$/\1/p'`
  15 changequote([,])dnl
  16
  17 AM_INIT_AUTOMAKE(opcodes, ${BFD_VERSION})
  18
  19 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  20 dnl to call AC_CHECK_PROG.
  21 AC_CHECK_TOOL(AR, ar)
  22 AC_CHECK_TOOL(RANLIB, ranlib, :)
  23
  24 dnl Default to a non shared library.  This may be overridden by the
  25 dnl configure option --enable-shared.
  26 AM_DISABLE_SHARED
  27
  28 AM_PROG_LIBTOOL
  29
  30 AC_ARG_ENABLE(targets,
  31 [  --enable-targets        alternative target configurations],
  32 [case "${enableval}" in
  33   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  34             ;;
  35   no)       enable_targets= ;;
  36   *)        enable_targets=$enableval ;;
  37 esac])dnl
  38 AC_ARG_ENABLE(commonbfdlib,
  39 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  40 [case "${enableval}" in
  41   yes) commonbfdlib=true ;;
  42   no)  commonbfdlib=false ;;
  43   *)   AC_MSG_ERROR([bad value ${enableval} for opcodes commonbfdlib option]) ;;
  44 esac])dnl
  45
  46 build_warnings="-W -Wall"
  47 AC_ARG_ENABLE(build-warnings,
  48 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  49 [case "${enableval}" in
  50   yes)  ;;
  51   no)   build_warnings="-w";;
  52   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  53         build_warnings="${build_warnings} ${t}";;
  54   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  55         build_warnings="${t} ${build_warnings}";;
  56   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  57 esac
  58 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  59   echo "Setting warning flags = $build_warnings" 6>&1
  60 fi])dnl
  61 WARN_CFLAGS=""
  62 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  63     WARN_CFLAGS="${build_warnings}"
  64 fi
  65 AC_SUBST(WARN_CFLAGS)
  66
  67 AM_CONFIG_HEADER(config.h:config.in)
  68
  69 if test -z "$target" ; then
  70     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  71 fi
  72 AC_ARG_PROGRAM
  73
  74 AM_MAINTAINER_MODE
  75 AC_EXEEXT
  76
  77 # host-specific stuff:
  78
  79 AC_PROG_CC
  80
  81 ALL_LINGUAS=
  82 CY_GNU_GETTEXT
  83
  84 . ${srcdir}/../bfd/configure.host
  85
  86 AC_SUBST(HDEFINES)
  87 AC_PROG_INSTALL
  88
  89 AC_CHECK_HEADERS(string.h strings.h stdlib.h)
  90
  91 cgen_maint=no
  92 cgendir='$(srcdir)/../cgen'
  93
  94 AC_ARG_ENABLE(cgen-maint,
  95 [  --enable-cgen-maint[=dir]    build cgen generated files],
  96 [case "${enableval}" in
  97   yes)  cgen_maint=yes ;;
  98   no)   cgen_maint=no ;;
  99   *)
 100         # argument is cgen install directory (not implemented yet).
 101         # Having a `share' directory might be more appropriate for the .scm,
 102         # .cpu, etc. files.
 103         cgen_maint=yes
 104         cgendir=${cgen_maint}/lib/cgen
 105         ;;
 106 esac])dnl
 107 AM_CONDITIONAL(CGEN_MAINT, test x${cgen_maint} = xyes)
 108 AC_SUBST(cgendir)
 109
 110 using_cgen=no
 111
 112 # Horrible hacks to build DLLs on Windows.
 113 WIN32LDFLAGS=
 114 WIN32LIBADD=
 115 case "${host}" in
 116 *-*-cygwin*)
 117   if test "$enable_shared" = "yes"; then
 118     WIN32LDFLAGS="-no-undefined"
 119     WIN32LIBADD="-L`pwd`/../bfd -lbfd -L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin"
 120   fi
 121   ;;
 122 esac
 123 AC_SUBST(WIN32LDFLAGS)
 124 AC_SUBST(WIN32LIBADD)
 125
 126 # target-specific stuff:
 127
 128 # Canonicalize the secondary target names.
 129 if test -n "$enable_targets" ; then
 130     for targ in `echo $enable_targets | sed 's/,/ /g'`
 131     do
 132         result=`$ac_config_sub $targ 2>/dev/null`
 133         if test -n "$result" ; then
 134             canon_targets="$canon_targets $result"
 135         else
 136             # Allow targets that config.sub doesn't recognize, like "all".
 137             canon_targets="$canon_targets $targ"
 138         fi
 139     done
 140 fi
 141
 142 all_targets=false
 143 selarchs=
 144 for targ in $target $canon_targets
 145 do
 146     if test "x$targ" = "xall" ; then
 147         all_targets=true
 148     else
 149         . $srcdir/../bfd/config.bfd
 150         selarchs="$selarchs $targ_archs"
 151     fi
 152 done
 153
 154 # Utility var, documents generic cgen support files.
 155
 156 cgen_files="cgen-opc.lo cgen-asm.lo cgen-dis.lo"
 157
 158 # We don't do any links based on the target system, just makefile config.
 159
 160 if test x${all_targets} = xfalse ; then
 161
 162     # Target architecture .o files.
 163     ta=
 164
 165     for arch in $selarchs
 166     do
 167         ad=`echo $arch | sed -e s/bfd_//g -e s/_arch//g`
 168         archdefs="$archdefs -DARCH_$ad"
 169         case "$arch" in
 170         bfd_a29k_arch)          ta="$ta a29k-dis.lo" ;;
 171         bfd_alliant_arch)       ;;
 172         bfd_alpha_arch)         ta="$ta alpha-dis.lo alpha-opc.lo" ;;
 173         bfd_arc_arch)           ta="$ta arc-dis.lo arc-opc.lo arc-ext.lo" ;;
 174         bfd_arm_arch)           ta="$ta arm-dis.lo" ;;
 175         bfd_avr_arch)           ta="$ta avr-dis.lo" ;;
 176         bfd_convex_arch)        ;;
 177         bfd_cris_arch)          ta="$ta cris-dis.lo cris-opc.lo" ;;
 178         bfd_d10v_arch)          ta="$ta d10v-dis.lo d10v-opc.lo" ;;
 179         bfd_d30v_arch)          ta="$ta d30v-dis.lo d30v-opc.lo" ;;
 180         bfd_fr30_arch)          ta="$ta fr30-asm.lo fr30-desc.lo fr30-dis.lo fr30-ibld.lo fr30-opc.lo" using_cgen=yes ;;
 181         bfd_h8300_arch)         ta="$ta h8300-dis.lo" ;;
 182         bfd_h8500_arch)         ta="$ta h8500-dis.lo" ;;
 183         bfd_hppa_arch)          ta="$ta hppa-dis.lo" ;;
 184         bfd_i370_arch)          ta="$ta i370-dis.lo i370-opc.lo" ;;
 185         bfd_i386_arch)          ta="$ta i386-dis.lo" ;;
 186         bfd_i860_arch)          ta="$ta i860-dis.lo" ;;
 187         bfd_i960_arch)          ta="$ta i960-dis.lo" ;;
 188         bfd_ia64_arch)          ta="$ta ia64-dis.lo ia64-opc.lo" ;;
 189         bfd_m32r_arch)          ta="$ta m32r-asm.lo m32r-desc.lo m32r-dis.lo m32r-ibld.lo m32r-opc.lo m32r-opinst.lo" using_cgen=yes ;;
 190         bfd_m68hc11_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 191         bfd_m68hc12_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 192         bfd_m68k_arch)          ta="$ta m68k-dis.lo m68k-opc.lo" ;;
 193         bfd_m88k_arch)          ta="$ta m88k-dis.lo" ;;
 194         bfd_mcore_arch)         ta="$ta mcore-dis.lo" ;;
 195         bfd_mips_arch)          ta="$ta mips-dis.lo mips-opc.lo mips16-opc.lo" ;;
 196         bfd_mn10200_arch)       ta="$ta m10200-dis.lo m10200-opc.lo" ;;
 197         bfd_mn10300_arch)       ta="$ta m10300-dis.lo m10300-opc.lo" ;;
 198         bfd_ns32k_arch)         ta="$ta ns32k-dis.lo" ;;
 199         bfd_pj_arch)            ta="$ta pj-dis.lo pj-opc.lo" ;;
 200         bfd_powerpc_arch)       ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 201         bfd_pyramid_arch)       ;;
 202         bfd_powerpc_64_arch)    ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 203         bfd_romp_arch)          ;;
 204         bfd_rs6000_arch)        ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 205         bfd_s390_arch)          ta="$ta s390-dis.lo s390-opc.lo" ;;
 206         bfd_sh_arch)
 207                                 ta="$ta sh-dis.lo" ;;
 208         bfd_sparc_arch)         ta="$ta sparc-dis.lo sparc-opc.lo" ;;
 209         bfd_tahoe_arch)         ;;
 210         bfd_tic30_arch)         ta="$ta tic30-dis.lo" ;;
 211         bfd_tic54x_arch)        ta="$ta tic54x-dis.lo tic54x-opc.lo" ;;
 212         bfd_tic80_arch)         ta="$ta tic80-dis.lo tic80-opc.lo" ;;
 213         bfd_v850_arch)          ta="$ta v850-opc.lo v850-dis.lo" ;;
 214         bfd_v850e_arch)         ta="$ta v850-opc.lo v850-dis.lo" ;;
 215         bfd_v850ea_arch)        ta="$ta v850-opc.lo v850-dis.lo" ;;
 216         bfd_vax_arch)           ta="$ta vax-dis.lo" ;;
 217         bfd_w65_arch)           ta="$ta w65-dis.lo" ;;
 218         bfd_we32k_arch)         ;;
 219         bfd_z8k_arch)           ta="$ta z8k-dis.lo" ;;
 220
 221         "")                     ;;
 222         *)              AC_MSG_ERROR(*** unknown target architecture $arch) ;;
 223         esac
 224     done
 225
 226     if test $using_cgen = yes ; then
 227         ta="$ta $cgen_files"
 228     fi
 229
 230     # Weed out duplicate .o files.
 231     f=""
 232     for i in $ta ; do
 233         case " $f " in
 234         *" $i "*) ;;
 235         *) f="$f $i" ;;
 236         esac
 237     done
 238     ta="$f"
 239
 240     # And duplicate -D flags.
 241     f=""
 242     for i in $archdefs ; do
 243         case " $f " in
 244         *" $i "*) ;;
 245         *) f="$f $i" ;;
 246         esac
 247     done
 248     archdefs="$f"
 249
 250     BFD_MACHINES="$ta"
 251
 252 else    # all_targets is true
 253     archdefs=-DARCH_all
 254     BFD_MACHINES='$(ALL_MACHINES)'
 255 fi
 256
 257 AC_SUBST(archdefs)
 258 AC_SUBST(BFD_MACHINES)
 259
 260 AC_OUTPUT(Makefile po/Makefile.in:po/Make-in,
 261 [sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile])