ld/configure.in

   1 dnl Process this file with autoconf to produce a configure script
   2 dnl
   3 AC_PREREQ(2.57)
   4 AC_INIT(ldmain.c)
   5
   6 AC_CANONICAL_SYSTEM
   7 AC_ISC_POSIX
   8
   9 changequote(,)dnl
  10 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  11 changequote([,])dnl
  12 AM_INIT_AUTOMAKE(ld, ${BFD_VERSION})
  13
  14 AC_ARG_WITH(lib-path, [  --with-lib-path=dir1:dir2...  set default LIB_PATH],LIB_PATH=$withval)
  15 AC_ARG_ENABLE(targets,
  16 [  --enable-targets        alternative target configurations],
  17 [case "${enableval}" in
  18   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  19             ;;
  20   no)       enable_targets= ;;
  21   *)        enable_targets=$enableval ;;
  22 esac])dnl
  23 AC_ARG_ENABLE(64-bit-bfd,
  24 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  25 [case "${enableval}" in
  26   yes)  want64=true  ;;
  27   no)   want64=false ;;
  28   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  29 esac],[want64=false])dnl
  30
  31 AC_ARG_WITH(sysroot,
  32 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
  33 [
  34  case ${with_sysroot} in
  35  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
  36  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
  37  esac
  38
  39  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
  40  use_sysroot=yes
  41
  42  if test "x$prefix" = xNONE; then
  43   test_prefix=/usr/local
  44  else
  45   test_prefix=$prefix
  46  fi
  47  if test "x$exec_prefix" = xNONE; then
  48   test_exec_prefix=$test_prefix
  49  else
  50   test_exec_prefix=$exec_prefix
  51  fi
  52  case ${TARGET_SYSTEM_ROOT} in
  53  "${test_prefix}"|"${test_prefix}/"*|\
  54  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
  55  '${prefix}'|'${prefix}/'*|\
  56  '${exec_prefix}'|'${exec_prefix}/'*)
  57    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
  58    TARGET_SYSTEM_ROOT_DEFINE="$t"
  59    ;;
  60  esac
  61 ], [
  62  use_sysroot=no
  63  TARGET_SYSTEM_ROOT=
  64  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
  65 ])
  66 AC_SUBST(use_sysroot)
  67 AC_SUBST(TARGET_SYSTEM_ROOT)
  68 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
  69
  70 AC_ARG_ENABLE([got],
  71 AS_HELP_STRING([--enable-got=<type>],
  72                [GOT handling scheme (target, single, negative, multigot)]),
  73 [case "${enableval}" in
  74   target | single | negative | multigot)  got_handling=$enableval ;;
  75   *)  AC_ERROR(bad value ${enableval} for --enable-got option) ;;
  76 esac],
  77 [got_handling=target])
  78
  79 case "${got_handling}" in
  80   target)
  81     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_TARGET_DEFAULT],
  82               [Define to choose default GOT handling scheme]) ;;
  83   single)
  84     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_SINGLE],
  85               [Define to choose default GOT handling scheme]) ;;
  86   negative)
  87     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_NEGATIVE],
  88               [Define to choose default GOT handling scheme]) ;;
  89   multigot)
  90     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_MULTIGOT],
  91               [Define to choose default GOT handling scheme]) ;;
  92   *)  AC_ERROR(bad value ${got_handling} for --enable-got option) ;;
  93 esac
  94
  95 AM_BINUTILS_WARNINGS
  96
  97 AM_CONFIG_HEADER(config.h:config.in)
  98
  99 if test -z "$target" ; then
 100     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
 101 fi
 102 if test -z "$host" ; then
 103     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
 104 fi
 105
 106 # host-specific stuff:
 107
 108 AC_PROG_CC
 109 AC_GNU_SOURCE
 110 AC_PROG_INSTALL
 111
 112 AM_PROG_LIBTOOL
 113
 114 ALL_LINGUAS="fr sv tr es da vi zh_CN zh_TW ga fi"
 115 ZW_GNU_GETTEXT_SISTER_DIR
 116 AM_PO_SUBDIRS
 117
 118 AC_EXEEXT
 119
 120 AC_PROG_YACC
 121 AM_PROG_LEX
 122
 123 AM_MAINTAINER_MODE
 124 AM_CONDITIONAL(GENINSRC_NEVER, false)
 125
 126 . ${srcdir}/configure.host
 127
 128 AC_SUBST(HDEFINES)
 129 AC_SUBST(HOSTING_CRT0)
 130 AC_SUBST(HOSTING_LIBS)
 131 AC_SUBST(NATIVE_LIB_DIRS)
 132
 133 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h elf-hints.h limits.h sys/param.h)
 134 AC_CHECK_FUNCS(glob mkstemp realpath sbrk waitpid)
 135 AC_HEADER_DIRENT
 136
 137 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 138 AC_CACHE_VAL(ld_cv_decl_getopt_unistd_h,
 139 [AC_TRY_COMPILE([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);],
 140 ld_cv_decl_getopt_unistd_h=yes, ld_cv_decl_getopt_unistd_h=no)])
 141 AC_MSG_RESULT($ld_cv_decl_getopt_unistd_h)
 142 if test $ld_cv_decl_getopt_unistd_h = yes; then
 143   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 144             [Is the prototype for getopt in <unistd.h> in the expected format?])
 145 fi
 146
 147 BFD_BINARY_FOPEN
 148
 149 AC_CHECK_DECLS([strstr, free, sbrk, getenv, environ])
 150
 151 # Link in zlib if we can.  This is needed only for the bootstrap tests
 152 # right now, since those tests use libbfd, which depends on zlib.
 153 AC_SEARCH_LIBS(zlibVersion, z, [AC_CHECK_HEADERS(zlib.h)])
 154
 155 # When converting linker scripts into strings for use in emulation
 156 # files, use astring.sed if the compiler supports ANSI string
 157 # concatenation, or ostring.sed otherwise.  This is to support the
 158 # broken Microsoft MSVC compiler, which limits the length of string
 159 # constants, while still supporting pre-ANSI compilers which do not
 160 # support string concatenation.
 161 AC_MSG_CHECKING([whether ANSI C string concatenation works])
 162 AC_CACHE_VAL(ld_cv_string_concatenation,
 163 [AC_TRY_COMPILE(,[char *a = "a" "a";],
 164   [ld_cv_string_concatenation=yes],
 165   [ld_cv_string_concatenation=no])])
 166 AC_MSG_RESULT($ld_cv_string_concatenation)
 167 if test "$ld_cv_string_concatenation" = "yes"; then
 168   STRINGIFY=astring.sed
 169 else
 170   STRINGIFY=ostring.sed
 171 fi
 172 AC_SUBST(STRINGIFY)
 173
 174 # target-specific stuff:
 175
 176 all_targets=
 177 EMUL=
 178 all_emuls=
 179 all_emul_extras=
 180 all_libpath=
 181
 182 dnl We need to get an arbitrary number of tdir definitions into
 183 dnl Makefile.  We can't do it using AC_SUBST, because autoconf does
 184 dnl not permit literal newlines in an AC_SUBST variables.  So we use a
 185 dnl file.
 186 rm -f tdirs
 187
 188 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 189 do
 190   if test "$targ_alias" = "all"; then
 191     all_targets=true
 192   else
 193     # Canonicalize the secondary target names.
 194     result=`$ac_config_sub $targ_alias 2>/dev/null`
 195     if test -n "$result"; then
 196         targ=$result
 197     else
 198         targ=$targ_alias
 199     fi
 200
 201     . ${srcdir}/configure.tgt
 202
 203     if test "$targ" = "$target"; then
 204       EMUL=$targ_emul
 205     fi
 206
 207     if test x${want64} = xfalse; then
 208       . ${srcdir}/../bfd/config.bfd
 209     fi
 210
 211     if test x${want64} = xtrue; then
 212       targ_extra_emuls="$targ_extra_emuls $targ64_extra_emuls"
 213       targ_extra_libpath="$targ_extra_libpath $targ64_extra_libpath"
 214     fi
 215
 216     for i in $targ_emul $targ_extra_emuls $targ_extra_libpath; do
 217         case " $all_emuls " in
 218         *" e${i}.o "*) ;;
 219         *)
 220           all_emuls="$all_emuls e${i}.o"
 221           eval result=\$tdir_$i
 222           test -z "$result" && result=$targ_alias
 223           echo tdir_$i=$result >> tdirs
 224           ;;
 225         esac
 226     done
 227
 228     for i in $targ_emul $targ_extra_libpath; do
 229         case " $all_libpath " in
 230         *" ${i} "*) ;;
 231         *)
 232           if test -z "$all_libpath"; then
 233             all_libpath=${i}
 234           else
 235             all_libpath="$all_libpath ${i}"
 236           fi
 237           ;;
 238         esac
 239     done
 240
 241     for i in $targ_extra_ofiles; do
 242         case " $all_emul_extras " in
 243         *" ${i} "*) ;;
 244         *)
 245           all_emul_extras="$all_emul_extras ${i}"
 246           ;;
 247         esac
 248     done
 249   fi
 250 done
 251
 252 AC_SUBST(EMUL)
 253
 254 TDIRS=tdirs
 255 AC_SUBST_FILE(TDIRS)
 256
 257 if test x${all_targets} = xtrue; then
 258   if test x${want64} = xfalse; then
 259     AC_CHECK_SIZEOF(long)
 260     if test "x${ac_cv_sizeof_long}" = "x8"; then
 261       want64=true
 262     fi
 263   fi
 264   if test x${want64} = xtrue; then
 265     EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)'
 266   else
 267     EMULATION_OFILES='$(ALL_EMULATIONS)'
 268   fi
 269   EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)'
 270 else
 271   EMULATION_OFILES=$all_emuls
 272   EMUL_EXTRA_OFILES=$all_emul_extras
 273 fi
 274 AC_SUBST(EMULATION_OFILES)
 275 AC_SUBST(EMUL_EXTRA_OFILES)
 276 AC_SUBST(LIB_PATH)
 277
 278 EMULATION_LIBPATH=$all_libpath
 279 AC_SUBST(EMULATION_LIBPATH)
 280
 281 if test x${enable_static} = xno; then
 282   TESTBFDLIB="--rpath ../bfd/.libs ../bfd/.libs/libbfd.so"
 283 else
 284   TESTBFDLIB="../bfd/.libs/libbfd.a"
 285 fi
 286 AC_SUBST(TESTBFDLIB)
 287
 288 target_vendor=${target_vendor=$host_vendor}
 289 case "$target_vendor" in
 290   hp) EXTRA_SHLIB_EXTENSION=".sl" ;;
 291   *)  EXTRA_SHLIB_EXTENSION= ;;
 292 esac
 293
 294 case "$target_os" in
 295   lynxos) EXTRA_SHLIB_EXTENSION=".a" ;;
 296 esac
 297
 298 if test x${EXTRA_SHLIB_EXTENSION} != x ; then
 299   AC_DEFINE_UNQUOTED(EXTRA_SHLIB_EXTENSION, "$EXTRA_SHLIB_EXTENSION",
 300    [Additional extension a shared object might have.])
 301 fi
 302
 303 dnl Required by html and install-html
 304 AC_SUBST(datarootdir)
 305 AC_SUBST(docdir)
 306 AC_SUBST(htmldir)
 307
 308 AC_OUTPUT(Makefile po/Makefile.in:po/Make-in)