libsframe/configure.ac

   1 dnl                                            -*- Autoconf -*-
   2 dnl Process this file with autoconf to produce a configure script.
   3 dnl
   4 dnl   Copyright (C) 2022 Free Software Foundation, Inc.
   5 dnl
   6 dnl This file is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 2 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program; see the file COPYING.  If not see
  18 dnl <http://www.gnu.org/licenses/>.
  19 dnl
  20
  21 AC_INIT([libsframe], BFD_VERSION)
  22 AC_CONFIG_SRCDIR(sframe.c)
  23 AC_USE_SYSTEM_EXTENSIONS
  24 AM_INIT_AUTOMAKE
  25
  26 # Checks for programs.
  27 AC_PROG_MAKE_SET
  28 AC_PROG_CC
  29 AC_PROG_RANLIB
  30 AM_PROG_AR
  31
  32 dnl Default to a non shared library.  This may be overridden by the
  33 dnl configure option --enable-shared.
  34 AC_DISABLE_SHARED
  35
  36 LT_INIT
  37 AC_SYS_LARGEFILE
  38
  39 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
  40 AC_CHECK_PROGS([ACLOCAL], [aclocal], [$MISSING aclocal])
  41 AC_CHECK_PROGS([AUTOCONF], [autoconf], [$MISSING autoconf])
  42 AC_CHECK_PROGS([AUTOHEADER], [autoheader], [$MISSING autoheader])
  43
  44 dnl Figure out what compiler warnings we can enable.
  45 dnl See config/warnings.m4 for details.
  46
  47 ACX_PROG_CC_WARNING_OPTS([-Wall -Wextra -Wwrite-strings \
  48                           -Wmissing-format-attribute \
  49                           -Wstrict-prototypes -Wmissing-prototypes],
  50                           [ac_libsframe_warn_cflags])
  51
  52 dnl The libsframe testsuite uses dejagnu.h.
  53 dnl If the version of dejagnu and gcc are incompatible then the libsframe
  54 dnl testsuite is not built.
  55
  56 DEJAGNU_CHECK_VERSION
  57 AM_CONDITIONAL([HAVE_COMPAT_DEJAGNU], [test "x$ac_cv_dejagnu_compat" = "xyes"])
  58
  59 COMPAT_DEJAGNU=$ac_cv_dejagnu_compat
  60 AC_SUBST(COMPAT_DEJAGNU)
  61
  62 dnl Check for makeinfo for building documentation
  63 build_info=
  64 AC_CHECK_PROGS([MAKEINFO], makeinfo, makeinfo, )
  65 if test "x$MAKEINFO" = "x"; then
  66     MAKEINFO="@echo makeinfo missing; true"
  67     build_info=
  68 else
  69     BUILD_INFO=info
  70     case "$MAKEINFO" in
  71       */missing\ makeinfo*)
  72         build_info=
  73         AC_MSG_WARN([
  74 *** Makeinfo is missing. Info documentation will not be built.])
  75         ;;
  76       *)
  77         build_info=yes
  78         ;;
  79     esac
  80 fi
  81 AM_CONDITIONAL(BUILD_INFO, test "${build_info}" = yes)
  82
  83 AM_MAINTAINER_MODE
  84 AM_INSTALL_LIBBFD
  85
  86 AC_FUNC_MMAP
  87 AC_CHECK_HEADERS(byteswap.h endian.h)
  88
  89 dnl Check for bswap_{16,32,64}
  90 AC_CHECK_DECLS([bswap_16, bswap_32, bswap_64], [], [], [[#include <byteswap.h>]])
  91
  92 AC_CONFIG_FILES(Makefile)
  93 AC_CONFIG_HEADERS(config.h)
  94 AC_OUTPUT
  95
  96 GNU_MAKE_JOBSERVER