gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 dnl v2.5 needed for --bindir et al
   8 AC_PREREQ(2.57)
   9 AC_INIT(as.h)
  10
  11 dnl Autoconf 2.57 will find the aux dir without this.  However, unless
  12 dnl we specify this explicitly, automake-1.7 will assume that ylwrap is in
  13 dnl gas/ instead of gas/../.
  14 AC_CONFIG_AUX_DIR(..)
  15 AC_CANONICAL_SYSTEM
  16 AC_ISC_POSIX
  17
  18 changequote(,)dnl
  19 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  20 changequote([,])dnl
  21 AM_INIT_AUTOMAKE(gas, ${BFD_VERSION})
  22
  23 AM_PROG_LIBTOOL
  24
  25 user_bfd_gas=
  26 AC_ARG_ENABLE(bfd-assembler,
  27 [  --enable-bfd-assembler  use BFD back end for writing object files],
  28 [case "${enableval}" in
  29   yes) need_bfd=yes user_bfd_gas=yes ;;
  30   no)  user_bfd_gas=no ;;
  31   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  32 esac])dnl
  33 AC_ARG_ENABLE(targets,
  34 [    targets            alternative target configurations besides the primary],
  35 [case "${enableval}" in
  36   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  37             ;;
  38   no)       enable_targets= ;;
  39   *)        enable_targets=$enableval ;;
  40 esac])dnl
  41 AC_ARG_ENABLE(commonbfdlib,
  42 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  43 [case "${enableval}" in
  44   yes) commonbfdlib=true ;;
  45   no)  commonbfdlib=false ;;
  46   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  47 esac])dnl
  48
  49 using_cgen=no
  50
  51 build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
  52 AC_ARG_ENABLE(build-warnings,
  53 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  54 [case "${enableval}" in
  55   yes)  ;;
  56   no)   build_warnings="-w";;
  57   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  58         build_warnings="${build_warnings} ${t}";;
  59   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  60         build_warnings="${t} ${build_warnings}";;
  61   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  62 esac
  63 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  64   echo "Setting warning flags = $build_warnings" 6>&1
  65 fi])dnl
  66 WARN_CFLAGS=""
  67 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  68     WARN_CFLAGS="${build_warnings}"
  69 fi
  70 AC_SUBST(WARN_CFLAGS)
  71
  72 # Generate a header file
  73 AM_CONFIG_HEADER(config.h:config.in)
  74
  75 # If we are on a DOS filesystem, we must use gdb.ini rather than
  76 # .gdbinit.
  77 case "${host}" in
  78   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-windows*)
  79     GDBINIT="gdb.ini"
  80     AC_CONFIG_FILES(gdb.ini:gdbinit.in)
  81     ;;
  82   *)
  83     GDBINIT=".gdbinit"
  84     AC_CONFIG_FILES(.gdbinit:gdbinit.in)
  85     ;;
  86 esac
  87 AC_SUBST(GDBINIT)
  88
  89 te_file=generic
  90
  91 # Makefile target for installing gas in $(tooldir)/bin.
  92 install_tooldir=install-exec-tooldir
  93
  94 canon_targets=""
  95 all_targets=no
  96 if test -n "$enable_targets" ; then
  97   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  98     if test $t = "all"; then
  99       all_targets=yes
 100       continue
 101     fi
 102     result=`$ac_config_sub $t 2>/dev/null`
 103     if test -n "$result" ; then
 104       canon_targets="$canon_targets $result"
 105 #    else
 106 #      # Permit "all", etc.  We don't support it yet though.
 107 #      canon_targets="$canon_targets $t"
 108     fi
 109   done
 110   GAS_UNIQ(canon_targets)
 111 fi
 112
 113 emulations=""
 114
 115 for this_target in $target $canon_targets ; do
 116
 117 changequote(,)dnl
 118     eval `echo $this_target | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/cpu=\1 vendor=\2 os=\3/'`
 119 changequote([,])dnl
 120
 121     # check for architecture variants
 122     arch=
 123     endian=
 124     case ${cpu} in
 125       am33_2.0)         cpu_type=mn10300 endian=little ;;
 126       alpha*)           cpu_type=alpha ;;
 127       arm*b|xscale*b|strongarm*b) cpu_type=arm endian=big ;;
 128       arm*|xscale*|strongarm*)    cpu_type=arm endian=little ;;
 129       c4x*)             cpu_type=tic4x ;;
 130       hppa*)            cpu_type=hppa ;;
 131 changequote(,)dnl
 132       i[3-7]86)         cpu_type=i386 arch=i386;;
 133       x86_64)           cpu_type=i386 arch=x86_64;;
 134       ia64)             cpu_type=ia64 ;;
 135       ip2k)             cpu_type=ip2k endian=big ;;
 136       iq2000)           cpu_type=iq2000 endian=big ;;
 137       m6811|m6812|m68hc12) cpu_type=m68hc11 ;;
 138       m680[012346]0)    cpu_type=m68k ;;
 139 changequote([,])dnl
 140       m68008)           cpu_type=m68k ;;
 141       m683??)           cpu_type=m68k ;;
 142       m5200)            cpu_type=m68k ;;
 143       m8*)              cpu_type=m88k ;;
 144       mips*el)          cpu_type=mips endian=little ;;
 145       mips*)            cpu_type=mips endian=big ;;
 146       or32*)            cpu_type=or32 endian=big ;;
 147       pjl*)             cpu_type=pj endian=little ;;
 148       pj*)              cpu_type=pj endian=big ;;
 149       powerpc*le*)      cpu_type=ppc endian=little ;;
 150       powerpc*)         cpu_type=ppc endian=big ;;
 151       rs6000*)          cpu_type=ppc ;;
 152       s390x*)           cpu_type=s390 arch=s390x ;;
 153       s390*)            cpu_type=s390 arch=s390 ;;
 154       sh5*)             cpu_type=sh64 endian=big ;;
 155       sh5le*)           cpu_type=sh64 endian=little ;;
 156       sh64*)            cpu_type=sh64 endian=big ;;
 157       sh64le*)          cpu_type=sh64 endian=little ;;
 158       sh*le)            cpu_type=sh endian=little ;;
 159       sh*)              cpu_type=sh endian=big ;;
 160       sparclite*)       cpu_type=sparc arch=sparclite ;;
 161       sparclet*)        cpu_type=sparc arch=sparclet ;;
 162       sparc64*)         cpu_type=sparc arch=v9-64 ;;
 163       sparc86x*)        cpu_type=sparc arch=sparc86x  ;;
 164       sparc*)           cpu_type=sparc arch=sparclite ;; # ??? See tc-sparc.c.
 165       v850*)            cpu_type=v850 ;;
 166       xtensa*)          cpu_type=xtensa arch=xtensa ;;
 167       m32r)             cpu_type=m32r target_cpu=m32r endian=big ;;
 168       m32rle)           cpu_type=m32r target_cpu=m32r endian=little ;;
 169       *)                cpu_type=${cpu} ;;
 170     esac
 171
 172     if test ${this_target} = $target ; then
 173       target_cpu_type=${cpu_type}
 174     elif test ${target_cpu_type} != ${cpu_type} ; then
 175       continue
 176     fi
 177
 178     generic_target=${cpu_type}-$vendor-$os
 179     dev=no
 180     bfd_gas=no
 181     em=generic
 182
 183     # assign object format
 184     case ${generic_target} in
 185       a29k-*-coff)                      fmt=coff ;;
 186       a29k-amd-udi)                     fmt=coff ;;
 187       a29k-amd-ebmon)                   fmt=coff ;;
 188       a29k-nyu-sym1)                    fmt=coff ;;
 189       a29k-*-rtems*)                    fmt=coff ;;
 190       a29k-*-vxworks*)                  fmt=coff ;;
 191
 192       alpha*-*-*vms*)                   fmt=evax ;;
 193       alpha*-*-netware*)                fmt=ecoff ;;
 194       alpha*-*-osf*)                    fmt=ecoff ;;
 195       alpha*-*-linuxecoff*)             fmt=ecoff ;;
 196       alpha*-*-linux-gnu*)              fmt=elf em=linux ;;
 197       alpha*-*-netbsd*)                 fmt=elf em=nbsd ;;
 198       alpha*-*-openbsd*)                fmt=elf em=obsd ;;
 199
 200       # cpu_type for am33_2.0 is set to mn10300
 201       mn10300-*-linux*)                 fmt=elf bfd_gas=yes em=linux ;;
 202
 203       arc-*-elf*)                       fmt=elf ;;
 204
 205       arm-*-aout)                       fmt=aout ;;
 206       arm-*-coff | thumb-*-coff)        fmt=coff ;;
 207       arm-*-rtems* | thumb-*-rtems*)    fmt=elf ;;
 208       arm-*-elf | thumb-*-elf)          fmt=elf ;;
 209       arm-*-kaos*)                      fmt=elf ;;
 210       arm*-*-conix*)                    fmt=elf ;;
 211       arm-*-linux*aout*)                fmt=aout em=linux ;;
 212       arm*-*-linux-gnu*)                fmt=elf  em=linux ;;
 213       arm*-*-uclinux*)                  fmt=elf  em=linux ;;
 214       arm-*-netbsdelf*)                 fmt=elf  em=nbsd ;;
 215       arm-*-*n*bsd*)                    fmt=aout em=nbsd ;;
 216       arm-**-nto*)                      fmt=elf ;;
 217       arm-*-oabi | thumb-*-oabi)        fmt=elf ;;
 218       arm-epoc-pe | thumb-epoc-pe)      fmt=coff em=epoc-pe ;;
 219       arm-wince-pe | arm-*-wince)       fmt=coff em=wince-pe ;;
 220       arm-*-pe | thumb-*-pe)            fmt=coff em=pe ;;
 221       arm-*-riscix*)                    fmt=aout em=riscix ;;
 222
 223       avr-*-*)                          fmt=elf ;;
 224
 225       cris-*-linux-gnu*)                fmt=multi bfd_gas=yes em=linux ;;
 226       cris-*-*)                         fmt=multi bfd_gas=yes ;;
 227
 228       d10v-*-*)                         fmt=elf ;;
 229       d30v-*-*)                         fmt=elf ;;
 230       dlx-*-*)                          fmt=elf ;;
 231
 232       fr30-*-*)                         fmt=elf ;;
 233       frv-*-*linux*)                    fmt=elf em=linux;;
 234       frv-*-*)                          fmt=elf ;;
 235
 236       hppa-*-linux*)    case ${cpu} in
 237                             hppa*64*)   fmt=elf em=hppalinux64;;
 238                             hppa*)      fmt=elf em=linux;;
 239                         esac ;;
 240       hppa-*-*elf*)                     fmt=elf em=hppa ;;
 241       hppa-*-lites*)                    fmt=elf em=hppa ;;
 242       hppa-*-netbsd*)                   fmt=elf em=nbsd ;;
 243       hppa-*-openbsd*)                  fmt=elf em=hppa ;;
 244       hppa-*-osf*)                      fmt=som em=hppa ;;
 245       hppa-*-rtems*)                    fmt=elf em=hppa ;;
 246       hppa-*-hpux11*)   case ${cpu} in
 247                             hppa*64*)   fmt=elf em=hppa64 ;;
 248                             hppa*)      fmt=som em=hppa ;;
 249                         esac ;;
 250       hppa-*-hpux*)                     fmt=som em=hppa ;;
 251       hppa-*-mpeix*)                    fmt=som em=hppa ;;
 252       hppa-*-bsd*)                      fmt=som em=hppa ;;
 253       hppa-*-hiux*)                     fmt=som em=hppa ;;
 254
 255       h8300-*-rtems*)                   fmt=coff ;;
 256       h8300-*-coff)                     fmt=coff ;;
 257       h8300-*-elf)                      fmt=elf ;;
 258       h8500-*-rtems*)                   fmt=coff ;;
 259       h8500-*-coff)                     fmt=coff ;;
 260
 261       i370-*-elf* | i370-*-linux*)      fmt=elf ;;
 262       i386-ibm-aix*)                    fmt=coff em=i386aix ;;
 263       i386-sequent-bsd*)                fmt=aout em=dynix ;;
 264       i386-*-beospe*)                   fmt=coff em=pe ;;
 265       i386-*-beos*)                     fmt=elf ;;
 266       i386-*-coff)                      fmt=coff ;;
 267       i386-*-elf)                       fmt=elf ;;
 268       i386-*-kaos*)                     fmt=elf ;;
 269       i386-*-bsd*)                      fmt=aout em=386bsd ;;
 270       i386-*-netbsd0.8)                 fmt=aout em=386bsd ;;
 271       i386-*-netbsdpe*)                 fmt=coff em=pe ;;
 272       i386-*-netbsd*-gnu* | \
 273       i386-*-knetbsd*-gnu | \
 274       i386-*-netbsdelf*)                fmt=elf em=nbsd ;;
 275       i386-*-*n*bsd*)   case ${cpu} in
 276                             x86_64)     fmt=elf em=nbsd ;;
 277                             *)          fmt=aout em=nbsd ;;
 278                         esac ;;
 279       i386-*-linux*aout*)               fmt=aout em=linux ;;
 280       i386-*-linux*oldld)               fmt=aout em=linux ;;
 281       i386-*-linux*coff*)               fmt=coff em=linux ;;
 282       i386-*-linux-gnu*)                fmt=elf em=linux ;;
 283       x86_64-*-linux-gnu*)              fmt=elf em=linux ;;
 284       i386-*-lynxos*)                   fmt=elf em=lynx bfd_gas=yes ;;
 285 changequote(,)dnl
 286       i386-*-sysv[45]*)                 fmt=elf ;;
 287       i386-*-solaris*)                  fmt=elf ;;
 288       i386-*-freebsdaout*)              fmt=aout em=386bsd ;;
 289       i386-*-freebsd[12].*)             fmt=aout em=386bsd ;;
 290       i386-*-freebsd[12])               fmt=aout em=386bsd ;;
 291 changequote([,])dnl
 292       i386-*-freebsd* | i386-*-kfreebsd*-gnu)
 293                                         fmt=elf em=freebsd ;;
 294       i386-*-sysv*)                     fmt=coff ;;
 295       i386-*-sco3.2v5*coff)             fmt=coff ;;
 296       i386-*-isc*)                      fmt=coff ;;
 297       i386-*-sco3.2v5*)                 fmt=elf
 298           if test ${this_target} = $target; then
 299             AC_DEFINE(SCO_ELF, 1, [Define if defaulting to ELF on SCO 5.])
 300           fi ;;
 301       i386-*-sco3.2*)                   fmt=coff ;;
 302       i386-*-vsta)                      fmt=aout ;;
 303       i386-*-msdosdjgpp* \
 304       | i386-*-go32* \
 305       | i386-go32-rtems*)               fmt=coff em=go32
 306             AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?]) ;;
 307       i386-*-rtemself*)                 fmt=elf ;;
 308       i386-*-rtemscoff*)                fmt=coff ;;
 309       i386-*-rtems*)                    fmt=elf ;;
 310       i386-*-gnu*)                      fmt=elf ;;
 311       i386-*-mach*)                     fmt=aout em=mach ;;
 312       i386-*-msdos*)                    fmt=aout ;;
 313       i386-*-moss*)                     fmt=elf ;;
 314       i386-*-pe)                        fmt=coff em=pe ;;
 315       i386-*-cygwin*)                   fmt=coff em=pe ;;
 316       i386-*-interix*)                  fmt=coff em=interix ;;
 317       i386-*-mingw32*)                  fmt=coff em=pe ;;
 318       i386-*-nto-qnx*)                  fmt=elf ;;
 319       i386-*-*nt*)                      fmt=coff em=pe ;;
 320       i386-*-chaos)                     fmt=elf ;;
 321
 322       i860-*-*)                         fmt=elf endian=little
 323                 AC_MSG_WARN(GAS support for ${generic_target} is preliminary and a work in progress) ;;
 324       i960-*-bout)                      fmt=bout ;;
 325       i960-*-coff)                      fmt=coff em=ic960 ;;
 326       i960-*-rtems*)                    fmt=coff em=ic960 ;;
 327       i960-*-nindy*)                    fmt=bout ;;
 328       i960-*-vxworks5.0)                fmt=bout ;;
 329       i960-*-vxworks5.*)                fmt=coff em=ic960 ;;
 330       i960-*-vxworks*)                  fmt=bout ;;
 331       i960-*-elf*)                      fmt=elf ;;
 332
 333       ia64-*-elf*)                      fmt=elf ;;
 334       ia64-*-aix*)                      fmt=elf em=ia64aix ;;
 335       ia64-*-linux-gnu*)                fmt=elf em=linux ;;
 336       ia64-*-hpux*)                     fmt=elf em=hpux ;;
 337       ia64-*-netbsd*)                   fmt=elf em=nbsd ;;
 338
 339       ip2k-*-*)                         fmt=elf ;;
 340
 341       iq2000-*-elf)                     fmt=elf bfd_gas=yes ;;
 342
 343       m32r-*-elf*)                      fmt=elf ;;
 344       m32r-*-linux*)                    fmt=elf em=linux;;
 345
 346       m68hc11-*-* | m6811-*-*)          fmt=elf ;;
 347       m68hc12-*-* | m6812-*-*)          fmt=elf ;;
 348
 349       m68k-*-vxworks*)                  fmt=aout em=sun3 ;;
 350       m68k-ericsson-ose)                fmt=aout em=sun3 ;;
 351       m68k-*-sunos*)                    fmt=aout em=sun3 ;;
 352       m68k-motorola-sysv*)              fmt=coff em=delta ;;
 353       m68k-bull-sysv3*)                 fmt=coff em=dpx2 ;;
 354       m68k-apollo-*)                    fmt=coff em=apollo ;;
 355       m68k-*-elf*)                      fmt=elf ;;
 356       m68k-*-sysv4*)                    fmt=elf em=svr4 ;;
 357       m68k-*-sysv*)                     fmt=coff ;;
 358       m68k-*-coff | m68k-*-rtemscoff*)  fmt=coff ;;
 359       m68k-*-rtems*)                    fmt=elf ;;
 360       m68k-*-hpux*)                     fmt=hp300 em=hp300 ;;
 361       m68k-*-linux*aout*)               fmt=aout em=linux ;;
 362       m68k-*-linux-gnu*)                fmt=elf em=linux ;;
 363       m68k-*-uclinux*)                  fmt=elf ;;
 364       m68k-*-gnu*)                      fmt=elf ;;
 365       m68k-*-lynxos*)                   fmt=coff em=lynx ;;
 366       m68k-*-netbsdelf*)                fmt=elf em=nbsd ;;
 367       m68k-*-netbsd*)                   fmt=aout em=nbsd bfd_gas=yes ;;
 368       m68k-*-openbsd*)                  fmt=aout em=nbsd bfd_gas=yes ;;
 369       m68k-apple-aux*)                  fmt=coff em=aux ;;
 370       m68k-*-psos*)                     fmt=elf em=psos;;
 371
 372       m88k-motorola-sysv3*)             fmt=coff em=delt88 ;;
 373       m88k-*-coff*)                     fmt=coff ;;
 374
 375       mcore-*-elf)                      fmt=elf ;;
 376       mcore-*-pe)                       fmt=coff em=pe bfd_gas=yes ;;
 377
 378       # don't change em like *-*-bsd does
 379       mips-dec-openbsd*)                fmt=elf endian=little ;;
 380       mips-sony-bsd*)                   fmt=ecoff ;;
 381       mips-*-bsd*)
 382             AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.) ;;
 383       mips-*-ultrix*)                   fmt=ecoff endian=little ;;
 384       mips-*-osf*)                      fmt=ecoff endian=little ;;
 385       mips-*-ecoff*)                    fmt=ecoff ;;
 386       mips-*-pe*)                       fmt=coff endian=little em=pe ;;
 387       mips-*-irix6*)                    fmt=elf em=irix ;;
 388       mips-*-irix5*)                    fmt=elf em=irix ;;
 389       mips-*-irix*)                     fmt=ecoff em=irix ;;
 390       mips-*-lnews*)                    fmt=ecoff em=lnews ;;
 391       mips-*-riscos*)                   fmt=ecoff ;;
 392       mips*-*-linux*)                   fmt=elf em=tmips ;;
 393       mips-*-sysv4*MP* | mips-*-gnu*)   fmt=elf em=tmips ;;
 394       mips-*-sysv*)                     fmt=ecoff ;;
 395       mips-*-elf* | mips-*-rtems*)      fmt=elf ;;
 396       mips-*-netbsd*)                   fmt=elf ;;
 397       mips-*-openbsd*)                  fmt=elf ;;
 398
 399       mmix-*-*)                         fmt=elf ;;
 400       mn10200-*-*)                      fmt=elf ;;
 401       mn10300-*-*)                      fmt=elf ;;
 402       msp430-*-*)                       fmt=elf ;;
 403       openrisc-*-*)                     fmt=elf ;;
 404       or32-*-rtems*)                    fmt=elf ;;
 405       or32-*-coff)                      fmt=coff ;;
 406       or32-*-elf)                       fmt=elf ;;
 407       pj*)                              fmt=elf ;;
 408
 409       ppc-*-pe | ppc-*-cygwin*)         fmt=coff em=pe ;;
 410       ppc-*-winnt*)                     fmt=coff em=pe ;;
 411 changequote(,)dnl
 412       ppc-*-aix5.[01])                  fmt=coff em=aix5 ;;
 413 changequote([,])dnl
 414       ppc-*-aix5.*)                     fmt=coff em=aix5
 415         AC_DEFINE(AIX_WEAK_SUPPORT, 1,
 416                   [Define if using AIX 5.2 value for C_WEAKEXT.])
 417       ;;
 418       ppc-*-aix*)                       fmt=coff ;;
 419       ppc-*-beos*)                      fmt=coff ;;
 420       ppc-*-*n*bsd* | ppc-*-elf*)       fmt=elf ;;
 421       ppc-*-eabi* | ppc-*-sysv4*)       fmt=elf ;;
 422       ppc-*-linux-gnu*)                 fmt=elf em=linux
 423             case "$endian" in
 424                 big)  ;;
 425                 *)    AC_MSG_ERROR(GNU/Linux must be configured big endian) ;;
 426             esac ;;
 427       ppc-*-solaris*)                   fmt=elf
 428             if test ${this_target} = $target; then
 429                 AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 430                           [Define if default target is PowerPC Solaris.])
 431             fi
 432             if test x${endian} = xbig; then
 433                 AC_MSG_ERROR(Solaris must be configured little endian)
 434             fi ;;
 435       ppc-*-rtems*)                     fmt=elf ;;
 436       ppc-*-macos*)                     fmt=coff em=macos ;;
 437       ppc-*-netware*)                   fmt=elf em=ppcnw ;;
 438       ppc-*-nto*)                       fmt=elf ;;
 439       ppc-*-kaos*)                      fmt=elf ;;
 440       ppc-*-lynxos*)                    fmt=elf em=lynx bfd_gas=yes ;;
 441
 442       s390x-*-linux-gnu*)               fmt=elf em=linux ;;
 443       s390-*-linux-gnu*)                fmt=elf em=linux ;;
 444
 445       sh*-*-linux*)                     fmt=elf em=linux
 446             case ${cpu} in
 447                 sh*eb)  endian=big ;;
 448                 *)      endian=little ;;
 449             esac ;;
 450       sh5*-*-netbsd*)                   fmt=elf em=nbsd ;;
 451       sh64*-*-netbsd*)                  fmt=elf em=nbsd ;;
 452       sh*-*-netbsdelf*)                 fmt=elf em=nbsd ;;
 453       sh-*-elf*)                        fmt=elf ;;
 454       sh-*-coff*)                       fmt=coff ;;
 455       sh-*-nto*)                        fmt=elf ;;
 456       sh-*-pe*)                         fmt=coff em=pe bfd_gas=yes endian=little ;;
 457       sh-*-rtemscoff*)                  fmt=coff ;;
 458       sh-*-rtems*)                      fmt=elf ;;
 459       sh-*-kaos*)                       fmt=elf ;;
 460       shle*-*-kaos*)                    fmt=elf ;;
 461       sh64-*-elf*)                      fmt=elf ;;
 462
 463       ns32k-pc532-mach*)                fmt=aout em=pc532mach ;;
 464       ns32k-pc532-ux*)                  fmt=aout em=pc532mach ;;
 465       ns32k-pc532-lites*)               fmt=aout em=nbsd532 ;;
 466       ns32k-*-*n*bsd*)                  fmt=aout em=nbsd532 ;;
 467
 468       sparc-*-rtemsaout*)               fmt=aout ;;
 469       sparc-*-rtemself*)                fmt=elf ;;
 470       sparc-*-rtems*)                   fmt=elf ;;
 471       sparc-*-sunos4*)                  fmt=aout em=sun3 ;;
 472       sparc-*-aout | sparc*-*-vxworks*) fmt=aout em=sparcaout ;;
 473       sparc-*-coff)                     fmt=coff ;;
 474       sparc-*-linux*aout*)              fmt=aout em=linux ;;
 475       sparc-*-linux-gnu*)               fmt=elf em=linux ;;
 476       sparc-*-lynxos*)                  fmt=coff em=lynx ;;
 477       sparc-fujitsu-none)               fmt=aout ;;
 478       sparc-*-elf)                      fmt=elf ;;
 479       sparc-*-sysv4*)                   fmt=elf ;;
 480       sparc-*-solaris*)                 fmt=elf ;;
 481       sparc-*-netbsdelf*)               fmt=elf em=nbsd ;;
 482       sparc-*-*n*bsd*)  case ${cpu} in
 483                             sparc64)    fmt=elf em=nbsd ;;
 484                             *)          fmt=aout em=nbsd ;;
 485                         esac ;;
 486       strongarm-*-coff)                 fmt=coff ;;
 487       strongarm-*-elf)                  fmt=elf ;;
 488       strongarm-*-kaos*)                fmt=elf ;;
 489       xscale-*-coff)                    fmt=coff ;;
 490       xscale-*-elf)                     fmt=elf ;;
 491
 492       tic30-*-*aout*)                   fmt=aout bfd_gas=yes ;;
 493       tic30-*-*coff*)                   fmt=coff bfd_gas=yes ;;
 494       tic4x-*-* | c4x-*-*)              fmt=coff bfd_gas=yes ;;
 495       tic54x-*-* | c54x*-*-*)           fmt=coff bfd_gas=yes need_libm=yes;;
 496       tic80-*-*)                        fmt=coff ;;
 497
 498       v850-*-*)                         fmt=elf ;;
 499       v850e-*-*)                        fmt=elf ;;
 500       v850ea-*-*)                       fmt=elf ;;
 501
 502       vax-*-netbsdelf*)                 fmt=elf em=nbsd ;;
 503       vax-*-netbsd*)                    fmt=aout em=nbsd ;;
 504       vax-*-bsd* | vax-*-ultrix*)       fmt=aout ;;
 505       vax-*-linux-gnu*)                 fmt=elf em=linux bfd_gas=yes ;;
 506       vax-*-vms)                        fmt=vms ;;
 507
 508       w65-*-*)                          fmt=coff ;;
 509
 510       xstormy16-*-*)                    fmt=elf ;;
 511
 512       xtensa-*-*)                       fmt=elf ;;
 513
 514       z8k-*-coff | z8k-*-sim)           fmt=coff ;;
 515
 516       *-*-aout | *-*-scout)             fmt=aout ;;
 517       *-*-freebsd* | *-*-kfreebsd*-gnu) fmt=elf em=freebsd ;;
 518       *-*-nindy*)                       fmt=bout ;;
 519       *-*-bsd*)                         fmt=aout em=sun3 ;;
 520       *-*-generic)                      fmt=generic ;;
 521       *-*-xray | *-*-hms)               fmt=coff ;;
 522       *-*-sim)                          fmt=coff ;;
 523       *-*-elf | *-*-sysv4* | *-*-solaris*) fmt=elf dev=yes ;;
 524       *-*-aros*)                        fmt=elf em=linux bfd_gas=yes ;;
 525       *-*-vxworks | *-*-windiss)        fmt=elf ;;
 526       *-*-netware)                      fmt=elf ;;
 527     esac
 528
 529     if test ${this_target} = $target ; then
 530       endian_def=
 531       if test x${endian} = xbig; then
 532         endian_def=1
 533       elif test x${endian} = xlittle; then
 534         endian_def=0
 535       fi
 536       if test x${endian_def} != x; then
 537         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 538                            [Define as 1 if big endian.])
 539       fi
 540     fi
 541
 542     case ${cpu_type}-${fmt} in
 543         alpha*-* | arm-* | i386-* | ia64*-* | mips-* | ns32k-* \
 544                 | pdp11-* | ppc-* | sparc-* | strongarm-* | xscale-* \
 545                 | *-elf | *-ecoff | *-som)
 546             bfd_gas=yes ;;
 547     esac
 548
 549 # Other random stuff.
 550
 551     case ${cpu_type} in
 552       mips)
 553         # Set mips_cpu to the name of the default CPU.
 554         case ${target_cpu} in
 555           mips | mipsbe | mipseb | mipsle | mipsel | mips64 | mips64el)
 556             mips_cpu=from-abi
 557             ;;
 558           mipsisa32 | mipsisa32el)
 559             mips_cpu=mips32
 560             ;;
 561           mipsisa32r2 | mipsisa32r2el)
 562             mips_cpu=mips32r2
 563             ;;
 564           mipsisa64 | mipsisa64el)
 565             mips_cpu=mips64
 566             ;;
 567           mipsisa64r2 | mipsisa64r2el)
 568             mips_cpu=mips64r2
 569             ;;
 570           mipstx39 | mipstx39el)
 571             mips_cpu=r3900
 572             ;;
 573           mips64vr | mips64vrel)
 574             mips_cpu=vr4100
 575             ;;
 576           mipsisa32r2* | mipsisa64r2*)
 577 changequote(,)dnl
 578             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r2//' -e 's/el$//'`
 579 changequote([,])dnl
 580             ;;
 581           mips64* | mipsisa64* | mipsisa32*)
 582 changequote(,)dnl
 583             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..//' -e 's/el$//'`
 584 changequote([,])dnl
 585             ;;
 586           *)
 587             AC_ERROR($target_cpu isn't a supported MIPS CPU name)
 588             ;;
 589         esac
 590         # See whether it's appropriate to set E_MIPS_ABI_O32 for o32
 591         # binaries.  It's a GNU extension that some OSes don't understand.
 592         # The value only matters on ELF targets.
 593         case ${target} in
 594           *-*-irix*)
 595             use_e_mips_abi_o32=0
 596             ;;
 597           *)
 598             use_e_mips_abi_o32=1
 599             ;;
 600         esac
 601         # Decide whether to generate 32-bit or 64-bit code by default.
 602         # Used to resolve -march=from-abi when an embedded ABI is selected.
 603         case ${target} in
 604           mips64*-*-* | mipsisa64*-*-*)
 605             mips_default_64bit=1
 606             ;;
 607           *)
 608             mips_default_64bit=0
 609             ;;
 610         esac
 611         # Decide which ABI to target by default.
 612         case ${target} in
 613           mips64*-linux* | mips-sgi-irix6*)
 614             mips_default_abi=N32_ABI
 615             ;;
 616           mips*-linux*)
 617             mips_default_abi=O32_ABI
 618             ;;
 619           *)
 620             mips_default_abi=NO_ABI
 621             ;;
 622         esac
 623         AC_DEFINE_UNQUOTED(MIPS_CPU_STRING_DEFAULT, "$mips_cpu",
 624                            [Default CPU for MIPS targets. ])
 625         AC_DEFINE_UNQUOTED(USE_E_MIPS_ABI_O32, $use_e_mips_abi_o32,
 626                            [Allow use of E_MIPS_ABI_O32 on MIPS targets. ])
 627         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_64BIT, $mips_default_64bit,
 628                            [Generate 64-bit code by default on MIPS targets. ])
 629         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_ABI, $mips_default_abi,
 630                            [Choose a default ABI for MIPS targets. ])
 631         ;;
 632     esac
 633
 634     # Do we need the opcodes library?
 635     case ${cpu_type} in
 636       vax | i386 | tic30)
 637         ;;
 638
 639       *)
 640         need_opcodes=yes
 641
 642         case "${enable_shared}" in
 643         yes) shared_opcodes=true ;;
 644         *opcodes*) shared_opcodes=true ;;
 645         *) shared_opcodes=false ;;
 646         esac
 647         if test "${shared_opcodes}" = "true"; then
 648           # A shared libopcodes must be linked against libbfd.
 649           need_bfd=yes
 650         fi
 651         ;;
 652     esac
 653
 654     # Any other special object files needed ?
 655     case ${cpu_type} in
 656       fr30 | ip2k | iq2000 | m32r | openrisc)
 657         using_cgen=yes
 658         ;;
 659
 660       frv)
 661         using_cgen=yes
 662         ;;
 663       m68k)
 664         case ${extra_objects} in
 665         *m68k-parse.o*) ;;
 666         *) extra_objects="$extra_objects m68k-parse.o" ;;
 667         esac
 668         ;;
 669
 670       mips)
 671         echo ${extra_objects} | grep -s "itbl-parse.o"
 672         if test $? -ne 0 ; then
 673           extra_objects="$extra_objects itbl-parse.o"
 674         fi
 675
 676         echo ${extra_objects} | grep -s "itbl-lex.o"
 677         if test $? -ne 0 ; then
 678           extra_objects="$extra_objects itbl-lex.o"
 679         fi
 680
 681         echo ${extra_objects} | grep -s "itbl-ops.o"
 682         if test $? -ne 0 ; then
 683           extra_objects="$extra_objects itbl-ops.o"
 684         fi
 685         ;;
 686
 687       i386 | s390 | sparc)
 688         if test $this_target = $target ; then
 689           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 690         fi
 691         ;;
 692
 693       xstormy16)
 694         using_cgen=yes
 695         ;;
 696
 697       xtensa)
 698         echo ${extra_objects} | grep -s "xtensa-relax.o"
 699         if test $? -ne 0 ; then
 700           extra_objects="$extra_objects xtensa-relax.o"
 701         fi
 702         ;;
 703
 704       *)
 705         ;;
 706     esac
 707
 708     if test $using_cgen = yes ; then
 709         case "x${extra_objects}" in
 710         *cgen.o*) ;;
 711         *) extra_objects="$extra_objects cgen.o" ;;
 712         esac
 713     fi
 714
 715 # See if we really can support this configuration with the emulation code.
 716
 717     if test $this_target = $target ; then
 718       primary_bfd_gas=$bfd_gas
 719       obj_format=$fmt
 720       te_file=$em
 721
 722       if test $bfd_gas = no ; then
 723         # Can't support other configurations this way.
 724         break
 725       fi
 726     elif test $bfd_gas = no ; then
 727       # Can't support this configuration.
 728       break
 729     fi
 730
 731 # From target name and format, produce a list of supported emulations.
 732
 733     case ${generic_target}-${fmt} in
 734       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 735       mips*-*-linux*-*) case "$endian" in
 736                         big)    emulation="mipsbelf mipslelf mipself" ;;
 737                         *)      emulation="mipslelf mipsbelf mipself" ;;
 738                         esac ;;
 739       mips-*-lnews*-ecoff) ;;
 740       mips-*-*-ecoff)   case "$endian" in
 741                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 742                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 743                         esac ;;
 744       mips-*-*-elf)     case "$endian" in
 745                         big)    emulation="mipsbelf mipslelf mipself" ;;
 746                         *)      emulation="mipslelf mipsbelf mipself" ;;
 747                         esac ;;
 748       mips-*-sysv4*MP*-*) emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 749       # i386-pc-pe-coff != i386-pc-coff.
 750       i386-*-pe-coff)   ;;
 751       # Uncommenting the next line will turn on support for i386 AOUT
 752       # for the default linux configuration
 753       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 754       #
 755       i386-*-aout)      emulation="i386aout" ;;
 756       i386-*-coff)      emulation="i386coff" ;;
 757       i386-*-elf)       emulation="i386elf" ;;
 758
 759       # Always all formats.  The first stated emulation becomes the default.
 760       cris-*-*aout*)    emulation="crisaout criself" ;;
 761       cris-*-*)         emulation="criself crisaout" ;;
 762     esac
 763
 764     emulations="$emulations $emulation"
 765
 766 done
 767
 768 # Turn on all targets if possible
 769 if test ${all_targets} = "yes"; then
 770   case ${target_cpu_type} in
 771   i386)
 772     case ${obj_format} in
 773     aout)
 774       emulations="$emulations i386coff i386elf"
 775       ;;
 776     coff)
 777       emulations="$emulations i386aout i386elf"
 778     ;;
 779     elf)
 780       emulations="$emulations i386aout i386coff"
 781       ;;
 782     esac
 783   ;;
 784   esac
 785 fi
 786
 787 # Assign floating point type.  Most processors with FP support
 788 # IEEE FP.  On those that don't support FP at all, usually IEEE
 789 # is emulated.
 790 case ${target_cpu} in
 791   vax | tahoe ) atof=${target_cpu} ;;
 792   pdp11)        atof=vax ;;
 793   *)            atof=ieee ;;
 794 esac
 795
 796 case "${obj_format}" in
 797   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 798 esac
 799
 800 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 801 cgen_cpu_prefix=""
 802 if test $using_cgen = yes ; then
 803   case ${target_cpu} in
 804     *) cgen_cpu_prefix=${target_cpu} ;;
 805   esac
 806   AC_SUBST(cgen_cpu_prefix)
 807   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 808 fi
 809
 810 dnl
 811 dnl Make sure the desired support files exist.
 812 dnl
 813
 814 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 815   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 816 fi
 817
 818 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 819   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 820 fi
 821
 822 case ${user_bfd_gas}-${primary_bfd_gas} in
 823   yes-yes | no-no)
 824     # We didn't override user's choice.
 825     ;;
 826   no-yes)
 827     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 828     ;;
 829   no-preferred)
 830     primary_bfd_gas=no
 831     ;;
 832   *-preferred)
 833     primary_bfd_gas=yes
 834     ;;
 835   yes-*)
 836     primary_bfd_gas=yes
 837     ;;
 838   -*)
 839     # User specified nothing.
 840     ;;
 841 esac
 842
 843 # Some COFF configurations want these random other flags set.
 844 case ${obj_format} in
 845   coff)
 846     case ${target_cpu_type} in
 847       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 848       m68k) AC_DEFINE(M68KCOFF, 1, [Using m68k COFF?]) ;;
 849       m88k) AC_DEFINE(M88KCOFF, 1, [Using m88k COFF?]) ;;
 850     esac
 851     ;;
 852 esac
 853
 854 # Getting this done right is going to be a bitch.  Each configuration specified
 855 # with --enable-targets=... should be checked for environment, format, cpu, and
 856 # bfd_gas setting.
 857 #
 858 # For each configuration, the necessary object file support code must be linked
 859 # in.  This might be only one, it might be up to four.  The necessary emulation
 860 # code needs to be provided, too.
 861 #
 862 # And then there's "--enable-targets=all"....
 863 #
 864 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 865
 866 formats="${obj_format}"
 867 emfiles=""
 868 EMULATIONS=""
 869 GAS_UNIQ(emulations)
 870 for em in . $emulations ; do
 871   case $em in
 872     .)  continue ;;
 873     mipsbelf | mipslelf | mipself)
 874         fmt=elf   file=mipself ;;
 875     mipsbecoff | mipslecoff | mipsecoff)
 876         fmt=ecoff file=mipsecoff ;;
 877     *coff)
 878         fmt=coff  file=$em ;;
 879     *aout)
 880         fmt=aout file=$em ;;
 881     *elf)
 882         fmt=elf file=$em ;;
 883   esac
 884   formats="$formats $fmt"
 885   emfiles="$emfiles e-$file.o"
 886   EMULATIONS="$EMULATIONS &$em,"
 887 done
 888 GAS_UNIQ(formats)
 889 GAS_UNIQ(emfiles)
 890 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 891   for fmt in $formats ; do
 892     case $fmt in
 893       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 894       bout)     AC_DEFINE(OBJ_MAYBE_BOUT, 1,    [b.out support?])   ;;
 895       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 896       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 897       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 898       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 899       hp300)    AC_DEFINE(OBJ_MAYBE_HP300, 1,   [HP300 support?])   ;;
 900       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE, 1,    [IEEE support?])    ;;
 901       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 902       vms)      AC_DEFINE(OBJ_MAYBE_VMS, 1,     [VMS support?])     ;;
 903     esac
 904     extra_objects="$extra_objects obj-$fmt.o"
 905   done
 906   obj_format=multi
 907 fi
 908 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 909   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 910   # e-mips* has more than one emulation per file, e-i386* has just one at the
 911   # moment.  If only one emulation is specified, then don't define
 912   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 913   case "${obj_format}${emfiles}" in
 914     multi* | *mips*)
 915       extra_objects="$extra_objects $emfiles"
 916       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 917   esac
 918 fi
 919 AC_SUBST(extra_objects)
 920 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 921 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 922                    [Default emulation.])
 923
 924 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 925   yes-*-coff)   need_bfd=yes ;;
 926   no-*-coff)    need_bfd=yes
 927                 AC_DEFINE(MANY_SEGMENTS, 1, [old COFF support?]) ;;
 928 esac
 929
 930 reject_dev_configs=yes
 931
 932 case ${reject_dev_configs}-${dev} in
 933   yes-yes) # Oops.
 934     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 935     ;;
 936 esac
 937
 938 AC_SUBST(target_cpu_type)
 939 AC_SUBST(obj_format)
 940 AC_SUBST(te_file)
 941 AC_SUBST(install_tooldir)
 942 AC_SUBST(atof)
 943 dnl AC_SUBST(emulation)
 944
 945 case "${primary_bfd_gas}" in
 946   yes)  AC_DEFINE(BFD_ASSEMBLER, 1, [Use BFD interface?])
 947         need_bfd=yes ;;
 948 esac
 949
 950 # do we need the opcodes library?
 951 case "${need_opcodes}" in
 952 yes)
 953   OPCODES_LIB=../opcodes/libopcodes.la
 954   ;;
 955 esac
 956
 957 case "${need_bfd}" in
 958 yes)
 959   BFDLIB=../bfd/libbfd.la
 960   BFDVER_H=../bfd/bfdver.h
 961   ALL_OBJ_DEPS="$ALL_OBJ_DEPS"' ../bfd/bfd.h $(INCDIR)/symcat.h'
 962   ;;
 963 esac
 964
 965 AC_SUBST(BFDLIB)
 966 AC_SUBST(OPCODES_LIB)
 967
 968 AC_SUBST(BFDVER_H)
 969 AC_SUBST(ALL_OBJ_DEPS)
 970
 971 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 972 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 973 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 974 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 975 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 976
 977 AC_PROG_CC
 978
 979 AC_PROG_YACC
 980 AM_PROG_LEX
 981
 982 ALL_LINGUAS="fr tr es"
 983 CY_GNU_GETTEXT
 984
 985 AM_MAINTAINER_MODE
 986 AC_EXEEXT
 987
 988 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 989
 990 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 991 # people who are not cross-compiling but are compiling cross-assemblers.
 992 AC_MSG_CHECKING(whether compiling a cross-assembler)
 993 if test "${host}" = "${target}"; then
 994   cross_gas=no
 995 else
 996   cross_gas=yes
 997   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 998 fi
 999 AC_MSG_RESULT($cross_gas)
