gas/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl   Copyright (C) 2012-2023 Free Software Foundation, Inc.
   7 dnl
   8 dnl This file is free software; you can redistribute it and/or modify
   9 dnl it under the terms of the GNU General Public License as published by
  10 dnl the Free Software Foundation; either version 3 of the License, or
  11 dnl (at your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful,
  14 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl GNU General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program; see the file COPYING3.  If not see
  20 dnl <http://www.gnu.org/licenses/>.
  21 dnl
  22 dnl v2.5 needed for --bindir et al
  23 m4_include([../bfd/version.m4])
  24 AC_INIT([gas], BFD_VERSION)
  25 AC_CONFIG_SRCDIR(as.h)
  26
  27 dnl Autoconf 2.57 will find the aux dir without this.  However, unless
  28 dnl we specify this explicitly, automake-1.7 will assume that ylwrap is in
  29 dnl gas/ instead of gas/../.
  30 AC_CONFIG_AUX_DIR(..)
  31 AC_CANONICAL_TARGET
  32
  33 AM_INIT_AUTOMAKE
  34 AM_SILENT_RULES([yes])
  35
  36 AC_PROG_CC
  37 AC_GNU_SOURCE
  38 AC_USE_SYSTEM_EXTENSIONS
  39
  40 LT_INIT
  41 ACX_LARGEFILE
  42 ACX_PROG_CMP_IGNORE_INITIAL
  43
  44 AC_ARG_ENABLE(targets,
  45 [  --enable-targets        alternative target configurations besides the primary],
  46 [case "${enableval}" in
  47   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  48             ;;
  49   no)       enable_targets= ;;
  50   *)        enable_targets=$enableval ;;
  51 esac])dnl
  52
  53 ac_checking=
  54 . ${srcdir}/../bfd/development.sh
  55 test "$development" = true && ac_checking=yes
  56 AC_ARG_ENABLE(checking,
  57 [  --enable-checking       enable run-time checks],
  58 [case "${enableval}" in
  59   no|none)  ac_checking= ;;
  60   *)        ac_checking=yes ;;
  61 esac])dnl
  62 if test x$ac_checking != x ; then
  63   AC_DEFINE(ENABLE_CHECKING, 1, [Define if you want run-time sanity checks.])
  64 fi
  65
  66 # PR gas/19109
  67 # Decide the default method for compressing debug sections.
  68 ac_default_compressed_debug_sections=unset
  69 # Provide a configure time option to override our default.
  70 AC_ARG_ENABLE(compressed_debug_sections,
  71               AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,none}],
  72               [compress debug sections by default]),
  73 [case ,"${enableval}", in
  74   ,yes, | ,all, | *,gas,*) ac_default_compressed_debug_sections=yes ;;
  75   ,no, | ,none,)  ac_default_compressed_debug_sections=no ;;
  76   *)   ac_default_compressed_debug_sections=unset ;;
  77 esac])dnl
  78
  79 # Select default compression algorithm.
  80 ac_default_compressed_debug_sections_algorithm=COMPRESS_DEBUG_GABI_ZLIB
  81 AC_ARG_ENABLE(default_compressed_debug_sections_algorithm,
  82               AS_HELP_STRING([--enable-default-compressed-debug-sections-algorithm={zlib,zstd}],
  83               [Default compression algorithm for --enable-compressed-debug-sections.]),
  84 [case "${enableval}" in
  85    zstd) ac_default_compressed_debug_sections_algorithm=COMPRESS_DEBUG_ZSTD ;;
  86 esac])dnl
  87
  88 # PR gas/19520
  89 # Decide if x86 assembler should generate relax relocations.
  90 ac_default_x86_relax_relocations=unset
  91 # Provide a configure time option to override our default.
  92 AC_ARG_ENABLE(x86_relax_relocations,
  93               AS_HELP_STRING([--enable-x86-relax-relocations],
  94               [generate x86 relax relocations by default]),
  95 [case "${enableval}" in
  96   no)  ac_default_x86_relax_relocations=0 ;;
  97 esac])dnl
  98
  99 # Decide if ELF assembler should generate common symbols with the
 100 # STT_COMMON type.
 101 ac_default_elf_stt_common=unset
 102 # Provide a configure time option to override our default.
 103 AC_ARG_ENABLE(elf_stt_common,
 104               AS_HELP_STRING([--enable-elf-stt-common],
 105               [generate ELF common symbols with STT_COMMON type by default]),
 106 [case "${enableval}" in
 107   yes)  ac_default_elf_stt_common=1 ;;
 108 esac])dnl
 109
 110
 111 # Decide if the ELF assembler should default to generating
 112 # GNU Build notes if none are provided by the input.
 113 ac_default_generate_build_notes=0
 114 # Provide a configuration option to override the default.
 115 AC_ARG_ENABLE(generate_build_notes,
 116               AS_HELP_STRING([--enable-generate-build-notes],
 117               [generate GNU Build notes if none are provided by the input]),
 118 [case "${enableval}" in
 119   yes)  ac_default_generate_build_notes=1 ;;
 120   no)   ac_default_generate_build_notes=0 ;;
 121 esac])dnl
 122
 123 # Decide if the MIPS assembler should default to enable MIPS fix Loongson3
 124 # LLSC errata.
 125 ac_default_mips_fix_loongson3_llsc=unset
 126 # Provide a configuration option to override the default.
 127 AC_ARG_ENABLE(mips-fix-loongson3-llsc,
 128              AS_HELP_STRING([--enable-mips-fix-loongson3-llsc],
 129              [enable MIPS fix Loongson3 LLSC errata]),
 130 [case "${enableval}" in
 131   yes)  ac_default_mips_fix_loongson3_llsc=1 ;;
 132   no)   ac_default_mips_fix_loongson3_llsc=0 ;;
 133 esac])dnl
 134
 135 # Decide if the x86 ELF assembler should default to generating GNU x86
 136 # used ISA and feature properties.
 137 ac_default_generate_x86_used_note=unset
 138 # Provide a configuration option to override the default.
 139 AC_ARG_ENABLE(x86-used-note,
 140               AS_HELP_STRING([--enable-x86-used-note],
 141               [generate GNU x86 used ISA and feature properties]),
 142 [case "${enableval}" in
 143   yes)  ac_default_generate_x86_used_note=1 ;;
 144   no)   ac_default_generate_x86_used_note=0 ;;
 145 esac])dnl
 146
 147 # Decide if the RISC-V ELF assembler should default to generating attribute.
 148 ac_default_generate_riscv_attr=unset
 149 # Provide a configuration option to override the default.
 150 AC_ARG_ENABLE(default-riscv-attribute,
 151               AS_HELP_STRING([--enable-default-riscv-attribute],
 152               [generate RISC-V arch attribute by default]),
 153 [case "${enableval}" in
 154   yes)  ac_default_generate_riscv_attr=1 ;;
 155   no)   ac_default_generate_riscv_attr=0 ;;
 156 esac])dnl
 157
 158 using_cgen=no
 159
 160 AM_BINUTILS_WARNINGS
 161
 162 # Generate a header file
 163 AC_CONFIG_HEADERS(config.h:config.in)
 164
 165 dnl Option --with-cpu=TYPE allows configure type control of the default
 166 dnl cpu type within the assembler.  Currently only the ARC target
 167 dnl supports this feature, but others may be added in the future.
 168 AC_ARG_WITH(cpu,
 169             AS_HELP_STRING([--with-cpu=CPU],
 170             [default cpu variant is CPU (currently only supported on ARC)]),
 171             [AC_DEFINE_UNQUOTED(TARGET_WITH_CPU,
 172                                 "${with_cpu}",
 173                                 [Target specific CPU.])],
 174             [])
 175
 176 # PR 14072
 177 AH_VERBATIM([00_CONFIG_H_CHECK],
 178 [/* Check that config.h is #included before system headers
 179    (this works only for glibc, but that should be enough).  */
 180 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
 181 #  error config.h must be #included before system headers
 182 #endif
 183 #define __CONFIG_H__ 1])
 184
 185 # If we are on a DOS filesystem, we must use gdb.ini rather than
 186 # .gdbinit.
 187 case "${host}" in
 188   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-windows*)
 189     GDBINIT="gdb.ini"
 190     AC_CONFIG_FILES(gdb.ini:gdbinit.in)
 191     ;;
 192   *)
 193     GDBINIT=".gdbinit"
 194     AC_CONFIG_FILES(.gdbinit:gdbinit.in)
 195     ;;
 196 esac
 197 AC_SUBST(GDBINIT)
 198
 199 #We need this for the host.
 200 AC_C_BIGENDIAN
 201
 202 te_file=generic
 203
 204 # Makefile target for installing gas in $(tooldir)/bin.
 205 install_tooldir=install-exec-tooldir
 206
 207 canon_targets=""
 208 all_targets=no
 209 if test -n "$enable_targets" ; then
 210   for t in `echo $enable_targets | sed 's/,/ /g'`; do
 211     if test $t = "all"; then
 212       all_targets=yes
 213       continue
 214     fi
 215     result=`$ac_config_sub $t 2>/dev/null`
 216     if test -n "$result" ; then
 217       canon_targets="$canon_targets $result"
 218 #    else
 219 #      # Permit "all", etc.  We don't support it yet though.
 220 #      canon_targets="$canon_targets $t"
 221     fi
 222   done
 223   GAS_UNIQ(canon_targets)
 224 fi
 225
 226 emulations=""
 227
 228 for this_target in $target $canon_targets ; do
 229
 230     targ=${this_target}
 231     . ${srcdir}/configure.tgt
 232
 233     case ${target_cpu} in
 234       crisv32)
 235         AC_DEFINE_UNQUOTED(DEFAULT_CRIS_ARCH, $arch,
 236                            [Default CRIS architecture.])
 237         ;;
 238     esac
 239
 240     if test ${this_target} = $target ; then
 241       target_cpu_type=${cpu_type}
 242     elif test ${target_cpu_type} != ${cpu_type} ; then
 243       continue
 244     fi
 245
 246     generic_target=${cpu_type}-${target_vendor}-${target_os}
 247     case ${generic_target} in
 248       i386-*-msdosdjgpp* \
 249       | i386-*-go32*)
 250         AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?])
 251         ;;
 252
 253       i386-*-linux-* | x86_64-*-linux-*)
 254         if test ${this_target} = $target \
 255            && test ${ac_default_generate_x86_used_note} = unset; then
 256           ac_default_generate_x86_used_note=1
 257         fi
 258         ;;
 259
 260       i386-*-solaris2 \
 261       | x86_64-*-solaris2 \
 262       | i386-*-solaris2.[[0-9]] \
 263       | i386-*-solaris2.1[[01]] \
 264       | x86_64-*-solaris2.1[[01]])
 265         if test ${this_target} = $target \
 266            && test ${ac_default_x86_relax_relocations} = unset; then
 267           ac_default_x86_relax_relocations=0
 268         fi
 269         ;;
 270
 271       microblaze*)
 272         ;;
 273
 274 changequote(,)dnl
 275       ppc-*-aix5.[01]*)
 276         ;;
 277       ppc-*-aix[5-9].*)
 278 changequote([,])dnl
 279         AC_DEFINE(AIX_WEAK_SUPPORT, 1,
 280                   [Define if using AIX 5.2 value for C_WEAKEXT.])
 281         ;;
 282       ppc-*-solaris*)
 283         if test ${this_target} = $target; then
 284           AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 285                     [Define if default target is PowerPC Solaris.])
 286         fi
 287         if test x${endian} = xbig; then
 288           AC_MSG_ERROR(Solaris must be configured little endian)
 289         fi
 290         ;;
 291     esac
 292
 293     if test ${this_target} = $target ; then
 294       endian_def=
 295       if test x${endian} = xbig; then
 296         endian_def=1
 297       elif test x${endian} = xlittle; then
 298         endian_def=0
 299       fi
 300       if test x${endian_def} != x; then
 301         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 302                            [Define as 1 if big endian.])
 303       fi
 304     fi
 305
 306 # Other random stuff.
 307
 308     case ${cpu_type} in
 309       mips)
 310         # Set mips_cpu to the name of the default CPU.
 311         case ${target_cpu} in
 312           mips | mipsbe | mipseb | mipsle | mipsel | mips64 | mips64el)
 313             mips_cpu=from-abi
 314             ;;
 315           mipsisa32 | mipsisa32el)
 316             mips_cpu=mips32
 317             ;;
 318           mipsisa32r2 | mipsisa32r2el)
 319             mips_cpu=mips32r2
 320             ;;
 321           mipsisa32r3 | mipsisa32r3el)
 322             mips_cpu=mips32r3
 323             ;;
 324           mipsisa32r5 | mipsisa32r5el)
 325             mips_cpu=mips32r5
 326             ;;
 327           mipsisa32r6 | mipsisa32r6el)
 328             mips_cpu=mips32r6
 329             ;;
 330           mipsisa64 | mipsisa64el)
 331             mips_cpu=mips64
 332             ;;
 333           mipsisa64r2 | mipsisa64r2el)
 334             mips_cpu=mips64r2
 335             ;;
 336           mipsisa64r3 | mipsisa64r3el)
 337             mips_cpu=mips64r3
 338             ;;
 339           mipsisa64r5 | mipsisa64r5el)
 340             mips_cpu=mips64r5
 341             ;;
 342           mipsisa64r6 | mipsisa64r6el)
 343             mips_cpu=mips64r6
 344             ;;
 345           mipstx39 | mipstx39el)
 346             mips_cpu=r3900
 347             ;;
 348           mips64vr | mips64vrel)
 349             mips_cpu=vr4100
 350             ;;
 351           mipsisa32r2* | mipsisa64r2*)
 352 changequote(,)dnl
 353             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r2//' -e 's/el$//'`
 354 changequote([,])dnl
 355             ;;
 356           mipsisa32r6* | mipsisa64r6*)
 357 changequote(,)dnl
 358             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r6//' -e 's/el$//'`
 359 changequote([,])dnl
 360             ;;
 361           mips64* | mipsisa64* | mipsisa32*)
 362 changequote(,)dnl
 363             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..//' -e 's/el$//'`
 364 changequote([,])dnl
 365             ;;
 366           mips*)
 367 changequote(,)dnl
 368             mips_cpu=`echo $target_cpu | sed -e 's/^mips//' -e 's/el$//'`
 369 changequote([,])dnl
 370             ;;
 371           *)
 372             AC_MSG_ERROR($target_cpu isn't a supported MIPS CPU name)
 373             ;;
 374         esac
 375         # See whether it's appropriate to set E_MIPS_ABI_O32 for o32
 376         # binaries.  It's a GNU extension that some OSes don't understand.
 377         case ${target} in
 378           *-*-irix*)
 379             use_e_mips_abi_o32=0
 380             ;;
 381           *)
 382             use_e_mips_abi_o32=1
 383             ;;
 384         esac
 385         # Decide whether to generate 32-bit or 64-bit code by default.
 386         # Used to resolve -march=from-abi when an embedded ABI is selected.
 387         case ${target} in
 388           mips64*-*-* | mipsisa64*-*-*)
 389             mips_default_64bit=1
 390             ;;
 391           *)
 392             mips_default_64bit=0
 393             ;;
 394         esac
 395         # Decide which ABI to target by default.
 396         case ${target} in
 397           mips64*-openbsd* | mips64*-linux-gnuabi64)
 398             mips_default_abi=N64_ABI
 399             ;;
 400           mips64*-linux* | mips-sgi-irix6* | mips64*-freebsd* \
 401           | mips64*-kfreebsd*-gnu | mips64*-ps2-elf*)
 402             mips_default_abi=N32_ABI
 403             ;;
 404           mips*-linux* | mips*-freebsd* | mips*-kfreebsd*-gnu)
 405             mips_default_abi=O32_ABI
 406             ;;
 407           *)
 408             mips_default_abi=NO_ABI
 409             ;;
 410         esac
 411         AC_DEFINE_UNQUOTED(MIPS_CPU_STRING_DEFAULT, "$mips_cpu",
 412                            [Default CPU for MIPS targets. ])
 413         AC_DEFINE_UNQUOTED(USE_E_MIPS_ABI_O32, $use_e_mips_abi_o32,
 414                            [Allow use of E_MIPS_ABI_O32 on MIPS targets. ])
 415         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_64BIT, $mips_default_64bit,
 416                            [Generate 64-bit code by default on MIPS targets. ])
 417         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_ABI, $mips_default_abi,
 418                            [Choose a default ABI for MIPS targets. ])
 419         ;;
 420     esac
 421
 422     # Do we need the opcodes library?
 423     case ${cpu_type} in
 424       vax | tic30 | i386 | arm)
 425         ;;
 426
 427       *)
 428         need_opcodes=yes
 429
 430         case "${enable_shared}" in
 431         yes) shared_opcodes=true ;;
 432         *opcodes*) shared_opcodes=true ;;
 433         *) shared_opcodes=false ;;
 434         esac
 435         ;;
 436     esac
 437
 438     # Any other special object files needed ?
 439     case ${cpu_type} in
 440
 441       bfin)
 442         for f in config/bfin-parse.o config/bfin-lex-wrapper.o; do
 443           case " $extra_objects " in
 444             *" $f "*) ;;
 445             *) extra_objects="$extra_objects $f" ;;
 446           esac
 447         done
 448         ;;
 449
 450       bpf)
 451         if test $this_target = $target ; then
 452           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 453         fi
 454         ;;
 455       epiphany | fr30 | ip2k | iq2000 | lm32 | m32r | or1k)
 456         using_cgen=yes
 457         ;;
 458
 459       loongarch)
 460         for f in config/loongarch-parse.o config/loongarch-lex-wrapper.o; do
 461           case " $extra_objects " in
 462             *" $f "*) ;;
 463             *) extra_objects="$extra_objects $f" ;;
 464           esac
 465         done
 466         # --target=loongarch[32|64]-*-*.  */
 467         if test $this_target = $target ; then
 468           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 469         fi
 470         ;;
 471
 472       m32c)
 473         using_cgen=yes
 474         ;;
 475       frv)
 476         using_cgen=yes
 477         ;;
 478       kvx)
 479         for f in config/kvx-parse.o; do
 480           case " $extra_objects " in
 481             *" $f "*) ;;
 482             *) extra_objects="$extra_objects $f" ;;
 483           esac
 484         done
 485         ;;
 486       m68k)
 487         f=config/m68k-parse.o
 488         case " $extra_objects " in
 489           *" $f "*) ;;
 490           *) extra_objects="$extra_objects $f" ;;
 491         esac
 492         ;;
 493
 494       mep)
 495         using_cgen=yes
 496         ;;
 497
 498       mips)
 499         for f in itbl-parse.o itbl-lex-wrapper.o itbl-ops.o; do
 500           case " $extra_objects " in
 501             *" $f "*) ;;
 502             *) extra_objects="$extra_objects $f" ;;
 503           esac
 504         done
 505         ;;
 506
 507       mt)
 508         using_cgen=yes
 509         ;;
 510
 511       nds32)
 512         # setup NDS32_LINUX_TOOLCHAIN definition
 513         if test "linux" = $em; then
 514           AC_DEFINE(NDS32_LINUX_TOOLCHAIN, 1,
 515             [Define value for nds32_linux_toolchain])
 516         else
 517           AC_DEFINE(NDS32_LINUX_TOOLCHAIN, 0,
 518             [Define default value for nds32_linux_toolchain])
 519         fi
 520
 521         # Decide BASELINE, REDUCED_REGS, FPU_DP_EXT, FPU_SP_EXT features
 522         # based on arch_name.
 523         AC_MSG_CHECKING(for default configuration of --with-arch)
 524         if test "x${with_arch}" != x; then
 525           case ${with_arch} in
 526             v2j | v2s | v2f | v2 | v3m | v3j | v3s | v3f | v3 )
 527               AC_DEFINE_UNQUOTED(NDS32_DEFAULT_ARCH_NAME, "$with_arch",
 528                                  [Define value for nds32_arch_name])
 529               ;;
 530             *)
 531               AC_MSG_ERROR(This kind of arch name does *NOT* exist!)
 532               ;;
 533           esac
 534         fi
 535         AC_MSG_RESULT($with_arch)
 536
 537         # Decide features one by one.
 538         AC_MSG_CHECKING(for default configuration of --enable-dx-regs)
 539         if test "x${enable_dx_regs}" = xyes; then
 540           AC_DEFINE(NDS32_DEFAULT_DX_REGS, 1,
 541                     [Define value for nds32_dx_regs])
 542         else
 543           AC_DEFINE(NDS32_DEFAULT_DX_REGS, 0,
 544                     [Define default value for nds32_dx_regs])
 545         fi
 546         AC_MSG_RESULT($enable_dx_regs)
 547
 548         AC_MSG_CHECKING(for default configuration of --enable-perf-ext)
 549         if test "x${enable_perf_ext}" = xno; then
 550           AC_DEFINE(NDS32_DEFAULT_PERF_EXT, 0,
 551                     [Define value for nds32_perf_ext])
 552         else
 553           AC_DEFINE(NDS32_DEFAULT_PERF_EXT, 1,
 554                     [Define default value for nds32_perf_ext])
 555         fi
 556         AC_MSG_RESULT($enable_perf_ext)
 557
 558         AC_MSG_CHECKING(for default configuration of --enable-perf-ext2)
 559         if test "x${enable_perf_ext2}" = xno; then
 560           AC_DEFINE(NDS32_DEFAULT_PERF_EXT2, 0,
 561                     [Define value for nds32_perf_ext2])
 562         else
 563           AC_DEFINE(NDS32_DEFAULT_PERF_EXT2, 1,
 564                     [Define default value for nds32_perf_ext2])
 565         fi
 566         AC_MSG_RESULT($enable_perf_ext2)
 567
 568         AC_MSG_CHECKING(for default configuration of --enable-string-ext)
 569         if test "x${enable_string_ext}" = xno; then
 570           AC_DEFINE(NDS32_DEFAULT_STRING_EXT, 0,
 571                     [Define value for nds32_string_ext])
 572         else
 573           AC_DEFINE(NDS32_DEFAULT_STRING_EXT, 1,
 574                     [Define default value for nds32_string_ext])
 575         fi
 576         AC_MSG_RESULT($enable_string_ext)
 577
 578         AC_MSG_CHECKING(for default configuration of --enable-audio-ext)
 579         if test "x${enable_audio_ext}" = xno; then
 580           AC_DEFINE(NDS32_DEFAULT_AUDIO_EXT, 0,
 581                     [Define value for nds32_audio_ext])
 582         else
 583           AC_DEFINE(NDS32_DEFAULT_AUDIO_EXT, 1,
 584                     [Define default value for nds32_audio_ext])
 585         fi
 586         AC_MSG_RESULT($enable_audio_ext)
 587
 588         AC_MSG_CHECKING(for default configuration of --enable-dsp-ext)
 589         if test "x${enable_dsp_ext}" = xno; then
 590           AC_DEFINE(NDS32_DEFAULT_DSP_EXT, 0,
 591                     [Define value for nds32_dsp_ext])
 592         else
 593           AC_DEFINE(NDS32_DEFAULT_DSP_EXT, 1,
 594                     [Define default value for nds32_dsp_ext])
 595         fi
 596         AC_MSG_RESULT($enable_dsp_ext)
 597
 598         AC_MSG_CHECKING(for default configuration of --enable-zol-ext)
 599         if test "x${enable_zol_ext}" = xno; then
 600           AC_DEFINE(NDS32_DEFAULT_ZOL_EXT, 0,
 601                     [Define value for nds32_zol_ext])
 602         else
 603           AC_DEFINE(NDS32_DEFAULT_ZOL_EXT, 1,
 604                     [Define default value for nds32_zol_ext])
 605         fi
 606         AC_MSG_RESULT($enable_zol_ext)
 607         ;;
 608
 609       aarch64 | i386 | s390 | sparc)
 610         if test $this_target = $target ; then
 611           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 612         fi
 613         ;;
 614
 615       riscv)
 616         # --target=riscv[32|64]-*-*.  */
 617         if test $this_target = $target ; then
 618           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 619         fi
 620
 621         # --with-arch=<value>.  The syntax of <value> is same as Gas option -march.
 622         AC_MSG_CHECKING(for default configuration of --with-arch)
 623         if test "x${with_arch}" != x; then
 624         AC_DEFINE_UNQUOTED(DEFAULT_RISCV_ARCH_WITH_EXT, "$with_arch",
 625                            [Define default value for RISC-V -march.])
 626         fi
 627         AC_MSG_RESULT($with_arch)
 628
 629         # --with-isa-spec=[2.2|20190608|20191213].
 630         AC_MSG_CHECKING(for default configuration of --with-isa-spec)
 631         if test "x${with_isa_spec}" != x; then
 632           AC_DEFINE_UNQUOTED(DEFAULT_RISCV_ISA_SPEC, "$with_isa_spec",
 633                              [Define default value for RISC-V -misa-spec.])
 634         fi
 635         AC_MSG_RESULT($with_isa_spec)
 636
 637         # --with-priv-spec=[1.9.1|1.10|1.11|1.12].
 638         AC_MSG_CHECKING(for default configuration of --with-priv-spec)
 639         if test "x${with_priv_spec}" != x; then
 640           AC_DEFINE_UNQUOTED(DEFAULT_RISCV_PRIV_SPEC, "$with_priv_spec",
 641                              [Define default value for RISC-V -mpriv-spec])
 642         fi
 643         AC_MSG_RESULT($with_priv_spec)
 644         ;;
 645
 646       rl78)
 647         f=config/rl78-parse.o
 648         case " $extra_objects " in
 649           *" $f "*) ;;
 650           *) extra_objects="$extra_objects $f" ;;
 651         esac
 652         ;;
 653
 654       rx)
 655         f=config/rx-parse.o
 656         case " $extra_objects " in
 657           *" $f "*) ;;
 658           *) extra_objects="$extra_objects $f" ;;
 659         esac
 660         ;;
 661
 662       xstormy16)
 663         using_cgen=yes
 664         ;;
 665
 666       xtensa)
 667         f=config/xtensa-relax.o
 668         case " $extra_objects " in
 669           *" $f "*) ;;
 670           *) extra_objects="$extra_objects $f" ;;
 671         esac
 672         ;;
 673
 674       *)
 675         ;;
 676     esac
 677
 678     if test $using_cgen = yes ; then
 679         f=cgen.o
 680         case " $extra_objects " in
 681           *" $f "*) ;;
 682           *) extra_objects="$extra_objects $f" ;;
 683         esac
 684     fi
 685
 686 # See if we really can support this configuration with the emulation code.
 687
 688     if test $this_target = $target ; then
 689       obj_format=$fmt
 690       te_file=$em
 691     fi
 692
 693     case ${te_file} in
 694       vms)
 695         f=config/te-vms.o
 696         case " $extra_objects " in
 697           *" $f "*) ;;
 698           *) extra_objects="$extra_objects $f" ;;
 699         esac ;;
 700     esac
 701
 702 # From target name and format, produce a list of supported emulations.
 703
 704     case ${generic_target}-${fmt} in
 705       mips-*-*-*)       case "$endian" in
 706                         big)    emulation="mipsbelf mipslelf mipself" ;;
 707                         *)      emulation="mipslelf mipsbelf mipself" ;;
 708                         esac ;;
 709       # i386-pc-pe-coff != i386-pc-coff.
 710       i386-*-pe-coff)   ;;
 711       # Uncommenting the next line will turn on support for i386 AOUT
 712       # for the default linux configuration
 713       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 714       #
 715       i386-*-aout)      emulation="i386aout" ;;
 716       i386-*-coff)      emulation="i386coff" ;;
 717       i386-*-elf)       emulation="i386elf" ;;
 718
 719       # Always all formats.  The first stated emulation becomes the default.
 720       cris-*-*aout*)    emulation="crisaout criself" ;;
 721       cris-*-*)         emulation="criself crisaout" ;;
 722     esac
 723
 724     emulations="$emulations $emulation"
 725
 726 done
 727
 728 if test ${ac_default_x86_relax_relocations} = unset; then
 729   ac_default_x86_relax_relocations=1
 730 fi
 731 AC_DEFINE_UNQUOTED(DEFAULT_GENERATE_X86_RELAX_RELOCATIONS,
 732   $ac_default_x86_relax_relocations,
 733   [Define to 1 if you want to generate x86 relax relocations by default.])
 734
 735 if test ${ac_default_elf_stt_common} = unset; then
 736   ac_default_elf_stt_common=0
 737 fi
 738 AC_DEFINE_UNQUOTED(DEFAULT_GENERATE_ELF_STT_COMMON,
 739   $ac_default_elf_stt_common,
 740   [Define to 1 if you want to generate ELF common symbols with the
 741    STT_COMMON type by default.])
 742
 743 AC_DEFINE_UNQUOTED(DEFAULT_GENERATE_BUILD_NOTES,
 744   $ac_default_generate_build_notes,
 745   [Define to 1 if you want to generate GNU Build attribute notes
 746    by default, if none are contained in the input.])
 747
 748 if test ${ac_default_generate_x86_used_note} = unset; then
 749   ac_default_generate_x86_used_note=0
 750 fi
 751 AC_DEFINE_UNQUOTED(DEFAULT_X86_USED_NOTE,
 752   $ac_default_generate_x86_used_note,
 753   [Define to 1 if you want to generate GNU x86 used ISA and feature
 754    properties by default.])
 755
 756 if test ${ac_default_generate_riscv_attr} = unset; then
 757   ac_default_generate_riscv_attr=1
 758 fi
 759
 760 AC_DEFINE_UNQUOTED(DEFAULT_RISCV_ATTR,
 761   $ac_default_generate_riscv_attr,
 762   [Define to 1 if you want to generate RISC-V arch attribute by default.])
 763
 764 if test ${ac_default_mips_fix_loongson3_llsc} = unset; then
 765   ac_default_mips_fix_loongson3_llsc=0
 766 fi
 767 AC_DEFINE_UNQUOTED(DEFAULT_MIPS_FIX_LOONGSON3_LLSC,
 768   $ac_default_mips_fix_loongson3_llsc,
 769   [Define to 1 if you want to fix Loongson3 LLSC Errata by default.])
 770
 771 if test x$ac_default_compressed_debug_sections = xyes ; then
 772   AC_DEFINE(DEFAULT_FLAG_COMPRESS_DEBUG, 1, [Define if you want compressed debug sections by default.])
 773 fi
 774
 775 AC_DEFINE_UNQUOTED(DEFAULT_COMPRESSED_DEBUG_ALGORITHM, $ac_default_compressed_debug_sections_algorithm,
 776                    [Default compression algorithm for --enable-compressed-debug-sections.])
 777
 778 # Turn on all targets if possible
 779 if test ${all_targets} = "yes"; then
 780   case ${target_cpu_type} in
 781   i386)
 782     case ${obj_format} in
 783     aout)
 784       emulations="$emulations i386coff i386elf"
 785       ;;
 786     coff)
 787       emulations="$emulations i386aout i386elf"
 788     ;;
 789     elf)
 790       emulations="$emulations i386aout i386coff"
 791       ;;
 792     esac
 793   ;;
 794   x86_64)
 795     case ${obj_format} in
 796     aout)
 797       emulations="$emulations i386coff i386elf"
 798       ;;
 799     coff)
 800       emulations="$emulations i386aout i386elf"
 801     ;;
 802     elf)
 803       emulations="$emulations i386aout i386coff"
 804       ;;
 805     esac
 806   ;;
 807   esac
 808 fi
 809
 810 # PE code has way too many macros tweaking behaviour
 811 case ${te_file} in
 812   pe*) emulations="" ;;
 813 esac
 814
 815 # Assign floating point type.  Most processors with FP support
 816 # IEEE FP.  On those that don't support FP at all, usually IEEE
 817 # is emulated.
 818 case ${target_cpu} in
 819   vax | pdp11 ) atof=vax ;;
 820   *)            atof=ieee ;;
 821 esac
 822
 823 case "${obj_format}" in
 824   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 825 esac
 826
 827 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 828 cgen_cpu_prefix=""
 829 if test $using_cgen = yes ; then
 830   case ${target_cpu} in
 831     or1knd)
 832        cgen_cpu_prefix=or1k ;;
 833     *) cgen_cpu_prefix=${target_cpu} ;;
 834   esac
 835   AC_SUBST(cgen_cpu_prefix)
 836   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 837 fi
 838
 839 dnl
 840 dnl Make sure the desired support files exist.
 841 dnl
 842
 843 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 844   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 845 fi
 846
 847 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 848   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 849 fi
 850
 851 # Some COFF configurations want these random other flags set.
 852 case ${obj_format} in
 853   coff)
 854     case ${target_cpu_type} in
 855       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 856       x86_64) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 857     esac
 858     ;;
 859 esac
 860
 861 # Getting this done right is going to be a bitch.  Each configuration specified
 862 # with --enable-targets=... should be checked for environment, format, cpu
 863 # setting.
 864 #
 865 # For each configuration, the necessary object file support code must be linked
 866 # in.  This might be only one, it might be up to four.  The necessary emulation
 867 # code needs to be provided, too.
 868 #
 869 # And then there's "--enable-targets=all"....
 870 #
 871 # For now, just always do it for MIPS ELF configurations.  Sigh.
 872
 873 formats="${obj_format}"
 874 emfiles=""
 875 EMULATIONS=""
 876 GAS_UNIQ(emulations)
 877 for em in . $emulations ; do
 878   case $em in
 879     .)  continue ;;
 880     mipsbelf | mipslelf | mipself)
 881         fmt=elf   file=mipself ;;
 882     *coff)
 883         fmt=coff  file=$em ;;
 884     *aout)
 885         fmt=aout file=$em ;;
 886     *elf)
 887         fmt=elf file=$em ;;
 888   esac
 889   formats="$formats $fmt"
 890   emfiles="$emfiles config/e-$file.o"
 891   EMULATIONS="$EMULATIONS &$em,"
 892 done
 893 GAS_UNIQ(formats)
 894 GAS_UNIQ(emfiles)
 895 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 896   for fmt in $formats ; do
 897     case $fmt in
 898       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 899       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 900       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 901       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 902       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 903       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 904     esac
 905     extra_objects="$extra_objects config/obj-$fmt.o"
 906   done
 907   obj_format=multi
 908 fi
 909 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 910   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 911   # e-mipself has more than one emulation per file, e-i386* has just one at the
 912   # moment.  If only one emulation is specified, then don't define
 913   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 914   case "${obj_format}${emfiles}" in
 915     multi* | *mipself*)
 916       extra_objects="$extra_objects $emfiles"
 917       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 918   esac
 919 fi
 920 AC_SUBST(extra_objects)
 921 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 922 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 923                    [Default emulation.])
 924
 925 reject_dev_configs=yes
 926
 927 case ${reject_dev_configs}-${dev} in
 928   yes-yes) # Oops.
 929     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 930     ;;
 931 esac
 932
 933 AC_SUBST(target_cpu_type)
 934 AC_SUBST(obj_format)
 935 AC_SUBST(te_file)
 936 AC_SUBST(install_tooldir)
 937 AC_SUBST(atof)
 938 dnl AC_SUBST(emulation)
 939
 940 # do we need the opcodes library?
 941 case "${need_opcodes}" in
 942 yes)
 943   OPCODES_LIB=../opcodes/libopcodes.la
 944   ;;
 945 esac
 946
 947 AC_SUBST(OPCODES_LIB)
 948
 949 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 950 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 951 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 952 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 953 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 954
 955 AC_PROG_YACC
 956 AM_PROG_LEX
 957
 958 ALL_LINGUAS="es fi fr id ja ru rw sv tr uk zh_CN"
 959 ZW_GNU_GETTEXT_SISTER_DIR
 960 AM_PO_SUBDIRS
 961
 962 AM_MAINTAINER_MODE
 963 AM_CONDITIONAL(GENINSRC_NEVER, false)
 964 AC_EXEEXT
 965
 966 AC_CHECK_HEADERS(memory.h sys/stat.h sys/types.h unistd.h)
 967
 968 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 969 # people who are not cross-compiling but are compiling cross-assemblers.
 970 AC_MSG_CHECKING(whether compiling a cross-assembler)
 971 if test "${host}" = "${target}"; then
 972   cross_gas=no
 973 else
 974   cross_gas=yes
 975   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 976 fi
 977 AC_MSG_RESULT($cross_gas)
 978
 979 AC_CHECK_FUNCS(strsignal)
 980
 981 AM_LC_MESSAGES
 982
 983 # do we need the math library?
 984 case "${need_libm}" in
 985 yes)
 986   LT_LIB_M
 987   AC_SUBST(LIBM)
 988   ;;
 989 esac
 990
 991 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 992 # enough, but on some of those systems, the assert macro relies on requoting
 993 # working properly!
 994 GAS_WORKING_ASSERT
 995
 996 # On some systems, the system header files may not declare malloc, realloc,
 997 # and free.  There are places where gas needs these functions to have been
 998 # declared -- such as when taking their addresses.
 999 gas_test_headers="
