binutils/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 AC_PREREQ(2.13)
   4 AC_INIT(ar.c)
   5
   6 AC_CANONICAL_SYSTEM
   7 AC_ISC_POSIX
   8
   9 changequote(,)dnl
  10 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  11 changequote([,])dnl
  12 AM_INIT_AUTOMAKE(binutils, ${BFD_VERSION})
  13
  14 AM_PROG_LIBTOOL
  15
  16 AC_ARG_ENABLE(targets,
  17 [  --enable-targets        alternative target configurations],
  18 [case "${enableval}" in
  19   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  20             ;;
  21   no)       enable_targets= ;;
  22   *)        enable_targets=$enableval ;;
  23 esac])dnl
  24 AC_ARG_ENABLE(commonbfdlib,
  25 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  26 [case "${enableval}" in
  27   yes) commonbfdlib=true ;;
  28   no)  commonbfdlib=false ;;
  29   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  30 esac])dnl
  31
  32 build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
  33 AC_ARG_ENABLE(build-warnings,
  34 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  35 [case "${enableval}" in
  36   yes)  ;;
  37   no)   build_warnings="-w";;
  38   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  39         build_warnings="${build_warnings} ${t}";;
  40   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  41         build_warnings="${t} ${build_warnings}";;
  42   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  43 esac
  44 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  45   echo "Setting warning flags = $build_warnings" 6>&1
  46 fi])dnl
  47 WARN_CFLAGS=""
  48 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  49     WARN_CFLAGS="${build_warnings}"
  50 fi
  51 AC_SUBST(WARN_CFLAGS)
  52
  53 AM_CONFIG_HEADER(config.h:config.in)
  54
  55 if test -z "$target" ; then
  56     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  57 fi
  58 if test -z "$host" ; then
  59     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
  60 fi
  61
  62 AC_PROG_CC
  63
  64 AC_PROG_YACC
  65 AM_PROG_LEX
  66
  67 ALL_LINGUAS="fr tr ja es sv da zh_CN ru"
  68 CY_GNU_GETTEXT
  69
  70 AM_MAINTAINER_MODE
  71 AC_EXEEXT
  72 if test -n "$EXEEXT"; then
  73   AC_DEFINE(HAVE_EXECUTABLE_SUFFIX, 1,
  74             [Does the platform use an executable suffix?])
  75 fi
  76 AC_DEFINE_UNQUOTED(EXECUTABLE_SUFFIX, "${EXEEXT}",
  77                    [Suffix used for executables, if any.])
  78
  79 # host-specific stuff:
  80
  81 HDEFINES=
  82
  83 . ${srcdir}/../bfd/configure.host
  84
  85 AC_SUBST(HDEFINES)
  86 AR=${AR-ar}
  87 AC_SUBST(AR)
  88 AC_PROG_RANLIB
  89 AC_PROG_INSTALL
  90
  91 BFD_CC_FOR_BUILD
  92
  93 DEMANGLER_NAME=c++filt
  94 case "${host}" in
  95   *-*-go32* | *-*-msdos*)
  96     DEMANGLER_NAME=cxxfilt
  97 esac
  98 AC_SUBST(DEMANGLER_NAME)
  99
 100 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h fcntl.h sys/file.h)
 101 AC_HEADER_SYS_WAIT
 102 AC_FUNC_ALLOCA
 103 AC_CHECK_FUNCS(sbrk utimes setmode getc_unlocked strcoll)
 104
 105 # Check whether fopen64 is available and whether _LARGEFILE64_SOURCE
 106 # needs to be defined for it
 107 AC_MSG_CHECKING([for fopen64])
 108 AC_CACHE_VAL(bu_cv_have_fopen64,
 109 [AC_TRY_LINK([#include <stdio.h>], [FILE *f = fopen64 ("/tmp/foo","r");],
 110 bu_cv_have_fopen64=yes,
 111 [saved_CPPFLAGS=$CPPFLAGS
 112  CPPFLAGS="$CPPFLAGS -D_LARGEFILE64_SOURCE"
 113  AC_TRY_LINK([#include <stdio.h>], [FILE *f = fopen64 ("/tmp/foo","r");],
 114 bu_cv_have_fopen64="need -D_LARGEFILE64_SOURCE",
 115 bu_cv_have_fopen64=no)
 116  CPPFLAGS=$saved_CPPFLAGS])])
 117 AC_MSG_RESULT($bu_cv_have_fopen64)
 118 if test "$bu_cv_have_fopen64" != no; then
 119   AC_DEFINE([HAVE_FOPEN64], 1,
 120             [Is fopen64 available?])
 121   if test "$bu_cv_have_fopen64" = "need -D_LARGEFILE64_SOURCE"; then
 122     AC_DEFINE([_LARGEFILE64_SOURCE], 1,
 123               [Enable LFS])
 124   fi
 125 fi
 126
 127 # Some systems have frexp only in -lm, not in -lc.
 128 AC_SEARCH_LIBS(frexp, m)
 129
 130 AC_MSG_CHECKING(for time_t in time.h)
 131 AC_CACHE_VAL(bu_cv_decl_time_t_time_h,
 132 [AC_TRY_COMPILE([#include <time.h>], [time_t i;],
 133 bu_cv_decl_time_t_time_h=yes, bu_cv_decl_time_t_time_h=no)])
 134 AC_MSG_RESULT($bu_cv_decl_time_t_time_h)
 135 if test $bu_cv_decl_time_t_time_h = yes; then
 136   AC_DEFINE([HAVE_TIME_T_IN_TIME_H], 1,
 137             [Is the type time_t defined in <time.h>?])
 138 fi
 139
 140 AC_MSG_CHECKING(for time_t in sys/types.h)
 141 AC_CACHE_VAL(bu_cv_decl_time_t_types_h,
 142 [AC_TRY_COMPILE([#include <sys/types.h>], [time_t i;],
 143 bu_cv_decl_time_t_types_h=yes, bu_cv_decl_time_t_types_h=no)])
 144 AC_MSG_RESULT($bu_cv_decl_time_t_types_h)
 145 if test $bu_cv_decl_time_t_types_h = yes; then
 146   AC_DEFINE([HAVE_TIME_T_IN_TYPES_H], 1,
 147             [Is the type time_t defined in <sys/types.h>?])
 148 fi
 149
 150 # Under Next 3.2 <utime.h> apparently does not define struct utimbuf
 151 # by default.
 152 AC_MSG_CHECKING([for utime.h])
 153 AC_CACHE_VAL(bu_cv_header_utime_h,
 154 [AC_TRY_COMPILE([#include <sys/types.h>
 155 #ifdef HAVE_TIME_H
 156 #include <time.h>
 157 #endif
 158 #include <utime.h>],
 159 [struct utimbuf s;],
 160 bu_cv_header_utime_h=yes, bu_cv_header_utime_h=no)])
 161 AC_MSG_RESULT($bu_cv_header_utime_h)
 162 if test $bu_cv_header_utime_h = yes; then
 163   AC_DEFINE(HAVE_GOOD_UTIME_H, 1, [Does <utime.h> define struct utimbuf?])
 164 fi
 165
 166 BFD_NEED_DECLARATION(fprintf)
 167 BFD_NEED_DECLARATION(strstr)
 168 BFD_NEED_DECLARATION(sbrk)
 169 BFD_NEED_DECLARATION(getenv)
 170 BFD_NEED_DECLARATION(environ)
 171
 172 BFD_BINARY_FOPEN
 173
 174 # target-specific stuff:
 175
 176 # Canonicalize the secondary target names.
 177 if test -n "$enable_targets"; then
 178     for targ in `echo $enable_targets | sed 's/,/ /g'`
 179     do
 180         result=`$ac_config_sub $targ 2>/dev/null`
 181         if test -n "$result"; then
 182             canon_targets="$canon_targets $result"
 183         else
 184             # Allow targets that config.sub doesn't recognize, like "all".
 185             canon_targets="$canon_targets $targ"
 186         fi
 187     done
 188 fi
 189
 190 all_targets=false
 191 BUILD_NLMCONV=
 192 NLMCONV_DEFS=
 193 BUILD_SRCONV=
 194 BUILD_DLLTOOL=
 195 DLLTOOL_DEFS=
 196 BUILD_WINDRES=
 197 BUILD_DLLWRAP=
 198 BUILD_MISC=
 199 OBJDUMP_DEFS=
 200
 201 for targ in $target $canon_targets
 202 do
 203     if test "x$targ" = "xall"; then
 204         all_targets=true
 205         BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 206         BUILD_SRCONV='$(SRCONV_PROG)'
 207         NLMCONV_DEFS="-DNLMCONV_I386 -DNLMCONV_ALPHA -DNLMCONV_POWERPC -DNLMCONV_SPARC"
 208     else
 209         case $targ in
 210 changequote(,)dnl
 211         i[3-7]86*-*-netware*)
 212 changequote([,])dnl
 213           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 214           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_I386"
 215           ;;
 216         alpha*-*-netware*)
 217           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 218           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_ALPHA"
 219           ;;
 220         powerpc*-*-netware*)
 221           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 222           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_POWERPC"
 223           ;;
 224         sparc*-*-netware*)
 225           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 226           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_SPARC"
 227           ;;
 228         esac
 229         case $targ in
 230         *-*-hms*) BUILD_SRCONV='$(SRCONV_PROG)' ;;
 231         esac
 232         case $targ in
 233         arm-epoc-pe*)
 234           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 235           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM_EPOC -DDLLTOOL_ARM"
 236           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 237           ;;
 238         arm-*-pe* | arm-*-wince)
 239           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 240           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM"
 241           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 242           ;;
 243         thumb-*-pe*)
 244           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 245           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM"
 246           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 247           ;;
 248         arm*-* | xscale-* | strongarm-* | d10v-*)
 249           OBJDUMP_DEFS="-DDISASSEMBLER_NEEDS_RELOCS"
 250           ;;
 251 changequote(,)dnl
 252         i[3-7]86-*-pe* | i[3-7]86-*-cygwin* | i[3-7]86-*-mingw32** | i[3-7]86-*-netbsdpe*)
 253 changequote([,])dnl
 254           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 255           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 256           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 257           BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 258           ;;
 259 changequote(,)dnl
 260         i[3-7]86-*-interix)
 261 changequote([,])dnl
 262           BUILD_DLLTOOL='$(DLLTOOL_PROG)'
 263           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 264           ;;
 265 changequote(,)dnl
 266         powerpc*-aix5.[01])
 267 changequote([,])dnl
 268           ;;
 269         powerpc*-aix5.*)
 270           OBJDUMP_DEFS="-DAIX_WEAK_SUPPORT"
 271           ;;
 272         powerpc*-*-pe* | powerpc*-*-cygwin*)
 273           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 274           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_PPC"
 275           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 276           ;;
 277         sh*-*-pe)
 278           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 279           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_SH"
 280           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 281           ;;
 282         mips*-*-pe)
 283           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 284           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MIPS"
 285           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 286           ;;
 287         mcore-*-pe)
 288           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 289           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MCORE"
 290           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 291           ;;
 292         mcore-*-elf)
 293           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 294           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MCORE_ELF"
 295           ;;
 296         c4x-*-* | tic4x-*-*)
 297           OBJDUMP_DEFS="$OBJDUMP_DEFS -DSKIP_ZEROES=32"
 298           ;;
 299         ia64-*-*)
 300           OBJDUMP_DEFS="$OBJDUMP_DEFS -DSKIP_ZEROES=16"
 301           ;;
 302         esac
 303     fi
 304 done
 305
 306 if test "${with_windres+set}" = set; then
 307           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 308 fi
 309
 310 AC_SUBST(NLMCONV_DEFS)
 311 AC_SUBST(BUILD_NLMCONV)
 312 AC_SUBST(BUILD_SRCONV)
 313 AC_SUBST(BUILD_DLLTOOL)
 314 AC_SUBST(DLLTOOL_DEFS)
 315 AC_SUBST(BUILD_WINDRES)
 316 AC_SUBST(BUILD_DLLWRAP)
 317 AC_SUBST(BUILD_MISC)
 318 AC_SUBST(OBJDUMP_DEFS)
 319
 320 AC_DEFINE_UNQUOTED(TARGET, "${target}", [Configured target name.])
 321
 322 targ=$target
 323 . $srcdir/../bfd/config.bfd
 324 if test "x$targ_underscore" = "xyes"; then
 325     UNDERSCORE=1
 326 else
 327     UNDERSCORE=0
 328 fi
 329 AC_DEFINE_UNQUOTED(TARGET_PREPENDS_UNDERSCORE, $UNDERSCORE,
 330  [Define to 1 if user symbol names have a leading underscore, 0 if not.])
 331
 332 # Emulation
 333 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 334 do
 335   # Canonicalize the secondary target names.
 336  result=`$ac_config_sub $targ_alias 2>/dev/null`
 337  if test -n "$result"; then
 338    targ=$result
 339  else
 340    targ=$targ_alias
 341  fi
 342
 343  . ${srcdir}/configure.tgt
 344
 345   EMULATION=$targ_emul
 346   EMULATION_VECTOR=$targ_emul_vector
 347 done
 348
 349 AC_SUBST(EMULATION)
 350 AC_SUBST(EMULATION_VECTOR)
 351
 352 AC_OUTPUT(Makefile doc/Makefile po/Makefile.in:po/Make-in,
 353 [
 354 case "x$CONFIG_FILES" in
 355 *) sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile ;;
 356 esac
 357 ])