opcodes/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT
   6 AC_CONFIG_SRCDIR([z8k-dis.c])
   7
   8 AC_CANONICAL_TARGET
   9 AC_ISC_POSIX
  10
  11 # We currently only use the version number for the name of any shared
  12 # library.  For user convenience, we always use the same version
  13 # number that BFD is using.
  14 changequote(,)dnl
  15 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  16 changequote([,])dnl
  17
  18 AM_INIT_AUTOMAKE(opcodes, ${BFD_VERSION})
  19
  20 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  21 dnl to call AC_CHECK_PROG.
  22 AC_CHECK_TOOL(AR, ar)
  23 AC_CHECK_TOOL(RANLIB, ranlib, :)
  24
  25 dnl Default to a non shared library.  This may be overridden by the
  26 dnl configure option --enable-shared.
  27 AM_DISABLE_SHARED
  28
  29 AM_PROG_LIBTOOL
  30
  31 AC_ARG_ENABLE(targets,
  32 [  --enable-targets        alternative target configurations],
  33 [case "${enableval}" in
  34   yes | "") AC_MSG_ERROR([enable-targets option must specify target names or 'all'])
  35             ;;
  36   no)       enable_targets= ;;
  37   *)        enable_targets=$enableval ;;
  38 esac])dnl
  39 AC_ARG_ENABLE(commonbfdlib,
  40 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  41 [case "${enableval}" in
  42   yes) commonbfdlib=true ;;
  43   no)  commonbfdlib=false ;;
  44   *)   AC_MSG_ERROR([bad value ${enableval} for opcodes commonbfdlib option]) ;;
  45 esac])dnl
  46
  47 build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
  48 AC_ARG_ENABLE(build-warnings,
  49 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  50 [case "${enableval}" in
  51   yes)  ;;
  52   no)   build_warnings="-w";;
  53   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  54         build_warnings="${build_warnings} ${t}";;
  55   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  56         build_warnings="${t} ${build_warnings}";;
  57   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  58 esac
  59 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  60   echo "Setting warning flags = $build_warnings" 6>&1
  61 fi])dnl
  62 WARN_CFLAGS=""
  63 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  64     WARN_CFLAGS="${build_warnings}"
  65 fi
  66 AC_SUBST(WARN_CFLAGS)
  67
  68 AM_CONFIG_HEADER(config.h:config.in)
  69
  70 if test -z "$target" ; then
  71     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  72 fi
  73
  74 AM_MAINTAINER_MODE
  75 AM_INSTALL_LIBBFD
  76 AC_EXEEXT
  77
  78 # host-specific stuff:
  79
  80 AC_PROG_CC
  81
  82 ALL_LINGUAS="fr sv tr es da de id pt_BR ro nl"
  83 CY_GNU_GETTEXT
  84
  85 . ${srcdir}/../bfd/configure.host
  86
  87 BFD_CC_FOR_BUILD
  88
  89 AC_SUBST(HDEFINES)
  90 AC_PROG_INSTALL
  91
  92 AC_CHECK_HEADERS(string.h strings.h stdlib.h)
  93
  94 cgen_maint=no
  95 cgendir='$(srcdir)/../cgen'
  96
  97 AC_ARG_ENABLE(cgen-maint,
  98 [  --enable-cgen-maint[=dir]    build cgen generated files],
  99 [case "${enableval}" in
 100   yes)  cgen_maint=yes ;;
 101   no)   cgen_maint=no ;;
 102   *)
 103         # argument is cgen install directory (not implemented yet).
 104         # Having a `share' directory might be more appropriate for the .scm,
 105         # .cpu, etc. files.
 106         cgen_maint=yes
 107         cgendir=${cgen_maint}/lib/cgen
 108         ;;
 109 esac])dnl
 110 AM_CONDITIONAL(CGEN_MAINT, test x${cgen_maint} = xyes)
 111 AC_SUBST(cgendir)
 112
 113 using_cgen=no
 114
 115 # Horrible hacks to build DLLs on Windows.
 116 WIN32LDFLAGS=
 117 WIN32LIBADD=
 118 case "${host}" in
 119 *-*-cygwin*)
 120   if test "$enable_shared" = "yes"; then
 121     WIN32LDFLAGS="-no-undefined"
 122     WIN32LIBADD="-L`pwd`/../bfd -lbfd -L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin"
 123   fi
 124   ;;
 125 esac
 126 AC_SUBST(WIN32LDFLAGS)
 127 AC_SUBST(WIN32LIBADD)
 128
 129 # target-specific stuff:
 130
 131 # Canonicalize the secondary target names.
 132 if test -n "$enable_targets" ; then
 133     for targ in `echo $enable_targets | sed 's/,/ /g'`
 134     do
 135         result=`$ac_config_sub $targ 2>/dev/null`
 136         if test -n "$result" ; then
 137             canon_targets="$canon_targets $result"
 138         else
 139             # Allow targets that config.sub doesn't recognize, like "all".
 140             canon_targets="$canon_targets $targ"
 141         fi
 142     done
 143 fi
 144
 145 all_targets=false
 146 selarchs=
 147 for targ in $target $canon_targets
 148 do
 149     if test "x$targ" = "xall" ; then
 150         all_targets=true
 151     else
 152         . $srcdir/../bfd/config.bfd
 153         selarchs="$selarchs $targ_archs"
 154     fi
 155 done
 156
 157 # Utility var, documents generic cgen support files.
 158
 159 cgen_files="cgen-opc.lo cgen-asm.lo cgen-dis.lo"
 160
 161 # We don't do any links based on the target system, just makefile config.
 162
 163 if test x${all_targets} = xfalse ; then
 164
 165     # Target architecture .o files.
 166     ta=
 167
 168     for arch in $selarchs
 169     do
 170         ad=`echo $arch | sed -e s/bfd_//g -e s/_arch//g`
 171         archdefs="$archdefs -DARCH_$ad"
 172         case "$arch" in
 173         bfd_a29k_arch)          ta="$ta a29k-dis.lo" ;;
 174         bfd_alliant_arch)       ;;
 175         bfd_alpha_arch)         ta="$ta alpha-dis.lo alpha-opc.lo" ;;
 176         bfd_arc_arch)           ta="$ta arc-dis.lo arc-opc.lo arc-ext.lo" ;;
 177         bfd_arm_arch)           ta="$ta arm-dis.lo" ;;
 178         bfd_avr_arch)           ta="$ta avr-dis.lo" ;;
 179         bfd_convex_arch)        ;;
 180         bfd_cris_arch)          ta="$ta cris-dis.lo cris-opc.lo" ;;
 181         bfd_crx_arch)           ta="$ta crx-dis.lo crx-opc.lo" ;;
 182         bfd_d10v_arch)          ta="$ta d10v-dis.lo d10v-opc.lo" ;;
 183         bfd_d30v_arch)          ta="$ta d30v-dis.lo d30v-opc.lo" ;;
 184         bfd_dlx_arch)           ta="$ta dlx-dis.lo" ;;
 185         bfd_fr30_arch)          ta="$ta fr30-asm.lo fr30-desc.lo fr30-dis.lo fr30-ibld.lo fr30-opc.lo" using_cgen=yes ;;
 186         bfd_h8300_arch)         ta="$ta h8300-dis.lo" ;;
 187         bfd_h8500_arch)         ta="$ta h8500-dis.lo" ;;
 188         bfd_hppa_arch)          ta="$ta hppa-dis.lo" ;;
 189         bfd_i370_arch)          ta="$ta i370-dis.lo i370-opc.lo" ;;
 190         bfd_i386_arch)          ta="$ta i386-dis.lo" ;;
 191         bfd_i860_arch)          ta="$ta i860-dis.lo" ;;
 192         bfd_i960_arch)          ta="$ta i960-dis.lo" ;;
 193         bfd_ia64_arch)          ta="$ta ia64-dis.lo ia64-opc.lo" ;;
 194         bfd_ip2k_arch)          ta="$ta ip2k-asm.lo ip2k-desc.lo ip2k-dis.lo ip2k-ibld.lo ip2k-opc.lo" using_cgen=yes ;;
 195         bfd_iq2000_arch)        ta="$ta iq2000-asm.lo iq2000-desc.lo iq2000-dis.lo iq2000-ibld.lo iq2000-opc.lo" using_cgen=yes ;;
 196         bfd_m32r_arch)          ta="$ta m32r-asm.lo m32r-desc.lo m32r-dis.lo m32r-ibld.lo m32r-opc.lo m32r-opinst.lo" using_cgen=yes ;;
 197         bfd_m68hc11_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 198         bfd_m68hc12_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 199         bfd_m68k_arch)          ta="$ta m68k-dis.lo m68k-opc.lo" ;;
 200         bfd_m88k_arch)          ta="$ta m88k-dis.lo" ;;
 201         bfd_maxq_arch)          ta="$ta maxq-dis.lo" ;;
 202         bfd_mcore_arch)         ta="$ta mcore-dis.lo" ;;
 203         bfd_mips_arch)          ta="$ta mips-dis.lo mips-opc.lo mips16-opc.lo" ;;
 204         bfd_mmix_arch)          ta="$ta mmix-dis.lo mmix-opc.lo" ;;
 205         bfd_mn10200_arch)       ta="$ta m10200-dis.lo m10200-opc.lo" ;;
 206         bfd_mn10300_arch)       ta="$ta m10300-dis.lo m10300-opc.lo" ;;
 207         bfd_msp430_arch)        ta="$ta msp430-dis.lo" ;;
 208         bfd_ns32k_arch)         ta="$ta ns32k-dis.lo" ;;
 209         bfd_openrisc_arch)      ta="$ta openrisc-asm.lo openrisc-desc.lo openrisc-dis.lo openrisc-ibld.lo openrisc-opc.lo" using_cgen=yes ;;
 210         bfd_or32_arch)          ta="$ta or32-dis.lo or32-opc.lo" using_cgen=yes ;;
 211         bfd_pdp11_arch)         ta="$ta pdp11-dis.lo pdp11-opc.lo" ;;
 212         bfd_pj_arch)            ta="$ta pj-dis.lo pj-opc.lo" ;;
 213         bfd_powerpc_arch)       ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 214         bfd_powerpc_64_arch)    ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 215         bfd_pyramid_arch)       ;;
 216         bfd_romp_arch)          ;;
 217         bfd_rs6000_arch)        ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 218         bfd_s390_arch)          ta="$ta s390-dis.lo s390-opc.lo" ;;
 219         bfd_sh_arch)
 220           # We can't decide what we want just from the CPU family.
 221           # We want SH5 support unless a specific version of sh is
 222           # specified, as in sh3-elf, sh3b-linux-gnu, etc.
 223           # Include it just for ELF targets, since the SH5 bfd:s are ELF only.
 224           for t in $target $canon_targets; do
 225             case $t in
 226               all |  sh5*-* | sh64*-* | sh-*-*elf* | shl*-*-*elf* | \
 227               sh-*-linux* | shl-*-linux*)
 228                                 ta="$ta sh64-dis.lo sh64-opc.lo"
 229                                 archdefs="$archdefs -DINCLUDE_SHMEDIA"
 230                                 break;;
 231             esac;
 232           done
 233                                 ta="$ta sh-dis.lo" ;;
 234         bfd_sparc_arch)         ta="$ta sparc-dis.lo sparc-opc.lo" ;;
 235         bfd_tahoe_arch)         ;;
 236         bfd_tic30_arch)         ta="$ta tic30-dis.lo" ;;
 237         bfd_tic4x_arch)         ta="$ta tic4x-dis.lo" ;;
 238         bfd_tic54x_arch)        ta="$ta tic54x-dis.lo tic54x-opc.lo" ;;
 239         bfd_tic80_arch)         ta="$ta tic80-dis.lo tic80-opc.lo" ;;
 240         bfd_v850_arch)          ta="$ta v850-opc.lo v850-dis.lo" ;;
 241         bfd_v850e_arch)         ta="$ta v850-opc.lo v850-dis.lo" ;;
 242         bfd_v850ea_arch)        ta="$ta v850-opc.lo v850-dis.lo" ;;
 243         bfd_vax_arch)           ta="$ta vax-dis.lo" ;;
 244         bfd_w65_arch)           ta="$ta w65-dis.lo" ;;
 245         bfd_we32k_arch)         ;;
 246         bfd_xstormy16_arch)     ta="$ta xstormy16-asm.lo xstormy16-desc.lo xstormy16-dis.lo xstormy16-ibld.lo xstormy16-opc.lo" using_cgen=yes ;;
 247         bfd_xtensa_arch)        ta="$ta xtensa-dis.lo" ;;
 248         bfd_z8k_arch)           ta="$ta z8k-dis.lo" ;;
 249         bfd_frv_arch)           ta="$ta frv-asm.lo frv-desc.lo frv-dis.lo frv-ibld.lo frv-opc.lo" using_cgen=yes ;;
 250
 251         "")                     ;;
 252         *)              AC_MSG_ERROR(*** unknown target architecture $arch) ;;
 253         esac
 254     done
 255
 256     if test $using_cgen = yes ; then
 257         ta="$ta $cgen_files"
 258     fi
 259
 260     # Weed out duplicate .o files.
 261     f=""
 262     for i in $ta ; do
 263         case " $f " in
 264         *" $i "*) ;;
 265         *) f="$f $i" ;;
 266         esac
 267     done
 268     ta="$f"
 269
 270     # And duplicate -D flags.
 271     f=""
 272     for i in $archdefs ; do
 273         case " $f " in
 274         *" $i "*) ;;
 275         *) f="$f $i" ;;
 276         esac
 277     done
 278     archdefs="$f"
 279
 280     BFD_MACHINES="$ta"
 281
 282 else    # all_targets is true
 283     archdefs=-DARCH_all
 284     BFD_MACHINES='$(ALL_MACHINES)'
 285 fi
 286
 287 AC_SUBST(archdefs)
 288 AC_SUBST(BFD_MACHINES)
 289
 290 AC_CONFIG_FILES([Makefile po/Makefile.in:po/Make-in])
 291 AC_CONFIG_COMMANDS([default],[[sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile]],[[]])
 292 AC_OUTPUT