gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 dnl v2.5 needed for --bindir et al
   8 AC_PREREQ(2.13)
   9 AC_INIT(as.h)
  10
  11 AC_CANONICAL_SYSTEM
  12 AC_ISC_POSIX
  13
  14 changequote(,)dnl
  15 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  16 changequote([,])dnl
  17 AM_INIT_AUTOMAKE(gas, ${BFD_VERSION})
  18
  19 AM_PROG_LIBTOOL
  20
  21 user_bfd_gas=
  22 AC_ARG_ENABLE(bfd-assembler,
  23 [  --enable-bfd-assembler  use BFD back end for writing object files],
  24 [case "${enableval}" in
  25   yes) need_bfd=yes user_bfd_gas=yes ;;
  26   no)  user_bfd_gas=no ;;
  27   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  28 esac])dnl
  29 AC_ARG_ENABLE(targets,
  30 [    targets            alternative target configurations besides the primary],
  31 [case "${enableval}" in
  32   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  33             ;;
  34   no)       enable_targets= ;;
  35   *)        enable_targets=$enableval ;;
  36 esac])dnl
  37 AC_ARG_ENABLE(commonbfdlib,
  38 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  39 [case "${enableval}" in
  40   yes) commonbfdlib=true ;;
  41   no)  commonbfdlib=false ;;
  42   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  43 esac])dnl
  44
  45 using_cgen=no
  46
  47 build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
  48 AC_ARG_ENABLE(build-warnings,
  49 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  50 [case "${enableval}" in
  51   yes)  ;;
  52   no)   build_warnings="-w";;
  53   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  54         build_warnings="${build_warnings} ${t}";;
  55   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  56         build_warnings="${t} ${build_warnings}";;
  57   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  58 esac
  59 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  60   echo "Setting warning flags = $build_warnings" 6>&1
  61 fi])dnl
  62 WARN_CFLAGS=""
  63 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  64     WARN_CFLAGS="${build_warnings}"
  65 fi
  66 AC_SUBST(WARN_CFLAGS)
  67
  68 # Generate a header file
  69 AM_CONFIG_HEADER(config.h:config.in)
  70
  71 # If we are on a DOS filesystem, we must use gdb.ini rather than
  72 # .gdbinit.
  73 GDBINIT=".gdbinit"
  74 case "${host}" in
  75   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-windows*)
  76     GDBINIT="gdb.ini"
  77     ;;
  78 esac
  79 AC_SUBST(GDBINIT)
  80
  81 te_file=generic
  82
  83 # Makefile target for installing gas in $(tooldir)/bin.
  84 install_tooldir=install-exec-tooldir
  85
  86 canon_targets=""
  87 all_targets=no
  88 if test -n "$enable_targets" ; then
  89   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  90     if test $t = "all"; then
  91       all_targets=yes
  92       continue
  93     fi
  94     result=`$ac_config_sub $t 2>/dev/null`
  95     if test -n "$result" ; then
  96       canon_targets="$canon_targets $result"
  97 #    else
  98 #      # Permit "all", etc.  We don't support it yet though.
  99 #      canon_targets="$canon_targets $t"
 100     fi
 101   done
 102   GAS_UNIQ(canon_targets)
 103 fi
 104
 105 emulations=""
 106
 107 for this_target in $target $canon_targets ; do
 108
 109 changequote(,)dnl
 110     eval `echo $this_target | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/cpu=\1 vendor=\2 os=\3/'`
 111 changequote([,])dnl
 112
 113     # check for architecture variants
 114     arch=
 115     endian=
 116     case ${cpu} in
 117       alpha*)           cpu_type=alpha ;;
 118       arm*b|xscale*b|strongarm*b) cpu_type=arm endian=big ;;
 119       arm*|xscale*|strongarm*)    cpu_type=arm endian=little ;;
 120       hppa*)            cpu_type=hppa ;;
 121 changequote(,)dnl
 122       i[3456]86)        cpu_type=i386 arch=i386;;
 123       x86_64)           cpu_type=i386 arch=x86_64;;
 124       ia64)             cpu_type=ia64 ;;
 125       ip2k)             cpu_type=ip2k endian=big ;;
 126       iq2000)           cpu_type=iq2000 endian=big ;;
 127       m6811|m6812|m68hc12) cpu_type=m68hc11 ;;
 128       m680[012346]0)    cpu_type=m68k ;;
 129 changequote([,])dnl
 130       m68008)           cpu_type=m68k ;;
 131       m683??)           cpu_type=m68k ;;
 132       m5200)            cpu_type=m68k ;;
 133       m8*)              cpu_type=m88k ;;
 134       mips*el)          cpu_type=mips endian=little ;;
 135       mips*)            cpu_type=mips endian=big ;;
 136       or32*)            cpu_type=or32 endian=big ;;
 137       pjl*)             cpu_type=pj endian=little ;;
 138       pj*)              cpu_type=pj endian=big ;;
 139       powerpc*le*)      cpu_type=ppc endian=little ;;
 140       powerpc*)         cpu_type=ppc endian=big ;;
 141       rs6000*)          cpu_type=ppc ;;
 142       s390x*)           cpu_type=s390 arch=s390x ;;
 143       s390*)            cpu_type=s390 arch=s390 ;;
 144       sh5*)             cpu_type=sh64 endian=big ;;
 145       sh5le*)           cpu_type=sh64 endian=little ;;
 146       sh64*)            cpu_type=sh64 endian=big ;;
 147       sh64le*)          cpu_type=sh64 endian=little ;;
 148       sh*le)            cpu_type=sh endian=little ;;
 149       sh*)              cpu_type=sh endian=big ;;
 150       sparclite*)       cpu_type=sparc arch=sparclite ;;
 151       sparclet*)        cpu_type=sparc arch=sparclet ;;
 152       sparc64*)         cpu_type=sparc arch=v9-64 ;;
 153       sparc86x*)        cpu_type=sparc arch=sparc86x  ;;
 154       sparc*)           cpu_type=sparc arch=sparclite ;; # ??? See tc-sparc.c.
 155       v850*)            cpu_type=v850 ;;
 156       *)                cpu_type=${cpu} ;;
 157     esac
 158
 159     if test ${this_target} = $target ; then
 160       target_cpu_type=${cpu_type}
 161     elif test ${target_cpu_type} != ${cpu_type} ; then
 162       continue
 163     fi
 164
 165     generic_target=${cpu_type}-$vendor-$os
 166     dev=no
 167     bfd_gas=no
 168     em=generic
 169
 170     # assign object format
 171     case ${generic_target} in
 172       a29k-*-coff)                      fmt=coff ;;
 173       a29k-amd-udi)                     fmt=coff ;;
 174       a29k-amd-ebmon)                   fmt=coff ;;
 175       a29k-nyu-sym1)                    fmt=coff ;;
 176       a29k-*-rtems*)                    fmt=coff ;;
 177       a29k-*-vxworks*)                  fmt=coff ;;
 178
 179       alpha*-*-*vms*)                   fmt=evax ;;
 180       alpha*-*-netware*)                fmt=ecoff ;;
 181       alpha*-*-osf*)                    fmt=ecoff ;;
 182       alpha*-*-linuxecoff*)             fmt=ecoff ;;
 183       alpha*-*-linux-gnu*)              fmt=elf em=linux ;;
 184       alpha*-*-netbsd*)                 fmt=elf em=nbsd ;;
 185       alpha*-*-openbsd*)                fmt=elf em=obsd ;;
 186
 187       arc-*-elf*)                       fmt=elf ;;
 188
 189       arm-*-aout)                       fmt=aout ;;
 190       arm-*-coff | thumb-*-coff)        fmt=coff ;;
 191       arm-*-rtems | thumb-*-rtems)      fmt=elf ;;
 192       arm-*-elf | thumb-*-elf)          fmt=elf ;;
 193       arm-*-kaos*)                      fmt=elf ;;
 194       arm*-*-conix*)                    fmt=elf ;;
 195       arm-*-linux*aout*)                fmt=aout em=linux ;;
 196       arm*-*-linux-gnu*)                fmt=elf  em=linux ;;
 197       arm*-*-uclinux*)                  fmt=elf  em=linux ;;
 198       arm-*-netbsdelf*)                 fmt=elf  em=nbsd ;;
 199       arm-*-*n*bsd*)                    fmt=aout em=nbsd ;;
 200       arm-**-nto*)                      fmt=elf ;;
 201       arm-*-oabi | thumb-*-oabi)        fmt=elf ;;
 202       arm-epoc-pe | thumb-epoc-pe)      fmt=coff em=epoc-pe ;;
 203       arm-*-wince)                      fmt=coff em=wince-pe ;;
 204       arm-*-pe | thumb-*-pe)            fmt=coff em=pe ;;
 205       arm-*-riscix*)                    fmt=aout em=riscix ;;
 206       arm-*-vxworks)                    fmt=coff ;;
 207
 208       avr-*-*)                          fmt=elf ;;
 209
 210       cris-*-*)                         fmt=multi bfd_gas=yes ;;
 211
 212       d10v-*-*)                         fmt=elf ;;
 213       d30v-*-*)                         fmt=elf ;;
 214       dlx-*-*)                          fmt=elf ;;
 215
 216       fr30-*-*)                         fmt=elf ;;
 217       frv-*-*)                          fmt=elf ;;
 218
 219       hppa-*-linux*)    case ${cpu} in
 220                             hppa*64*)   fmt=elf em=hppalinux64;;
 221                             hppa*)      fmt=elf em=linux;;
 222                         esac ;;
 223       hppa-*-*elf*)                     fmt=elf em=hppa ;;
 224       hppa-*-lites*)                    fmt=elf em=hppa ;;
 225       hppa-*-netbsd*)                   fmt=elf em=nbsd ;;
 226       hppa-*-openbsd*)                  fmt=elf em=hppa ;;
 227       hppa-*-osf*)                      fmt=som em=hppa ;;
 228       hppa-*-rtems*)                    fmt=elf em=hppa ;;
 229       hppa-*-hpux11*)   case ${cpu} in
 230                             hppa*64*)   fmt=elf em=hppa64 ;;
 231                             hppa*)      fmt=som em=hppa ;;
 232                         esac ;;
 233       hppa-*-hpux*)                     fmt=som em=hppa ;;
 234       hppa-*-mpeix*)                    fmt=som em=hppa ;;
 235       hppa-*-bsd*)                      fmt=som em=hppa ;;
 236       hppa-*-hiux*)                     fmt=som em=hppa ;;
 237
 238       h8300-*-rtems*)                   fmt=coff ;;
 239       h8300-*-coff)                     fmt=coff ;;
 240       h8300-*-elf)                      fmt=elf ;;
 241       h8500-*-rtems*)                   fmt=coff ;;
 242       h8500-*-coff)                     fmt=coff ;;
 243
 244       i370-*-elf* | i370-*-linux*)      fmt=elf ;;
 245       i386-ibm-aix*)                    fmt=coff em=i386aix ;;
 246       i386-sequent-bsd*)                fmt=aout em=dynix ;;
 247       i386-*-beospe*)                   fmt=coff em=pe ;;
 248       i386-*-beos*)                     fmt=elf ;;
 249       i386-*-coff)                      fmt=coff ;;
 250       i386-*-elf)                       fmt=elf ;;
 251       i386-*-kaos*)                     fmt=elf ;;
 252       i386-*-bsd*)                      fmt=aout em=386bsd ;;
 253       i386-*-netbsd0.8)                 fmt=aout em=386bsd ;;
 254       i386-*-netbsdpe*)                 fmt=coff em=pe ;;
 255       i386-*-netbsdelf*)                fmt=elf em=nbsd ;;
 256       i386-*-*n*bsd*)   case ${cpu} in
 257                             x86_64)     fmt=elf em=nbsd ;;
 258                             *)          fmt=aout em=nbsd ;;
 259                         esac ;;
 260       i386-*-linux*aout*)               fmt=aout em=linux ;;
 261       i386-*-linux*oldld)               fmt=aout em=linux ;;
 262       i386-*-linux*coff*)               fmt=coff em=linux ;;
 263       i386-*-linux-gnu*)                fmt=elf em=linux ;;
 264       x86_64-*-linux-gnu*)              fmt=elf em=linux ;;
 265       i386-*-lynxos*)                   fmt=coff em=lynx ;;
 266 changequote(,)dnl
 267       i386-*-sysv[45]*)                 fmt=elf ;;
 268       i386-*-solaris*)                  fmt=elf ;;
 269       i386-*-freebsdaout*)              fmt=aout em=386bsd ;;
 270       i386-*-freebsd[12].*)             fmt=aout em=386bsd ;;
 271       i386-*-freebsd[12])               fmt=aout em=386bsd ;;
 272 changequote([,])dnl
 273       i386-*-sysv*)                     fmt=coff ;;
 274       i386-*-sco3.2v5*coff)             fmt=coff ;;
 275       i386-*-isc*)                      fmt=coff ;;
 276       i386-*-sco3.2v5*)                 fmt=elf
 277           if test ${this_target} = $target; then
 278             AC_DEFINE(SCO_ELF, 1, [Define if defaulting to ELF on SCO 5.])
 279           fi ;;
 280       i386-*-sco3.2*)                   fmt=coff ;;
 281       i386-*-vsta)                      fmt=aout ;;
 282       i386-*-msdosdjgpp* \
 283       | i386-*-go32* \
 284       | i386-go32-rtems*)               fmt=coff em=go32
 285             AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?]) ;;
 286       i386-*-rtemself*)                 fmt=elf ;;
 287       i386-*-rtemscoff*)                fmt=coff ;;
 288       i386-*-rtems*)                    fmt=elf ;;
 289       i386-*-gnu*)                      fmt=elf ;;
 290       i386-*-mach*)                     fmt=aout em=mach ;;
 291       i386-*-msdos*)                    fmt=aout ;;
 292       i386-*-moss*)                     fmt=elf ;;
 293       i386-*-pe)                        fmt=coff em=pe ;;
 294       i386-*-cygwin*)                   fmt=coff em=pe ;;
 295       i386-*-interix*)                  fmt=coff em=interix ;;
 296       i386-*-mingw32*)                  fmt=coff em=pe ;;
 297       i386-*-nto-qnx*)                  fmt=elf ;;
 298       i386-*-*nt*)                      fmt=coff em=pe ;;
 299       i386-*-vxworks*)                  fmt=aout ;;
 300       i386-*-chaos)                     fmt=elf ;;
 301
 302       i860-*-*)                         fmt=elf endian=little
 303                 AC_MSG_WARN(GAS support for ${generic_target} is preliminary and a work in progress) ;;
 304       i960-*-bout)                      fmt=bout ;;
 305       i960-*-coff)                      fmt=coff em=ic960 ;;
 306       i960-*-rtems*)                    fmt=coff em=ic960 ;;
 307       i960-*-nindy*)                    fmt=bout ;;
 308       i960-*-vxworks5.0)                fmt=bout ;;
 309       i960-*-vxworks5.*)                fmt=coff em=ic960 ;;
 310       i960-*-vxworks*)                  fmt=bout ;;
 311       i960-*-elf*)                      fmt=elf ;;
 312
 313       ia64-*-elf*)                      fmt=elf ;;
 314       ia64-*-aix*)                      fmt=elf em=ia64aix ;;
 315       ia64-*-linux-gnu*)                fmt=elf em=linux ;;
 316       ia64-*-hpux*)                     fmt=elf em=hpux ;;
 317       ia64-*-netbsd*)                   fmt=elf em=nbsd ;;
 318
 319       ip2k-*-*)                         fmt=elf ;;
 320
 321       iq2000-*-elf)                     fmt=elf bfd_gas=yes ;;
 322
 323       m32r-*-*)                         fmt=elf ;;
 324
 325       m68hc11-*-* | m6811-*-*)          fmt=elf ;;
 326       m68hc12-*-* | m6812-*-*)          fmt=elf ;;
 327
 328       m68k-*-vxworks*)                  fmt=aout em=sun3 ;;
 329       m68k-ericsson-ose)                fmt=aout em=sun3 ;;
 330       m68k-*-sunos*)                    fmt=aout em=sun3 ;;
 331       m68k-motorola-sysv*)              fmt=coff em=delta ;;
 332       m68k-bull-sysv3*)                 fmt=coff em=dpx2 ;;
 333       m68k-apollo-*)                    fmt=coff em=apollo ;;
 334       m68k-*-elf*)                      fmt=elf ;;
 335       m68k-*-sysv4*)                    fmt=elf em=svr4 ;;
 336       m68k-*-sysv*)                     fmt=coff ;;
 337       m68k-*-coff | m68k-*-rtemscoff*)  fmt=coff ;;
 338       m68k-*-rtems*)                    fmt=elf ;;
 339       m68k-*-hpux*)                     fmt=hp300 em=hp300 ;;
 340       m68k-*-linux*aout*)               fmt=aout em=linux ;;
 341       m68k-*-linux-gnu*)                fmt=elf em=linux ;;
 342       m68k-*-gnu*)                      fmt=elf ;;
 343       m68k-*-lynxos*)                   fmt=coff em=lynx ;;
 344       m68k-*-netbsdelf*)                fmt=elf em=nbsd ;;
 345       m68k-*-netbsd*)                   fmt=aout em=nbsd bfd_gas=yes ;;
 346       m68k-*-openbsd*)                  fmt=aout em=nbsd bfd_gas=yes ;;
 347       m68k-apple-aux*)                  fmt=coff em=aux ;;
 348       m68k-*-psos*)                     fmt=elf em=psos;;
 349
 350       m88k-motorola-sysv3*)             fmt=coff em=delt88 ;;
 351       m88k-*-coff*)                     fmt=coff ;;
 352
 353       mcore-*-elf)                      fmt=elf ;;
 354       mcore-*-pe)                       fmt=coff em=pe bfd_gas=yes ;;
 355
 356       # don't change em like *-*-bsd does
 357       mips-dec-openbsd*)                fmt=elf endian=little ;;
 358       mips-dec-bsd*)                    fmt=aout endian=little ;;
 359       mips-sony-bsd*)                   fmt=ecoff ;;
 360       mips-*-bsd*)
 361             AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.) ;;
 362       mips-*-ultrix*)                   fmt=ecoff endian=little ;;
 363       mips-*-osf*)                      fmt=ecoff endian=little ;;
 364       mips-*-ecoff*)                    fmt=ecoff ;;
 365       mips-*-pe*)                       fmt=coff endian=little em=pe ;;
 366       mips-*-irix6*)                    fmt=elf em=irix ;;
 367       mips-*-irix5*)                    fmt=elf em=irix ;;
 368       mips-*-irix*)                     fmt=ecoff em=irix ;;
 369       mips-*-lnews*)                    fmt=ecoff em=lnews ;;
 370       mips-*-riscos*)                   fmt=ecoff ;;
 371       mips*-*-linux*)                   fmt=elf em=tmips ;;
 372       mips-*-sysv4*MP* | mips-*-gnu*)   fmt=elf em=tmips ;;
 373       mips-*-sysv*)                     fmt=ecoff ;;
 374       mips-*-elf* | mips-*-rtems*)      fmt=elf ;;
 375       mips-*-*n*bsd*)                   fmt=elf ;;
 376       mips-*-vxworks*)                  fmt=elf ;;
 377
 378       mmix-*-*)                         fmt=elf ;;
 379       mn10200-*-*)                      fmt=elf ;;
 380       mn10300-*-*)                      fmt=elf ;;
 381       msp430-*-*)                       fmt=elf ;;
 382       openrisc-*-*)                     fmt=elf ;;
 383       or32-*-rtems*)                    fmt=coff ;;
 384       or32-*-coff)                      fmt=coff ;;
 385       or32-*-elf)                       fmt=elf ;;
 386       pj*)                              fmt=elf ;;
 387
 388       ppc-*-pe | ppc-*-cygwin*)         fmt=coff em=pe ;;
 389       ppc-*-winnt*)                     fmt=coff em=pe ;;
 390       ppc-*-aix5*)                      fmt=coff em=aix5 ;;
 391       ppc-*-aix*)                       fmt=coff ;;
 392       ppc-*-beos*)                      fmt=coff ;;
 393       ppc-*-*n*bsd* | ppc-*-elf*)       fmt=elf ;;
 394       ppc-*-eabi* | ppc-*-sysv4*)       fmt=elf ;;
 395       ppc-*-linux-gnu*)                 fmt=elf
 396             case "$endian" in
 397                 big)  ;;
 398                 *)    AC_MSG_ERROR(GNU/Linux must be configured big endian) ;;
 399             esac ;;
 400       ppc-*-solaris*)                   fmt=elf
 401             if test ${this_target} = $target; then
 402                 AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 403                           [Define if default target is PowerPC Solaris.])
 404             fi
 405             if test x${endian} = xbig; then
 406                 AC_MSG_ERROR(Solaris must be configured little endian)
 407             fi ;;
 408       ppc-*-rtems*)                     fmt=elf ;;
 409       ppc-*-macos* | ppc-*-mpw*)        fmt=coff em=macos ;;
 410       ppc-*-netware*)                   fmt=elf em=ppcnw ;;
 411       ppc-**-nto*)                      fmt=elf ;;
 412       ppc-*-vxworks*)                   fmt=elf ;;
 413       ppc-*-windiss*)                   fmt=elf ;;
 414       ppc-*-kaos*)                      fmt=elf ;;
 415
 416       s390x-*-linux-gnu*)               fmt=elf em=linux ;;
 417       s390-*-linux-gnu*)                fmt=elf em=linux ;;
 418
 419       sh*-*-linux*)                     fmt=elf em=linux
 420             case ${cpu} in
 421                 sh*eb)  endian=big ;;
 422                 *)      endian=little ;;
 423             esac ;;
 424       sh5*-*-netbsd*)                   fmt=elf em=nbsd ;;
 425       sh64*-*-netbsd*)                  fmt=elf em=nbsd ;;
 426       sh*-*-netbsdelf*)                 fmt=elf em=nbsd ;;
 427       sh-*-elf*)                        fmt=elf ;;
 428       sh-*-coff*)                       fmt=coff ;;
 429       sh-*-nto*)                        fmt=elf ;;
 430       sh-*-pe*)                         fmt=coff em=pe bfd_gas=yes endian=little ;;
 431       sh-*-rtemself*)                   fmt=elf ;;
 432       sh-*-rtems*)                      fmt=coff ;;
 433       sh-*-kaos*)                       fmt=elf ;;
 434       shle*-*-kaos*)                    fmt=elf ;;
 435       sh64-*-elf*)                      fmt=elf ;;
 436
 437       ns32k-pc532-mach*)                fmt=aout em=pc532mach ;;
 438       ns32k-pc532-ux*)                  fmt=aout em=pc532mach ;;
 439       ns32k-pc532-lites*)               fmt=aout em=nbsd532 ;;
 440       ns32k-*-*n*bsd*)                  fmt=aout em=nbsd532 ;;
 441
 442       sparc-*-rtemsaout*)               fmt=aout ;;
 443       sparc-*-rtemself*)                fmt=elf ;;
 444       sparc-*-rtems*)                   fmt=elf ;;
 445       sparc-*-sunos4*)                  fmt=aout em=sun3 ;;
 446       sparc-*-aout | sparc*-*-vxworks*) fmt=aout em=sparcaout ;;
 447       sparc-*-coff)                     fmt=coff ;;
 448       sparc-*-linux*aout*)              fmt=aout em=linux ;;
 449       sparc-*-linux-gnu*)               fmt=elf em=linux ;;
 450       sparc-*-lynxos*)                  fmt=coff em=lynx ;;
 451       sparc-fujitsu-none)               fmt=aout ;;
 452       sparc-*-elf)                      fmt=elf ;;
 453       sparc-*-sysv4*)                   fmt=elf ;;
 454       sparc-*-solaris*)                 fmt=elf ;;
 455       sparc-*-netbsdelf*)               fmt=elf em=nbsd ;;
 456       sparc-*-*n*bsd*)  case ${cpu} in
 457                             sparc64)    fmt=elf em=nbsd ;;
 458                             *)          fmt=aout em=nbsd ;;
 459                         esac ;;
 460       strongarm-*-coff)                 fmt=coff ;;
 461       strongarm-*-elf)                  fmt=elf ;;
 462       strongarm-*-kaos*)                fmt=elf ;;
 463       xscale-*-coff)                    fmt=coff ;;
 464       xscale-*-elf)                     fmt=elf ;;
 465
 466       tic30-*-*aout*)                   fmt=aout bfd_gas=yes ;;
 467       tic30-*-*coff*)                   fmt=coff bfd_gas=yes ;;
 468       tic4x-*-* | c4x-*-*)              fmt=coff bfd_gas=yes ;;
 469       tic54x-*-* | c54x*-*-*)           fmt=coff bfd_gas=yes need_libm=yes;;
 470       tic80-*-*)                        fmt=coff ;;
 471
 472       v850-*-*)                         fmt=elf ;;
 473       v850e-*-*)                        fmt=elf ;;
 474       v850ea-*-*)                       fmt=elf ;;
 475
 476       vax-*-netbsdelf*)                 fmt=elf em=nbsd ;;
 477       vax-*-netbsd*)                    fmt=aout em=nbsd ;;
 478       vax-*-bsd* | vax-*-ultrix*)       fmt=aout ;;
 479       vax-*-vms)                        fmt=vms ;;
 480
 481       w65-*-*)                          fmt=coff ;;
 482
 483       xstormy16-*-*)                    fmt=elf ;;
 484
 485       z8k-*-coff | z8k-*-sim)           fmt=coff ;;
 486
 487       *-*-aout | *-*-scout)             fmt=aout ;;
 488       *-*-freebsd*)                     fmt=elf em=freebsd ;;
 489       *-*-nindy*)                       fmt=bout ;;
 490       *-*-bsd*)                         fmt=aout em=sun3 ;;
 491       *-*-generic)                      fmt=generic ;;
 492       *-*-xray | *-*-hms)               fmt=coff ;;
 493       *-*-sim)                          fmt=coff ;;
 494       *-*-elf | *-*-sysv4* | *-*-solaris*) fmt=elf dev=yes ;;
 495       *-*-aros*)                                fmt=elf em=linux bfd_gas=yes ;;
 496       *-*-vxworks)                      fmt=aout ;;
 497       *-*-netware)                      fmt=elf ;;
 498     esac
 499
 500     if test ${this_target} = $target ; then
 501       endian_def=
 502       if test x${endian} = xbig; then
 503         endian_def=1
 504       elif test x${endian} = xlittle; then
 505         endian_def=0
 506       fi
 507       if test x${endian_def} != x; then
 508         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 509                            [Define as 1 if big endian.])
 510       fi
 511     fi
 512
 513     case ${cpu_type}-${fmt} in
 514         alpha*-* | arm-* | i386-* | ia64*-* | mips-* | ns32k-* \
 515                 | pdp11-* | ppc-* | sparc-* | strongarm-* | xscale-* \
 516                 | *-elf | *-ecoff | *-som)
 517             bfd_gas=yes ;;
 518     esac
 519
 520 # Other random stuff.
 521
 522     case ${cpu_type} in
 523       mips)
 524         # Set mips_cpu to the name of the default CPU.
 525         case ${target_cpu} in
 526           mips | mipsbe | mipseb | mipsle | mipsel | mips64 | mips64el)
 527             mips_cpu=from-abi
 528             ;;
 529           mipsisa32 | mipsisa32el)
 530             mips_cpu=mips32
 531             ;;
 532           mipsisa32r2 | mipsisa32r2el)
 533             mips_cpu=mips32r2
 534             ;;
 535           mipsisa64 | mipsisa64el)
 536             mips_cpu=mips64
 537             ;;
 538           mipstx39 | mipstx39el)
 539             mips_cpu=r3900
 540             ;;
 541           mips64vr | mips64vrel)
 542             mips_cpu=vr4100
 543             ;;
 544           mipsisa32r2*)
 545 changequote(,)dnl
 546             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r2//' -e 's/el$//'`
 547 changequote([,])dnl
 548             ;;
 549           mips64* | mipsisa64* | mipsisa32*)
 550 changequote(,)dnl
 551             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..//' -e 's/el$//'`
 552 changequote([,])dnl
 553             ;;
 554           *)
 555             AC_ERROR($target_cpu isn't a supported MIPS CPU name)
 556             ;;
 557         esac
 558         # See whether it's appropriate to set E_MIPS_ABI_O32 for o32
 559         # binaries.  It's a GNU extension that some OSes don't understand.
 560         # The value only matters on ELF targets.
 561         case ${target} in
 562           *-*-irix*)
 563             use_e_mips_abi_o32=0
 564             ;;
 565           *)
 566             use_e_mips_abi_o32=1
 567             ;;
 568         esac
 569         # Decide whether to generate 32-bit or 64-bit code by default.
 570         # Used to resolve -march=from-abi when an embedded ABI is selected.
 571         case ${target} in
 572           mips64*-*-* | mipsisa64*-*-*)
 573             mips_default_64bit=1
 574             ;;
 575           *)
 576             mips_default_64bit=0
 577             ;;
 578         esac
 579         AC_DEFINE_UNQUOTED(MIPS_CPU_STRING_DEFAULT, "$mips_cpu",
 580                            [Default CPU for MIPS targets. ])
 581         AC_DEFINE_UNQUOTED(USE_E_MIPS_ABI_O32, $use_e_mips_abi_o32,
 582                            [Allow use of E_MIPS_ABI_O32 on MIPS targets. ])
 583         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_64BIT, $mips_default_64bit,
 584                            [Generate 64-bit code by default on MIPS targets. ])
 585         ;;
 586     esac
 587
 588     # Do we need the opcodes library?
 589     case ${cpu_type} in
 590       vax | i386 | tic30)
 591         ;;
 592
 593       *)
 594         need_opcodes=yes
 595
 596         case "${enable_shared}" in
 597         yes) shared_opcodes=true ;;
 598         *opcodes*) shared_opcodes=true ;;
 599         *) shared_opcodes=false ;;
 600         esac
 601         if test "${shared_opcodes}" = "true"; then
 602           # A shared libopcodes must be linked against libbfd.
 603           need_bfd=yes
 604         fi
 605         ;;
 606     esac
 607
 608     # Any other special object files needed ?
 609     case ${cpu_type} in
 610       fr30 | ip2k | iq2000 | m32r | openrisc)
 611         using_cgen=yes
 612         ;;
 613
 614       frv)
 615         using_cgen=yes
 616         ;;
 617       m68k)
 618         case ${extra_objects} in
 619         *m68k-parse.o*) ;;
 620         *) extra_objects="$extra_objects m68k-parse.o" ;;
 621         esac
 622         ;;
 623
 624       mips)
 625         echo ${extra_objects} | grep -s "itbl-parse.o"
 626         if test $? -ne 0 ; then
 627           extra_objects="$extra_objects itbl-parse.o"
 628         fi
 629
 630         echo ${extra_objects} | grep -s "itbl-lex.o"
 631         if test $? -ne 0 ; then
 632           extra_objects="$extra_objects itbl-lex.o"
 633         fi
 634
 635         echo ${extra_objects} | grep -s "itbl-ops.o"
 636         if test $? -ne 0 ; then
 637           extra_objects="$extra_objects itbl-ops.o"
 638         fi
 639         ;;
 640
 641       i386 | s390 | sparc)
 642         if test $this_target = $target ; then
 643           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 644         fi
 645         ;;
 646
 647       xstormy16)
 648         using_cgen=yes
 649         ;;
 650
 651       *)
 652         ;;
 653     esac
 654
 655     if test $using_cgen = yes ; then
 656         case "x${extra_objects}" in
 657         *cgen.o*) ;;
 658         *) extra_objects="$extra_objects cgen.o" ;;
 659         esac
 660     fi
 661
 662 # See if we really can support this configuration with the emulation code.
 663
 664     if test $this_target = $target ; then
 665       primary_bfd_gas=$bfd_gas
 666       obj_format=$fmt
 667       te_file=$em
 668
 669       if test $bfd_gas = no ; then
 670         # Can't support other configurations this way.
 671         break
 672       fi
 673     elif test $bfd_gas = no ; then
 674       # Can't support this configuration.
 675       break
 676     fi
 677
 678 # From target name and format, produce a list of supported emulations.
 679
 680     case ${generic_target}-${fmt} in
 681       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 682       mips*-*-linux*-*) case "$endian" in
 683                         big)    emulation="mipsbelf mipslelf mipself" ;;
 684                         *)      emulation="mipslelf mipsbelf mipself" ;;
 685                         esac ;;
 686       mips-*-lnews*-ecoff) ;;
 687       mips-*-*-ecoff)   case "$endian" in
 688                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 689                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 690                         esac ;;
 691       mips-*-*-elf)     case "$endian" in
 692                         big)    emulation="mipsbelf mipslelf mipself" ;;
 693                         *)      emulation="mipslelf mipsbelf mipself" ;;
 694                         esac ;;
 695       mips-*-sysv4*MP*-*) emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 696       # i386-pc-pe-coff != i386-pc-coff.
 697       i386-*-pe-coff)   ;;
 698       # Uncommenting the next line will turn on support for i386 AOUT
 699       # for the default linux configuration
 700       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 701       #
 702       i386-*-aout)      emulation="i386aout" ;;
 703       i386-*-coff)      emulation="i386coff" ;;
 704       i386-*-elf)       emulation="i386elf" ;;
 705
 706       # Always all formats.  The first stated emulation becomes the default.
 707       cris-*-*aout*)    emulation="crisaout criself" ;;
 708       cris-*-*)         emulation="criself crisaout" ;;
 709     esac
 710
 711     emulations="$emulations $emulation"
 712
 713 done
 714
 715 # Turn on all targets if possible
 716 if test ${all_targets} = "yes"; then
 717   case ${target_cpu_type} in
 718   i386)
 719     case ${obj_format} in
 720     aout)
 721       emulations="$emulations i386coff i386elf"
 722       ;;
 723     coff)
 724       emulations="$emulations i386aout i386elf"
 725     ;;
 726     elf)
 727       emulations="$emulations i386aout i386coff"
 728       ;;
 729     esac
 730   ;;
 731   esac
 732 fi
 733
 734 # Assign floating point type.  Most processors with FP support
 735 # IEEE FP.  On those that don't support FP at all, usually IEEE
 736 # is emulated.
 737 case ${target_cpu} in
 738   vax | tahoe ) atof=${target_cpu} ;;
 739   pdp11)        atof=vax ;;
 740   *)            atof=ieee ;;
 741 esac
 742
 743 case "${obj_format}" in
 744   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 745 esac
 746
 747 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 748 cgen_cpu_prefix=""
 749 if test $using_cgen = yes ; then
 750   case ${target_cpu} in
 751     *) cgen_cpu_prefix=${target_cpu} ;;
 752   esac
 753   AC_SUBST(cgen_cpu_prefix)
 754   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 755 fi
 756
 757 dnl
 758 dnl Make sure the desired support files exist.
 759 dnl
 760
 761 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 762   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 763 fi
 764
 765 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 766   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 767 fi
 768
 769 case ${user_bfd_gas}-${primary_bfd_gas} in
 770   yes-yes | no-no)
 771     # We didn't override user's choice.
 772     ;;
 773   no-yes)
 774     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 775     ;;
 776   no-preferred)
 777     primary_bfd_gas=no
 778     ;;
 779   *-preferred)
 780     primary_bfd_gas=yes
 781     ;;
 782   yes-*)
 783     primary_bfd_gas=yes
 784     ;;
 785   -*)
 786     # User specified nothing.
 787     ;;
 788 esac
 789
 790 # Some COFF configurations want these random other flags set.
 791 case ${obj_format} in
 792   coff)
 793     case ${target_cpu_type} in
 794       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 795       m68k) AC_DEFINE(M68KCOFF, 1, [Using m68k COFF?]) ;;
 796       m88k) AC_DEFINE(M88KCOFF, 1, [Using m88k COFF?]) ;;
 797     esac
 798     ;;
 799 esac
 800
 801 # Getting this done right is going to be a bitch.  Each configuration specified
 802 # with --enable-targets=... should be checked for environment, format, cpu, and
 803 # bfd_gas setting.
 804 #
 805 # For each configuration, the necessary object file support code must be linked
 806 # in.  This might be only one, it might be up to four.  The necessary emulation
 807 # code needs to be provided, too.
 808 #
 809 # And then there's "--enable-targets=all"....
 810 #
 811 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 812
 813 formats="${obj_format}"
 814 emfiles=""
 815 EMULATIONS=""
 816 GAS_UNIQ(emulations)
 817 for em in . $emulations ; do
 818   case $em in
 819     .)  continue ;;
 820     mipsbelf | mipslelf | mipself)
 821         fmt=elf   file=mipself ;;
 822     mipsbecoff | mipslecoff | mipsecoff)
 823         fmt=ecoff file=mipsecoff ;;
 824     *coff)
 825         fmt=coff  file=$em ;;
 826     *aout)
 827         fmt=aout file=$em ;;
 828     *elf)
 829         fmt=elf file=$em ;;
 830   esac
 831   formats="$formats $fmt"
 832   emfiles="$emfiles e-$file.o"
 833   EMULATIONS="$EMULATIONS &$em,"
 834 done
 835 GAS_UNIQ(formats)
 836 GAS_UNIQ(emfiles)
 837 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 838   for fmt in $formats ; do
 839     case $fmt in
 840       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 841       bout)     AC_DEFINE(OBJ_MAYBE_BOUT, 1,    [b.out support?])   ;;
 842       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 843       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 844       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 845       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 846       hp300)    AC_DEFINE(OBJ_MAYBE_HP300, 1,   [HP300 support?])   ;;
 847       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE, 1,    [IEEE support?])    ;;
 848       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 849       vms)      AC_DEFINE(OBJ_MAYBE_VMS, 1,     [VMS support?])     ;;
 850     esac
 851     extra_objects="$extra_objects obj-$fmt.o"
 852   done
 853   obj_format=multi
 854 fi
 855 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 856   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 857   # e-mips* has more than one emulation per file, e-i386* has just one at the
 858   # moment.  If only one emulation is specified, then don't define
 859   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 860   case "${obj_format}${emfiles}" in
 861     multi* | *mips*)
 862       extra_objects="$extra_objects $emfiles"
 863       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 864   esac
 865 fi
 866 AC_SUBST(extra_objects)
 867 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 868 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 869                    [Default emulation.])
 870
 871 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 872   yes-*-coff)   need_bfd=yes ;;
 873   no-*-coff)    need_bfd=yes
 874                 AC_DEFINE(MANY_SEGMENTS, 1, [old COFF support?]) ;;
 875 esac
 876
 877 reject_dev_configs=yes
 878
 879 case ${reject_dev_configs}-${dev} in
 880   yes-yes) # Oops.
 881     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 882     ;;
 883 esac
 884
 885 AC_SUBST(target_cpu_type)
 886 AC_SUBST(obj_format)
 887 AC_SUBST(te_file)
 888 AC_SUBST(install_tooldir)
 889 AC_SUBST(atof)
 890 dnl AC_SUBST(emulation)
 891
 892 case "${primary_bfd_gas}" in
 893   yes)  AC_DEFINE(BFD_ASSEMBLER, 1, [Use BFD interface?])
 894         need_bfd=yes ;;
 895 esac
 896
 897 # do we need the opcodes library?
 898 case "${need_opcodes}" in
 899 yes)
 900   OPCODES_LIB=../opcodes/libopcodes.la
 901   ;;
 902 esac
 903
 904 case "${need_bfd}" in
 905 yes)
 906   BFDLIB=../bfd/libbfd.la
 907   BFDVER_H=../bfd/bfdver.h
 908   ALL_OBJ_DEPS="$ALL_OBJ_DEPS"' ../bfd/bfd.h $(INCDIR)/symcat.h'
 909   ;;
 910 esac
 911
 912 AC_SUBST(BFDLIB)
 913 AC_SUBST(OPCODES_LIB)
 914
 915 AC_SUBST(BFDVER_H)
 916 AC_SUBST(ALL_OBJ_DEPS)
 917
 918 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 919 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 920 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 921 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 922 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 923
 924 AC_PROG_CC
 925
 926 AC_PROG_YACC
 927 AM_PROG_LEX
 928
 929 ALL_LINGUAS="fr tr es"
 930 CY_GNU_GETTEXT
 931
 932 AM_MAINTAINER_MODE
 933 AC_EXEEXT
 934
 935 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 936
 937 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 938 # people who are not cross-compiling but are compiling cross-assemblers.
 939 AC_MSG_CHECKING(whether compiling a cross-assembler)
 940 if test "${host}" = "${target}"; then
 941   cross_gas=no
 942 else
 943   cross_gas=yes
 944   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 945 fi
 946 AC_MSG_RESULT($cross_gas)
 947
 948 dnl ansidecl.h will deal with const
 949 dnl AC_CONST
 950 AC_FUNC_ALLOCA
 951 AC_C_INLINE
 952
 953 # VMS doesn't have unlink.
 954 AC_CHECK_FUNCS(unlink remove, break)
 955
 956 # Some systems don't have sbrk().
 957 AC_CHECK_FUNCS(sbrk)
 958
 959 # do we need the math library?
 960 case "${need_libm}" in
 961 yes)
 962   AC_CHECK_LIBM
 963   AC_SUBST(LIBM)
 964   ;;
 965 esac
 966
 967 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 968 # enough, but on some of those systems, the assert macro relies on requoting
 969 # working properly!
 970 GAS_WORKING_ASSERT
 971
 972 # On some systems, the system header files may not declare malloc, realloc,
 973 # and free.  There are places where gas needs these functions to have been
 974 # declared -- such as when taking their addresses.
 975 gas_test_headers="
 976 #ifdef HAVE_MEMORY_H
 977 #include <memory.h>
 978 #endif
 979 #ifdef HAVE_STRING_H
 980 #include <string.h>
 981 #else
 982 #ifdef HAVE_STRINGS_H
 983 #include <strings.h>
 984 #endif
 985 #endif
 986 #ifdef HAVE_STDLIB_H
 987 #include <stdlib.h>
 988 #endif
 989 #ifdef HAVE_UNISTD_H
 990 #include <unistd.h>
 991 #endif
 992 "
 993 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
 994 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 995 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 996 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
 997 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
 998
 999 # Does errno.h declare errno, or do we have to add a separate declaration
1000 # for it?
1001 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
1002 #ifdef HAVE_ERRNO_H
1003 #include <errno.h>
1004 #endif
1005 ])
1006
1007 dnl This must come last.
1008
1009 dnl We used to make symlinks to files in the source directory, but now
1010 dnl we just use the right name for .c files, and create .h files in
1011 dnl the build directory which include the right .h file.  Make sure
1012 dnl the old symlinks don't exist, so that a reconfigure in an existing
1013 dnl directory behaves reasonably.
1014
1015 AC_OUTPUT(Makefile doc/Makefile ${GDBINIT}:gdbinit.in po/Makefile.in:po/Make-in,
1016 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
1017  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
1018  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
1019  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
1020  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
1021  if test "x$cgen_cpu_prefix" != x ; then
1022    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
1023  fi
1024
1025  sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile],
1026 [target_cpu_type=${target_cpu_type}
1027  cgen_cpu_prefix=${cgen_cpu_prefix}
1028  obj_format=${obj_format}
1029  te_file=${te_file}])