opcodes/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT
   6 AC_CONFIG_SRCDIR([z8k-dis.c])
   7
   8 AC_CANONICAL_TARGET
   9 AC_ISC_POSIX
  10
  11 # We currently only use the version number for the name of any shared
  12 # library.  For user convenience, we always use the same version
  13 # number that BFD is using.
  14 changequote(,)dnl
  15 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  16 changequote([,])dnl
  17
  18 AM_INIT_AUTOMAKE(opcodes, ${BFD_VERSION})
  19
  20 AC_PROG_CC
  21 AC_GNU_SOURCE
  22
  23 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  24 dnl to call AC_CHECK_PROG.
  25 AC_CHECK_TOOL(AR, ar)
  26 AC_CHECK_TOOL(RANLIB, ranlib, :)
  27
  28 dnl Default to a non shared library.  This may be overridden by the
  29 dnl configure option --enable-shared.
  30 AM_DISABLE_SHARED
  31
  32 AM_PROG_LIBTOOL
  33
  34 AC_ARG_ENABLE(targets,
  35 [  --enable-targets        alternative target configurations],
  36 [case "${enableval}" in
  37   yes | "") AC_MSG_ERROR([enable-targets option must specify target names or 'all'])
  38             ;;
  39   no)       enable_targets= ;;
  40   *)        enable_targets=$enableval ;;
  41 esac])dnl
  42 AC_ARG_ENABLE(commonbfdlib,
  43 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  44 [case "${enableval}" in
  45   yes) commonbfdlib=true ;;
  46   no)  commonbfdlib=false ;;
  47   *)   AC_MSG_ERROR([bad value ${enableval} for opcodes commonbfdlib option]) ;;
  48 esac])dnl
  49
  50 AM_BINUTILS_WARNINGS
  51
  52 AM_CONFIG_HEADER(config.h:config.in)
  53
  54 if test -z "$target" ; then
  55     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  56 fi
  57
  58 AM_MAINTAINER_MODE
  59 AM_INSTALL_LIBBFD
  60 AC_EXEEXT
  61
  62 # host-specific stuff:
  63
  64 ALL_LINGUAS="fr sv tr es da de id pt_BR ro nl fi vi ga zh_CN"
  65 ZW_GNU_GETTEXT_SISTER_DIR
  66 AM_PO_SUBDIRS
  67
  68 . ${srcdir}/../bfd/configure.host
  69
  70 BFD_CC_FOR_BUILD
  71
  72 AC_SUBST(HDEFINES)
  73 AC_PROG_INSTALL
  74
  75 AC_CHECK_HEADERS(string.h strings.h stdlib.h limits.h)
  76
  77 AC_CHECK_DECLS([basename, stpcpy])
  78
  79 cgen_maint=no
  80 cgendir='$(srcdir)/../cgen'
  81
  82 AC_ARG_ENABLE(cgen-maint,
  83 [  --enable-cgen-maint[=dir]    build cgen generated files],
  84 [case "${enableval}" in
  85   yes)  cgen_maint=yes ;;
  86   no)   cgen_maint=no ;;
  87   *)
  88         # argument is cgen install directory (not implemented yet).
  89         # Having a `share' directory might be more appropriate for the .scm,
  90         # .cpu, etc. files.
  91         cgen_maint=yes
  92         cgendir=${cgen_maint}/lib/cgen
  93         ;;
  94 esac])dnl
  95 AM_CONDITIONAL(CGEN_MAINT, test x${cgen_maint} = xyes)
  96 AC_SUBST(cgendir)
  97
  98 using_cgen=no
  99
 100 # Horrible hacks to build DLLs on Windows.
 101 WIN32LDFLAGS=
 102 WIN32LIBADD=
 103 case "${host}" in
 104 *-*-cygwin*)
 105   if test "$enable_shared" = "yes"; then
 106     WIN32LDFLAGS="-no-undefined"
 107     WIN32LIBADD="-L`pwd`/../bfd -lbfd -L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin"
 108   fi
 109   ;;
 110 esac
 111 AC_SUBST(WIN32LDFLAGS)
 112 AC_SUBST(WIN32LIBADD)
 113
 114 # target-specific stuff:
 115
 116 # Canonicalize the secondary target names.
 117 if test -n "$enable_targets" ; then
 118     for targ in `echo $enable_targets | sed 's/,/ /g'`
 119     do
 120         result=`$ac_config_sub $targ 2>/dev/null`
 121         if test -n "$result" ; then
 122             canon_targets="$canon_targets $result"
 123         else
 124             # Allow targets that config.sub doesn't recognize, like "all".
 125             canon_targets="$canon_targets $targ"
 126         fi
 127     done
 128 fi
 129
 130 all_targets=false
 131 selarchs=
 132 for targ in $target $canon_targets
 133 do
 134     if test "x$targ" = "xall" ; then
 135         all_targets=true
 136     else
 137         . $srcdir/../bfd/config.bfd
 138         selarchs="$selarchs $targ_archs"
 139     fi
 140 done
 141
 142 # Utility var, documents generic cgen support files.
 143
 144 cgen_files="cgen-opc.lo cgen-asm.lo cgen-dis.lo cgen-bitset.lo"
 145
 146 # We don't do any links based on the target system, just makefile config.
 147
 148 if test x${all_targets} = xfalse ; then
 149
 150     # Target architecture .o files.
 151     ta=
 152
 153     for arch in $selarchs
 154     do
 155         ad=`echo $arch | sed -e s/bfd_//g -e s/_arch//g`
 156         archdefs="$archdefs -DARCH_$ad"
 157         case "$arch" in
 158         bfd_alpha_arch)         ta="$ta alpha-dis.lo alpha-opc.lo" ;;
 159         bfd_arc_arch)           ta="$ta arc-dis.lo arc-opc.lo arc-ext.lo" ;;
 160         bfd_arm_arch)           ta="$ta arm-dis.lo" ;;
 161         bfd_avr_arch)           ta="$ta avr-dis.lo" ;;
 162         bfd_bfin_arch)          ta="$ta bfin-dis.lo" ;;
 163         bfd_cr16_arch)          ta="$ta cr16-dis.lo cr16-opc.lo" ;;
 164         bfd_cris_arch)          ta="$ta cris-dis.lo cris-opc.lo cgen-bitset.lo" ;;
 165         bfd_crx_arch)           ta="$ta crx-dis.lo crx-opc.lo" ;;
 166         bfd_d10v_arch)          ta="$ta d10v-dis.lo d10v-opc.lo" ;;
 167         bfd_d30v_arch)          ta="$ta d30v-dis.lo d30v-opc.lo" ;;
 168         bfd_dlx_arch)           ta="$ta dlx-dis.lo" ;;
 169         bfd_fr30_arch)          ta="$ta fr30-asm.lo fr30-desc.lo fr30-dis.lo fr30-ibld.lo fr30-opc.lo" using_cgen=yes ;;
 170         bfd_frv_arch)           ta="$ta frv-asm.lo frv-desc.lo frv-dis.lo frv-ibld.lo frv-opc.lo" using_cgen=yes ;;
 171         bfd_h8300_arch)         ta="$ta h8300-dis.lo" ;;
 172         bfd_h8500_arch)         ta="$ta h8500-dis.lo" ;;
 173         bfd_hppa_arch)          ta="$ta hppa-dis.lo" ;;
 174         bfd_i370_arch)          ta="$ta i370-dis.lo i370-opc.lo" ;;
 175         bfd_i386_arch)          ta="$ta i386-dis.lo i386-opc.lo" ;;
 176         bfd_i860_arch)          ta="$ta i860-dis.lo" ;;
 177         bfd_i960_arch)          ta="$ta i960-dis.lo" ;;
 178         bfd_ia64_arch)          ta="$ta ia64-dis.lo ia64-opc.lo" ;;
 179         bfd_ip2k_arch)          ta="$ta ip2k-asm.lo ip2k-desc.lo ip2k-dis.lo ip2k-ibld.lo ip2k-opc.lo" using_cgen=yes ;;
 180         bfd_iq2000_arch)        ta="$ta iq2000-asm.lo iq2000-desc.lo iq2000-dis.lo iq2000-ibld.lo iq2000-opc.lo" using_cgen=yes ;;
 181         bfd_m32c_arch)          ta="$ta m32c-asm.lo m32c-desc.lo m32c-dis.lo m32c-ibld.lo m32c-opc.lo" using_cgen=yes ;;
 182         bfd_m32r_arch)          ta="$ta m32r-asm.lo m32r-desc.lo m32r-dis.lo m32r-ibld.lo m32r-opc.lo m32r-opinst.lo" using_cgen=yes ;;
 183         bfd_m68hc11_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 184         bfd_m68hc12_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 185         bfd_m68k_arch)          ta="$ta m68k-dis.lo m68k-opc.lo" ;;
 186         bfd_m88k_arch)          ta="$ta m88k-dis.lo" ;;
 187         bfd_maxq_arch)          ta="$ta maxq-dis.lo" ;;
 188         bfd_mcore_arch)         ta="$ta mcore-dis.lo" ;;
 189         bfd_mep_arch)           ta="$ta mep-asm.lo mep-desc.lo mep-dis.lo mep-ibld.lo mep-opc.lo" using_cgen=yes ;;
 190         bfd_mips_arch)          ta="$ta mips-dis.lo mips-opc.lo mips16-opc.lo" ;;
 191         bfd_mmix_arch)          ta="$ta mmix-dis.lo mmix-opc.lo" ;;
 192         bfd_mn10200_arch)       ta="$ta m10200-dis.lo m10200-opc.lo" ;;
 193         bfd_mn10300_arch)       ta="$ta m10300-dis.lo m10300-opc.lo" ;;
 194         bfd_mt_arch)            ta="$ta mt-asm.lo mt-desc.lo mt-dis.lo mt-ibld.lo mt-opc.lo" using_cgen=yes ;;
 195         bfd_msp430_arch)        ta="$ta msp430-dis.lo" ;;
 196         bfd_ns32k_arch)         ta="$ta ns32k-dis.lo" ;;
 197         bfd_openrisc_arch)      ta="$ta openrisc-asm.lo openrisc-desc.lo openrisc-dis.lo openrisc-ibld.lo openrisc-opc.lo" using_cgen=yes ;;
 198         bfd_or32_arch)          ta="$ta or32-dis.lo or32-opc.lo" using_cgen=yes ;;
 199         bfd_pdp11_arch)         ta="$ta pdp11-dis.lo pdp11-opc.lo" ;;
 200         bfd_pj_arch)            ta="$ta pj-dis.lo pj-opc.lo" ;;
 201         bfd_powerpc_arch)       ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 202         bfd_powerpc_64_arch)    ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 203         bfd_pyramid_arch)       ;;
 204         bfd_romp_arch)          ;;
 205         bfd_rs6000_arch)        ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 206         bfd_s390_arch)          ta="$ta s390-dis.lo s390-opc.lo" ;;
 207         bfd_score_arch)         ta="$ta score-dis.lo" ;;
 208         bfd_sh_arch)
 209           # We can't decide what we want just from the CPU family.
 210           # We want SH5 support unless a specific version of sh is
 211           # specified, as in sh3-elf, sh3b-linux-gnu, etc.
 212           # Include it just for ELF targets, since the SH5 bfd:s are ELF only.
 213           for t in $target $canon_targets; do
 214             case $t in
 215               all |  sh5*-* | sh64*-* | sh-*-*elf* | shl*-*-*elf* | \
 216               sh-*-linux* | shl-*-linux*)
 217                                 ta="$ta sh64-dis.lo sh64-opc.lo"
 218                                 archdefs="$archdefs -DINCLUDE_SHMEDIA"
 219                                 break;;
 220             esac;
 221           done
 222                                 ta="$ta sh-dis.lo cgen-bitset.lo" ;;
 223         bfd_sparc_arch)         ta="$ta sparc-dis.lo sparc-opc.lo" ;;
 224         bfd_spu_arch)           ta="$ta spu-dis.lo spu-opc.lo" ;;
 225         bfd_tahoe_arch)         ;;
 226         bfd_tic30_arch)         ta="$ta tic30-dis.lo" ;;
 227         bfd_tic4x_arch)         ta="$ta tic4x-dis.lo" ;;
 228         bfd_tic54x_arch)        ta="$ta tic54x-dis.lo tic54x-opc.lo" ;;
 229         bfd_tic80_arch)         ta="$ta tic80-dis.lo tic80-opc.lo" ;;
 230         bfd_v850_arch)          ta="$ta v850-opc.lo v850-dis.lo" ;;
 231         bfd_v850e_arch)         ta="$ta v850-opc.lo v850-dis.lo" ;;
 232         bfd_v850ea_arch)        ta="$ta v850-opc.lo v850-dis.lo" ;;
 233         bfd_vax_arch)           ta="$ta vax-dis.lo" ;;
 234         bfd_w65_arch)           ta="$ta w65-dis.lo" ;;
 235         bfd_we32k_arch)         ;;
 236         bfd_xc16x_arch)         ta="$ta xc16x-asm.lo xc16x-desc.lo xc16x-dis.lo xc16x-ibld.lo xc16x-opc.lo" using_cgen=yes ;;
 237         bfd_xstormy16_arch)     ta="$ta xstormy16-asm.lo xstormy16-desc.lo xstormy16-dis.lo xstormy16-ibld.lo xstormy16-opc.lo" using_cgen=yes ;;
 238         bfd_xtensa_arch)        ta="$ta xtensa-dis.lo" ;;
 239         bfd_z80_arch)           ta="$ta z80-dis.lo" ;;
 240         bfd_z8k_arch)           ta="$ta z8k-dis.lo" ;;
 241
 242         "")                     ;;
 243         *)              AC_MSG_ERROR(*** unknown target architecture $arch) ;;
 244         esac
 245     done
 246
 247     if test $using_cgen = yes ; then
 248         ta="$ta $cgen_files"
 249     fi
 250
 251     # Weed out duplicate .o files.
 252     f=""
 253     for i in $ta ; do
 254         case " $f " in
 255         *" $i "*) ;;
 256         *) f="$f $i" ;;
 257         esac
 258     done
 259     ta="$f"
 260
 261     # And duplicate -D flags.
 262     f=""
 263     for i in $archdefs ; do
 264         case " $f " in
 265         *" $i "*) ;;
 266         *) f="$f $i" ;;
 267         esac
 268     done
 269     archdefs="$f"
 270
 271     BFD_MACHINES="$ta"
 272
 273 else    # all_targets is true
 274     archdefs=-DARCH_all
 275     BFD_MACHINES='$(ALL_MACHINES)'
 276 fi
 277
 278 AC_SUBST(archdefs)
 279 AC_SUBST(BFD_MACHINES)
 280
 281 AC_CONFIG_FILES([Makefile po/Makefile.in:po/Make-in])
 282 AC_OUTPUT