bfd/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT
   6 AC_CONFIG_SRCDIR([libbfd.c])
   7
   8 AC_CANONICAL_TARGET
   9 AC_ISC_POSIX
  10
  11 AM_INIT_AUTOMAKE(bfd, 2.16.91)
  12
  13 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  14 dnl to call AC_CHECK_PROG.
  15 AC_CHECK_TOOL(AR, ar)
  16 AC_CHECK_TOOL(RANLIB, ranlib, :)
  17
  18 dnl Default to a non shared library.  This may be overridden by the
  19 dnl configure option --enable-shared.
  20 AM_DISABLE_SHARED
  21
  22 AM_PROG_LIBTOOL
  23
  24 AC_ARG_ENABLE(64-bit-bfd,
  25 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  26 [case "${enableval}" in
  27   yes)  want64=true  ;;
  28   no)   want64=false ;;
  29   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  30 esac],[want64=false])dnl
  31 AC_ARG_ENABLE(targets,
  32 [  --enable-targets        alternative target configurations],
  33 [case "${enableval}" in
  34   yes | "") AC_MSG_ERROR([enable-targets option must specify target names or 'all'])
  35             ;;
  36   no)       enable_targets= ;;
  37   *)        enable_targets=$enableval ;;
  38 esac])dnl
  39 AC_ARG_ENABLE(commonbfdlib,
  40 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  41 [case "${enableval}" in
  42   yes) commonbfdlib=true ;;
  43   no)  commonbfdlib=false ;;
  44   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  45 esac])dnl
  46 AC_ARG_WITH(mmap,
  47 [  --with-mmap             try using mmap for BFD input files if available],
  48 [case "${withval}" in
  49   yes)  want_mmap=true ;;
  50   no)   want_mmap=false ;;
  51   *)    AC_MSG_ERROR(bad value ${withval} for BFD with-mmap option) ;;
  52 esac],[want_mmap=false])dnl
  53
  54 AC_ARG_ENABLE(secureplt,
  55 [  --enable-secureplt      Default to creating read-only plt entries],
  56 [case "${enableval}" in
  57   yes)  use_secureplt=true  ;;
  58   no)   use_secureplt=false ;;
  59   *)    AC_MSG_ERROR(bad value ${enableval} for secureplt option) ;;
  60 esac],[use_secureplt=false])dnl
  61 if test $use_secureplt = true; then
  62   AC_DEFINE(USE_SECUREPLT, 1,
  63     [Define if we should default to creating read-only plt entries])
  64 fi
  65
  66 AM_BINUTILS_WARNINGS
  67
  68 AM_CONFIG_HEADER(config.h:config.in)
  69
  70 if test -z "$target" ; then
  71     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  72 fi
  73
  74 AM_MAINTAINER_MODE
  75 AM_INSTALL_LIBBFD
  76 AC_EXEEXT
  77
  78 host64=false
  79 target64=false
  80 bfd_default_target_size=32
  81
  82 # host stuff:
  83
  84 AC_PROG_CC
  85 AC_GNU_SOURCE
  86
  87 ALL_LINGUAS="fr tr ja es sv da zh_CN ro rw vi"
  88 CY_GNU_GETTEXT
  89
  90 # Permit host specific settings.
  91 . ${srcdir}/configure.host
  92
  93 AC_SUBST(HDEFINES)
  94 AC_PROG_INSTALL
  95
  96 BFD_HOST_64BIT_LONG=0
  97 BFD_HOST_LONG_LONG=0
  98 BFD_HOST_64_BIT_DEFINED=0
  99 BFD_HOST_64_BIT=
 100 BFD_HOST_U_64_BIT=
 101
 102 AC_MSG_CHECKING([for long long])
 103 AC_CACHE_VAL(bfd_cv_has_long_long,
 104 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[unsigned long long ll = 18446744073709551615ULL;]])],[bfd_cv_has_long_long=yes],[bfd_cv_has_long_long=no])])
 105 AC_MSG_RESULT($bfd_cv_has_long_long)
 106 if test $bfd_cv_has_long_long = yes; then
 107   BFD_HOST_LONG_LONG=1
 108   AC_CHECK_SIZEOF(long long)
 109 fi
 110
 111 AC_CHECK_SIZEOF(long)
 112 if test "x${ac_cv_sizeof_long}" = "x8"; then
 113   host64=true
 114   BFD_HOST_64BIT_LONG=1
 115   test -n "${HOST_64BIT_TYPE}" || HOST_64BIT_TYPE="long"
 116   test -n "${HOST_U_64BIT_TYPE}" || HOST_U_64BIT_TYPE="unsigned long"
 117 elif test "x${ac_cv_sizeof_long_long}" = "x8"; then
 118   test -n "${HOST_64BIT_TYPE}" || HOST_64BIT_TYPE="long long"
 119   test -n "${HOST_U_64BIT_TYPE}" || HOST_U_64BIT_TYPE="unsigned long long"
 120 fi
 121
 122 if test -n "${HOST_64BIT_TYPE}" -a -n "${HOST_U_64BIT_TYPE}"; then
 123   BFD_HOST_64_BIT_DEFINED=1
 124   BFD_HOST_64_BIT="${HOST_64BIT_TYPE}"
 125   BFD_HOST_U_64_BIT="${HOST_U_64BIT_TYPE}"
 126 fi
 127
 128 AC_SUBST(BFD_HOST_64BIT_LONG)
 129 AC_SUBST(BFD_HOST_LONG_LONG)
 130 AC_SUBST(BFD_HOST_64_BIT_DEFINED)
 131 AC_SUBST(BFD_HOST_64_BIT)
 132 AC_SUBST(BFD_HOST_U_64_BIT)
 133
 134 BFD_CC_FOR_BUILD
 135
 136 AC_CHECK_HEADERS(stddef.h string.h strings.h stdlib.h time.h unistd.h)
 137 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h)
 138 AC_HEADER_TIME
 139 AC_HEADER_DIRENT
 140 ACX_HEADER_STRING
 141 AC_CHECK_FUNCS(fcntl getpagesize setitimer sysconf fdopen getuid getgid)
 142 AC_CHECK_FUNCS(strtoull)
 143
 144 AC_CHECK_DECLS(basename)
 145 AC_CHECK_DECLS(ftello)
 146 AC_CHECK_DECLS(ftello64)
 147 AC_CHECK_DECLS(fseeko)
 148 AC_CHECK_DECLS(fseeko64)
 149
 150 BFD_BINARY_FOPEN
 151
 152 AC_CHECK_DECLS(ffs)
 153 AC_CHECK_DECLS(free)
 154 AC_CHECK_DECLS(getenv)
 155 AC_CHECK_DECLS(malloc)
 156 AC_CHECK_DECLS(realloc)
 157 AC_CHECK_DECLS(stpcpy)
 158 AC_CHECK_DECLS(strstr)
 159 AC_CHECK_DECLS(snprintf)
 160 AC_CHECK_DECLS(vsnprintf)
 161
 162 # If we are configured native, pick a core file support file.
 163 COREFILE=
 164 COREFLAG=
 165 TRAD_HEADER=
 166 if test "${target}" = "${host}"; then
 167   case "${host}" in
 168   alpha*-*-freebsd* | alpha*-*-kfreebsd*-gnu)
 169         COREFILE=''
 170         ;;
 171   alpha*-*-linux-*)
 172         COREFILE=trad-core.lo
 173         TRAD_HEADER='"hosts/alphalinux.h"'
 174         ;;
 175   alpha*-*-netbsd* | alpha*-*-openbsd*)
 176         COREFILE=netbsd-core.lo
 177         ;;
 178   alpha*-*-*)           COREFILE=osf-core.lo ;;
 179   arm-*-freebsd* | arm-*-kfreebsd*-gnu)
 180                         COREFILE='' ;;
 181   arm-*-netbsd*)        COREFILE=netbsd-core.lo ;;
 182   arm-*-riscix)         COREFILE=trad-core.lo ;;
 183   hppa*-*-hpux*)        COREFILE=hpux-core.lo ;;
 184   hppa*-*-hiux*)        COREFILE=hpux-core.lo ;;
 185   hppa*-*-mpeix*)       COREFILE=hpux-core.lo ;;
 186   hppa*-*-bsd*)         COREFILE="hpux-core.lo hppabsd-core.lo"
 187                         COREFLAG="-DHPUX_CORE -DHPPABSD_CORE" ;;
 188   hppa*-*-netbsd* | hppa*-*-openbsd*)
 189         COREFILE=netbsd-core.lo
 190         ;;
 191
 192   i370-*-*)
 193         COREFILE=trad-core.lo
 194         TRAD_HEADER='"hosts/i370linux.h"'
 195         ;;
 196
 197 changequote(,)dnl
 198   i[3-7]86-sequent-bsd*)
 199 changequote([,])dnl
 200         COREFILE=trad-core.lo
 201         TRAD_HEADER='"hosts/symmetry.h"'
 202         ;;
 203 changequote(,)dnl
 204   i[3-7]86-sequent-sysv4*) ;;
 205   i[3-7]86-sequent-sysv*)
 206 changequote([,])dnl
 207         COREFILE=trad-core.lo
 208         TRAD_HEADER='"hosts/symmetry.h"'
 209         ;;
 210 changequote(,)dnl
 211   i[3-7]86-*-bsdi)
 212 changequote([,])dnl
 213         COREFILE=
 214         ;;
 215 changequote(,)dnl
 216   i[3-7]86-*-bsd* | i[3-7]86-*-freebsd[123] | i[3-7]86-*-freebsd[123]\.* | i[3-7]86-*-freebsd4\.[01234] | i[3-7]86-*-freebsd4\.[01234]\.* | i[3-7]86-*-freebsd*aout*)
 217 changequote([,])dnl
 218         COREFILE=trad-core.lo
 219         TRAD_HEADER='"hosts/i386bsd.h"'
 220         ;;
 221 changequote(,)dnl
 222   i[3-7]86-*-freebsd* | i[3-7]86-*-kfreebsd*-gnu)
 223 changequote([,])dnl
 224         COREFILE=''
 225         TRAD_HEADER='"hosts/i386bsd.h"'
 226         ;;
 227 changequote(,)dnl
 228   i[3-7]86-*-netbsd* | i[3-7]86-*-knetbsd*-gnu | i[3-7]86-*-openbsd*)
 229 changequote([,])dnl
 230         COREFILE=netbsd-core.lo
 231         ;;
 232 changequote(,)dnl
 233   i[3-7]86-esix-sysv3*)
 234 changequote([,])dnl
 235         COREFILE=trad-core.lo
 236         TRAD_HEADER='"hosts/esix.h"'
 237         ;;
 238 changequote(,)dnl
 239   i[3-7]86-*-sco3.2v5*)
 240 changequote([,])dnl
 241         COREFILE=sco5-core.lo
 242         ;;
 243 changequote(,)dnl
 244   i[3-7]86-*-sco* | i[3-7]86-*-isc*)
 245 changequote([,])dnl
 246         COREFILE=trad-core.lo
 247         TRAD_HEADER='"hosts/i386sco.h"'
 248         ;;
 249 changequote(,)dnl
 250   i[3-7]86-*-mach3*)
 251 changequote([,])dnl
 252         COREFILE=trad-core.lo
 253         TRAD_HEADER='"hosts/i386mach3.h"'
 254         ;;
 255 changequote(,)dnl
 256   i[3-7]86-*-linux-*)
 257 changequote([,])dnl
 258         COREFILE=trad-core.lo
 259         TRAD_HEADER='"hosts/i386linux.h"'
 260         ;;
 261 changequote(,)dnl
 262   i[3-7]86-*-isc*)      COREFILE=trad-core.lo ;;
 263   i[3-7]86-*-aix*)      COREFILE=aix386-core.lo ;;
 264 changequote([,])dnl
 265   i860-*-mach3* | i860-*-osf1*)
 266         COREFILE=trad-core.lo
 267         TRAD_HEADER='"hosts/i860mach3.h"'
 268         ;;
 269   mips-*-netbsd* | mips*-*-openbsd*)
 270         COREFILE=netbsd-core.lo
 271         ;;
 272   mips-dec-*)
 273         COREFILE=trad-core.lo
 274         TRAD_HEADER='"hosts/decstation.h"'
 275         ;;
 276   mips-sgi-irix4*)      COREFILE=irix-core.lo ;;
 277   mips-sgi-irix5*)      COREFILE=irix-core.lo ;;
 278   mips-sgi-irix6*)      COREFILE=irix-core.lo ;;
 279   mips-*-sysv4*)        ;;
 280   mips-*-sysv* | mips-*-riscos*)
 281         COREFILE=trad-core.lo
 282         TRAD_HEADER='"hosts/riscos.h"'
 283         ;;
 284   mips-sony-bsd*)
 285         COREFILE=trad-core.lo
 286         TRAD_HEADER='"hosts/news-mips.h"'
 287         ;;
 288   m68*-bull*-sysv*)
 289         COREFILE=trad-core.lo
 290         TRAD_HEADER='"hosts/dpx2.h"'
 291         ;;
 292   m68*-hp-hpux*)        COREFILE=hpux-core.lo ;;
 293   m68*-hp-bsd*)
 294         COREFILE=trad-core.lo
 295         TRAD_HEADER='"hosts/hp300bsd.h"'
 296         ;;
 297   m68*-*-linux-*)
 298         COREFILE=trad-core.lo
 299         TRAD_HEADER='"hosts/m68klinux.h"'
 300         ;;
 301   m68*-motorola-sysv*)
 302         COREFILE=trad-core.lo
 303         TRAD_HEADER='"hosts/delta68.h"'
 304         ;;
 305   m68*-sony-*)
 306         COREFILE=trad-core.lo
 307         TRAD_HEADER='"hosts/news.h"'
 308         ;;
 309   m68*-*-netbsd* | m68*-*-openbsd*)
 310         COREFILE=netbsd-core.lo
 311         ;;
 312   m68*-apple-aux*)
 313         COREFILE=trad-core.lo
 314         TRAD_HEADER='"hosts/m68kaux.h"'
 315         ;;
 316   m88*-*-sysv4*)
 317         ;;
 318   m88*-motorola-sysv*)
 319         COREFILE=ptrace-core.lo
 320         ;;
 321   m88*-*-mach3*)
 322         COREFILE=trad-core.lo
 323         TRAD_HEADER='"hosts/m88kmach3.h"'
 324         ;;
 325   m88*-*-openbsd*)
 326         COREFILE=netbsd-core.lo
 327         ;;
 328   ns32k-pc532-mach)
 329         COREFILE=trad-core.lo
 330         TRAD_HEADER='"hosts/pc532mach.h"'
 331         ;;
 332   ns32k-*-netbsd* | ns32k-*-openbsd*)
 333         COREFILE=netbsd-core.lo
 334         ;;
 335   rs6000-*-lynx*)
 336         COREFILE=lynx-core.lo
 337         ;;
 338   rs6000-*-aix5.* | powerpc-*-aix5.*)
 339         COREFILE=rs6000-core.lo
 340         COREFLAG="$COREFLAG -DAIX_5_CORE -DAIX_CORE_DUMPX_CORE"
 341         ;;
 342 changequote(,)dnl
 343   rs6000-*-aix4.[3-9]* | powerpc-*-aix4.[3-9]*)
 344 changequote([,])dnl
 345         COREFILE=rs6000-core.lo
 346         COREFLAG="$COREFLAG -DAIX_CORE_DUMPX_CORE"
 347         # Not all versions of AIX with -DAIX_CORE_DUMPX_CORE
 348         # have c_impl as a member of struct core_dumpx
 349         AC_MSG_CHECKING([for c_impl in struct core_dumpx])
 350         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <core.h>]], [[struct core_dumpx c; c.c_impl = 0;]])],[AC_DEFINE(HAVE_ST_C_IMPL, 1,
 351             [Define if struct core_dumpx has member c_impl])
 352           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 353         ;;
 354   rs6000-*-aix4*)       COREFILE=rs6000-core.lo ;;
 355   rs6000-*-*)           COREFILE=rs6000-core.lo ;;
 356   powerpc-*-aix4*)      COREFILE=rs6000-core.lo ;;
 357   powerpc-*-aix*)       COREFILE=rs6000-core.lo ;;
 358   powerpc-*-beos*)      ;;
 359   powerpc-*-freebsd* | powerpc-*-kfreebsd*-gnu)
 360                         COREFILE='' ;;
 361   powerpc-*-netbsd*)    COREFILE=netbsd-core.lo ;;
 362   powerpc-*-*bsd*)      COREFILE=netbsd-core.lo ;;
 363   s390*-*-*)            COREFILE=trad-core.lo ;;
 364   sh*-*-netbsd*)        COREFILE=netbsd-core.lo ;;
 365   sparc-*-netbsd* | sparc*-*-openbsd*)
 366         COREFILE=netbsd-core.lo
 367         ;;
 368   tahoe-*-*)
 369         COREFILE=trad-core.lo
 370         TRAD_HEADER='"hosts/tahoe.h"'
 371         ;;
 372   vax-*-netbsd* | vax-*-openbsd*)
 373         COREFILE=netbsd-core.lo
 374         ;;
 375   vax-*-ultrix2*)
 376         COREFILE=trad-core.lo
 377         TRAD_HEADER='"hosts/vaxult2.h"'
 378         ;;
 379   vax-*-ultrix*)
 380         COREFILE=trad-core.lo
 381         TRAD_HEADER='"hosts/vaxult2.h"'
 382         ;;
 383   vax-*-linux-*)
 384         COREFILE=trad-core.lo
 385         TRAD_HEADER='"hosts/vaxlinux.h"'
 386         ;;
 387   vax-*-*)
 388         COREFILE=trad-core.lo
 389         TRAD_HEADER='"hosts/vaxbsd.h"'
 390         ;;
 391   x86_64-*-netbsd* | x86_64-*-openbsd*)
 392         COREFILE=netbsd-core.lo
 393         ;;
 394   esac
 395
 396   case "$COREFILE" in
 397   aix386-core.lo)       COREFLAG=-DAIX386_CORE ;;
 398   hppabsd-core.lo)      COREFLAG=-DHPPABSD_CORE ;;
 399   hpux-core.lo)         COREFLAG=-DHPUX_CORE ;;
 400   irix-core.lo)         COREFLAG=-DIRIX_CORE ;;
 401   lynx-core.lo)         COREFLAG=-DLYNX_CORE ;;
 402   netbsd-core.lo)       COREFLAG=-DNETBSD_CORE ;;
 403   osf-core.lo)          COREFLAG=-DOSF_CORE ;;
 404   ptrace-core.lo)       COREFLAG=-DPTRACE_CORE ;;
 405   rs6000-core.lo)       COREFLAG="$COREFLAG -DAIX_CORE" ;;
 406   sco5-core.lo)         COREFLAG="$COREFLAG -DSCO5_CORE" ;;
 407   trad-core.lo)         COREFLAG="$COREFLAG -DTRAD_CORE" ;;
 408   esac
 409
 410   # ELF corefile support has several flavors, but all of
 411   # them use something called <sys/procfs.h>
 412   AC_CHECK_HEADERS(sys/procfs.h)
 413   if test "$ac_cv_header_sys_procfs_h" = yes; then
 414     BFD_HAVE_SYS_PROCFS_TYPE(prstatus_t)
 415     BFD_HAVE_SYS_PROCFS_TYPE(prstatus32_t)
 416     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(prstatus_t, pr_who)
 417     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(prstatus32_t, pr_who)
 418     BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 419     BFD_HAVE_SYS_PROCFS_TYPE(pxstatus_t)
 420     BFD_HAVE_SYS_PROCFS_TYPE(pstatus32_t)
 421     BFD_HAVE_SYS_PROCFS_TYPE(prpsinfo_t)
 422     BFD_HAVE_SYS_PROCFS_TYPE(prpsinfo32_t)
 423     BFD_HAVE_SYS_PROCFS_TYPE(psinfo_t)
 424     BFD_HAVE_SYS_PROCFS_TYPE(psinfo32_t)
 425     BFD_HAVE_SYS_PROCFS_TYPE(lwpstatus_t)
 426     BFD_HAVE_SYS_PROCFS_TYPE(lwpxstatus_t)
 427     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_context)
 428     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_reg)
 429     BFD_HAVE_SYS_PROCFS_TYPE(win32_pstatus_t)
 430   fi
 431 fi
 432 AC_SUBST(COREFILE)
 433 AC_SUBST(COREFLAG)
 434 if test -n "$TRAD_HEADER"; then
 435   AC_DEFINE_UNQUOTED(TRAD_HEADER, $TRAD_HEADER,
 436     [Name of host specific header file to include in trad-core.c.])
 437 fi
 438
 439 # Horrible hacks to build DLLs on Windows.
 440 WIN32LDFLAGS=
 441 WIN32LIBADD=
 442 case "${host}" in
 443 *-*-cygwin*)
 444   if test "$enable_shared" = "yes"; then
 445     WIN32LDFLAGS="-no-undefined"
 446     WIN32LIBADD="-L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin -lkernel32"
 447   fi
 448   ;;
 449 *-*-linux*)
 450   # We borrow WIN32LIBADD so that the shared libbfd won't depend on
 451   # libiberty.a.
 452   case "${host}" in
 453   mips*-*-linux*)
 454     # Linux/MIPS uses PIC by default.
 455     if test "$enable_shared" = "yes"; then
 456       WIN32LIBADD="-L../libiberty -liberty"
 457     fi
 458     ;;
 459   *)
 460 changequote(,)dnl
 461     x=`sed -n -e 's/^[  ]*PICFLAG[      ]*=[    ]*//p' < ../libiberty/Makefile | sed -n '$p'`
 462 changequote([,])dnl
 463     if test -n "$x"; then
 464       WIN32LIBADD="-L../libiberty/pic -liberty"
 465     fi
 466   ;;
 467   esac
 468   ;;
 469 esac
 470 AC_SUBST(WIN32LDFLAGS)
 471 AC_SUBST(WIN32LIBADD)
 472
 473 # target stuff:
 474
 475 # Canonicalize the secondary target names.
 476 if test -n "$enable_targets" ; then
 477     for targ in `echo $enable_targets | sed 's/,/ /g'`
 478     do
 479         result=`$ac_config_sub $targ 2>/dev/null`
 480         if test -n "$result" ; then
 481             canon_targets="$canon_targets $result"
 482         else
 483             # Allow targets that config.sub doesn't recognize, like "all".
 484             canon_targets="$canon_targets $targ"
 485         fi
 486     done
 487 fi
 488
 489 all_targets=false
 490 defvec=
 491 selvecs=
 492 assocvecs=
 493 selarchs=
 494 TDEFINES=
 495 for targ in $target $canon_targets
 496 do
 497     if test "x$targ" = "xall"; then
 498         all_targets=true
 499         assocvecs="$assocvecs $targ_defvec $targ_selvecs"
 500     else
 501         . $srcdir/config.bfd
 502         if test "x$targ" = "x$target"; then
 503             defvec=$targ_defvec
 504         fi
 505         selvecs="$selvecs $targ_defvec $targ_selvecs"
 506         selarchs="$selarchs $targ_archs"
 507         TDEFINES="$TDEFINES $targ_cflags"
 508     fi
 509 done
 510 AC_SUBST(TDEFINES)
 511
 512 # This processing still needs to be done if we're to decide properly whether
 513 # 64-bit support needs to be compiled in.  Currently, it will be included if
 514 # the default or any other explicitly requested target requires it; it
 515 # will not be included on a 32-bit host if no 64-bit target is requested, and
 516 # no "--with-64-bit-bfd" option is given, even if "--enable-targets=all" is
 517 # used.
 518
 519 # uniq the default and selected vectors in all the configured targets.
 520 f=""
 521 for i in $selvecs ; do
 522     case " $f " in
 523     *" $i "*) ;;
 524     *) f="$f $i" ;;
 525     esac
 526 done
 527 selvecs="$f"
 528
 529
 530 # uniq the associated vectors in all the configured targets.
 531 f=""
 532 for i in $assocvecs ; do
 533     case " $f " in
 534     *" $i "*) ;;
 535     *) f="$f $i" ;;
 536     esac
 537 done
 538 assocvecs="$f"
 539
 540
 541 # uniq the architectures in all the configured targets.
 542 f=""
 543 for i in $selarchs ; do
 544     case " $f " in
 545     *" $i "*) ;;
 546     *) f="$f $i" ;;
 547     esac
 548 done
 549 selarchs="$f"
 550
 551 # Target backend .o files.
 552 tb=
 553
 554 elf="elf.lo elflink.lo elf-strtab.lo elf-eh-frame.lo dwarf1.lo"
 555
 556 for vec in $selvecs
 557 do
 558     target_size=32
 559     case "$vec" in
 560     # This list is alphabetized to make it easy to compare
 561     # with the two vector lists in targets.c.  For the same reason,
 562     # use one entry per line, even though this leads to long lines.
 563     a_out_adobe_vec)            tb="$tb aout-adobe.lo aout32.lo" ;;
 564     aix5coff64_vec)             tb="$tb coff64-rs6000.lo xcofflink.lo aix5ppc-core.lo"; target_size=64 ;;
 565     aout0_big_vec)              tb="$tb aout0.lo aout32.lo" ;;
 566     aout_arm_big_vec)           tb="$tb aout-arm.lo aout32.lo" ;;
 567     aout_arm_little_vec)        tb="$tb aout-arm.lo aout32.lo" ;;
 568     apollocoff_vec)             tb="$tb coff-apollo.lo" ;;
 569     arm_epoc_pe_big_vec)        tb="$tb epoc-pe-arm.lo peigen.lo cofflink.lo " ;;
 570     arm_epoc_pe_little_vec)     tb="$tb epoc-pe-arm.lo peigen.lo cofflink.lo " ;;
 571     arm_epoc_pei_big_vec)       tb="$tb epoc-pei-arm.lo peigen.lo cofflink.lo " ;;
 572     arm_epoc_pei_little_vec)    tb="$tb epoc-pei-arm.lo peigen.lo cofflink.lo " ;;
 573     armcoff_big_vec)            tb="$tb coff-arm.lo cofflink.lo " ;;
 574     armcoff_little_vec)         tb="$tb coff-arm.lo cofflink.lo " ;;
 575     armnetbsd_vec)              tb="$tb armnetbsd.lo aout32.lo" ;;
 576     armpe_big_vec)              tb="$tb pe-arm.lo peigen.lo cofflink.lo " ;;
 577     armpe_little_vec)           tb="$tb pe-arm.lo peigen.lo cofflink.lo " ;;
 578     armpei_big_vec)             tb="$tb pei-arm.lo peigen.lo cofflink.lo " ;;
 579     armpei_little_vec)          tb="$tb pei-arm.lo peigen.lo cofflink.lo " ;;
 580     b_out_vec_big_host)         tb="$tb bout.lo aout32.lo" ;;
 581     b_out_vec_little_host)      tb="$tb bout.lo aout32.lo" ;;
 582     bfd_efi_app_ia32_vec)       tb="$tb efi-app-ia32.lo peigen.lo cofflink.lo" ;;
 583     bfd_efi_app_ia64_vec)       tb="$tb efi-app-ia64.lo pepigen.lo cofflink.lo"; target_size=64 ;;
 584     bfd_elf32_am33lin_vec)      tb="$tb elf32-am33lin.lo elf32.lo $elf" ;;
 585     bfd_elf32_avr_vec)          tb="$tb elf32-avr.lo elf32.lo $elf" ;;
 586     bfd_elf32_bfin_vec)         tb="$tb elf32-bfin.lo elf32.lo $elf" ;;
 587     bfd_elf32_big_generic_vec)  tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 588     bfd_elf32_bigarc_vec)       tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 589     bfd_elf32_bigarm_vec)       tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 590     bfd_elf32_bigarm_symbian_vec)
 591                                 tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 592     bfd_elf32_bigarm_vxworks_vec)
 593                                 tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 594     bfd_elf32_bigmips_vec)      tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 595     bfd_elf32_cr16c_vec)        tb="$tb elf32-cr16c.lo elf32.lo $elf" ;;
 596     bfd_elf32_cris_vec)         tb="$tb elf32-cris.lo elf32.lo $elf" ;;
 597     bfd_elf32_crx_vec)          tb="$tb elf32-crx.lo elf32.lo $elf" ;;
 598     bfd_elf32_d10v_vec)         tb="$tb elf32-d10v.lo elf32.lo $elf" ;;
 599     bfd_elf32_d30v_vec)         tb="$tb elf32-d30v.lo elf32.lo $elf" ;;
 600     bfd_elf32_dlx_big_vec)      tb="$tb elf32-dlx.lo elf32.lo $elf" ;;
 601     bfd_elf32_fr30_vec)         tb="$tb elf32-fr30.lo elf32.lo $elf" ;;
 602     bfd_elf32_frv_vec)          tb="$tb elf32-frv.lo elf32.lo $elf" ;;
 603     bfd_elf32_frvfdpic_vec)     tb="$tb elf32-frv.lo elf32.lo $elf" ;;
 604     bfd_elf32_h8300_vec)        tb="$tb elf32-h8300.lo elf32.lo $elf" ;;
 605     bfd_elf32_hppa_linux_vec)   tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 606     bfd_elf32_hppa_nbsd_vec)    tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 607     bfd_elf32_hppa_vec)         tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 608     bfd_elf32_i370_vec)         tb="$tb elf32-i370.lo elf32.lo $elf" ;;
 609     bfd_elf32_i386_freebsd_vec) tb="$tb elf32-i386.lo elf-vxworks.lo elf32.lo $elf" ;;
 610     bfd_elf32_i386_vxworks_vec) tb="$tb elf32-i386.lo elf-vxworks.lo elf32.lo $elf" ;;
 611     bfd_elf32_i386_vec)         tb="$tb elf32-i386.lo elf-vxworks.lo elf32.lo $elf" ;;
 612     bfd_elf32_i860_little_vec)  tb="$tb elf32-i860.lo elf32.lo $elf" ;;
 613     bfd_elf32_i860_vec)         tb="$tb elf32-i860.lo elf32.lo $elf" ;;
 614     bfd_elf32_i960_vec)         tb="$tb elf32-i960.lo elf32.lo $elf" ;;
 615     bfd_elf32_ia64_big_vec)     tb="$tb elf32-ia64.lo elf32.lo $elf" ;;
 616     bfd_elf32_ia64_hpux_big_vec) tb="$tb elf32-ia64.lo elf32.lo $elf";;
 617     bfd_elf32_ip2k_vec)         tb="$tb elf32-ip2k.lo elf32.lo $elf" ;;
 618     bfd_elf32_iq2000_vec)       tb="$tb elf32-iq2000.lo elf32.lo $elf" ;;
 619     bfd_elf32_little_generic_vec) tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 620     bfd_elf32_littlearc_vec)    tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 621     bfd_elf32_littlearm_symbian_vec)
 622                                 tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 623     bfd_elf32_littlearm_vxworks_vec)
 624                                 tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 625     bfd_elf32_littlearm_vec)    tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 626     bfd_elf32_littlemips_vec)   tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 627     bfd_elf32_m32c_vec)         tb="$tb elf32-m32c.lo elf32.lo $elf" ;;
 628     bfd_elf32_m32r_vec)         tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 629     bfd_elf32_m32rle_vec)       tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 630     bfd_elf32_m32rlin_vec)      tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 631     bfd_elf32_m32rlelin_vec)    tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 632     bfd_elf32_m68hc11_vec)      tb="$tb elf32-m68hc11.lo elf32-m68hc1x.lo elf32.lo $elf" ;;
 633     bfd_elf32_m68hc12_vec)      tb="$tb elf32-m68hc12.lo elf32-m68hc1x.lo elf32.lo $elf" ;;
 634     bfd_elf32_m68k_vec)         tb="$tb elf32-m68k.lo elf32.lo $elf" ;;
 635     bfd_elf32_m88k_vec)         tb="$tb elf32-m88k.lo elf32.lo $elf" ;;
 636     bfd_elf32_mcore_big_vec)    tb="$tb elf32-mcore.lo elf32.lo $elf" ;;
 637     bfd_elf32_mcore_little_vec) tb="$tb elf32-mcore.lo elf32.lo $elf" ;;
 638     bfd_elf32_mn10200_vec)      tb="$tb elf-m10200.lo elf32.lo $elf" ;;
 639     bfd_elf32_mn10300_vec)      tb="$tb elf-m10300.lo elf32.lo $elf" ;;
 640     bfd_elf32_mt_vec)           tb="$tb elf32-mt.lo elf32.lo $elf" ;;
 641     bfd_elf32_msp430_vec)       tb="$tb elf32-msp430.lo elf32.lo $elf" ;;
 642     bfd_elf32_nbigmips_vec)     tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 643     bfd_elf32_nlittlemips_vec)  tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 644     bfd_elf32_ntradbigmips_vec) tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 645     bfd_elf32_ntradlittlemips_vec) tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 646     bfd_elf32_openrisc_vec)     tb="$tb elf32-openrisc.lo elf32.lo $elf" ;;
 647     bfd_elf32_or32_big_vec)     tb="$tb elf32-or32.lo elf32.lo $elf" ;;
 648     bfd_elf32_pj_vec)           tb="$tb elf32-pj.lo elf32.lo $elf";;
 649     bfd_elf32_pjl_vec)          tb="$tb elf32-pj.lo elf32.lo $elf";;
 650     bfd_elf32_powerpc_vec)      tb="$tb elf32-ppc.lo elf-vxworks.lo elf32.lo $elf" ;;
 651     bfd_elf32_powerpcle_vec)    tb="$tb elf32-ppc.lo elf-vxworks.lo elf32.lo $elf" ;;
 652     bfd_elf32_powerpc_vxworks_vec) tb="$tb elf32-ppc.lo elf-vxworks.lo elf32.lo $elf" ;;
 653     bfd_elf32_s390_vec)         tb="$tb elf32-s390.lo elf32.lo $elf" ;;
 654     # FIXME: We include cofflink.lo not because it's needed for
 655     # bfd_elf32_sh64[l]_vec, but because we include bfd_elf32_sh[l]_vec
 656     # which needs it but does not list it.  Should be fixed in right place.
 657     bfd_elf32_sh64_vec)         tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 658     bfd_elf32_sh64l_vec)        tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 659     bfd_elf32_sh64lin_vec)      tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 660     bfd_elf32_sh64blin_vec)     tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 661     bfd_elf32_sh64lnbsd_vec)    tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" ;;
 662     bfd_elf32_sh64nbsd_vec)     tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" ;;
 663     bfd_elf32_sh_vec)           tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
 664     bfd_elf32_shblin_vec)       tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 665     bfd_elf32_shl_vec)          tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
 666     bfd_elf32_shl_symbian_vec)  tb="$tb elf32-sh-symbian.lo elf32-sh64-com.lo elf32.lo $elf coff-sh.lo" ;;
 667     bfd_elf32_shlin_vec)        tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 668     bfd_elf32_shlnbsd_vec)      tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 669     bfd_elf32_shnbsd_vec)       tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 670     bfd_elf32_sparc_vec)        tb="$tb elf32-sparc.lo elfxx-sparc.lo elf32.lo $elf" ;;
 671     bfd_elf32_tradbigmips_vec)  tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 672     bfd_elf32_tradlittlemips_vec) tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 673     bfd_elf32_us_cris_vec)      tb="$tb elf32-cris.lo elf32.lo $elf" ;;
 674     bfd_elf32_v850_vec)         tb="$tb elf32-v850.lo elf32.lo $elf" ;;
 675     bfd_elf32_vax_vec)          tb="$tb elf32-vax.lo elf32.lo $elf" ;;
 676     bfd_elf32_xstormy16_vec)    tb="$tb elf32-xstormy16.lo elf32.lo $elf" ;;
 677     bfd_elf32_xtensa_le_vec)    tb="$tb xtensa-isa.lo xtensa-modules.lo elf32-xtensa.lo elf32.lo $elf" ;;
 678     bfd_elf32_xtensa_be_vec)    tb="$tb xtensa-isa.lo xtensa-modules.lo elf32-xtensa.lo elf32.lo $elf" ;;
 679     bfd_elf64_alpha_freebsd_vec) tb="$tb elf64-alpha.lo elf64.lo $elf"; target_size=64 ;;
 680     bfd_elf64_alpha_vec)        tb="$tb elf64-alpha.lo elf64.lo $elf"; target_size=64 ;;
 681     bfd_elf64_big_generic_vec)  tb="$tb elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 682     bfd_elf64_bigmips_vec)      tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 683     bfd_elf64_hppa_linux_vec)   tb="$tb elf64-hppa.lo elf64.lo $elf"; target_size=64 ;;
 684     bfd_elf64_hppa_vec)         tb="$tb elf64-hppa.lo elf64.lo $elf"; target_size=64 ;;
 685     bfd_elf64_ia64_big_vec)     tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 686     bfd_elf64_ia64_hpux_big_vec) tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 687     bfd_elf64_ia64_little_vec)  tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 688     bfd_elf64_little_generic_vec) tb="$tb elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 689     bfd_elf64_littlemips_vec)   tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 690     bfd_elf64_mmix_vec)         tb="$tb elf64-mmix.lo elf64.lo $elf" target_size=64 ;;
 691     bfd_elf64_powerpc_vec)      tb="$tb elf64-ppc.lo elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 692     bfd_elf64_powerpcle_vec)    tb="$tb elf64-ppc.lo elf64-gen.lo elf64.lo $elf" target_size=64 ;;
 693     bfd_elf64_s390_vec)         tb="$tb elf64-s390.lo elf64.lo $elf"; target_size=64 ;;
 694     bfd_elf64_sh64_vec)         tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 695     bfd_elf64_sh64l_vec)        tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 696     bfd_elf64_sh64lin_vec)      tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 697     bfd_elf64_sh64blin_vec)     tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 698     bfd_elf64_sh64lnbsd_vec)    tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 699     bfd_elf64_sh64nbsd_vec)     tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 700     bfd_elf64_sparc_vec)        tb="$tb elf64-sparc.lo elfxx-sparc.lo elf64.lo $elf"; target_size=64 ;;
 701     bfd_elf64_tradbigmips_vec)  tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 702     bfd_elf64_tradlittlemips_vec) tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 703     bfd_elf64_x86_64_vec)       tb="$tb elf64-x86-64.lo elf64.lo $elf"; target_size=64 ;;
 704     bfd_mmo_vec)                tb="$tb mmo.lo" target_size=64 ;;
 705     bfd_powerpc_pe_vec)         tb="$tb pe-ppc.lo peigen.lo cofflink.lo" ;;
 706     bfd_powerpc_pei_vec)        tb="$tb pei-ppc.lo peigen.lo cofflink.lo" ;;
 707     bfd_powerpcle_pe_vec)       tb="$tb pe-ppc.lo peigen.lo cofflink.lo" ;;
 708     bfd_powerpcle_pei_vec)      tb="$tb pei-ppc.lo peigen.lo cofflink.lo" ;;
 709     cris_aout_vec)              tb="$tb aout-cris.lo" ;;
 710     demo_64_vec)                tb="$tb demo64.lo aout64.lo"; target_size=64 ;;
 711     ecoff_big_vec)              tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 712     ecoff_biglittle_vec)        tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 713     ecoff_little_vec)           tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 714     ecoffalpha_little_vec)      tb="$tb coff-alpha.lo ecoff.lo ecofflink.lo"; target_size=64 ;;
 715     go32coff_vec)               tb="$tb coff-go32.lo cofflink.lo" ;;
 716     go32stubbedcoff_vec)        tb="$tb coff-stgo32.lo cofflink.lo" ;;
 717     h8300coff_vec)              tb="$tb coff-h8300.lo reloc16.lo" ;;
 718     h8500coff_vec)              tb="$tb coff-h8500.lo reloc16.lo" ;;
 719     host_aout_vec)              tb="$tb host-aout.lo aout32.lo" ;;
 720     hp300bsd_vec)               tb="$tb hp300bsd.lo aout32.lo" ;;
 721     hp300hpux_vec)              tb="$tb hp300hpux.lo aout32.lo" ;;
 722     i386aout_vec)               tb="$tb i386aout.lo aout32.lo" ;;
 723     i386bsd_vec)                tb="$tb i386bsd.lo aout32.lo" ;;
 724     i386coff_vec)               tb="$tb coff-i386.lo cofflink.lo" ;;
 725     i386dynix_vec)              tb="$tb i386dynix.lo aout32.lo" ;;
 726     i386freebsd_vec)            tb="$tb i386freebsd.lo aout32.lo" ;;
 727     i386linux_vec)              tb="$tb i386linux.lo aout32.lo" ;;
 728     i386lynx_aout_vec)          tb="$tb i386lynx.lo lynx-core.lo aout32.lo" ;;
 729     i386lynx_coff_vec)          tb="$tb cf-i386lynx.lo cofflink.lo lynx-core.lo" ;;
 730     i386mach3_vec)              tb="$tb i386mach3.lo aout32.lo" ;;
 731     i386msdos_vec)              tb="$tb i386msdos.lo" ;;
 732     i386netbsd_vec)             tb="$tb i386netbsd.lo aout32.lo" ;;
 733     i386os9k_vec)               tb="$tb i386os9k.lo aout32.lo" ;;
 734     i386pe_vec)                 tb="$tb pe-i386.lo peigen.lo cofflink.lo" ;;
 735     i386pei_vec)                tb="$tb pei-i386.lo peigen.lo cofflink.lo" ;;
 736     i860coff_vec)               tb="$tb coff-i860.lo cofflink.lo" ;;
 737     icoff_big_vec)              tb="$tb coff-i960.lo cofflink.lo" ;;
 738     icoff_little_vec)           tb="$tb coff-i960.lo cofflink.lo" ;;
 739     ieee_vec)                   tb="$tb ieee.lo" ;;
 740     m68k4knetbsd_vec)           tb="$tb m68k4knetbsd.lo aout32.lo" ;;
 741     m68kaux_coff_vec)           tb="$tb coff-aux.lo coff-m68k.lo cofflink.lo" ;;
 742     m68kcoff_vec)               tb="$tb coff-m68k.lo cofflink.lo" ;;
 743     m68kcoffun_vec)             tb="$tb coff-u68k.lo coff-m68k.lo cofflink.lo" ;;
 744     m68klinux_vec)              tb="$tb m68klinux.lo aout32.lo" ;;
 745     m68knetbsd_vec)             tb="$tb m68knetbsd.lo aout32.lo" ;;
 746     m68ksysvcoff_vec)           tb="$tb coff-svm68k.lo cofflink.lo" ;;
 747     m88kbcs_vec)                tb="$tb coff-m88k.lo" ;;
 748     m88kmach3_vec)              tb="$tb m88kmach3.lo aout32.lo" ;;
 749     m88kopenbsd_vec)            tb="$tb m88kopenbsd.lo aout32.lo" ;;
 750     maxqcoff_vec)               tb="$tb coff-maxq.lo" ;;
 751     mach_o_be_vec)              tb="$tb mach-o.lo" ;;
 752     mach_o_le_vec)              tb="$tb mach-o.lo" ;;
 753     mach_o_fat_vec)             tb="$tb mach-o.lo" ;;
 754     mcore_pe_big_vec)           tb="$tb pe-mcore.lo peigen.lo cofflink.lo" ;;
 755     mcore_pe_little_vec)        tb="$tb pe-mcore.lo peigen.lo cofflink.lo" ;;
 756     mcore_pei_big_vec)          tb="$tb pei-mcore.lo peigen.lo cofflink.lo" ;;
 757     mcore_pei_little_vec)       tb="$tb pei-mcore.lo peigen.lo cofflink.lo" ;;
 758     mipslpe_vec)                tb="$tb pe-mips.lo peigen.lo cofflink.lo" ;;
 759     mipslpei_vec)               tb="$tb pei-mips.lo peigen.lo cofflink.lo" ;;
 760     newsos3_vec)                tb="$tb newsos3.lo aout32.lo" ;;
 761     nlm32_alpha_vec)            tb="$tb nlm32-alpha.lo nlm32.lo nlm.lo"; target_size=64 ;;
 762     nlm32_i386_vec)             tb="$tb nlm32-i386.lo nlm32.lo nlm.lo" ;;
 763     nlm32_powerpc_vec)          tb="$tb nlm32-ppc.lo nlm32.lo nlm.lo" ;;
 764     nlm32_sparc_vec)            tb="$tb nlm32-sparc.lo nlm32.lo nlm.lo" ;;
 765     or32coff_big_vec)           tb="$tb coff-or32.lo cofflink.lo" ;;
 766     pc532machaout_vec)          tb="$tb pc532-mach.lo aout-ns32k.lo" ;;
 767     pc532netbsd_vec)            tb="$tb ns32knetbsd.lo aout-ns32k.lo" ;;
 768     pef_vec)                    tb="$tb pef.lo" ;;
 769     pef_xlib_vec)               tb="$tb pef.lo" ;;
 770     pdp11_aout_vec)             tb="$tb pdp11.lo" ;;
 771     pmac_xcoff_vec)             tb="$tb coff-rs6000.lo xcofflink.lo" ;;
 772     ppcboot_vec)                tb="$tb ppcboot.lo" ;;
 773     riscix_vec)                 tb="$tb aout32.lo riscix.lo" ;;
 774     rs6000coff64_vec)           tb="$tb coff64-rs6000.lo xcofflink.lo aix5ppc-core.lo"; target_size=64 ;;
 775     rs6000coff_vec)             tb="$tb coff-rs6000.lo xcofflink.lo" ;;
 776     shcoff_small_vec)           tb="$tb coff-sh.lo cofflink.lo" ;;
 777     shcoff_vec)                 tb="$tb coff-sh.lo cofflink.lo" ;;
 778     shlcoff_small_vec)          tb="$tb coff-sh.lo cofflink.lo" ;;
 779     shlcoff_vec)                tb="$tb coff-sh.lo cofflink.lo" ;;
 780     shlpe_vec)                  tb="$tb pe-sh.lo coff-sh.lo peigen.lo cofflink.lo" ;;
 781     shlpei_vec)                 tb="$tb pei-sh.lo coff-sh.lo peigen.lo cofflink.lo" ;;
 782     som_vec)                    tb="$tb som.lo" ;;
 783     sparccoff_vec)              tb="$tb coff-sparc.lo" ;;
 784     sparcle_aout_vec)           tb="$tb aout-sparcle.lo aout32.lo" ;;
 785     sparclinux_vec)             tb="$tb sparclinux.lo aout32.lo" ;;
 786     sparclynx_aout_vec)         tb="$tb sparclynx.lo lynx-core.lo aout32.lo" ;;
 787     sparclynx_coff_vec)         tb="$tb cf-sparclynx.lo lynx-core.lo" ;;
 788     sparcnetbsd_vec)            tb="$tb sparcnetbsd.lo aout32.lo" ;;
 789     sunos_big_vec)              tb="$tb sunos.lo aout32.lo" ;;
 790     sym_vec)                    tb="$tb xsym.lo" ;;
 791     tic30_aout_vec)             tb="$tb aout-tic30.lo" ;;
 792     tic30_coff_vec)             tb="$tb coff-tic30.lo" ;;
 793     tic4x_coff0_vec)            tb="$tb coff-tic4x.lo" ;;
 794     tic4x_coff0_beh_vec)        tb="$tb coff-tic4x.lo" ;;
 795     tic4x_coff1_vec)            tb="$tb coff-tic4x.lo" ;;
 796     tic4x_coff1_beh_vec)        tb="$tb coff-tic4x.lo" ;;
 797     tic4x_coff2_vec)            tb="$tb coff-tic4x.lo" ;;
 798     tic4x_coff2_beh_vec)        tb="$tb coff-tic4x.lo" ;;
 799     tic54x_coff0_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 800     tic54x_coff0_vec)           tb="$tb coff-tic54x.lo" ;;
 801     tic54x_coff1_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 802     tic54x_coff1_vec)           tb="$tb coff-tic54x.lo" ;;
 803     tic54x_coff2_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 804     tic54x_coff2_vec)           tb="$tb coff-tic54x.lo" ;;
 805     tic80coff_vec)              tb="$tb coff-tic80.lo cofflink.lo" ;;
 806     vaxnetbsd_vec)              tb="$tb vaxnetbsd.lo aout32.lo" ;;
 807     vax1knetbsd_vec)            tb="$tb vax1knetbsd.lo aout32.lo" ;;
 808     vaxbsd_vec)                 tb="$tb vaxbsd.lo aout32.lo" ;;
 809     versados_vec)               tb="$tb versados.lo" ;;
 810     vms_alpha_vec)              tb="$tb vms.lo vms-hdr.lo vms-gsd.lo vms-tir.lo vms-misc.lo"; target_size=64 ;;
 811     vms_vax_vec)                tb="$tb vms.lo vms-hdr.lo vms-gsd.lo vms-tir.lo vms-misc.lo" ;;
 812     w65_vec)                    tb="$tb coff-w65.lo reloc16.lo" ;;
 813     we32kcoff_vec)              tb="$tb coff-we32k.lo" ;;
 814     z80coff_vec)                tb="$tb coff-z80.lo reloc16.lo" ;;
 815     z8kcoff_vec)                tb="$tb coff-z8k.lo reloc16.lo cofflink.lo" ;;
 816
 817     # These appear out of order in targets.c
 818     srec_vec)                   tb="$tb srec.lo" ;;
 819     symbolsrec_vec)             tb="$tb srec.lo" ;;
 820     tekhex_vec)                 tb="$tb tekhex.lo" ;;
 821     cisco_core_big_vec)         tb="$tb cisco-core.lo" ;;
 822     cisco_core_little_vec)      tb="$tb cisco-core.lo" ;;
 823
 824     "")                 ;;
 825     *) AC_MSG_ERROR(*** unknown target vector $vec) ;;
 826     esac
 827
 828     if test ${target_size} = 64; then
 829         target64=true
 830     fi
 831     if test x"${vec}" = x"${defvec}"; then
 832         bfd_default_target_size=${target_size}
 833     fi
 834 done
 835
 836 # Target architecture .o files.
 837 # A couple of CPUs use shorter file names to avoid problems on DOS
 838 # filesystems.
 839 ta=`echo $selarchs | sed -e s/bfd_/cpu-/g -e s/_arch/.lo/g -e s/mn10200/m10200/ -e s/mn10300/m10300/`
 840
 841 # Weed out duplicate .o files.
 842 f=""
 843 for i in $tb ; do
 844     case " $f " in
 845     *" $i "*) ;;
 846     *) f="$f $i" ;;
 847     esac
 848 done
 849 tb="$f"
 850
 851 f=""
 852 for i in $ta ; do
 853     case " $f " in
 854     *" $i "*) ;;
 855     *) f="$f $i" ;;
 856     esac
 857 done
 858 ta="$f"
 859
 860 bfd_backends="$tb"
 861 bfd_machines="$ta"
 862
 863 if test x${all_targets} = xtrue ; then
 864   bfd_backends="${bfd_backends}"' $(ALL_BACKENDS)'
 865   bfd_machines="${bfd_machines}"' $(ALL_MACHINES)'
 866   selvecs=
 867   havevecs=
 868   selarchs=
 869   test -n "$assocvecs" &&
 870     assocvecs=`echo $assocvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 871 else    # all_targets is true
 872   # Only set these if they will be nonempty, for the clever echo.
 873   havevecs=
 874   assocvecs=
 875   test -n "$selvecs" &&
 876     havevecs=`echo $selvecs | sed -e 's/^/-DHAVE_/' -e 's/ \(.\)/ -DHAVE_\1/g'`
 877   test -n "$selvecs" &&
 878     selvecs=`echo $selvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 879   test -n "$selarchs" &&
 880     selarchs=`echo $selarchs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 881 fi      # all_targets is true
 882
 883 case ${host64}-${target64}-${want64} in
 884   *true*)
 885     wordsize=64
 886     bfd_libs='$(BFD64_LIBS) $(BFD32_LIBS)'
 887     all_backends='$(BFD64_BACKENDS) $(BFD32_BACKENDS)'
 888     if test $BFD_HOST_64_BIT_DEFINED = 0; then
 889       AC_MSG_WARN([You have requested a 64 bit BFD configuration, but])
 890       AC_MSG_WARN([your compiler may not have a 64 bit integral type])
 891     fi
 892     if test -n "$GCC" ; then
 893        bad_64bit_gcc=no;
 894        AC_MSG_CHECKING([for gcc version with buggy 64-bit support])
 895        # Add more tests for gcc versions with non-working 64-bit support here.
 896        AC_EGREP_CPP([: 2 : 91 : 1 :],[:__GNUC__:__GNUC_MINOR__:__i386__:],
 897                     bad_64bit_gcc=yes;
 898                     AC_MSG_RESULT([yes: egcs-1.1.2 on ix86 spotted]),
 899                     AC_MSG_RESULT(no))
 900        if test $bad_64bit_gcc = yes ; then
 901          AC_MSG_ERROR([A newer version of gcc is needed for the requested 64-bit BFD configuration])
 902        fi
 903     fi
 904     ;;
 905   false-false-false)
 906     wordsize=32
 907     bfd_libs='$(BFD32_LIBS)'
 908     all_backends='$(BFD32_BACKENDS)'
 909     ;;
 910 esac
 911
 912 AC_SUBST(wordsize)
 913 AC_SUBST(bfd_libs)
 914 AC_SUBST(all_backends)
 915 AC_SUBST(bfd_backends)
 916 AC_SUBST(bfd_machines)
 917 AC_SUBST(bfd_default_target_size)
 918
 919 # Determine the host dependant file_ptr a.k.a. off_t type.  In order
 920 # prefer: off64_t - if ftello64 and fseeko64, off_t - if ftello and
 921 # fseeko, long.  This assumes that sizeof off_t is .ge. sizeof long.
 922 # Hopefully a reasonable assumption since fseeko et.al. should be
 923 # upward compatible.
 924 AC_CHECK_FUNCS(ftello ftello64 fseeko fseeko64 fopen64)
 925 if test x"$ac_cv_func_ftello" = xyes -a x"$ac_cv_func_fseeko" = xyes; then
 926     AC_CHECK_SIZEOF(off_t)
 927 fi
 928 AC_MSG_CHECKING([file_ptr type])
 929 bfd_file_ptr="long"
 930 bfd_ufile_ptr="unsigned long"
 931 if test x"$ac_cv_func_ftello64" = xyes -a x"$ac_cv_func_fseeko64" = xyes \
 932         -o x"${ac_cv_sizeof_off_t}" = x8; then
 933     bfd_file_ptr=BFD_HOST_64_BIT
 934     bfd_ufile_ptr=BFD_HOST_U_64_BIT
 935 fi
 936 AC_MSG_RESULT($bfd_file_ptr)
 937 AC_SUBST(bfd_file_ptr)
 938 AC_SUBST(bfd_ufile_ptr)
 939
 940
 941 tdefaults=""
 942 test -n "${defvec}" && tdefaults="${tdefaults} -DDEFAULT_VECTOR=${defvec}"
 943 test -n "${selvecs}" && tdefaults="${tdefaults} -DSELECT_VECS='${selvecs}'"
 944 test -n "${assocvecs}" && tdefaults="${tdefaults} -DASSOCIATED_VECS='${assocvecs}'"
 945 test -n "${selarchs}" && tdefaults="${tdefaults} -DSELECT_ARCHITECTURES='${selarchs}'"
 946 test -n "${havevecs}" && tdefaults="${tdefaults} ${havevecs}"
 947 AC_SUBST(tdefaults)
 948
 949 dnl AC_CHECK_HEADERS(sys/mman.h)
 950 AC_FUNC_MMAP
 951 AC_CHECK_FUNCS(madvise mprotect)
 952 case ${want_mmap}+${ac_cv_func_mmap_fixed_mapped} in
 953   true+yes )  AC_DEFINE(USE_MMAP, 1, [Use mmap if it's available?]) ;;
 954 esac
 955
 956 rm -f doc/config.status
 957 AC_CONFIG_FILES([Makefile doc/Makefile bfd-in3.h:bfd-in2.h po/Makefile.in:po/Make-in])
 958 AC_CONFIG_COMMANDS([default],[[sed -e '/SRC-POTFILES =/r po/SRC-POTFILES' -e '/BLD-POTFILES =/r po/BLD-POTFILES' po/Makefile.in > po/Makefile]],[[]])
 959 AC_OUTPUT
 960