libiberty/configure.in

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 AC_PREREQ(2.12.1)
   4 AC_INIT(pexecute.c)
   5
   6 dnl We use these options to decide which functions to include.
   7 AC_ARG_WITH(target-subdir,
   8 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory])
   9 AC_ARG_WITH(cross-host,
  10 [  --with-cross-host=HOST           Configuring with a cross compiler])
  11 AC_ARG_WITH(newlib,
  12 [  --with-newlib                    Configuring with newlib])
  13
  14 if test "${srcdir}" = "."; then
  15   if test -z "${with_target_subdir}"; then
  16     libiberty_topdir="${srcdir}/.."
  17   else
  18     if test "${with_target_subdir}" != "."; then
  19       libiberty_topdir="${srcdir}/${with_multisrctop}../.."
  20     else
  21       libiberty_topdir="${srcdir}/${with_multisrctop}.."
  22     fi
  23   fi
  24 else
  25   libiberty_topdir="${srcdir}/.."
  26 fi
  27 AC_CONFIG_AUX_DIR($libiberty_topdir)
  28
  29 AC_CANONICAL_HOST
  30
  31 dnl When we start using automake:
  32 dnl AM_INIT_AUTOMAKE(libiberty, 1.0)
  33
  34 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  35 dnl to call AC_CHECK_PROG.
  36 AC_CHECK_TOOL(AR, ar)
  37 AC_CHECK_TOOL(RANLIB, ranlib, :)
  38
  39 # FIXME: We temporarily define our own version of AC_PROG_CC.  This is
  40 # copied from autoconf 2.12, but does not call AC_PROG_CC_WORKS.  We
  41 # are probably using a cross compiler, which will not be able to fully
  42 # link an executable.  This should really be fixed in autoconf
  43 # itself.
  44
  45 AC_DEFUN(LIB_AC_PROG_CC,
  46 [AC_BEFORE([$0], [AC_PROG_CPP])dnl
  47 AC_PROVIDE([AC_PROG_CC])
  48 AC_CHECK_PROG(CC, gcc, gcc)
  49 if test -z "$CC"; then
  50   AC_CHECK_PROG(CC, cc, cc, , , /usr/ucb/cc)
  51   test -z "$CC" && AC_MSG_ERROR([no acceptable cc found in \$PATH])
  52 fi
  53
  54 AC_PROG_CC_GNU
  55
  56 if test $ac_cv_prog_gcc = yes; then
  57   GCC=yes
  58 dnl Check whether -g works, even if CFLAGS is set, in case the package
  59 dnl plays around with CFLAGS (such as to build both debugging and
  60 dnl normal versions of a library), tasteless as that idea is.
  61   ac_test_CFLAGS="${CFLAGS+set}"
  62   ac_save_CFLAGS="$CFLAGS"
  63   CFLAGS=
  64   AC_PROG_CC_G
  65   if test "$ac_test_CFLAGS" = set; then
  66     CFLAGS="$ac_save_CFLAGS"
  67   elif test $ac_cv_prog_cc_g = yes; then
  68     CFLAGS="-g -O2"
  69   else
  70     CFLAGS="-O2"
  71   fi
  72 else
  73   GCC=
  74   test "${CFLAGS+set}" = set || CFLAGS="-g"
  75 fi
  76 ])
  77
  78 LIB_AC_PROG_CC
  79
  80 AC_ISC_POSIX
  81
  82 dnl When we start using libtool:
  83 dnl Default to a non shared library.  This may be overridden by the
  84 dnl configure option --enable-shared.
  85 dnl AM_DISABLE_SHARED
  86
  87 dnl When we start using libtool:
  88 dnl AM_PROG_LIBTOOL
  89
  90 dnl When we start using automake:
  91 dnl AM_CONFIG_HEADER(config.h:config.in)
  92 AC_CONFIG_HEADER(config.h:config.in)
  93
  94 dnl When we start using automake:
  95 dnl AM_MAINTAINER_MODE
  96 dnl AC_EXEEXT
  97
  98 dnl When we start using automake:
  99 dnl AM_PROG_INSTALL
 100 AC_PROG_INSTALL
 101
 102 . ${srcdir}/config.table
 103 host_makefile_frag=${frag}
 104 AC_SUBST_FILE(host_makefile_frag)
 105
 106 # It's OK to check for header files.  Although the compiler may not be
 107 # able to link anything, it had better be able to at least compile
 108 # something.
 109 AC_CHECK_HEADERS(sys/file.h sys/param.h stdlib.h string.h unistd.h strings.h sys/time.h sys/resource.h)
 110 AC_HEADER_SYS_WAIT
 111
 112 # This is the list of functions which libiberty will provide if they
 113 # are not available on the host.
 114
 115 funcs="asprintf"
 116 funcs="$funcs atexit"
 117 funcs="$funcs basename"
 118 funcs="$funcs bcmp"
 119 funcs="$funcs bcopy"
 120 funcs="$funcs bzero"
 121 funcs="$funcs calloc"
 122 funcs="$funcs clock"
 123 funcs="$funcs getcwd"
 124 funcs="$funcs getpagesize"
 125 funcs="$funcs index"
 126 funcs="$funcs insque"
 127 funcs="$funcs memchr"
 128 funcs="$funcs memcmp"
 129 funcs="$funcs memcpy"
 130 funcs="$funcs memmove"
 131 funcs="$funcs memset"
 132 funcs="$funcs mkstemps"
 133 funcs="$funcs random"
 134 funcs="$funcs rename"
 135 funcs="$funcs rindex"
 136 funcs="$funcs sigsetmask"
 137 funcs="$funcs strcasecmp"
 138 funcs="$funcs strchr"
 139 funcs="$funcs strdup"
 140 funcs="$funcs strncasecmp"
 141 funcs="$funcs strrchr"
 142 funcs="$funcs strstr"
 143 funcs="$funcs strtod"
 144 funcs="$funcs strtol"
 145 funcs="$funcs strtoul"
 146 funcs="$funcs tmpnam"
 147 funcs="$funcs vasprintf"
 148 funcs="$funcs vfprintf"
 149 funcs="$funcs vprintf"
 150 funcs="$funcs vsprintf"
 151 funcs="$funcs waitpid"
 152
 153 # Also in the old function.def file: alloca, vfork, getopt.
 154
 155 vars="sys_errlist sys_nerr sys_siglist"
 156
 157 checkfuncs="getrusage on_exit psignal strerror strsignal sysconf times"
 158
 159 # These are neither executed nor required, but they help keep
 160 # autoheader happy without adding a bunch of text to acconfig.h.
 161 if test "x" = "y"; then
 162   AC_CHECK_FUNCS(asprintf atexit basename bcmp bcopy bzero calloc clock getcwd)
 163   AC_CHECK_FUNCS(getpagesize index insque mkstemps memchr memcmp memcpy memmove)
 164   AC_CHECK_FUNCS(memset random rename rindex sigsetmask strcasecmp)
 165   AC_CHECK_FUNCS(strchr strdup strncasecmp strrchr strstr strtod strtol)
 166   AC_CHECK_FUNCS(strtoul tmpnam vasprintf vfprintf vprintf vsprintf waitpid)
 167   AC_DEFINE(HAVE_SYS_ERRLIST)
 168   AC_DEFINE(HAVE_SYS_NERR)
 169   AC_DEFINE(HAVE_SYS_SIGLIST)
 170   AC_CHECK_FUNCS(getrusage on_exit psignal strerror strsignal sysconf times)
 171 fi
 172
 173 # For each of these functions, if the host does not provide the
 174 # function we want to put FN.o in LIBOBJS, and if the host does
 175 # provide the function, we want to define HAVE_FN in config.h.  Also,
 176 # if the host does not provide alloca, we set ALLOCA to alloca.o
 177
 178 setobjs=
 179 if test -n "${with_target_subdir}"; then
 180
 181   # We are being configured as a target library.  AC_REPLACE_FUNCS
 182   # may not work correctly, because the compiler may not be able to
 183   # link executables.  Note that we may still be being configured
 184   # native.
 185
 186   # If we are being configured for newlib, we know which functions
 187   # newlib provide and which ones we will be expected to provide.
 188
 189   if test "x${with_newlib}" = "xyes"; then
 190     ALLOCA="alloca.o"
 191     LIBOBJS="asprintf.o basename.o insque.o random.o strdup.o vasprintf.o"
 192
 193     for f in $funcs; do
 194       case "$f" in
 195         asprintf | basename | insque | random | strdup | vasprintf)
 196           ;;
 197         *)
 198           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 199           AC_DEFINE_UNQUOTED($n)
 200           ;;
 201       esac
 202     done
 203
 204     # newlib doesnt provide any of the variables in $vars, so we
 205     # dont have to check them here.
 206
 207     # Of the functions in $checkfuncs, newlib only has strerror.
 208     AC_DEFINE(HAVE_STRERROR)
 209
 210     setobjs=yes
 211
 212   fi
 213 fi
 214
 215 if test -z "${setobjs}"; then
 216   case "${host}" in
 217
 218   *-*-vxworks*)
 219     # Handle VxWorks configuration specially, since on VxWorks the
 220     # libraries are actually on the target board, not in the file
 221     # system.
 222     LIBOBJS="basename.o getpagesize.o insque.o random.o strcasecmp.o"
 223     LIBOBJS="$LIBOBJS strncasecmp.o strdup.o vfork.o waitpid.o vasprintf.o"
 224     for f in $funcs; do
 225       case "$f" in
 226         basename | getpagesize | insque | random | strcasecmp)
 227           ;;
 228         strncasecmp | strdup | vfork | waitpid | vasprintf)
 229           ;;
 230         *)
 231           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 232           AC_DEFINE_UNQUOTED($n)
 233           ;;
 234       esac
 235     done
 236
 237     # VxWorks doesn't provide any of the variables in $vars, so we
 238     # don't have to check them here.
 239
 240     # Of the functions in $checkfuncs, VxWorks only has strerror.
 241     AC_DEFINE(HAVE_STRERROR)
 242
 243     setobjs=yes
 244     ;;
 245
 246   esac
 247 fi
 248
 249 if test -z "${setobjs}"; then
 250
 251   case "${host}" in
 252
 253   *-*-cygwin*)
 254     # The Cygwin library actually uses a couple of files from
 255     # libiberty when it is built.  If we are building a native
 256     # Cygwin, and we run the tests, we will appear to have these
 257     # files.  However, when we go on to build winsup, we will wind up
 258     # with a library which does not have the files, since they should
 259     # have come from libiberty.
 260
 261     # We handle this by removing the functions the winsup library
 262     # provides from our shell variables, so that they appear to be
 263     # missing.
 264
 265     funcs="`echo $funcs | sed -e 's/random//'`"
 266     LIBOBJS="$LIBOBJS random.o"
 267     vars="`echo $vars | sed -e 's/sys_siglist//'`"
 268     checkfuncs="`echo $checkfuncs | sed -e 's/strsignal//' -e 's/psignal//'`"
 269     ;;
 270
 271   *-*-mingw32*)
 272     # Under mingw32, sys_nerr and sys_errlist exist, but they are
 273     # macros, so the test below won't find them.
 274     vars="`echo $vars | sed -e 's/sys_nerr//' -e 's/sys_errlist//'`"
 275     AC_DEFINE(HAVE_SYS_NERR)
 276     AC_DEFINE(HAVE_SYS_ERRLIST)
 277     ;;
 278
 279   *-*-uwin*)
 280     # Under some versions of uwin, vfork is notoriously buggy and the test
 281     # can hang configure; on other versions, vfork exists just as a stub.
 282     # FIXME: This should be removed once vfork in uwin's runtime is fixed.
 283     ac_cv_func_vfork_works=no
 284     ;;
 285
 286   esac
 287
 288   # We haven't set the list of objects yet.  Use the standard autoconf
 289   # tests.  This will only work if the compiler works.
 290   AC_PROG_CC_WORKS
 291   AC_REPLACE_FUNCS($funcs)
 292   AC_FUNC_ALLOCA
 293   AC_FUNC_VFORK
 294   if test $ac_cv_func_vfork_works = no; then
 295     LIBOBJS="$LIBOBJS vfork.o"
 296   fi
 297   for v in $vars; do
 298     AC_MSG_CHECKING([for $v])
 299     AC_CACHE_VAL(libiberty_cv_var_$v,
 300       [AC_TRY_LINK([int *p;], [extern int $v; p = &$v;],
 301                    [eval "libiberty_cv_var_$v=yes"],
 302                    [eval "libiberty_cv_var_$v=no"])])
 303     if eval "test \"`echo '$libiberty_cv_var_'$v`\" = yes"; then
 304       AC_MSG_RESULT(yes)
 305       n=HAVE_`echo $v | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 306       AC_DEFINE_UNQUOTED($n)
 307     else
 308       AC_MSG_RESULT(no)
 309     fi
 310   done
 311   AC_CHECK_FUNCS($checkfuncs)
 312 fi
 313
 314 # Install a library built with a cross compiler in $(tooldir) rather
 315 # than $(libdir).
 316 if test -z "${with_cross_host}"; then
 317   INSTALL_DEST=libdir
 318 else
 319   INSTALL_DEST=tooldir
 320 fi
 321 AC_SUBST(INSTALL_DEST)
 322
 323 # We need multilib support, but only if configuring for the target.
 324 AC_OUTPUT(Makefile,
 325 [test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 326 if test -n "$CONFIG_FILES"; then
 327   if test -n "${with_target_subdir}"; then
 328     # FIXME: We shouldn't need to set ac_file
 329     ac_file=Makefile
 330     . ${libiberty_topdir}/config-ml.in
 331   fi
 332 fi],
 333 srcdir=${srcdir}
 334 host=${host}
 335 target=${target}
 336 with_target_subdir=${with_target_subdir}
 337 with_multisubdir=${with_multisubdir}
 338 ac_configure_args="--enable-multilib ${ac_configure_args}"
 339 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 340 libiberty_topdir=${libiberty_topdir}
 341 )