ld/scripttempl/elfm68hc11.sc

   1 #
   2 # Unusual variables checked by this code:
   3 #       NOP - four byte opcode for no-op (defaults to 0)
   4 #       DATA_ADDR - if end-of-text-plus-one-page isn't right for data start
   5 #       OTHER_READWRITE_SECTIONS - other than .data .bss .ctors .sdata ...
   6 #               (e.g., .PARISC.global)
   7 #       OTHER_SECTIONS - at the end
   8 #       EXECUTABLE_SYMBOLS - symbols that must be defined for an
   9 #               executable (e.g., _DYNAMIC_LINK)
  10 #       TEXT_START_SYMBOLS - symbols that appear at the start of the
  11 #               .text section.
  12 #       DATA_START_SYMBOLS - symbols that appear at the start of the
  13 #               .data section.
  14 #       OTHER_BSS_SYMBOLS - symbols that appear at the start of the
  15 #               .bss section besides __bss_start.
  16 #       EMBEDDED - whether this is for an embedded system.
  17 #
  18 # When adding sections, do note that the names of some sections are used
  19 # when specifying the start address of the next.
  20 #
  21 test -z "$ENTRY" && ENTRY=_start
  22 test -z "${BIG_OUTPUT_FORMAT}" && BIG_OUTPUT_FORMAT=${OUTPUT_FORMAT}
  23 test -z "${LITTLE_OUTPUT_FORMAT}" && LITTLE_OUTPUT_FORMAT=${OUTPUT_FORMAT}
  24 if [ -z "$MACHINE" ]; then OUTPUT_ARCH=${ARCH}; else OUTPUT_ARCH=${ARCH}:${MACHINE}; fi
  25 test "$LD_FLAG" = "N" && DATA_ADDR=.
  26
  27 CTOR=".ctors ${CONSTRUCTING-0} :
  28   {
  29     ${CONSTRUCTING+ PROVIDE (__CTOR_LIST__ = .); }
  30     ${CONSTRUCTING+${CTOR_START}}
  31     *(.ctors)
  32     /* We don't want to include the .ctor section from
  33        from the crtend.o file until after the sorted ctors.
  34        The .ctor section from the crtend file contains the
  35        end of ctors marker and it must be last
  36
  37     KEEP (*(EXCLUDE_FILE (*crtend.o) .ctors))
  38     KEEP (*(SORT(.ctors.*)))
  39     KEEP (*(.ctors)) */
  40
  41     ${CONSTRUCTING+${CTOR_END}}
  42     ${CONSTRUCTING+ PROVIDE(__CTOR_END__ = .); }
  43   } ${RELOCATING+ > ${TEXT_MEMORY}}"
  44
  45 DTOR="  .dtors  ${CONSTRUCTING-0} :
  46   {
  47     ${CONSTRUCTING+ PROVIDE(__DTOR_LIST__ = .); }
  48     *(.dtors)
  49     /*
  50     KEEP (*crtbegin.o(.dtors))
  51     KEEP (*(EXCLUDE_FILE (*crtend.o) .dtors))
  52     KEEP (*(SORT(.dtors.*)))
  53     KEEP (*(.dtors)) */
  54     ${CONSTRUCTING+ PROVIDE(__DTOR_END__ = .); }
  55   } ${RELOCATING+ > ${TEXT_MEMORY}}"
  56
  57
  58 VECTORS="
  59   /* If the 'vectors_addr' symbol is defined, it indicates the start address
  60      of interrupt vectors.  This depends on the 68HC11 operating mode:
  61
  62                         Addr
  63      Single chip        0xffc0
  64      Extended mode      0xffc0
  65      Bootstrap          0x00c0
  66      Test               0xbfc0
  67
  68      In general, the vectors address is 0xffc0.  This can be overriden
  69      with the '-defsym vectors_addr=0xbfc0' ld option.
  70
  71      Note: for the bootstrap mode, the interrupt vectors are at 0xbfc0 but
  72      they are redirected to 0x00c0 by the internal PROM.  Application's vectors
  73      must also consist of jump instructions (see Motorola's manual).  */
  74
  75   PROVIDE (_vectors_addr = DEFINED (vectors_addr) ? vectors_addr : 0xffc0);
  76   .vectors DEFINED (vectors_addr) ? vectors_addr : 0xffc0 :
  77   {
  78     KEEP (*(.vectors))
  79   }"
  80
  81 #
  82 # We provide two emulations: a fixed on that defines some memory banks
  83 # and a configurable one that includes a user provided memory definition.
  84 #
  85 case $GENERIC_BOARD in
  86   yes|1|YES)
  87         MEMORY_DEF="
  88 /* Get memory banks definition from some user configuration file.
  89    This file must be located in some linker directory (search path
  90    with -L<dir>). See fixed memory banks emulation script.  */
  91 INCLUDE memory.x;
  92 "
  93         ;;
  94   *)
  95 MEMORY_DEF="
  96 /* Fixed definition of the available memory banks.
  97    See generic emulation script for a user defined configuration.  */
  98 MEMORY
  99 {
 100   page0 (rwx) : ORIGIN = 0x0, LENGTH = 256
 101   text  (rx)  : ORIGIN = ${ROM_START_ADDR}, LENGTH = ${ROM_SIZE}
 102   data        : ORIGIN = ${RAM_START_ADDR}, LENGTH = ${RAM_SIZE}
 103   eeprom      : ORIGIN = ${EEPROM_START_ADDR}, LENGTH = ${EEPROM_SIZE}
 104 }
 105
 106 /* Setup the stack on the top of the data memory bank.  */
 107 PROVIDE (_stack = ${RAM_START_ADDR} + ${RAM_SIZE} - 1);
 108 "
 109         ;;
 110 esac
 111
 112 STARTUP_CODE="
 113     /* Startup code.  */
 114     KEEP (*(.install0)) /* Section should setup the stack pointer.  */
 115     KEEP (*(.install1)) /* Place holder for applications.  */
 116     KEEP (*(.install2)) /* Optional installation of data sections in RAM.  */
 117     KEEP (*(.install3)) /* Place holder for applications.  */
 118     KEEP (*(.install4)) /* Section that calls the main.  */
 119 "
 120
 121 FINISH_CODE="
 122     /* Finish code.  */
 123     KEEP (*(.fini0))    /* Beginning of finish code (_exit symbol).  */
 124     KEEP (*(.fini1))    /* Place holder for applications.  */
 125     KEEP (*(.fini2))    /* C++ destructors.  */
 126     KEEP (*(.fini3))    /* Place holder for applications.  */
 127     KEEP (*(.fini4))    /* Runtime exit.  */
 128 "
 129
 130 PRE_COMPUTE_DATA_SIZE="
 131 /* SCz: this does not work yet... This is supposed to force the loading
 132    of _map_data.o (from libgcc.a) when the .data section is not empty.
 133    By doing so, this should bring the code that copies the .data section
 134    from ROM to RAM at init time.
 135
 136   ___pre_comp_data_size = SIZEOF(.data);
 137   __install_data_sections = ___pre_comp_data_size > 0 ?
 138                 __map_data_sections : 0;
 139 */
 140 "
 141
 142 INSTALL_RELOC="
 143   .install0 0 : { *(.install0) }
 144   .install1 0 : { *(.install1) }
 145   .install2 0 : { *(.install2) }
 146   .install3 0 : { *(.install3) }
 147   .install4 0 : { *(.install4) }
 148 "
 149
 150 FINISH_RELOC="
 151   .fini0 0 : { *(.fini0) }
 152   .fini1 0 : { *(.fini1) }
 153   .fini2 0 : { *(.fini2) }
 154   .fini3 0 : { *(.fini3) }
 155   .fini4 0 : { *(.fini4) }
 156 "
 157
 158 BSS_DATA_RELOC="
 159   .data1 0 : { *(.data1) }
 160
 161   /* We want the small data sections together, so single-instruction offsets
 162      can access them all, and initialized data all before uninitialized, so
 163      we can shorten the on-disk segment size.  */
 164   .sdata   0 : { *(.sdata) }
 165   .sbss    0 : { *(.sbss) }
 166   .scommon 0 : { *(.scommon) }
 167 "
 168
 169 SOFT_REGS_RELOC="
 170   .softregs 0 : { *(.softregs) }
 171 "
 172
 173 cat <<EOF
 174 ${RELOCATING+/* Linker script for 68HC11 executable (PROM).  */}
 175 ${RELOCATING-/* Linker script for 68HC11 object file (ld -r).  */}
 176
 177 OUTPUT_FORMAT("${OUTPUT_FORMAT}", "${BIG_OUTPUT_FORMAT}",
 178               "${LITTLE_OUTPUT_FORMAT}")
 179 OUTPUT_ARCH(${OUTPUT_ARCH})
 180 ENTRY(${ENTRY})
 181
 182 ${RELOCATING+${LIB_SEARCH_DIRS}}
 183 ${RELOCATING+${EXECUTABLE_SYMBOLS}}
 184 ${RELOCATING+${MEMORY_DEF}}
 185
 186 SECTIONS
 187 {
 188   .hash        ${RELOCATING-0} : { *(.hash)             }
 189   .dynsym      ${RELOCATING-0} : { *(.dynsym)           }
 190   .dynstr      ${RELOCATING-0} : { *(.dynstr)           }
 191   .gnu.version          ${RELOCATING-0} : { *(.gnu.version) }
 192   .gnu.version_d        ${RELOCATING-0} : { *(.gnu.version_d) }
 193   .gnu.version_r        ${RELOCATING-0} : { *(.gnu.version_r) }
 194
 195   .rel.text    ${RELOCATING-0} :
 196     {
 197       *(.rel.text)
 198       ${RELOCATING+*(.rel.text.*)}
 199       ${RELOCATING+*(.rel.gnu.linkonce.t.*)}
 200     }
 201   .rela.text   ${RELOCATING-0} :
 202     {
 203       *(.rela.text)
 204       ${RELOCATING+*(.rela.text.*)}
 205       ${RELOCATING+*(.rela.gnu.linkonce.t.*)}
 206     }
 207   .rel.data    ${RELOCATING-0} :
 208     {
 209       *(.rel.data)
 210       ${RELOCATING+*(.rel.data.*)}
 211       ${RELOCATING+*(.rel.gnu.linkonce.d.*)}
 212     }
 213   .rela.data   ${RELOCATING-0} :
 214     {
 215       *(.rela.data)
 216       ${RELOCATING+*(.rela.data.*)}
 217       ${RELOCATING+*(.rela.gnu.linkonce.d.*)}
 218     }
 219   .rel.rodata  ${RELOCATING-0} :
 220     {
 221       *(.rel.rodata)
 222       ${RELOCATING+*(.rel.rodata.*)}
 223       ${RELOCATING+*(.rel.gnu.linkonce.r.*)}
 224     }
 225   .rela.rodata ${RELOCATING-0} :
 226     {
 227       *(.rela.rodata)
 228       ${RELOCATING+*(.rela.rodata.*)}
 229       ${RELOCATING+*(.rela.gnu.linkonce.r.*)}
 230     }
 231   .rel.sdata   ${RELOCATING-0} :
 232     {
 233       *(.rel.sdata)
 234       ${RELOCATING+*(.rel.sdata.*)}
 235       ${RELOCATING+*(.rel.gnu.linkonce.s.*)}
 236     }
 237   .rela.sdata   ${RELOCATING-0} :
 238     {
 239       *(.rela.sdata)
 240       ${RELOCATING+*(.rela.sdata.*)}
 241       ${RELOCATING+*(.rela.gnu.linkonce.s.*)}
 242     }
 243   .rel.sbss    ${RELOCATING-0} :
 244     {
 245       *(.rel.sbss)
 246       ${RELOCATING+*(.rel.sbss.*)}
 247       ${RELOCATING+*(.rel.gnu.linkonce.sb.*)}
 248     }
 249   .rela.sbss   ${RELOCATING-0} :
 250     {
 251       *(.rela.sbss)
 252       ${RELOCATING+*(.rela.sbss.*)}
 253       ${RELOCATING+*(.rel.gnu.linkonce.sb.*)}
 254     }
 255   .rel.bss     ${RELOCATING-0} :
 256     {
 257       *(.rel.bss)
 258       ${RELOCATING+*(.rel.bss.*)}
 259       ${RELOCATING+*(.rel.gnu.linkonce.b.*)}
 260     }
 261   .rela.bss    ${RELOCATING-0} :
 262     {
 263       *(.rela.bss)
 264       ${RELOCATING+*(.rela.bss.*)}
 265       ${RELOCATING+*(.rela.gnu.linkonce.b.*)}
 266     }
 267   .rel.stext            ${RELOCATING-0} : { *(.rel.stest) }
 268   .rela.stext           ${RELOCATING-0} : { *(.rela.stest) }
 269   .rel.etext            ${RELOCATING-0} : { *(.rel.etest) }
 270   .rela.etext           ${RELOCATING-0} : { *(.rela.etest) }
 271   .rel.sdata            ${RELOCATING-0} : { *(.rel.sdata) }
 272   .rela.sdata           ${RELOCATING-0} : { *(.rela.sdata) }
 273   .rel.edata            ${RELOCATING-0} : { *(.rel.edata) }
 274   .rela.edata           ${RELOCATING-0} : { *(.rela.edata) }
 275   .rel.eit_v            ${RELOCATING-0} : { *(.rel.eit_v) }
 276   .rela.eit_v           ${RELOCATING-0} : { *(.rela.eit_v) }
 277   .rel.ebss             ${RELOCATING-0} : { *(.rel.ebss) }
 278   .rela.ebss            ${RELOCATING-0} : { *(.rela.ebss) }
 279   .rel.srodata          ${RELOCATING-0} : { *(.rel.srodata) }
 280   .rela.srodata         ${RELOCATING-0} : { *(.rela.srodata) }
 281   .rel.erodata          ${RELOCATING-0} : { *(.rel.erodata) }
 282   .rela.erodata         ${RELOCATING-0} : { *(.rela.erodata) }
 283   .rel.got              ${RELOCATING-0} : { *(.rel.got) }
 284   .rela.got             ${RELOCATING-0} : { *(.rela.got) }
 285   .rel.ctors            ${RELOCATING-0} : { *(.rel.ctors) }
 286   .rela.ctors           ${RELOCATING-0} : { *(.rela.ctors) }
 287   .rel.dtors            ${RELOCATING-0} : { *(.rel.dtors) }
 288   .rela.dtors           ${RELOCATING-0} : { *(.rela.dtors) }
 289   .rel.init             ${RELOCATING-0} : { *(.rel.init) }
 290   .rela.init            ${RELOCATING-0} : { *(.rela.init) }
 291   .rel.fini             ${RELOCATING-0} : { *(.rel.fini) }
 292   .rela.fini            ${RELOCATING-0} : { *(.rela.fini) }
 293   .rel.plt              ${RELOCATING-0} : { *(.rel.plt) }
 294   .rela.plt             ${RELOCATING-0} : { *(.rela.plt) }
 295
 296   /* Concatenate .page0 sections.  Put them in the page0 memory bank
 297      unless we are creating a relocatable file.  */
 298   .page0 :
 299   {
 300     *(.page0)
 301     ${RELOCATING+*(.softregs)}
 302   } ${RELOCATING+ > page0}
 303
 304   /* Start of text section.  */
 305   .stext ${RELOCATING-0} :
 306   {
 307     *(.stext)
 308   } ${RELOCATING+ > ${TEXT_MEMORY}}
 309
 310   .init ${RELOCATING-0} :
 311   {
 312     *(.init)
 313   } ${RELOCATING+=${NOP-0}}
 314
 315   ${RELOCATING-${INSTALL_RELOC}}
 316   ${RELOCATING-${FINISH_RELOC}}
 317
 318   .text ${RELOCATING-0}:
 319   {
 320     /* Put startup code at beginning so that _start keeps same address.  */
 321     ${RELOCATING+${STARTUP_CODE}}
 322
 323     ${RELOCATING+*(.init)}
 324     *(.text)
 325     ${RELOCATING+*(.text.*)}
 326     /* .gnu.warning sections are handled specially by elf32.em.  */
 327     *(.gnu.warning)
 328     ${RELOCATING+*(.gnu.linkonce.t.*)}
 329
 330     ${RELOCATING+${FINISH_CODE}}
 331
 332     ${RELOCATING+_etext = .;}
 333     ${RELOCATING+PROVIDE (etext = .);}
 334
 335   } ${RELOCATING+ > ${TEXT_MEMORY}}
 336
 337   .eh_frame ${RELOCATING-0} :
 338   {
 339     KEEP (*(.eh_frame))
 340   } ${RELOCATING+ > ${TEXT_MEMORY}}
 341
 342   .rodata  ${RELOCATING-0} :
 343   {
 344     *(.rodata)
 345     ${RELOCATING+*(.rodata.*)}
 346     ${RELOCATING+*(.gnu.linkonce.r*)}
 347   } ${RELOCATING+ > ${TEXT_MEMORY}}
 348
 349   .rodata1 ${RELOCATING-0} :
 350   {
 351     *(.rodata1)
 352   } ${RELOCATING+ > ${TEXT_MEMORY}}
 353
 354   /* Constructor and destructor tables are in ROM.  */
 355   ${RELOCATING+${CTOR}}
 356   ${RELOCATING+${DTOR}}
 357
 358   .jcr ${RELOCATING-0} :
 359   {
 360     KEEP (*(.jcr))
 361   } ${RELOCATING+ > ${TEXT_MEMORY}}
 362
 363   /* Start of the data section image in ROM.  */
 364   ${RELOCATING+__data_image = .;}
 365   ${RELOCATING+PROVIDE (__data_image = .);}
 366
 367   /* All read-only sections that normally go in PROM must be above.
 368      We construct the DATA image section in PROM at end of all these
 369      read-only sections.  The data image must be copied at init time.
 370      Refer to GNU ld, Section 3.6.8.2 Output Section LMA.  */
 371   .data  ${RELOCATING-0} : ${RELOCATING+AT (__data_image)}
 372   {
 373     ${RELOCATING+__data_section_start = .;}
 374     ${RELOCATING+PROVIDE (__data_section_start = .);}
 375
 376     ${RELOCATING+${DATA_START_SYMBOLS}}
 377     ${RELOCATING+*(.sdata)}
 378     *(.data)
 379     ${RELOCATING+*(.data.*)}
 380     ${RELOCATING+*(.data1)}
 381     ${RELOCATING+*(.gnu.linkonce.d.*)}
 382     ${CONSTRUCTING+CONSTRUCTORS}
 383
 384     ${RELOCATING+_edata  =  .;}
 385     ${RELOCATING+PROVIDE (edata = .);}
 386   } ${RELOCATING+ > ${DATA_MEMORY}}
 387
 388   ${RELOCATING+__data_section_size = SIZEOF(.data);}
 389   ${RELOCATING+PROVIDE (__data_section_size = SIZEOF(.data));}
 390   ${RELOCATING+__data_image_end = __data_image + __data_section_size;}
 391
 392   ${RELOCATING+${PRE_COMPUTE_DATA_SIZE}}
 393
 394   /* .install ${RELOCATING-0}:
 395   {
 396     . = _data_image_end;
 397   } ${RELOCATING+ > ${TEXT_MEMORY}} */
 398
 399   /* Relocation for some bss and data sections.  */
 400   ${RELOCATING-${BSS_DATA_RELOC}}
 401   ${RELOCATING-${SOFT_REGS_RELOC}}
 402
 403   .bss ${RELOCATING-0} :
 404   {
 405     ${RELOCATING+__bss_start = .;}
 406     ${RELOCATING+*(.sbss)}
 407     ${RELOCATING+*(.scommon)}
 408
 409     *(.dynbss)
 410     *(.bss)
 411     ${RELOCATING+*(.bss.*)}
 412     ${RELOCATING+*(.gnu.linkonce.b.*)}
 413     *(COMMON)
 414     ${RELOCATING+PROVIDE (_end = .);}
 415   } ${RELOCATING+ > ${DATA_MEMORY}}
 416   ${RELOCATING+__bss_size = SIZEOF(.bss);}
 417   ${RELOCATING+PROVIDE (__bss_size = SIZEOF(.bss));}
 418
 419   .eeprom ${RELOCATING-0} :
 420   {
 421     *(.eeprom)
 422     *(.eeprom.*)
 423   } ${RELOCATING+ > ${EEPROM_MEMORY}}
 424
 425   ${RELOCATING+${VECTORS}}
 426
 427   /* Stabs debugging sections.  */
 428   .stab          0 : { *(.stab) }
 429   .stabstr       0 : { *(.stabstr) }
 430   .stab.excl     0 : { *(.stab.excl) }
 431   .stab.exclstr  0 : { *(.stab.exclstr) }
 432   .stab.index    0 : { *(.stab.index) }
 433   .stab.indexstr 0 : { *(.stab.indexstr) }
 434
 435   .comment       0 : { *(.comment) }
 436
 437   /* DWARF debug sections.
 438      Symbols in the DWARF debugging sections are relative to the beginning
 439      of the section so we begin them at 0.
 440      Treatment of DWARF debug section must be at end of the linker
 441      script to avoid problems when there are undefined symbols. It's necessary
 442      to avoid that the DWARF section is relocated before such undefined
 443      symbols are found.  */
 444
 445   /* DWARF 1 */
 446   .debug         0 : { *(.debug) }
 447   .line          0 : { *(.line) }
 448
 449   /* GNU DWARF 1 extensions */
 450   .debug_srcinfo 0 : { *(.debug_srcinfo) }
 451   .debug_sfnames 0 : { *(.debug_sfnames) }
 452
 453   /* DWARF 1.1 and DWARF 2 */
 454   .debug_aranges  0 : { *(.debug_aranges) }
 455   .debug_pubnames 0 : { *(.debug_pubnames) }
 456
 457   /* DWARF 2 */
 458   .debug_info     0 : { *(.debug_info) *(.gnu.linkonce.wi.*) }
 459   .debug_abbrev   0 : { *(.debug_abbrev) }
 460   .debug_line     0 : { *(.debug_line) }
 461   .debug_frame    0 : { *(.debug_frame) }
 462   .debug_str      0 : { *(.debug_str) }
 463   .debug_loc      0 : { *(.debug_loc) }
 464   .debug_macinfo  0 : { *(.debug_macinfo) }
 465 }
 466 EOF