opcodes/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl   Copyright (C) 2012-2022 Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9 dnl
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program; see the file COPYING3.  If not see
  17 dnl <http://www.gnu.org/licenses/>.
  18 dnl
  19
  20 m4_include([../bfd/version.m4])
  21 AC_INIT([opcodes], BFD_VERSION)
  22 AC_CONFIG_SRCDIR([z8k-dis.c])
  23
  24 AC_CANONICAL_TARGET
  25
  26 AM_INIT_AUTOMAKE
  27 AM_SILENT_RULES([yes])
  28
  29 AC_PROG_CC
  30 AC_GNU_SOURCE
  31 AC_USE_SYSTEM_EXTENSIONS
  32
  33 dnl These must be called before LT_INIT, because it may want
  34 dnl to call AC_CHECK_PROG.
  35 AC_CHECK_TOOL(AR, ar)
  36 AC_CHECK_TOOL(RANLIB, ranlib, :)
  37
  38 dnl Default to a non shared library.  This may be overridden by the
  39 dnl configure option --enable-shared.
  40 AC_DISABLE_SHARED
  41
  42 LT_INIT
  43
  44 ac_checking=
  45 . ${srcdir}/../bfd/development.sh
  46 test "$development" = true && ac_checking=yes
  47 AC_ARG_ENABLE(checking,
  48 [  --enable-checking       enable run-time checks],
  49 [case "${enableval}" in
  50   no|none)  ac_checking= ;;
  51   *)        ac_checking=yes ;;
  52 esac])dnl
  53 if test x$ac_checking != x ; then
  54   AC_DEFINE(ENABLE_CHECKING, 1, [Define if you want run-time sanity checks.])
  55 fi
  56
  57 AC_ARG_ENABLE(targets,
  58 [  --enable-targets        alternative target configurations],
  59 [case "${enableval}" in
  60   yes | "") AC_MSG_ERROR([enable-targets option must specify target names or 'all'])
  61             ;;
  62   no)       enable_targets= ;;
  63   *)        enable_targets=$enableval ;;
  64 esac])dnl
  65
  66 AM_BINUTILS_WARNINGS
  67
  68 AC_CONFIG_HEADERS(config.h:config.in)
  69
  70 # PR 14072
  71 AH_VERBATIM([00_CONFIG_H_CHECK],
  72 [/* Check that config.h is #included before system headers
  73    (this works only for glibc, but that should be enough).  */
  74 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
  75 #  error config.h must be #included before system headers
  76 #endif
  77 #define __CONFIG_H__ 1])
  78
  79 if test -z "$target" ; then
  80     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  81 fi
  82
  83 AM_MAINTAINER_MODE
  84 AM_INSTALL_LIBBFD
  85 AC_EXEEXT
  86
  87 # host-specific stuff:
  88
  89 ALL_LINGUAS="da de es fi fr ga id it nl pt_BR ro sr sv tr uk vi zh_CN"
  90 ZW_GNU_GETTEXT_SISTER_DIR
  91 AM_PO_SUBDIRS
  92
  93 . ${srcdir}/../bfd/configure.host
  94
  95 BFD_CC_FOR_BUILD
  96 BFD_64_BIT
  97
  98 AC_SUBST(HDEFINES)
  99 AC_PROG_INSTALL
 100
 101 AC_CHECK_DECLS([basename, stpcpy])
 102
 103 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
 104 # since sigsetjmp might only be defined as a macro.
 105 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
 106 [AC_TRY_COMPILE([
 107 #include <setjmp.h>
 108 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
 109 bfd_cv_func_sigsetjmp=yes, bfd_cv_func_sigsetjmp=no)])
 110 if test $bfd_cv_func_sigsetjmp = yes; then
 111   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
 112 fi
 113
 114 cgen_maint=no
 115 cgendir='$(srcdir)/../cgen'
 116
 117 AC_ARG_ENABLE(cgen-maint,
 118 [  --enable-cgen-maint[=dir]    build cgen generated files],
 119 [case "${enableval}" in
 120   yes)  cgen_maint=yes ;;
 121   no)   cgen_maint=no ;;
 122   *)
 123         # Argument is a directory where cgen can be found.  In some
 124         # future world cgen could be installable, but right now this
 125         # is not the case.  Instead we assume the directory is a path
 126         # to the cgen source tree.
 127         cgen_maint=yes
 128         if test -r ${enableval}/iformat.scm; then
 129           # This looks like a cgen source tree.
 130           cgendir=${enableval}
 131         else
 132           AC_MSG_ERROR(${enableval} doesn't look like a cgen source tree)
 133         fi
 134         ;;
 135 esac])dnl
 136 AM_CONDITIONAL(CGEN_MAINT, test x${cgen_maint} = xyes)
 137 AC_SUBST(cgendir)
 138
 139 using_cgen=no
 140
 141 # Check if linker supports --as-needed and --no-as-needed options
 142 AC_CACHE_CHECK(linker --as-needed support, bfd_cv_ld_as_needed,
 143         [bfd_cv_ld_as_needed=no
 144         if $LD --help 2>/dev/null | grep as-needed > /dev/null; then
 145                 bfd_cv_ld_as_needed=yes
 146         fi
 147         ])
 148
 149 LT_LIB_M
 150
 151 #Libs for generator progs
 152 if test "x$cross_compiling" = "xno"; then
 153   BUILD_LIBS=../libiberty/libiberty.a
 154   BUILD_LIB_DEPS=$BUILD_LIBS
 155 else
 156   # if cross-compiling, assume that the system provides -liberty
 157   # and that the version is compatible with new headers.
 158   BUILD_LIBS=-liberty
 159   BUILD_LIB_DEPS=
 160 fi
 161 BUILD_LIBS="$BUILD_LIBS $LIBINTL"
 162 BUILD_LIB_DEPS="$BUILD_LIB_DEPS $LIBINTL_DEP"
 163
 164 AC_SUBST(BUILD_LIBS)
 165 AC_SUBST(BUILD_LIB_DEPS)
 166
 167 # Horrible hacks to build DLLs on Windows and a shared library elsewhere.
 168 SHARED_LDFLAGS=
 169 SHARED_LIBADD=
 170 SHARED_DEPENDENCIES=
 171 if test "$enable_shared" = "yes"; then
 172 # When building a shared libopcodes, link against the pic version of libiberty
 173 # so that apps that use libopcodes won't need libiberty just to satisfy any
 174 # libopcodes references.
 175 # We can't do that if a pic libiberty is unavailable since including non-pic
 176 # code would insert text relocations into libopcodes.
 177 # Note that linking against libbfd as we do here, which is itself linked
 178 # against libiberty, may not satisfy all the libopcodes libiberty references
 179 # since libbfd may not pull in the entirety of libiberty.
 180 # Also, jam libintl into the right place in all of this: after libiberty,
 181 # which uses it, but before -lcygwin, which it uses.
 182 changequote(,)dnl
 183   x=`sed -n -e 's/^[    ]*PICFLAG[      ]*=[    ]*//p' < ../libiberty/Makefile | sed -n '$p'`
 184 changequote([,])dnl
 185   if test -n "$x"; then
 186     SHARED_LIBADD="-L`pwd`/../libiberty/pic -liberty"
 187   fi
 188 fi
 189
 190 SHARED_LIBADD="$SHARED_LIBADD $LIBINTL"
 191
 192 if test "$enable_shared" = "yes"; then
 193   case "${host}" in
 194     *-*-cygwin*)
 195       SHARED_LDFLAGS="-no-undefined"
 196       SHARED_LIBADD="-L`pwd`/../bfd -lbfd -L`pwd`/../libiberty -liberty $SHARED_LIBADD"
 197       ;;
 198     *)
 199       SHARED_LIBADD="../bfd/libbfd.la ${SHARED_LIBADD}"
 200       SHARED_DEPENDENCIES="../bfd/libbfd.la"
 201       ;;
 202   esac
 203
 204   if test -n "$SHARED_LIBADD"; then
 205     if test -n "$LIBM"; then
 206       if test x"$bfd_cv_ld_as_needed" = xyes; then
 207         # Link against libm only when needed.  Put -lc, -lm inside -Wl
 208         # to stop libtool reordering these options.
 209         SHARED_LIBADD="$SHARED_LIBADD -Wl,-lc,--as-needed,`echo $LIBM | sed 's/ /,/g'`,--no-as-needed"
 210       else
 211         SHARED_LIBADD="$SHARED_LIBADD $LIBM"
 212       fi
 213     fi
 214   fi
 215 fi
 216 AC_SUBST(SHARED_LDFLAGS)
 217 AC_SUBST(SHARED_LIBADD)
 218 AC_SUBST(SHARED_DEPENDENCIES)
 219
 220 # target-specific stuff:
 221
 222 # Canonicalize the secondary target names.
 223 if test -n "$enable_targets" ; then
 224     for targ in `echo $enable_targets | sed 's/,/ /g'`
 225     do
 226         result=`$ac_config_sub $targ 2>/dev/null`
 227         if test -n "$result" ; then
 228             canon_targets="$canon_targets $result"
 229         else
 230             # Allow targets that config.sub doesn't recognize, like "all".
 231             canon_targets="$canon_targets $targ"
 232         fi
 233     done
 234 fi
 235
 236 all_targets=false
 237 selarchs=
 238 for targ in $target $canon_targets
 239 do
 240     if test "x$targ" = "xall" ; then
 241         all_targets=true
 242     else
 243         . $srcdir/../bfd/config.bfd
 244         selarchs="$selarchs $targ_archs"
 245     fi
 246 done
 247
 248 # Utility var, documents generic cgen support files.
 249
 250 cgen_files="cgen-opc.lo cgen-asm.lo cgen-dis.lo cgen-bitset.lo"
 251
 252 # We don't do any links based on the target system, just makefile config.
 253
 254 if test x${all_targets} = xfalse ; then
 255
 256     # Target architecture .o files.
 257     ta=
 258
 259     for arch in $selarchs
 260     do
 261         ad=`echo $arch | sed -e s/bfd_//g -e s/_arch//g`
 262         archdefs="$archdefs -DARCH_$ad"
 263         case "$arch" in
 264         bfd_aarch64_arch)       ta="$ta aarch64-asm.lo aarch64-dis.lo aarch64-opc.lo aarch64-asm-2.lo aarch64-dis-2.lo aarch64-opc-2.lo" ;;
 265         bfd_alpha_arch)         ta="$ta alpha-dis.lo alpha-opc.lo" ;;
 266         bfd_amdgcn_arch)        ;;
 267         bfd_arc_arch)           ta="$ta arc-dis.lo arc-opc.lo arc-ext.lo" ;;
 268         bfd_arm_arch)           ta="$ta arm-dis.lo" ;;
 269         bfd_avr_arch)           ta="$ta avr-dis.lo" ;;
 270         bfd_bfin_arch)          ta="$ta bfin-dis.lo" ;;
 271         bfd_cr16_arch)          ta="$ta cr16-dis.lo cr16-opc.lo" ;;
 272         bfd_cris_arch)          ta="$ta cris-desc.lo cris-dis.lo cris-opc.lo cgen-bitset.lo" ;;
 273         bfd_crx_arch)           ta="$ta crx-dis.lo crx-opc.lo" ;;
 274         bfd_csky_arch)          ta="$ta csky-dis.lo" ;;
 275         bfd_d10v_arch)          ta="$ta d10v-dis.lo d10v-opc.lo" ;;
 276         bfd_d30v_arch)          ta="$ta d30v-dis.lo d30v-opc.lo" ;;
 277         bfd_dlx_arch)           ta="$ta dlx-dis.lo" ;;
 278         bfd_fr30_arch)          ta="$ta fr30-asm.lo fr30-desc.lo fr30-dis.lo fr30-ibld.lo fr30-opc.lo" using_cgen=yes ;;
 279         bfd_frv_arch)           ta="$ta frv-asm.lo frv-desc.lo frv-dis.lo frv-ibld.lo frv-opc.lo" using_cgen=yes ;;
 280         bfd_ft32_arch)          ta="$ta ft32-opc.lo ft32-dis.lo" ;;
 281         bfd_moxie_arch)         ta="$ta moxie-dis.lo moxie-opc.lo" ;;
 282         bfd_h8300_arch)         ta="$ta h8300-dis.lo" ;;
 283         bfd_hppa_arch)          ta="$ta hppa-dis.lo" ;;
 284         bfd_i386_arch|bfd_iamcu_arch)
 285                                 ta="$ta i386-dis.lo" ;;
 286         bfd_ia64_arch)          ta="$ta ia64-dis.lo ia64-opc.lo" ;;
 287         bfd_ip2k_arch)          ta="$ta ip2k-asm.lo ip2k-desc.lo ip2k-dis.lo ip2k-ibld.lo ip2k-opc.lo" using_cgen=yes ;;
 288         bfd_epiphany_arch)      ta="$ta epiphany-asm.lo epiphany-desc.lo epiphany-dis.lo epiphany-ibld.lo epiphany-opc.lo" using_cgen=yes ;;
 289         bfd_iq2000_arch)        ta="$ta iq2000-asm.lo iq2000-desc.lo iq2000-dis.lo iq2000-ibld.lo iq2000-opc.lo" using_cgen=yes ;;
 290         bfd_lm32_arch)          ta="$ta lm32-asm.lo lm32-desc.lo lm32-dis.lo lm32-ibld.lo lm32-opc.lo lm32-opinst.lo" using_cgen=yes ;;
 291         bfd_m32c_arch)          ta="$ta m32c-asm.lo m32c-desc.lo m32c-dis.lo m32c-ibld.lo m32c-opc.lo" using_cgen=yes ;;
 292         bfd_m32r_arch)          ta="$ta m32r-asm.lo m32r-desc.lo m32r-dis.lo m32r-ibld.lo m32r-opc.lo m32r-opinst.lo" using_cgen=yes ;;
 293         bfd_m68hc11_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 294         bfd_m68hc12_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 295         bfd_m9s12x_arch)        ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 296         bfd_m9s12xg_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 297         bfd_s12z_arch)          ta="$ta s12z-dis.lo s12z-opc.lo" ;;
 298         bfd_m68k_arch)          ta="$ta m68k-dis.lo m68k-opc.lo" ;;
 299         bfd_mcore_arch)         ta="$ta mcore-dis.lo" ;;
 300         bfd_mep_arch)           ta="$ta mep-asm.lo mep-desc.lo mep-dis.lo mep-ibld.lo mep-opc.lo" using_cgen=yes ;;
 301         bfd_metag_arch)         ta="$ta metag-dis.lo" ;;
 302         bfd_microblaze_arch)    ta="$ta microblaze-dis.lo" ;;
 303         bfd_mips_arch)          ta="$ta mips-dis.lo mips-opc.lo mips16-opc.lo micromips-opc.lo" ;;
 304         bfd_mmix_arch)          ta="$ta mmix-dis.lo mmix-opc.lo" ;;
 305         bfd_mn10200_arch)       ta="$ta m10200-dis.lo m10200-opc.lo" ;;
 306         bfd_mn10300_arch)       ta="$ta m10300-dis.lo m10300-opc.lo" ;;
 307         bfd_mt_arch)            ta="$ta mt-asm.lo mt-desc.lo mt-dis.lo mt-ibld.lo mt-opc.lo" using_cgen=yes ;;
 308         bfd_msp430_arch)        ta="$ta msp430-dis.lo msp430-decode.lo" ;;
 309         bfd_nds32_arch)         ta="$ta nds32-asm.lo nds32-dis.lo" ;;
 310         bfd_nfp_arch)           ta="$ta nfp-dis.lo" ;;
 311         bfd_nios2_arch)         ta="$ta nios2-dis.lo nios2-opc.lo" ;;
 312         bfd_ns32k_arch)         ta="$ta ns32k-dis.lo" ;;
 313         bfd_or1k_arch)          ta="$ta or1k-asm.lo or1k-desc.lo or1k-dis.lo or1k-ibld.lo or1k-opc.lo" using_cgen=yes ;;
 314         bfd_pdp11_arch)         ta="$ta pdp11-dis.lo pdp11-opc.lo" ;;
 315         bfd_pj_arch)            ta="$ta pj-dis.lo pj-opc.lo" ;;
 316         bfd_powerpc_arch)       ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 317         bfd_powerpc_64_arch)    ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 318         bfd_pru_arch)           ta="$ta pru-dis.lo pru-opc.lo" ;;
 319         bfd_pyramid_arch)       ;;
 320         bfd_romp_arch)          ;;
 321         bfd_riscv_arch)         ta="$ta riscv-dis.lo riscv-opc.lo" ;;
 322         bfd_rs6000_arch)        ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 323         bfd_rl78_arch)          ta="$ta rl78-dis.lo rl78-decode.lo";;
 324         bfd_rx_arch)            ta="$ta rx-dis.lo rx-decode.lo";;
 325         bfd_s390_arch)          ta="$ta s390-dis.lo s390-opc.lo" ;;
 326         bfd_score_arch)         ta="$ta score-dis.lo score7-dis.lo" ;;
 327         bfd_sh_arch)            ta="$ta sh-dis.lo cgen-bitset.lo" ;;
 328         bfd_sparc_arch)         ta="$ta sparc-dis.lo sparc-opc.lo" ;;
 329         bfd_spu_arch)           ta="$ta spu-dis.lo spu-opc.lo" ;;
 330         bfd_tic30_arch)         ta="$ta tic30-dis.lo" ;;
 331         bfd_tic4x_arch)         ta="$ta tic4x-dis.lo" ;;
 332         bfd_tic54x_arch)        ta="$ta tic54x-dis.lo tic54x-opc.lo" ;;
 333         bfd_tic6x_arch)         ta="$ta tic6x-dis.lo" ;;
 334         bfd_tilegx_arch)        ta="$ta tilegx-dis.lo tilegx-opc.lo" ;;
 335         bfd_tilepro_arch)       ta="$ta tilepro-dis.lo tilepro-opc.lo" ;;
 336         bfd_v850_arch)          ta="$ta v850-opc.lo v850-dis.lo" ;;
 337         bfd_v850e_arch)         ta="$ta v850-opc.lo v850-dis.lo" ;;
 338         bfd_v850ea_arch)        ta="$ta v850-opc.lo v850-dis.lo" ;;
 339         bfd_v850_rh850_arch)    ta="$ta v850-opc.lo v850-dis.lo" ;;
 340         bfd_vax_arch)           ta="$ta vax-dis.lo" ;;
 341         bfd_visium_arch)        ta="$ta visium-dis.lo visium-opc.lo" ;;
 342         bfd_wasm32_arch)        ta="$ta wasm32-dis.lo" ;;
 343         bfd_xgate_arch)         ta="$ta xgate-dis.lo xgate-opc.lo" ;;
 344         bfd_xstormy16_arch)     ta="$ta xstormy16-asm.lo xstormy16-desc.lo xstormy16-dis.lo xstormy16-ibld.lo xstormy16-opc.lo" using_cgen=yes ;;
 345         bfd_xtensa_arch)        ta="$ta xtensa-dis.lo" ;;
 346         bfd_z80_arch)           ta="$ta z80-dis.lo" ;;
 347         bfd_z8k_arch)           ta="$ta z8k-dis.lo" ;;
 348         bfd_bpf_arch)           ta="$ta bpf-asm.lo bpf-desc.lo bpf-dis.lo bpf-ibld.lo bpf-opc.lo" using_cgen=yes ;;
 349         bfd_loongarch_arch)     ta="$ta loongarch-dis.lo loongarch-opc.lo loongarch-coder.lo" ;;
 350
 351         "")                     ;;
 352         *)              AC_MSG_ERROR(*** unknown target architecture $arch) ;;
 353         esac
 354     done
 355
 356     if test $using_cgen = yes ; then
 357         ta="$ta $cgen_files"
 358     fi
 359
 360     # Weed out duplicate .o files.
 361     f=""
 362     for i in $ta ; do
 363         case " $f " in
 364         *" $i "*) ;;
 365         *) f="$f $i" ;;
 366         esac
 367     done
 368     ta="$f"
 369
 370     # And duplicate -D flags.
 371     f=""
 372     for i in $archdefs ; do
 373         case " $f " in
 374         *" $i "*) ;;
 375         *) f="$f $i" ;;
 376         esac
 377     done
 378     archdefs="$f"
 379
 380     BFD_MACHINES="$ta"
 381
 382 else    # all_targets is true
 383     archdefs=-DARCH_all
 384     if test "$enable_64_bit_bfd" = "yes" ; then
 385         BFD_MACHINES='$(ALL32_MACHINES) $(ALL64_MACHINES)'
 386     else
 387         BFD_MACHINES='$(ALL32_MACHINES)'
 388     fi
 389 fi
 390
 391 AC_SUBST(archdefs)
 392 AC_SUBST(BFD_MACHINES)
 393
 394 AC_CONFIG_FILES([Makefile po/Makefile.in:po/Make-in])
 395 AC_OUTPUT
 396
 397 GNU_MAKE_JOBSERVER