ld/configure.in

   1 dnl Process this file with autoconf to produce a configure script
   2 dnl
   3 AC_PREREQ(2.59)
   4 AC_INIT
   5 AC_CONFIG_SRCDIR(ldmain.c)
   6
   7 AC_CANONICAL_TARGET
   8 AC_ISC_POSIX
   9
  10 changequote(,)dnl
  11 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  12 changequote([,])dnl
  13 AM_INIT_AUTOMAKE(ld, ${BFD_VERSION})
  14 AM_MAINTAINER_MODE
  15
  16 AC_ARG_WITH(lib-path, [  --with-lib-path=dir1:dir2...  set default LIB_PATH],LIB_PATH=$withval)
  17 AC_ARG_ENABLE(targets,
  18 [  --enable-targets        alternative target configurations],
  19 [case "${enableval}" in
  20   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  21             ;;
  22   no)       enable_targets= ;;
  23   *)        enable_targets=$enableval ;;
  24 esac])dnl
  25 AC_ARG_ENABLE(64-bit-bfd,
  26 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  27 [case "${enableval}" in
  28   yes)  want64=true  ;;
  29   no)   want64=false ;;
  30   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  31 esac],[want64=false])dnl
  32
  33 AC_ARG_WITH(sysroot,
  34 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
  35 [
  36  case ${with_sysroot} in
  37  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
  38  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
  39  esac
  40
  41  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
  42  use_sysroot=yes
  43
  44  if test "x$prefix" = xNONE; then
  45   test_prefix=/usr/local
  46  else
  47   test_prefix=$prefix
  48  fi
  49  if test "x$exec_prefix" = xNONE; then
  50   test_exec_prefix=$test_prefix
  51  else
  52   test_exec_prefix=$exec_prefix
  53  fi
  54  case ${TARGET_SYSTEM_ROOT} in
  55  "${test_prefix}"|"${test_prefix}/"*|\
  56  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
  57  '${prefix}'|'${prefix}/'*|\
  58  '${exec_prefix}'|'${exec_prefix}/'*)
  59    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
  60    TARGET_SYSTEM_ROOT_DEFINE="$t"
  61    ;;
  62  esac
  63 ], [
  64  use_sysroot=no
  65  TARGET_SYSTEM_ROOT=
  66  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
  67 ])
  68 AC_SUBST(use_sysroot)
  69 AC_SUBST(TARGET_SYSTEM_ROOT)
  70 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
  71
  72 AC_ARG_ENABLE([got],
  73 AS_HELP_STRING([--enable-got=<type>],
  74                [GOT handling scheme (target, single, negative, multigot)]),
  75 [case "${enableval}" in
  76   target | single | negative | multigot)  got_handling=$enableval ;;
  77   *)  AC_MSG_ERROR(bad value ${enableval} for --enable-got option) ;;
  78 esac],
  79 [got_handling=target])
  80
  81 case "${got_handling}" in
  82   target)
  83     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_TARGET_DEFAULT],
  84               [Define to choose default GOT handling scheme]) ;;
  85   single)
  86     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_SINGLE],
  87               [Define to choose default GOT handling scheme]) ;;
  88   negative)
  89     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_NEGATIVE],
  90               [Define to choose default GOT handling scheme]) ;;
  91   multigot)
  92     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_MULTIGOT],
  93               [Define to choose default GOT handling scheme]) ;;
  94   *)  AC_MSG_ERROR(bad value ${got_handling} for --enable-got option) ;;
  95 esac
  96
  97 AM_BINUTILS_WARNINGS
  98
  99 AC_CONFIG_HEADERS([config.h:config.in])
 100
 101 if test -z "$target" ; then
 102     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
 103 fi
 104 if test -z "$host" ; then
 105     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
 106 fi
 107
 108 # host-specific stuff:
 109
 110 AC_PROG_CC
 111 AC_GNU_SOURCE
 112 AC_USE_SYSTEM_EXTENSIONS
 113 ACX_LARGEFILE
 114 AC_PROG_INSTALL
 115
 116 LT_INIT
 117
 118 ALL_LINGUAS="fr sv tr es da vi zh_CN zh_TW ga fi id"
 119 ZW_GNU_GETTEXT_SISTER_DIR
 120 AM_PO_SUBDIRS
 121
 122 AC_EXEEXT
 123
 124 AC_PROG_YACC
 125 AM_PROG_LEX
 126
 127 AM_MAINTAINER_MODE
 128 AM_CONDITIONAL(GENINSRC_NEVER, false)
 129 ACX_PROG_CMP_IGNORE_INITIAL
 130
 131 . ${srcdir}/configure.host
 132
 133 AC_SUBST(HDEFINES)
 134 AC_SUBST(HOSTING_CRT0)
 135 AC_SUBST(HOSTING_LIBS)
 136 AC_SUBST(NATIVE_LIB_DIRS)
 137
 138 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h elf-hints.h limits.h sys/param.h)
 139 AC_CHECK_FUNCS(glob mkstemp realpath sbrk waitpid)
 140 AC_HEADER_DIRENT
 141
 142 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 143 AC_CACHE_VAL(ld_cv_decl_getopt_unistd_h,
 144 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 145 ld_cv_decl_getopt_unistd_h=yes, ld_cv_decl_getopt_unistd_h=no)])
 146 AC_MSG_RESULT($ld_cv_decl_getopt_unistd_h)
 147 if test $ld_cv_decl_getopt_unistd_h = yes; then
 148   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 149             [Is the prototype for getopt in <unistd.h> in the expected format?])
 150 fi
 151
 152 BFD_BINARY_FOPEN
 153
 154 AC_CHECK_DECLS([strstr, free, sbrk, getenv, environ])
 155
 156 # Link in zlib if we can.  This is needed only for the bootstrap tests
 157 # right now, since those tests use libbfd, which depends on zlib.
 158 AC_SEARCH_LIBS(zlibVersion, z, [AC_CHECK_HEADERS(zlib.h)])
 159
 160 # When converting linker scripts into strings for use in emulation
 161 # files, use astring.sed if the compiler supports ANSI string
 162 # concatenation, or ostring.sed otherwise.  This is to support the
 163 # broken Microsoft MSVC compiler, which limits the length of string
 164 # constants, while still supporting pre-ANSI compilers which do not
 165 # support string concatenation.
 166 AC_MSG_CHECKING([whether ANSI C string concatenation works])
 167 AC_CACHE_VAL(ld_cv_string_concatenation,
 168 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [char *a = "a" "a";])],
 169   ld_cv_string_concatenation=yes,
 170   ld_cv_string_concatenation=no)])
 171 AC_MSG_RESULT($ld_cv_string_concatenation)
 172 if test "$ld_cv_string_concatenation" = "yes"; then
 173   STRINGIFY=astring.sed
 174 else
 175   STRINGIFY=ostring.sed
 176 fi
 177 AC_SUBST(STRINGIFY)
 178
 179 # target-specific stuff:
 180
 181 all_targets=
 182 EMUL=
 183 all_emuls=
 184 all_emul_extras=
 185 all_libpath=
 186
 187 dnl We need to get an arbitrary number of tdir definitions into
 188 dnl Makefile.  We can't do it using AC_SUBST, because autoconf does
 189 dnl not permit literal newlines in an AC_SUBST variables.  So we use a
 190 dnl file.
 191 rm -f tdirs
 192
 193 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 194 do
 195   if test "$targ_alias" = "all"; then
 196     all_targets=true
 197   else
 198     # Canonicalize the secondary target names.
 199     result=`$ac_config_sub $targ_alias 2>/dev/null`
 200     if test -n "$result"; then
 201         targ=$result
 202     else
 203         targ=$targ_alias
 204     fi
 205
 206     . ${srcdir}/configure.tgt
 207
 208     if test "$targ" = "$target"; then
 209       EMUL=$targ_emul
 210     fi
 211
 212     if test x${want64} = xfalse; then
 213       . ${srcdir}/../bfd/config.bfd
 214     fi
 215
 216     if test x${want64} = xtrue; then
 217       targ_extra_emuls="$targ_extra_emuls $targ64_extra_emuls"
 218       targ_extra_libpath="$targ_extra_libpath $targ64_extra_libpath"
 219     fi
 220
 221     for i in $targ_emul $targ_extra_emuls $targ_extra_libpath; do
 222         case " $all_emuls " in
 223         *" e${i}.o "*) ;;
 224         *)
 225           all_emuls="$all_emuls e${i}.o"
 226           eval result=\$tdir_$i
 227           test -z "$result" && result=$targ_alias
 228           echo tdir_$i=$result >> tdirs
 229           ;;
 230         esac
 231     done
 232
 233     for i in $targ_emul $targ_extra_libpath; do
 234         case " $all_libpath " in
 235         *" ${i} "*) ;;
 236         *)
 237           if test -z "$all_libpath"; then
 238             all_libpath=${i}
 239           else
 240             all_libpath="$all_libpath ${i}"
 241           fi
 242           ;;
 243         esac
 244     done
 245
 246     for i in $targ_extra_ofiles; do
 247         case " $all_emul_extras " in
 248         *" ${i} "*) ;;
 249         *)
 250           all_emul_extras="$all_emul_extras ${i}"
 251           ;;
 252         esac
 253     done
 254   fi
 255 done
 256
 257 AC_SUBST(EMUL)
 258
 259 TDIRS=tdirs
 260 AC_SUBST_FILE(TDIRS)
 261
 262 if test x${all_targets} = xtrue; then
 263   if test x${want64} = xfalse; then
 264     AC_CHECK_SIZEOF(long)
 265     if test "x${ac_cv_sizeof_long}" = "x8"; then
 266       want64=true
 267     fi
 268   fi
 269   if test x${want64} = xtrue; then
 270     EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)'
 271   else
 272     EMULATION_OFILES='$(ALL_EMULATIONS)'
 273   fi
 274   EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)'
 275 else
 276   EMULATION_OFILES=$all_emuls
 277   EMUL_EXTRA_OFILES=$all_emul_extras
 278 fi
 279 AC_SUBST(EMULATION_OFILES)
 280 AC_SUBST(EMUL_EXTRA_OFILES)
 281 AC_SUBST(LIB_PATH)
 282
 283 EMULATION_LIBPATH=$all_libpath
 284 AC_SUBST(EMULATION_LIBPATH)
 285
 286 if test x${enable_static} = xno; then
 287   TESTBFDLIB="--rpath ../bfd/.libs ../bfd/.libs/libbfd.so"
 288 else
 289   TESTBFDLIB="../bfd/.libs/libbfd.a"
 290 fi
 291 AC_SUBST(TESTBFDLIB)
 292
 293 target_vendor=${target_vendor=$host_vendor}
 294 case "$target_vendor" in
 295   hp) EXTRA_SHLIB_EXTENSION=".sl" ;;
 296   *)  EXTRA_SHLIB_EXTENSION= ;;
 297 esac
 298
 299 case "$target_os" in
 300   lynxos) EXTRA_SHLIB_EXTENSION=".a" ;;
 301 esac
 302
 303 if test x${EXTRA_SHLIB_EXTENSION} != x ; then
 304   AC_DEFINE_UNQUOTED(EXTRA_SHLIB_EXTENSION, "$EXTRA_SHLIB_EXTENSION",
 305    [Additional extension a shared object might have.])
 306 fi
 307
 308 dnl Required by html, pdf, install-pdf and install-html
 309 AC_SUBST(datarootdir)
 310 AC_SUBST(docdir)
 311 AC_SUBST(htmldir)
 312 AC_SUBST(pdfdir)
 313
 314 AC_CONFIG_FILES(Makefile po/Makefile.in:po/Make-in)
 315 AC_OUTPUT