gold/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.59)
   4
   5 AC_INIT(gold, 0.1)
   6 AC_CONFIG_SRCDIR(gold.cc)
   7
   8 AC_CANONICAL_TARGET
   9
  10 AM_INIT_AUTOMAKE
  11
  12 AM_CONFIG_HEADER(config.h:config.in)
  13
  14 AC_ARG_WITH(sysroot,
  15 [  --with-sysroot[=DIR]    search for usr/lib et al within DIR],
  16 [sysroot=$withval], [sysroot=no])
  17
  18 if test "$sysroot" = "yes"; then
  19   sysroot='${exec_prefix}/${target_alias}/sys-root'
  20 elif test "$sysroot" = "no"; then
  21   sysroot=
  22 fi
  23
  24 sysroot_relocatable=0
  25 if test -n "$sysroot"; then
  26   case "sysroot" in
  27     "${prefix}" | "${prefix}/"* | \
  28     "${exec_prefix}" | "${exec_prefix}/"* | \
  29     '${prefix}' | '${prefix}/'*| \
  30     '${exec_prefix}' | '${exec_prefix}/'*)
  31       sysroot_relocatable=1
  32       ;;
  33   esac
  34 fi
  35
  36 AC_DEFINE_UNQUOTED(TARGET_SYSTEM_ROOT, "$sysroot",
  37   [System root for target files])
  38 AC_DEFINE_UNQUOTED(TARGET_SYSTEM_ROOT_RELOCATABLE, $sysroot_relocatable,
  39   [Whether the system root can be relocated])
  40
  41 dnl For now threads are a configure time option.
  42 AC_ARG_ENABLE([threads],
  43 [  --enable-threads        multi-threaded linking],
  44 [case "${enableval}" in
  45   yes | "") threads=yes ;;
  46   no) threads=no ;;
  47   *) threads=yes ;;
  48  esac],
  49 [threads=no])
  50 if test "$threads" = "yes"; then
  51   AC_DEFINE(ENABLE_THREADS, 1,
  52             [Define to do multi-threaded linking])
  53 fi
  54 AM_CONDITIONAL(THREADS, test "$threads" = "yes")
  55
  56 AC_ARG_ENABLE([targets],
  57 [  --enable-targets        alternative target configurations],
  58 [case "${enableval}" in
  59   yes | "")
  60     AC_MSG_ERROR([--enable-targets option must specify target names or 'all'])
  61     ;;
  62   no)
  63     enable_targets=
  64     ;;
  65   *)
  66     enable_targets=$enableval
  67     ;;
  68 esac],
  69 [# For now, enable all targets by default
  70  enable_targets=all
  71 ])
  72
  73 # Canonicalize the enabled targets.
  74 if test -n "$enable_targets"; then
  75   for targ in `echo $enable_targets | sed -e 's/,/ /g'`; do
  76     result=`$ac_config_sub $targ 2>/dev/null`
  77     if test -n "$result"; then
  78       canon_targets="$canon_targets $result"
  79     else
  80       # Permit unrecognized target names, like "all".
  81       canon_targets="$canon_targets $targ"
  82     fi
  83   done
  84 fi
  85
  86 # See which specific instantiations we need.
  87 targetobjs=
  88 all_targets=
  89 for targ in $target $canon_targets; do
  90   targ_32_little=
  91   targ_32_big=
  92   targ_64_little=
  93   targ_64_big=
  94   if test "$targ" = "all"; then
  95     targ_32_little=yes
  96     targ_32_big=yes
  97     targ_64_little=yes
  98     targ_64_big=yes
  99     all_targets=yes
 100   else
 101     case "$targ" in
 102     i?86-*)
 103       targ_32_little=yes
 104       targetobjs="$targetobjs i386.\$(OBJEXT)"
 105       ;;
 106     x86_64-*)
 107       targ_64_little=yes
 108       targetobjs="$targetobjs x86_64.\$(OBJEXT)"
 109       ;;
 110     *)
 111       AC_MSG_ERROR("unsupported target $targ")
 112       ;;
 113     esac
 114   fi
 115 done
 116
 117 if test -n "$targ_32_little"; then
 118   AC_DEFINE(HAVE_TARGET_32_LITTLE, 1,
 119               [Define to support 32-bit little-endian targets])
 120 fi
 121 if test -n "$targ_32_big"; then
 122   AC_DEFINE(HAVE_TARGET_32_BIG, 1,
 123               [Define to support 32-bit big-endian targets])
 124 fi
 125 if test -n "$targ_64_little"; then
 126   AC_DEFINE(HAVE_TARGET_64_LITTLE, 1,
 127               [Define to support 64-bit little-endian targets])
 128 fi
 129 if test -n "$targ_64_big"; then
 130   AC_DEFINE(HAVE_TARGET_64_BIG, 1,
 131               [Define to support 64-bit big-endian targets])
 132 fi
 133
 134 if test -n "$all_targets"; then
 135   TARGETOBJS='$(ALL_TARGETOBJS)'
 136 else
 137   TARGETOBJS="$targetobjs"
 138 fi
 139 AC_SUBST(TARGETOBJS)
 140
 141 AC_PROG_CC
 142 AC_PROG_CXX
 143 AC_PROG_YACC
 144 AC_PROG_RANLIB
 145 AC_PROG_INSTALL
 146 AC_PROG_LN_S
 147 ZW_GNU_GETTEXT_SISTER_DIR
 148 AM_PO_SUBDIRS
 149
 150 AC_C_BIGENDIAN
 151
 152 AC_EXEEXT
 153
 154 AM_CONDITIONAL(NATIVE_LINKER,
 155   test "x$target_alias" = "x" -o "x$host_alias" = "x$target_alias")
 156 AM_CONDITIONAL(GCC, test "$GCC" = yes)
 157
 158 dnl Some architectures do not support taking pointers of functions
 159 dnl defined in shared libraries except in -fPIC mode.  We need to
 160 dnl tell the unittest framework if we're compiling for one of those
 161 dnl targets, so it doesn't try to run the tests that do that.
 162 AM_CONDITIONAL(FN_PTRS_IN_SO_WITHOUT_PIC, [
 163   case $target_cpu in
 164     i?86) true;;
 165     x86_64) false;;
 166     *) true;;
 167   esac])
 168
 169 dnl Test for __thread support.
 170 AC_CACHE_CHECK([for thread support], [gold_cv_c_thread],
 171 [AC_COMPILE_IFELSE([__thread int i = 1;],
 172 [gold_cv_c_thread=yes], [gold_cv_c_thread=no])])
 173
 174 AM_CONDITIONAL(TLS, test "$gold_cv_c_thread" = "yes")
 175
 176 dnl On GNU/Linux TLS in static programs only works when using glibc
 177 dnl 2.4 or later.
 178 AC_CACHE_CHECK([for glibc >= 2.4], [gold_cv_lib_glibc24],
 179 [AC_COMPILE_IFELSE([
 180 #include <features.h>
 181 #if !defined __GLIBC__
 182 error
 183 #elif __GLIBC__ < 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ < 4)
 184 error
 185 #endif
 186 ], [gold_cv_lib_glibc24=yes], [gold_cv_lib_glibc24=no])])
 187
 188 AM_CONDITIONAL(STATIC_TLS, test "$gold_cv_lib_glibc24" = "yes")
 189
 190 AM_BINUTILS_WARNINGS
 191
 192 WARN_CXXFLAGS=`echo ${WARN_CFLAGS} | sed -e 's/-Wstrict-prototypes//' -e 's/-Wmissing-prototypes//'`
 193 AC_SUBST(WARN_CXXFLAGS)
 194
 195 dnl Force support for large files by default.  This may need to be
 196 dnl host dependent.  If build == host, we can check getconf LFS_CFLAGS.
 197 LFS_CXXFLAGS="-D_LARGEFILE_SOURCE -D_FILE_OFFSET_BITS=64"
 198 AC_SUBST(LFS_CXXFLAGS)
 199
 200 AC_REPLACE_FUNCS(pread)
 201
 202 AC_LANG_PUSH(C++)
 203
 204 AC_CHECK_HEADERS(tr1/unordered_set tr1/unordered_map)
 205 AC_CHECK_HEADERS(ext/hash_map ext/hash_set)
 206 AC_CHECK_FUNCS(mallinfo)
 207
 208 dnl Test whether the compiler can specify a member templates to call.
 209 AC_CACHE_CHECK([template member calls], [gold_cv_c_membertemplates],
 210 [AC_COMPILE_IFELSE([
 211 class c { public: template<int i> void fn(); };
 212 template<int i> void foo(c cv) { cv.fn<i>(); }
 213 template void foo<1>(c cv);],
 214 [gold_cv_c_membertemplates=yes], [gold_cv_c_membertemplates=no])])
 215
 216 if test "$gold_cv_c_membertemplates" = "yes"; then
 217   AC_DEFINE(HAVE_MEMBER_TEMPLATE_SPECIFICATIONS, [],
 218     [Whether the C++ compiler can call a template member with no arguments])
 219 fi
 220
 221 AC_LANG_POP(C++)
 222
 223 AM_MAINTAINER_MODE
 224
 225 AC_OUTPUT(Makefile testsuite/Makefile po/Makefile.in:po/Make-in)