1000 #ifdef HAVE_MEMORY_H
1001 #include <memory.h>
1002 #endif
1003 #include <string.h>
1004 #include <stdlib.h>
1005 #ifdef HAVE_UNISTD_H
1006 #include <unistd.h>
1007 #endif
1008 "
1009
1010 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
1011 AC_CACHE_VAL(gas_cv_decl_getopt_unistd_h,
1012 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
1013 gas_cv_decl_getopt_unistd_h=yes, gas_cv_decl_getopt_unistd_h=no)])
1014 AC_MSG_RESULT($gas_cv_decl_getopt_unistd_h)
1015 if test $gas_cv_decl_getopt_unistd_h = yes; then
1016   AC_DEFINE([HAVE_DECL_GETOPT], 1,
1017             [Is the prototype for getopt in <unistd.h> in the expected format?])
1018 fi
1019
1020 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
1021 GAS_CHECK_DECL_NEEDED(ffs, f, int (*f)(int), $gas_test_headers)
1022
1023 AC_CHECK_DECLS([asprintf, mempcpy, stpcpy])
1024
1025 BFD_BINARY_FOPEN
1026
1027 # Link in zlib/zstd if we can.  This allows us to write compressed debug sections.
1028 AM_ZLIB
1029 AC_ZSTD
1030
1031 # Support for VMS timestamps via cross compile
1032
1033 if test "$ac_cv_header_time_h" = yes; then
1034   GAS_HAVE_TIME_TYPE_MEMBER(struct tm, tm_gmtoff)
1035 fi
1036
1037 if test "$ac_cv_header_sys_stat_h" = yes; then
1038     GAS_HAVE_SYS_STAT_TYPE_MEMBER(struct stat, st_mtim, tv_sec)
1039     GAS_HAVE_SYS_STAT_TYPE_MEMBER(struct stat, st_mtim, tv_nsec)
1040 fi
1041
1042
1043 dnl Required for html, pdf, install-pdf and install-html targets.
1044 AC_SUBST(datarootdir)
1045 AC_SUBST(docdir)
1046 AC_SUBST(htmldir)
1047 AC_SUBST(pdfdir)
1048
1049 dnl This must come last.
1050
1051 dnl We used to make symlinks to files in the source directory, but now
1052 dnl we just use the right name for .c files, and create .h files in
1053 dnl the build directory which include the right .h file.  Make sure
1054 dnl the old symlinks don't exist, so that a reconfigure in an existing
1055 dnl directory behaves reasonably.
1056
1057 AC_CONFIG_FILES(Makefile po/Makefile.in:po/Make-in)
1058 AC_CONFIG_COMMANDS([default],
1059 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
1060  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
1061  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
1062  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
1063  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
1064  if test "x$cgen_cpu_prefix" != x ; then
1065    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
1066  fi],
1067 [target_cpu_type=${target_cpu_type}
1068  cgen_cpu_prefix=${cgen_cpu_prefix}
1069  obj_format=${obj_format}
1070  te_file=${te_file}])
1071
1072 AC_OUTPUT
1073
1074 GNU_MAKE_JOBSERVER