binutils/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl   Copyright (C) 2012-2024 Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9 dnl
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program; see the file COPYING3.  If not see
  17 dnl <http://www.gnu.org/licenses/>.
  18 dnl
  19
  20 m4_include([../bfd/version.m4])
  21 m4_include([../config/debuginfod.m4])
  22 AC_INIT([binutils], BFD_VERSION)
  23 AC_CONFIG_SRCDIR(ar.c)
  24
  25 AC_CANONICAL_TARGET
  26
  27 AM_INIT_AUTOMAKE
  28 AM_SILENT_RULES([yes])
  29
  30 AC_PROG_CC
  31 AC_GNU_SOURCE
  32 AC_USE_SYSTEM_EXTENSIONS
  33
  34 AC_C_BIGENDIAN
  35
  36 LT_INIT
  37 ACX_LARGEFILE
  38
  39 ac_checking=
  40 . ${srcdir}/../bfd/development.sh
  41 test "$development" = true && ac_checking=yes
  42 AC_ARG_ENABLE(checking,
  43 [  --enable-checking       enable run-time checks],
  44 [case "${enableval}" in
  45   no|none)  ac_checking= ;;
  46   *)        ac_checking=yes ;;
  47 esac])dnl
  48 if test x$ac_checking != x ; then
  49   AC_DEFINE(ENABLE_CHECKING, 1, [Define if you want run-time sanity checks.])
  50 fi
  51
  52 AC_ARG_ENABLE(targets,
  53 [  --enable-targets        alternative target configurations],
  54 [case "${enableval}" in
  55   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  56             ;;
  57   no)       enable_targets= ;;
  58   *)        enable_targets=$enableval ;;
  59 esac])dnl
  60
  61
  62 AC_ARG_ENABLE(deterministic-archives,
  63 [AS_HELP_STRING([--enable-deterministic-archives],
  64                 [ar and ranlib default to -D behavior])], [
  65 if test "${enableval}" = no; then
  66   default_ar_deterministic=0
  67 else
  68   default_ar_deterministic=1
  69 fi], [default_ar_deterministic=0])
  70
  71 AC_DEFINE_UNQUOTED(DEFAULT_AR_DETERMINISTIC, $default_ar_deterministic,
  72                    [Should ar and ranlib use -D behavior by default?])
  73
  74
  75 AC_ARG_ENABLE(default-strings-all,
  76 [AS_HELP_STRING([--disable-default-strings-all],
  77                 [strings defaults to --data behavior])], [
  78 if test "${enableval}" = no; then
  79   default_strings_all=0
  80 else
  81   default_strings_all=1
  82 fi], [default_strings_all=1])
  83
  84 AC_DEFINE_UNQUOTED(DEFAULT_STRINGS_ALL, $default_strings_all,
  85                    [Should strings use -a behavior by default?])
  86
  87
  88 AC_ARG_ENABLE(f-for-ifunc-symbols,
  89 [AS_HELP_STRING([--enable-f-for-ifunc-symbols],
  90         [Have nm use F and f for global and local ifunc symbols])], [
  91 if test "${enableval}" = no; then
  92   default_f_for_ifunc=0
  93 else
  94   default_f_for_ifunc=1
  95 fi], [default_f_for_ifunc=0])
  96
  97 AC_DEFINE_UNQUOTED(DEFAULT_F_FOR_IFUNC_SYMBOLS, $default_f_for_ifunc,
  98                    [Have nm use F and f for global and local ifunc symbols])
  99
 100
 101 AC_ARG_ENABLE(follow-debug-links,
 102 [AS_HELP_STRING([--enable-follow-debug-links],
 103         [Have readelf and objdump follow debug links by default])], [
 104 if test "${enableval}" = no; then
 105   default_for_follow_links=0
 106 else
 107   default_for_follow_links=1
 108 fi], [default_for_follow_links=1])
 109
 110 AC_DEFINE_UNQUOTED(DEFAULT_FOR_FOLLOW_LINKS, $default_for_follow_links,
 111                    [Have readelf and objdump follow debug links by default])
 112
 113
 114
 115
 116 AC_ARG_ENABLE(colored-disassembly,
 117 [AS_HELP_STRING([--enable-colored-disassembly],
 118         [Have objdump use colors in its disassembly by default])], [
 119 if test "${enableval}" = no; then
 120   default_for_colored_disassembly=0
 121 else
 122   default_for_colored_disassembly=1
 123 fi], [default_for_colored_disassembly=0])
 124
 125 AC_DEFINE_UNQUOTED(DEFAULT_FOR_COLORED_DISASSEMBLY, $default_for_colored_disassembly,
 126                    [Have objdump use colors in its disassembly by default])
 127
 128
 129 AC_DEBUGINFOD
 130
 131 GCC_ENABLE([libctf], [yes], [], [Handle .ctf type-info sections])
 132 if test "${enable_libctf}" = yes; then
 133     AC_DEFINE(ENABLE_LIBCTF, 1, [Handle .ctf type-info sections])
 134 fi
 135 AM_CONDITIONAL(ENABLE_LIBCTF, test "${enable_libctf}" = yes)
 136
 137 AM_BINUTILS_WARNINGS
 138
 139 AC_CONFIG_HEADERS(config.h:config.in)
 140
 141 AH_VERBATIM([00_CONFIG_H_CHECK],
 142 [/* Check that config.h is #included before system headers
 143    (this works only for glibc, but that should be enough).  */
 144 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
 145 #  error config.h must be #included before system headers
 146 #endif
 147 #define __CONFIG_H__ 1])
 148
 149 if test -z "$target" ; then
 150     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
 151 fi
 152 if test -z "$host" ; then
 153     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
 154 fi
 155
 156 AC_PROG_YACC
 157 AM_PROG_LEX
 158
 159 ALL_LINGUAS="bg ca da es fi fr hr id it ja pt ro ru rw sk sr sv tr uk vi zh_CN zh_TW"
 160 ZW_GNU_GETTEXT_SISTER_DIR
 161 AM_PO_SUBDIRS
 162
 163 AM_MAINTAINER_MODE
 164 AM_CONDITIONAL(GENINSRC_NEVER, false)
 165 AC_EXEEXT
 166 if test -n "$EXEEXT"; then
 167   AC_DEFINE(HAVE_EXECUTABLE_SUFFIX, 1,
 168             [Does the platform use an executable suffix?])
 169 fi
 170 AC_DEFINE_UNQUOTED(EXECUTABLE_SUFFIX, "${EXEEXT}",
 171                    [Suffix used for executables, if any.])
 172
 173 # host-specific stuff:
 174
 175 HDEFINES=
 176
 177 . ${srcdir}/../bfd/configure.host
 178
 179 AC_SUBST(HDEFINES)
 180 AR=${AR-ar}
 181 AC_SUBST(AR)
 182 AC_PROG_RANLIB
 183 AC_PROG_INSTALL
 184
 185 BFD_CC_FOR_BUILD
 186
 187 DEMANGLER_NAME=c++filt
 188 case "${host}" in
 189   *-*-go32* | *-*-msdos*)
 190     DEMANGLER_NAME=cxxfilt
 191 esac
 192 AC_SUBST(DEMANGLER_NAME)
 193
 194 # We use headers from include/ that check various HAVE_*_H macros, thus
 195 # should ensure they are set by configure.  This is true even when C99
 196 # guarantees they are available.
 197 # plugin-api.h tests HAVE_STDINT_H and HAVE_INTTYPES_H
 198 # Besides those, we need to check anything used in binutils/ not in C99.
 199 AC_CHECK_HEADERS(fcntl.h inttypes.h stdint.h sys/file.h \
 200                  sys/stat.h sys/time.h sys/types.h unistd.h)
 201 AC_HEADER_SYS_WAIT
 202 AC_FUNC_MMAP
 203 AC_CHECK_FUNCS(fseeko fseeko64 getc_unlocked mkdtemp mkstemp utimensat utimes)
 204
 205 AC_MSG_CHECKING([for mbstate_t])
 206 AC_TRY_COMPILE([#include <wchar.h>],
 207 [mbstate_t teststate;],
 208 have_mbstate_t=yes, have_mbstate_t=no)
 209 AC_MSG_RESULT($have_mbstate_t)
 210 if test x"$have_mbstate_t" = xyes; then
 211   AC_DEFINE(HAVE_MBSTATE_T,1,[Define if mbstate_t exists in wchar.h.])
 212 fi
 213
 214 # Copied from gnulib stat-time.m4.
 215 # We should just switch over to using gnulib.
 216 AC_CHECK_MEMBERS([struct stat.st_atim.tv_nsec],
 217   [AC_CACHE_CHECK([whether struct stat.st_atim is of type struct timespec],
 218      [ac_cv_typeof_struct_stat_st_atim_is_struct_timespec],
 219      [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 220         [[
 221           #include <sys/types.h>
 222           #include <sys/stat.h>
 223           #if HAVE_SYS_TIME_H
 224           # include <sys/time.h>
 225           #endif
 226           #include <time.h>
 227           struct timespec ts;
 228           struct stat st;
 229         ]],
 230         [[
 231           st.st_atim = ts;
 232         ]])],
 233         [ac_cv_typeof_struct_stat_st_atim_is_struct_timespec=yes],
 234         [ac_cv_typeof_struct_stat_st_atim_is_struct_timespec=no])])
 235    if test $ac_cv_typeof_struct_stat_st_atim_is_struct_timespec = yes; then
 236      AC_DEFINE([TYPEOF_STRUCT_STAT_ST_ATIM_IS_STRUCT_TIMESPEC], [1],
 237        [Define to 1 if the type of the st_atim member of a struct stat is
 238         struct timespec.])
 239    fi],
 240   [AC_CHECK_MEMBERS([struct stat.st_atimespec.tv_nsec], [],
 241      [AC_CHECK_MEMBERS([struct stat.st_atimensec], [],
 242         [AC_CHECK_MEMBERS([struct stat.st_atim.st__tim.tv_nsec], [], [],
 243            [#include <sys/types.h>
 244             #include <sys/stat.h>])],
 245         [#include <sys/types.h>
 246          #include <sys/stat.h>])],
 247      [#include <sys/types.h>
 248       #include <sys/stat.h>])],
 249   [#include <sys/types.h>
 250    #include <sys/stat.h>])
 251
 252 # Some systems have frexp only in -lm, not in -lc.
 253 AC_SEARCH_LIBS(frexp, m)
 254
 255 AM_LC_MESSAGES
 256
 257 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 258 AC_CACHE_VAL(bu_cv_decl_getopt_unistd_h,
 259 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 260 bu_cv_decl_getopt_unistd_h=yes, bu_cv_decl_getopt_unistd_h=no)])
 261 AC_MSG_RESULT($bu_cv_decl_getopt_unistd_h)
 262 if test $bu_cv_decl_getopt_unistd_h = yes; then
 263   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 264             [Is the prototype for getopt in <unistd.h> in the expected format?])
 265 fi
 266
 267 # Under Next 3.2 <utime.h> apparently does not define struct utimbuf
 268 # by default.
 269 AC_MSG_CHECKING([for utime.h])
 270 AC_CACHE_VAL(bu_cv_header_utime_h,
 271 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
 272 #ifdef HAVE_TIME_H
 273 #include <time.h>
 274 #endif
 275 #include <utime.h>],
 276 [struct utimbuf s;])],
 277 bu_cv_header_utime_h=yes, bu_cv_header_utime_h=no)])
 278 AC_MSG_RESULT($bu_cv_header_utime_h)
 279 if test $bu_cv_header_utime_h = yes; then
 280   AC_DEFINE(HAVE_GOOD_UTIME_H, 1, [Does <utime.h> define struct utimbuf?])
 281 fi
 282
 283 AC_CHECK_DECLS([asprintf, environ, getc_unlocked, stpcpy, strnlen])
 284
 285 # Link in zlib/zstd if we can.  This allows us to read compressed debug
 286 # sections.  This is used only by readelf.c (objdump uses bfd for
 287 # reading compressed sections).
 288 AM_ZLIB
 289 AC_ZSTD
 290
 291 BFD_BINARY_FOPEN
 292
 293 # Support for the msgpack C library.
 294 AC_ARG_WITH([msgpack],
 295             AC_HELP_STRING([--with-msgpack], [Enable msgpack support (auto/yes/no)]),
 296             [],
 297             [with_msgpack=auto])
 298
 299 AS_IF([test "$with_msgpack" != no],
 300   [PKG_CHECK_MODULES(MSGPACK, msgpack,
 301     [AC_DEFINE([HAVE_MSGPACK], [1], [Define to 1 if msgpack is available.])],
 302     [AS_IF([test "$with_msgpack" = yes],
 303       [AC_MSG_ERROR([--with-msgpack was given, but msgpack is missing or unusable.])])])])
 304
 305 # target-specific stuff:
 306
 307 # Canonicalize the secondary target names.
 308 if test -n "$enable_targets"; then
 309     for targ in `echo $enable_targets | sed 's/,/ /g'`
 310     do
 311         result=`$ac_config_sub $targ 2>/dev/null`
 312         if test -n "$result"; then
 313             canon_targets="$canon_targets $result"
 314         else
 315             # Allow targets that config.sub doesn't recognize, like "all".
 316             canon_targets="$canon_targets $targ"
 317         fi
 318     done
 319 fi
 320
 321 AC_CHECK_HEADER(iconv.h)
 322 AM_ICONV
 323
 324 BUILD_SRCONV=
 325 BUILD_DLLTOOL=
 326 DLLTOOL_DEFS=
 327 DLLTOOL_DEFAULT=
 328 BUILD_WINDRES=
 329 BUILD_WINDMC=
 330 BUILD_DLLWRAP=
 331 BUILD_MISC=
 332 BUILD_INSTALL_MISC=
 333 OBJDUMP_DEFS=
 334 OBJDUMP_PRIVATE_VECTORS=
 335 OBJDUMP_PRIVATE_OFILES=
 336 od_vectors=
 337
 338 for targ in $target $canon_targets
 339 do
 340     case $targ in
 341     all | *-*-hms*)
 342         BUILD_SRCONV='$(SRCONV_PROG)'
 343         ;;
 344     esac
 345
 346     case $targ in
 347     all | spu-*-*)
 348         BUILD_MISC='bin2c$(EXEEXT_FOR_BUILD)'
 349         ;;
 350     esac
 351
 352     case $targ in
 353     powerpc*-*-linux* | powerpc*-*-elf* | powerpc*-*-eabi*)
 354         BUILD_INSTALL_MISC=embedspu
 355         ;;
 356     esac
 357
 358     case $targ in
 359     mep-*)
 360         OBJDUMP_DEFS="-DSKIP_ZEROES=256 -DSKIP_ZEROES_AT_END=0"
 361         ;;
 362 changequote(,)dnl
 363     powerpc*-aix5.[01])
 364         ;;
 365     powerpc*-aix[5-9].*)
 366 changequote([,])dnl
 367         OBJDUMP_DEFS="-DAIX_WEAK_SUPPORT"
 368         ;;
 369     esac
 370
 371     case $targ in
 372     aarch64-*-mingw*)
 373         BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 374         if test -z "$DLLTOOL_DEFAULT"; then
 375             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_AARCH64"
 376         fi
 377         DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_AARCH64"
 378         BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 379         BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 380         BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 381         ;;
 382     arm-wince-pe* | arm-*-wince | arm*-*-cegcc* | arm*-*-mingw32ce*)
 383         BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 384         if test -z "$DLLTOOL_DEFAULT"; then
 385             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM_WINCE"
 386         fi
 387         DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM_WINCE -DDLLTOOL_ARM"
 388         BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 389         BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 390         ;;
 391     arm-*-pe*)
 392         BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 393         if test -z "$DLLTOOL_DEFAULT"; then
 394             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM"
 395         fi
 396         DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM"
 397         BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 398         BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 399         ;;
 400 changequote(,)dnl
 401     i[3-7]86-*-pe* | i[3-7]86-*-cygwin* | i[3-7]86-*-mingw32** | all)
 402 changequote([,])dnl
 403         BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 404         if test -z "$DLLTOOL_DEFAULT"; then
 405             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 406         fi
 407         DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 408         BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 409         BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 410         BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 411         ;;
 412 changequote(,)dnl
 413     i[3-7]86-*-interix)
 414 changequote([,])dnl
 415         BUILD_DLLTOOL='$(DLLTOOL_PROG)'
 416         if test -z "$DLLTOOL_DEFAULT"; then
 417             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 418         fi
 419         DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 420         ;;
 421     mcore-*-pe)
 422         BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 423         if test -z "$DLLTOOL_DEFAULT"; then
 424             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MCORE"
 425         fi
 426         DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MCORE"
 427         BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 428         BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 429         ;;
 430     mcore-*-elf)
 431         BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 432         if test -z "$DLLTOOL_DEFAULT"; then
 433             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MCORE_ELF"
 434         fi
 435         DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MCORE_ELF"
 436         ;;
 437     sh*-*-pe)
 438         BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 439         if test -z "$DLLTOOL_DEFAULT"; then
 440             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_SH"
 441         fi
 442         DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_SH"
 443         BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 444         BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 445         ;;
 446     x86_64-*-mingw* | x86_64-*-cygwin*)
 447         BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 448         if test -z "$DLLTOOL_DEFAULT"; then
 449             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MX86_64"
 450         fi
 451         DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MX86_64"
 452         BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 453         BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 454         BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 455         ;;
 456     esac
 457
 458     # Add objdump private vectors.
 459     case $targ in
 460     all)
 461         od_vectors="objdump_private_desc_elf32_avr objdump_private_desc_xcoff\
 462                     objdump_private_desc_pe objdump_private_desc_mach_o"
 463         ;;
 464     avr-*-*)
 465         od_vectors="$od_vectors objdump_private_desc_elf32_avr"
 466         ;;
 467     powerpc*-*-aix* | rs6000-*-aix*)
 468         od_vectors="$od_vectors objdump_private_desc_xcoff"
 469         ;;
 470     *-*-pe* | *-*-cygwin* | *-*-mingw*)
 471          od_vectors="$od_vectors objdump_private_desc_pe"
 472          ;;
 473     *-*-darwin*)
 474         od_vectors="$od_vectors objdump_private_desc_mach_o"
 475         ;;
 476     esac
 477 done
 478
 479 # Uniq objdump private vector, build objdump target ofiles.
 480 od_files=
 481 f=""
 482 for i in $od_vectors ; do
 483     case " $f " in
 484     *" $i "*) ;;
 485     *)
 486         f="$f $i"
 487         OBJDUMP_PRIVATE_VECTORS="$OBJDUMP_PRIVATE_VECTORS &$i,"
 488         case $i in
 489         objdump_private_desc_elf32_avr)
 490             od_files="$od_files od-elf32_avr" ;;
 491         objdump_private_desc_xcoff)
 492             od_files="$od_files od-xcoff" ;;
 493         objdump_private_desc_pe)
 494             od_files="$od_files od-pe" ;;
 495         objdump_private_desc_mach_o)
 496             od_files="$od_files od-macho" ;;
 497         *) AC_MSG_ERROR(*** unknown private vector $i) ;;
 498         esac
 499         ;;
 500     esac
 501 done
 502
 503 # Uniq objdump target ofiles
 504 f=""
 505 for i in $od_files ; do
 506     case " $f " in
 507     *" $i "*) ;;
 508     *)
 509         f="$f $i"
 510         OBJDUMP_PRIVATE_OFILES="$OBJDUMP_PRIVATE_OFILES $i.$objext"
 511         ;;
 512     esac
 513 done
 514
 515 DLLTOOL_DEFS="$DLLTOOL_DEFS $DLLTOOL_DEFAULT"
 516
 517 if test "${with_windres+set}" = set; then
 518           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 519 fi
 520
 521 if test "${with_windmc+set}" = set; then
 522           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 523 fi
 524
 525 OBJDUMP_DEFS="${OBJDUMP_DEFS} -DOBJDUMP_PRIVATE_VECTORS=\"${OBJDUMP_PRIVATE_VECTORS}\""
 526
 527 AC_SUBST(BUILD_SRCONV)
 528 AC_SUBST(BUILD_DLLTOOL)
 529 AC_SUBST(DLLTOOL_DEFS)
 530 AC_SUBST(BUILD_WINDRES)
 531 AC_SUBST(BUILD_WINDMC)
 532 AC_SUBST(BUILD_DLLWRAP)
 533 AC_SUBST(BUILD_MISC)
 534 AC_SUBST(BUILD_INSTALL_MISC)
 535 AC_SUBST(OBJDUMP_DEFS)
 536 AC_SUBST(OBJDUMP_PRIVATE_OFILES)
 537
 538 AC_DEFINE_UNQUOTED(TARGET, "${target}", [Configured target name.])
 539
 540 targ=$target
 541 . $srcdir/../bfd/config.bfd
 542 if test "x$targ_underscore" = "xyes"; then
 543     UNDERSCORE=1
 544 else
 545     UNDERSCORE=0
 546 fi
 547 AC_DEFINE_UNQUOTED(TARGET_PREPENDS_UNDERSCORE, $UNDERSCORE,
 548  [Define to 1 if user symbol names have a leading underscore, 0 if not.])
 549
 550 # Emulation
 551 targ=$target
 552 . ${srcdir}/configure.tgt
 553 EMULATION=$targ_emul
 554 EMULATION_VECTOR=$targ_emul_vector
 555
 556 AC_SUBST(EMULATION)
 557 AC_SUBST(EMULATION_VECTOR)
 558
 559 # Required for html and install-html
 560 AC_SUBST(datarootdir)
 561 AC_SUBST(docdir)
 562 AC_SUBST(htmldir)
 563 AC_SUBST(pdfdir)
 564
 565 AC_CONFIG_FILES(Makefile po/Makefile.in:po/Make-in)
 566 AC_OUTPUT
 567
 568 GNU_MAKE_JOBSERVER