1000
1001 dnl ansidecl.h will deal with const
1002 dnl AC_CONST
1003 AC_FUNC_ALLOCA
1004 AC_C_INLINE
1005
1006 # VMS doesn't have unlink.
1007 AC_CHECK_FUNCS(unlink remove, break)
1008
1009 # Some systems don't have sbrk().
1010 AC_CHECK_FUNCS(sbrk)
1011
1012 # do we need the math library?
1013 case "${need_libm}" in
1014 yes)
1015   AC_CHECK_LIBM
1016   AC_SUBST(LIBM)
1017   ;;
1018 esac
1019
1020 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
1021 # enough, but on some of those systems, the assert macro relies on requoting
1022 # working properly!
1023 GAS_WORKING_ASSERT
1024
1025 # On some systems, the system header files may not declare malloc, realloc,
1026 # and free.  There are places where gas needs these functions to have been
1027 # declared -- such as when taking their addresses.
1028 gas_test_headers="
1029 #ifdef HAVE_MEMORY_H
1030 #include <memory.h>
1031 #endif
1032 #ifdef HAVE_STRING_H
1033 #include <string.h>
1034 #else
1035 #ifdef HAVE_STRINGS_H
1036 #include <strings.h>
1037 #endif
1038 #endif
1039 #ifdef HAVE_STDLIB_H
1040 #include <stdlib.h>
1041 #endif
1042 #ifdef HAVE_UNISTD_H
1043 #include <unistd.h>
1044 #endif
1045 "
1046 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
1047 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
1048 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
1049 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
1050 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
1051
1052 # Does errno.h declare errno, or do we have to add a separate declaration
1053 # for it?
1054 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
1055 #ifdef HAVE_ERRNO_H
1056 #include <errno.h>
1057 #endif
1058 ])
1059
1060 dnl This must come last.
1061
1062 dnl We used to make symlinks to files in the source directory, but now
1063 dnl we just use the right name for .c files, and create .h files in
1064 dnl the build directory which include the right .h file.  Make sure
1065 dnl the old symlinks don't exist, so that a reconfigure in an existing
1066 dnl directory behaves reasonably.
1067
1068 AC_CONFIG_FILES(Makefile doc/Makefile po/Makefile.in:po/Make-in)
1069 AC_CONFIG_COMMANDS([default],
1070 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
1071  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
1072  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
1073  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
1074  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
1075  if test "x$cgen_cpu_prefix" != x ; then
1076    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
1077  fi
1078
1079  sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile],
1080 [target_cpu_type=${target_cpu_type}
1081  cgen_cpu_prefix=${cgen_cpu_prefix}
1082  obj_format=${obj_format}
1083  te_file=${te_file}])
1084
1085 AC_OUTPUT