libiberty/configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 AC_PREREQ(2.64)
   4 AC_INIT
   5 AC_CONFIG_SRCDIR([xmalloc.c])
   6
   7 # This works around the fact that libtool configuration may change LD
   8 # for this particular configuration, but some shells, instead of
   9 # keeping the changes in LD private, export them just because LD is
  10 # exported.  We don't use libtool yet, but some day we might, so...
  11 ORIGINAL_LD_FOR_MULTILIBS=$LD
  12
  13 dnl We use these options to decide which functions to include.
  14 AC_ARG_WITH(target-subdir,
  15 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  16 AC_ARG_WITH(build-subdir,
  17 [  --with-build-subdir=SUBDIR       Configuring in a subdirectory for build])
  18 AC_ARG_WITH(cross-host,
  19 [  --with-cross-host=HOST           Configuring with a cross compiler])
  20 AC_ARG_WITH(newlib,
  21 [  --with-newlib                    Configuring with newlib])
  22
  23 if test "${srcdir}" = "."; then
  24   if test -n "${with_build_subdir}"; then
  25     libiberty_topdir="${srcdir}/../.."
  26     with_target_subdir=
  27   elif test -z "${with_target_subdir}"; then
  28     libiberty_topdir="${srcdir}/.."
  29   else
  30     if test "${with_target_subdir}" != "."; then
  31       libiberty_topdir="${srcdir}/${with_multisrctop}../.."
  32     else
  33       libiberty_topdir="${srcdir}/${with_multisrctop}.."
  34     fi
  35   fi
  36 else
  37   libiberty_topdir="${srcdir}/.."
  38 fi
  39 AC_SUBST(libiberty_topdir)
  40 AC_CONFIG_AUX_DIR($libiberty_topdir)
  41
  42 dnl Very limited version of automake's enable-maintainer-mode
  43
  44 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
  45   dnl maintainer-mode is disabled by default
  46   AC_ARG_ENABLE(maintainer-mode,
  47 [  --enable-maintainer-mode
  48                           enable make rules and dependencies not useful
  49                           (and sometimes confusing) to the casual installer],
  50       maintainer_mode=$enableval,
  51       maintainer_mode=no)
  52
  53 AC_MSG_RESULT($maintainer_mode)
  54
  55 if test "$maintainer_mode" = "yes"; then
  56   MAINT=''
  57   NOTMAINT='#'
  58 else
  59   MAINT='#'
  60   NOTMAINT=''
  61 fi
  62 AC_SUBST(MAINT)dnl
  63 AC_SUBST(NOTMAINT)dnl
  64
  65 # Do we have a single-tree copy of texinfo?  Even if we do, we can't
  66 # rely on it - libiberty is built before texinfo.
  67 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
  68 if test "x$MAKEINFO" = "x"; then
  69     MAKEINFO="@echo makeinfo missing; true"
  70     BUILD_INFO=
  71 else
  72     BUILD_INFO=info
  73     case "$MAKEINFO" in
  74       */missing\ makeinfo*)
  75         BUILD_INFO=
  76         AC_MSG_WARN([
  77 *** Makeinfo is missing. Info documentation will not be built.])
  78         ;;
  79       *)
  80         case x"`$MAKEINFO --version | grep 'GNU texinfo'`" in
  81           x*\ [[1-3]].* )
  82             MAKEINFO="@echo $MAKEINFO is too old, 4.0 or newer required; true"
  83             BUILD_INFO=
  84             AC_MSG_WARN([
  85 *** Makeinfo is too old. Info documentation will not be built.])
  86           ;;
  87         esac
  88         ;;
  89     esac
  90 fi
  91 AC_SUBST(MAKEINFO)
  92 AC_SUBST(BUILD_INFO)
  93
  94 AC_CHECK_PROG(PERL, perl, perl, )
  95 if test x"$PERL" = x""; then
  96   HAVE_PERL='#'
  97 else
  98   HAVE_PERL=''
  99 fi
 100 AC_SUBST(HAVE_PERL)
 101
 102 AC_CANONICAL_HOST
 103
 104 dnl When we start using automake:
 105 dnl AM_INIT_AUTOMAKE(libiberty, 1.0)
 106
 107 dnl These must be called before AM_PROG_LIBTOOL, because it may want
 108 dnl to call AC_CHECK_PROG.
 109 AC_CHECK_TOOL(AR, ar)
 110 AC_CHECK_TOOL(RANLIB, ranlib, :)
 111
 112 dnl When switching to automake, replace the following with AM_ENABLE_MULTILIB.
 113 # Add --enable-multilib to configure.
 114 # Default to --enable-multilib
 115 AC_ARG_ENABLE(multilib,
 116 [  --enable-multilib       build many library versions (default)],
 117 [case "$enableval" in
 118   yes) multilib=yes ;;
 119   no)  multilib=no ;;
 120   *)   AC_MSG_ERROR([bad value $enableval for multilib option]) ;;
 121  esac],
 122               [multilib=yes])
 123
 124 # Even if the default multilib is not a cross compilation,
 125 # it may be that some of the other multilibs are.
 126 if test $cross_compiling = no && test $multilib = yes \
 127    && test "x${with_multisubdir}" != x ; then
 128    cross_compiling=maybe
 129 fi
 130
 131 GCC_NO_EXECUTABLES
 132 AC_PROG_CC
 133 AC_SYS_LARGEFILE
 134 AC_PROG_CPP_WERROR
 135
 136 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wwrite-strings -Wc++-compat \
 137                           -Wstrict-prototypes], [ac_libiberty_warn_cflags])
 138 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC([], [ac_libiberty_warn_cflags])
 139
 140 AC_PROG_CC_C_O
 141 # autoconf is lame and doesn't give us any substitution variable for this.
 142 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 143   NO_MINUS_C_MINUS_O=yes
 144 else
 145   OUTPUT_OPTION='-o $@'
 146 fi
 147 AC_SUBST(NO_MINUS_C_MINUS_O)
 148 AC_SUBST(OUTPUT_OPTION)
 149
 150 AC_C_CONST
 151 AC_C_INLINE
 152 AC_C_BIGENDIAN
 153
 154 dnl When we start using libtool:
 155 dnl Default to a non shared library.  This may be overridden by the
 156 dnl configure option --enable-shared.
 157 dnl AM_DISABLE_SHARED
 158
 159 dnl When we start using libtool:
 160 dnl AM_PROG_LIBTOOL
 161
 162 dnl When we start using automake:
 163 dnl AM_CONFIG_HEADER(config.h:config.in)
 164 AC_CONFIG_HEADER(config.h:config.in)
 165
 166 dnl When we start using automake:
 167 dnl AM_MAINTAINER_MODE
 168 dnl AC_EXEEXT
 169
 170 dnl When we start using automake:
 171 dnl AM_PROG_INSTALL
 172 AC_PROG_INSTALL
 173
 174 # Don't build the shared library for build.
 175 if [[ -n "${with_build_subdir}" ]]; then
 176   enable_shared=no
 177 fi
 178
 179 frag=
 180 case "${host}" in
 181   rs6000-ibm-aix3.1 | rs6000-ibm-aix)
 182                         frag=mh-aix ;;
 183   *-*-cxux7*)           frag=mh-cxux7 ;;
 184   *-*-freebsd2.1.*)     frag=mh-fbsd21 ;;
 185   *-*-freebsd2.2.[[012]])       frag=mh-fbsd21 ;;
 186   i370-*-opened*)       frag=mh-openedition ;;
 187   i[[34567]]86-*-windows*)      frag=mh-windows ;;
 188 esac
 189
 190 if [[ -n "${frag}" ]]; then
 191   frag=${libiberty_topdir}/libiberty/config/$frag
 192 fi
 193
 194 # If they didn't specify --enable-shared, don't generate shared libs.
 195 case "${enable_shared}" in
 196   yes) shared=yes ;;
 197   no) shared=no ;;
 198   "") shared=no ;;
 199   *) shared=yes ;;
 200 esac
 201 if [[ "${shared}" = "yes" ]]; then
 202   case "${host}" in
 203     *-*-cygwin*)        ;;
 204     alpha*-*-linux*)    PICFLAG=-fPIC ;;
 205     arm*-*-*)           PICFLAG=-fPIC ;;
 206     hppa*-*-*)          PICFLAG=-fPIC ;;
 207     i370-*-*)           PICFLAG=-fPIC ;;
 208     ia64-*-*)           PICFLAG=-fpic ;;
 209     i[[34567]]86-*-* | x86_64-*-*)
 210                         PICFLAG=-fpic ;;
 211     m68k-*-*)           PICFLAG=-fpic ;;
 212     mips*-*-linux*)     PICFLAG=-fPIC ;;
 213     powerpc*-*-aix*)    ;;
 214     powerpc*-*-*)       PICFLAG=-fPIC ;;
 215     sparc*-*-*)         case "${CFLAGS}" in
 216                           *-fpic* ) PICFLAG=-fpic ;;
 217                           * ) PICFLAG=-fPIC ;;
 218                         esac ;;
 219     s390*-*-*)          PICFLAG=-fpic ;;
 220     sh*-*-*)            PICFLAG=-fPIC ;;
 221   esac
 222 fi
 223 AC_SUBST(PICFLAG)
 224
 225 echo "# Warning: this fragment is automatically generated" > temp-frag
 226
 227 if [[ -n "${frag}" ]] && [[ -f "${frag}" ]]; then
 228   echo "Appending ${frag} to xhost-mkfrag"
 229   echo "# Following fragment copied from ${frag}" >> temp-frag
 230   cat ${frag} >> temp-frag
 231 fi
 232
 233 # record if we want to build shared libs.
 234 if [[ "${shared}" = "yes" ]]; then
 235   echo enable_shared = yes >> temp-frag
 236 else
 237   echo enable_shared = no >> temp-frag
 238 fi
 239
 240 frag=xhost-mkfrag
 241 ${CONFIG_SHELL-/bin/sh} ${libiberty_topdir}/move-if-change temp-frag xhost-mkfrag
 242
 243 host_makefile_frag=${frag}
 244 AC_SUBST_FILE(host_makefile_frag)
 245
 246 # It's OK to check for header files.  Although the compiler may not be
 247 # able to link anything, it had better be able to at least compile
 248 # something.
 249 AC_CHECK_HEADERS(sys/file.h sys/param.h limits.h stdlib.h malloc.h string.h unistd.h strings.h sys/time.h time.h sys/resource.h sys/stat.h sys/mman.h fcntl.h alloca.h sys/pstat.h sys/sysmp.h sys/sysinfo.h machine/hal_sysinfo.h sys/table.h sys/sysctl.h sys/systemcfg.h stdint.h stdio_ext.h)
 250 AC_HEADER_SYS_WAIT
 251 AC_HEADER_TIME
 252
 253 libiberty_AC_DECLARE_ERRNO
 254
 255 # Determine the size of an int for struct fibnode.
 256 AC_CHECK_SIZEOF([int])
 257
 258 # Look for a 64-bit type.
 259 AC_MSG_CHECKING([for a 64-bit type])
 260 AC_CACHE_VAL(liberty_cv_uint64,
 261 [AC_TRY_COMPILE(
 262 [#ifdef HAVE_STDINT_H
 263 #include <stdint.h>
 264 #endif],
 265 [extern uint64_t foo;],
 266 liberty_cv_uint64=uint64_t,
 267 [AC_TRY_COMPILE(
 268 [#ifdef HAVE_LIMITS_H
 269 #include <limits.h>
 270 #endif
 271 #ifndef CHAR_BIT
 272 #define CHAR_BIT 8
 273 #endif],
 274 [extern char foo[sizeof(long) * CHAR_BIT >= 64 ? 1 : -1];],
 275 liberty_cv_uint64="unsigned long",
 276 [AC_TRY_COMPILE(
 277 [#ifdef HAVE_LIMITS_H
 278 #include <limits.h>
 279 #endif
 280 #ifndef CHAR_BIT
 281 #define CHAR_BIT 8
 282 #endif],
 283 [extern char foo[sizeof(long long) * CHAR_BIT >= 64 ? 1 : -1];],
 284 liberty_cv_uint64="unsigned long long", liberty_cv_uint64=none)])])])
 285 AC_MSG_RESULT($liberty_cv_uint64)
 286 if test "$liberty_cv_uint64" != none; then
 287   AC_DEFINE_UNQUOTED(UNSIGNED_64BIT_TYPE, $liberty_cv_uint64,
 288                      [Define to an unsigned 64-bit type available in the compiler.])
 289 fi
 290
 291 AC_TYPE_INTPTR_T
 292 AC_TYPE_UINTPTR_T
 293
 294 # Given the above check, we always have uintptr_t or a fallback
 295 # definition.  So define HAVE_UINTPTR_T in case any imported code
 296 # relies on it.
 297 AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if you have the \`uintptr_t' type.])
 298
 299 AC_TYPE_PID_T
 300
 301 # This is the list of functions which libiberty will provide if they
 302 # are not available on the host.
 303
 304 funcs="asprintf"
 305 funcs="$funcs atexit"
 306 funcs="$funcs basename"
 307 funcs="$funcs bcmp"
 308 funcs="$funcs bcopy"
 309 funcs="$funcs bsearch"
 310 funcs="$funcs bzero"
 311 funcs="$funcs calloc"
 312 funcs="$funcs clock"
 313 funcs="$funcs ffs"
 314 funcs="$funcs getcwd"
 315 funcs="$funcs getpagesize"
 316 funcs="$funcs gettimeofday"
 317 funcs="$funcs index"
 318 funcs="$funcs insque"
 319 funcs="$funcs memchr"
 320 funcs="$funcs memcmp"
 321 funcs="$funcs memcpy"
 322 funcs="$funcs memmem"
 323 funcs="$funcs memmove"
 324 funcs="$funcs mempcpy"
 325 funcs="$funcs memset"
 326 funcs="$funcs mkstemps"
 327 funcs="$funcs putenv"
 328 funcs="$funcs random"
 329 funcs="$funcs rename"
 330 funcs="$funcs rindex"
 331 funcs="$funcs setenv"
 332 funcs="$funcs snprintf"
 333 funcs="$funcs sigsetmask"
 334 funcs="$funcs stpcpy"
 335 funcs="$funcs stpncpy"
 336 funcs="$funcs strcasecmp"
 337 funcs="$funcs strchr"
 338 funcs="$funcs strdup"
 339 funcs="$funcs strncasecmp"
 340 funcs="$funcs strndup"
 341 funcs="$funcs strrchr"
 342 funcs="$funcs strstr"
 343 funcs="$funcs strtod"
 344 funcs="$funcs strtol"
 345 funcs="$funcs strtoul"
 346 funcs="$funcs strverscmp"
 347 funcs="$funcs tmpnam"
 348 funcs="$funcs vasprintf"
 349 funcs="$funcs vfprintf"
 350 funcs="$funcs vprintf"
 351 funcs="$funcs vsnprintf"
 352 funcs="$funcs vsprintf"
 353 funcs="$funcs waitpid"
 354
 355 # Also in the old function.def file: alloca, vfork, getopt.
 356
 357 vars="sys_errlist sys_nerr sys_siglist"
 358
 359 checkfuncs="getrusage on_exit psignal strerror strsignal sysconf times sbrk gettimeofday"
 360 checkfuncs="$checkfuncs realpath canonicalize_file_name pstat_getstatic pstat_getdynamic sysmp"
 361 checkfuncs="$checkfuncs getsysinfo table sysctl wait3 wait4 __fsetlocking"
 362
 363 # These are neither executed nor required, but they help keep
 364 # autoheader happy without adding a bunch of text to acconfig.h.
 365 if test "x" = "y"; then
 366   AC_CHECK_FUNCS(asprintf atexit \
 367     basename bcmp bcopy bsearch bzero \
 368     calloc canonicalize_file_name clock \
 369     ffs __fsetlocking \
 370     getcwd getpagesize getrusage getsysinfo gettimeofday \
 371     index insque \
 372     memchr memcmp memcpy memmem memmove memset mkstemps \
 373     on_exit \
 374     psignal pstat_getdynamic pstat_getstatic putenv \
 375     random realpath rename rindex \
 376     sbrk setenv sigsetmask snprintf stpcpy stpncpy strcasecmp strchr strdup \
 377      strerror strncasecmp strndup strrchr strsignal strstr strtod strtol \
 378      strtoul strverscmp sysconf sysctl sysmp \
 379     table times tmpnam \
 380     vasprintf vfprintf vprintf vsprintf \
 381     wait3 wait4 waitpid)
 382   AC_CHECK_DECLS([basename(char *), ffs, asprintf, vasprintf, snprintf, vsnprintf])
 383   AC_DEFINE(HAVE_SYS_ERRLIST, 1, [Define if you have the sys_errlist variable.])
 384   AC_DEFINE(HAVE_SYS_NERR,    1, [Define if you have the sys_nerr variable.])
 385   AC_DEFINE(HAVE_SYS_SIGLIST, 1, [Define if you have the sys_siglist variable.])
 386 fi
 387
 388 # For each of these functions, if the host does not provide the
 389 # function we want to put FN.o in LIBOBJS, and if the host does
 390 # provide the function, we want to define HAVE_FN in config.h.
 391
 392 setobjs=
 393 CHECK=
 394 target_header_dir=
 395 if test -n "${with_target_subdir}"; then
 396
 397   # We are being configured as a target library.  AC_REPLACE_FUNCS
 398   # may not work correctly, because the compiler may not be able to
 399   # link executables.  Note that we may still be being configured
 400   # native.
 401
 402   # If we are being configured for newlib, we know which functions
 403   # newlib provide and which ones we will be expected to provide.
 404
 405   if test "x${with_newlib}" = "xyes"; then
 406     AC_LIBOBJ([asprintf])
 407     AC_LIBOBJ([basename])
 408     AC_LIBOBJ([insque])
 409     AC_LIBOBJ([random])
 410     AC_LIBOBJ([strdup])
 411     AC_LIBOBJ([vasprintf])
 412
 413     for f in $funcs; do
 414       case "$f" in
 415         asprintf | basename | insque | random | strdup | vasprintf)
 416           ;;
 417         *)
 418           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 419           AC_DEFINE_UNQUOTED($n)
 420           ;;
 421       esac
 422     done
 423
 424     # newlib doesnt provide any of the variables in $vars, so we
 425     # dont have to check them here.
 426
 427     # Of the functions in $checkfuncs, newlib only has strerror.
 428     AC_DEFINE(HAVE_STRERROR)
 429
 430     setobjs=yes
 431
 432   fi
 433
 434   # If we are being configured for Mingw, we know which functions
 435   # Mingw provides and which ones we will be expected to provide.
 436
 437   case "${host}" in
 438   *-*-mingw*)
 439     AC_LIBOBJ([asprintf])
 440     AC_LIBOBJ([basename])
 441     AC_LIBOBJ([bcmp])
 442     AC_LIBOBJ([bcopy])
 443     AC_LIBOBJ([bzero])
 444     AC_LIBOBJ([clock])
 445     AC_LIBOBJ([ffs])
 446     AC_LIBOBJ([getpagesize])
 447     AC_LIBOBJ([index])
 448     AC_LIBOBJ([insque])
 449     AC_LIBOBJ([mempcpy])
 450     AC_LIBOBJ([mkstemps])
 451     AC_LIBOBJ([random])
 452     AC_LIBOBJ([rindex])
 453     AC_LIBOBJ([sigsetmask])
 454     AC_LIBOBJ([stpcpy])
 455     AC_LIBOBJ([stpncpy])
 456     AC_LIBOBJ([strndup])
 457     AC_LIBOBJ([strverscmp])
 458     AC_LIBOBJ([vasprintf])
 459     AC_LIBOBJ([waitpid])
 460
 461     for f in $funcs; do
 462       case "$f" in
 463         asprintf | basename | bcmp | bcopy | bzero | clock | ffs | getpagesize | index | insque | mempcpy | mkstemps | random | rindex | sigsetmask | stpcpy | stpncpy | strdup | strndup | strverscmp | vasprintf | waitpid)
 464           ;;
 465         *)
 466           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 467           AC_DEFINE_UNQUOTED($n)
 468           ;;
 469       esac
 470     done
 471
 472     # Mingw doesnt provide any of the variables in $vars, so we
 473     # dont have to check them here.
 474
 475     # Of the functions in $checkfuncs, Mingw only has strerror.
 476     AC_DEFINE(HAVE_STRERROR)
 477
 478     setobjs=yes
 479     ;;
 480
 481   *-*-msdosdjgpp)
 482     AC_LIBOBJ([vasprintf])
 483     AC_LIBOBJ([vsnprintf])
 484     AC_LIBOBJ([snprintf])
 485     AC_LIBOBJ([asprintf])
 486
 487     for f in atexit basename bcmp bcopy bsearch bzero calloc clock ffs \
 488              getcwd getpagesize getrusage gettimeofday \
 489              index insque memchr memcmp memcpy memmove memset psignal \
 490              putenv random rename rindex sbrk setenv stpcpy strcasecmp \
 491              strchr strdup strerror strncasecmp strrchr strstr strtod \
 492              strtol strtoul sysconf times tmpnam vfprintf vprintf \
 493              vsprintf waitpid
 494     do
 495       n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 496       AC_DEFINE_UNQUOTED($n)
 497     done
 498
 499
 500     setobjs=yes
 501     ;;
 502
 503   esac
 504
 505   # We may wish to install the target headers somewhere.
 506   AC_ARG_ENABLE(install-libiberty,
 507   [  --enable-install-libiberty       Install headers for end users],
 508   enable_install_libiberty=$enableval,
 509   enable_install_libiberty=no)dnl
 510
 511   # Option parsed, now set things appropriately.
 512   case x"$enable_install_libiberty" in
 513     xyes|x)
 514       target_header_dir=libiberty
 515       ;;
 516     xno)
 517       target_header_dir=
 518       ;;
 519     *)
 520       # This could be sanity-checked in various ways...
 521       target_header_dir="${enable_install_libiberty}"
 522       ;;
 523   esac
 524
 525
 526 else
 527
 528    # Not a target library, so we set things up to run the test suite.
 529    CHECK=really-check
 530
 531 fi
 532
 533 AC_SUBST(CHECK)
 534 AC_SUBST(target_header_dir)
 535
 536 case "${host}" in
 537   *-*-cygwin* | *-*-mingw*)
 538     AC_DEFINE(HAVE_SYS_ERRLIST)
 539     AC_DEFINE(HAVE_SYS_NERR)
 540     ;;
 541 esac
 542
 543 if test -z "${setobjs}"; then
 544   case "${host}" in
 545
 546   *-*-vxworks*)
 547     # Handle VxWorks configuration specially, since on VxWorks the
 548     # libraries are actually on the target board, not in the file
 549     # system.
 550     AC_LIBOBJ([basename])
 551     AC_LIBOBJ([getpagesize])
 552     AC_LIBOBJ([insque])
 553     AC_LIBOBJ([random])
 554     AC_LIBOBJ([strcasecmp])
 555     AC_LIBOBJ([strncasecmp])
 556     AC_LIBOBJ([strdup])
 557     AC_LIBOBJ([vfork])
 558     AC_LIBOBJ([waitpid])
 559     AC_LIBOBJ([vasprintf])
 560     for f in $funcs; do
 561       case "$f" in
 562         basename | getpagesize | insque | random | strcasecmp)
 563           ;;
 564         strncasecmp | strdup | vfork | waitpid | vasprintf)
 565           ;;
 566         *)
 567           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 568           AC_DEFINE_UNQUOTED($n)
 569           ;;
 570       esac
 571     done
 572
 573     # VxWorks doesn't provide any of the variables in $vars, so we
 574     # don't have to check them here.
 575
 576     # Of the functions in $checkfuncs, VxWorks only has strerror.
 577     AC_DEFINE(HAVE_STRERROR)
 578
 579     setobjs=yes
 580     ;;
 581
 582   esac
 583 fi
 584
 585 if test -z "${setobjs}"; then
 586
 587   case "${host}" in
 588
 589   *-*-mingw32*)
 590     # Under mingw32, sys_nerr and sys_errlist exist, but they are
 591     # macros, so the test below won't find them.
 592     libiberty_cv_var_sys_nerr=yes
 593     libiberty_cv_var_sys_errlist=yes
 594     ;;
 595
 596   *-*-msdosdjgpp*)
 597     # vfork and fork are stubs.
 598     ac_cv_func_vfork_works=no
 599     ;;
 600
 601   *-*-uwin*)
 602     # Under some versions of uwin, vfork is notoriously buggy and the test
 603     # can hang configure; on other versions, vfork exists just as a stub.
 604     # FIXME: This should be removed once vfork in uwin's runtime is fixed.
 605     ac_cv_func_vfork_works=no
 606     # Under uwin 2.0+, sys_nerr and sys_errlist exist, but they are
 607     # macros (actually, these are imported from a DLL, but the end effect
 608     # is the same), so the test below won't find them.
 609     libiberty_cv_var_sys_nerr=yes
 610     libiberty_cv_var_sys_errlist=yes
 611     ;;
 612
 613   *-*-*vms*)
 614     # Under VMS, vfork works very different than on Unix. The standard test
 615     # won't work, and it isn't easily adaptable. It makes more sense to
 616     # just force it.
 617     ac_cv_func_vfork_works=yes
 618     ;;
 619
 620   esac
 621
 622   # We haven't set the list of objects yet.  Use the standard autoconf
 623   # tests.  This will only work if the compiler works.
 624   AC_ISC_POSIX
 625   AC_REPLACE_FUNCS($funcs)
 626   libiberty_AC_FUNC_C_ALLOCA
 627   AC_FUNC_FORK
 628   if test $ac_cv_func_vfork_works = no; then
 629     AC_LIBOBJ([vfork])
 630   fi
 631   # We only need _doprnt if we might use it to implement v*printf.
 632   if test $ac_cv_func_vprintf != yes \
 633      || test $ac_cv_func_vfprintf != yes \
 634      || test $ac_cv_func_vsprintf != yes; then
 635     AC_REPLACE_FUNCS(_doprnt)
 636   else
 637     AC_CHECK_FUNCS(_doprnt)
 638   fi
 639
 640   for v in $vars; do
 641     AC_MSG_CHECKING([for $v])
 642     AC_CACHE_VAL(libiberty_cv_var_$v,
 643       [AC_LINK_IFELSE([AC_LANG_PROGRAM([[int *p;]],[[extern int $v []; p = $v;]])],
 644                       [eval "libiberty_cv_var_$v=yes"],
 645                       [eval "libiberty_cv_var_$v=no"])])
 646     if eval "test \"`echo '$libiberty_cv_var_'$v`\" = yes"; then
 647       AC_MSG_RESULT(yes)
 648       n=HAVE_`echo $v | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 649       AC_DEFINE_UNQUOTED($n)
 650     else
 651       AC_MSG_RESULT(no)
 652     fi
 653   done
 654
 655   # special check for _system_configuration because AIX <4.3.2 do not
 656   # contain the `physmem' member.
 657   AC_MSG_CHECKING([for external symbol _system_configuration])
 658   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/systemcfg.h>]],
 659                         [[double x = _system_configuration.physmem;]])],
 660     [AC_MSG_RESULT([yes])
 661     AC_DEFINE(HAVE__SYSTEM_CONFIGURATION, 1,
 662               [Define if you have the _system_configuration variable.])],
 663     [AC_MSG_RESULT([no])])
 664
 665   AC_CHECK_FUNCS($checkfuncs)
 666   AC_CHECK_DECLS([basename(char *), ffs, asprintf, vasprintf, snprintf, vsnprintf])
 667   AC_CHECK_DECLS([calloc, getenv, getopt, malloc, realloc, sbrk])
 668   AC_CHECK_DECLS([strverscmp])
 669   libiberty_NEED_DECLARATION(canonicalize_file_name)
 670 fi
 671
 672 # Figure out which version of pexecute to use.
 673 case "${host}" in
 674      *-*-mingw* | *-*-winnt*)   pexecute=pex-win32  ;;
 675      *-*-msdosdjgpp*)           pexecute=pex-djgpp  ;;
 676      *-*-msdos*)                pexecute=pex-msdos  ;;
 677      *)                         pexecute=pex-unix   ;;
 678 esac
 679 AC_SUBST(pexecute)
 680
 681 libiberty_AC_FUNC_STRNCMP
 682
 683 # Install a library built with a cross compiler in $(tooldir) rather
 684 # than $(libdir).
 685 if test -z "${with_cross_host}"; then
 686   INSTALL_DEST=libdir
 687 else
 688   INSTALL_DEST=tooldir
 689 fi
 690 AC_SUBST(INSTALL_DEST)
 691
 692 m4_pattern_allow(LIBOBJS)
 693 L=""
 694 for l in x $LIBOBJS; do
 695   case $l in
 696     x) ;;
 697     *) L="$L ./$l" ;;
 698   esac
 699 done
 700 LIBOBJS="$L"
 701
 702 dnl Required by html and install-html
 703 AC_SUBST(datarootdir)
 704 AC_SUBST(docdir)
 705 AC_SUBST(htmldir)
 706
 707 # We need multilib support, but only if configuring for the target.
 708 AC_CONFIG_FILES([Makefile testsuite/Makefile])
 709 AC_CONFIG_COMMANDS([default],
 710   [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 711 if test -n "$CONFIG_FILES"; then
 712   if test -n "${with_target_subdir}"; then
 713     # FIXME: We shouldn't need to set ac_file
 714     ac_file=Makefile
 715     LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 716     . ${libiberty_topdir}/config-ml.in
 717   fi
 718 fi]],
 719 [[srcdir=${srcdir}
 720 host=${host}
 721 target=${target}
 722 with_target_subdir=${with_target_subdir}
 723 with_multisubdir=${with_multisubdir}
 724 ac_configure_args="--enable-multilib ${ac_configure_args}"
 725 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 726 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
 727 libiberty_topdir=${libiberty_topdir}
 728 ]])
 729 AC_OUTPUT