ld/configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2 dnl
   3 dnl   Copyright (C) 2012-2023 Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9 dnl
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program; see the file COPYING3.  If not see
  17 dnl <http://www.gnu.org/licenses/>.
  18 dnl
  19
  20 m4_include([../bfd/version.m4])
  21 AC_INIT([ld], BFD_VERSION)
  22 AC_CONFIG_SRCDIR(ldmain.c)
  23
  24 AC_CANONICAL_TARGET
  25 AC_CANONICAL_BUILD
  26
  27 AM_INIT_AUTOMAKE
  28 AM_SILENT_RULES([yes])
  29 AM_MAINTAINER_MODE
  30
  31 AC_PROG_CC
  32 AC_PROG_CXX
  33 AC_PROG_GREP
  34 AC_GNU_SOURCE
  35 AC_USE_SYSTEM_EXTENSIONS
  36 AC_PROG_INSTALL
  37 PKG_PROG_PKG_CONFIG
  38
  39 LT_INIT
  40 ACX_LARGEFILE
  41
  42 ac_checking=
  43 . ${srcdir}/../bfd/development.sh
  44 test "$development" = true && ac_checking=yes
  45 AC_ARG_ENABLE(checking,
  46 [  --enable-checking       enable run-time checks],
  47 [case "${enableval}" in
  48   no|none)  ac_checking= ;;
  49   *)        ac_checking=yes ;;
  50 esac])dnl
  51 if test x$ac_checking != x ; then
  52   AC_DEFINE(ENABLE_CHECKING, 1, [Define if you want run-time sanity checks.])
  53 fi
  54
  55 AC_ARG_WITH(lib-path, [  --with-lib-path=dir1:dir2...  set default LIB_PATH],LIB_PATH=$withval)
  56 AC_ARG_ENABLE(targets,
  57 [  --enable-targets        alternative target configurations],
  58 [case "${enableval}" in
  59   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  60             ;;
  61   no)       enable_targets= ;;
  62   *)        enable_targets=$enableval ;;
  63 esac])dnl
  64
  65 BFD_64_BIT
  66
  67 AC_ARG_WITH(sysroot,
  68 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
  69 [
  70  case ${with_sysroot} in
  71  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
  72  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
  73  esac
  74
  75  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
  76  use_sysroot=yes
  77
  78  if test "x$prefix" = xNONE; then
  79   test_prefix=/usr/local
  80  else
  81   test_prefix=$prefix
  82  fi
  83  if test "x$exec_prefix" = xNONE; then
  84   test_exec_prefix=$test_prefix
  85  else
  86   test_exec_prefix=$exec_prefix
  87  fi
  88  case ${TARGET_SYSTEM_ROOT} in
  89  "${test_prefix}"|"${test_prefix}/"*|\
  90  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
  91  '${prefix}'|'${prefix}/'*|\
  92  '${exec_prefix}'|'${exec_prefix}/'*)
  93    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
  94    TARGET_SYSTEM_ROOT_DEFINE="$t"
  95    ;;
  96  esac
  97 ], [
  98  use_sysroot=no
  99  TARGET_SYSTEM_ROOT=
 100  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
 101 ])
 102 AC_SUBST(use_sysroot)
 103 AC_SUBST(TARGET_SYSTEM_ROOT)
 104 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 105
 106 dnl Use --enable-gold to decide if this linker should be the default.
 107 dnl "install_as_default" is set to false if gold is the default linker.
 108 dnl "installed_linker" is the installed BFD linker name.
 109 AC_ARG_ENABLE(gold,
 110 [[  --enable-gold[=ARG]     build gold [ARG={default,yes,no}]]],
 111 [case "${enableval}" in
 112  default)
 113    install_as_default=no
 114    installed_linker=ld.bfd
 115    ;;
 116  yes|no)
 117    install_as_default=yes
 118    installed_linker=ld.bfd
 119    ;;
 120  *)
 121    AC_MSG_ERROR([invalid --enable-gold argument])
 122    ;;
 123  esac],
 124 [install_as_default=yes
 125  installed_linker=ld.bfd])
 126 AC_SUBST(install_as_default)
 127 AC_SUBST(installed_linker)
 128
 129 AC_ARG_ENABLE([got],
 130 AS_HELP_STRING([--enable-got=<type>],
 131                [GOT handling scheme (target, single, negative, multigot)]),
 132 [case "${enableval}" in
 133   target | single | negative | multigot)  got_handling=$enableval ;;
 134   *)  AC_MSG_ERROR(bad value ${enableval} for --enable-got option) ;;
 135 esac],
 136 [got_handling=target])
 137
 138 case "${got_handling}" in
 139   target)
 140     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_TARGET_DEFAULT],
 141               [Define to choose default GOT handling scheme]) ;;
 142   single)
 143     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_SINGLE],
 144               [Define to choose default GOT handling scheme]) ;;
 145   negative)
 146     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_NEGATIVE],
 147               [Define to choose default GOT handling scheme]) ;;
 148   multigot)
 149     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_MULTIGOT],
 150               [Define to choose default GOT handling scheme]) ;;
 151   *)  AC_MSG_ERROR(bad value ${got_handling} for --enable-got option) ;;
 152 esac
 153
 154 # PR gas/19109
 155 # Decide the default method for compressing debug sections.
 156 ac_default_compressed_debug_sections=unset
 157 # Provide a configure time option to override our default.
 158 AC_ARG_ENABLE(compressed_debug_sections,
 159               AS_HELP_STRING([--enable-compressed-debug-sections={all,ld,none}],
 160               [compress debug sections by default])],
 161 [case ,"${enableval}", in
 162   ,yes, | ,all, | *,ld,*) ac_default_compressed_debug_sections=yes ;;
 163   ,no, | ,none,)  ac_default_compressed_debug_sections=no ;;
 164 esac])dnl
 165
 166 # Select default compression algorithm.
 167 ac_default_compressed_debug_sections_algorithm=COMPRESS_DEBUG_GABI_ZLIB
 168 AC_ARG_ENABLE(default_compressed_debug_sections_algorithm,
 169               AS_HELP_STRING([--enable-default-compressed-debug-sections-algorithm={zlib,zstd}],
 170               [Default compression algorithm for --enable-compressed-debug-sections.]),
 171 [case "${enableval}" in
 172    zstd) ac_default_compressed_debug_sections_algorithm=COMPRESS_DEBUG_ZSTD ;;
 173 esac])dnl
 174
 175 # Decide setting DT_RUNPATH instead of DT_RPATH by default
 176 ac_default_new_dtags=unset
 177 # Provide a configure time option to override our default.
 178 AC_ARG_ENABLE(new_dtags,
 179               AS_HELP_STRING([--enable-new-dtags],
 180               [set DT_RUNPATH instead of DT_RPATH by default])],
 181 [case "${enableval}" in
 182   yes) ac_default_new_dtags=1 ;;
 183   no) ac_default_new_dtags=0 ;;
 184 esac])dnl
 185
 186 # Decide if -z relro should be enabled in ELF linker by default.
 187 ac_default_ld_z_relro=unset
 188 # Provide a configure time option to override our default.
 189 AC_ARG_ENABLE(relro,
 190               AS_HELP_STRING([--enable-relro],
 191               [enable -z relro in ELF linker by default]),
 192 [case "${enableval}" in
 193   yes)  ac_default_ld_z_relro=1 ;;
 194   no)  ac_default_ld_z_relro=0 ;;
 195 esac])dnl
 196
 197 # Decide if DT_TEXTREL check should be enabled in ELF linker.
 198 ac_default_ld_textrel_check=unset
 199 AC_ARG_ENABLE([textrel-check],
 200               AC_HELP_STRING([--enable-textrel-check=@<:@yes|no|warning|error@:>@],
 201                              [enable DT_TEXTREL check in ELF linker]),
 202 [case "${enableval}" in
 203   yes|no|warning|error) ac_default_ld_textrel_check=${enableval} ;;
 204 esac])
 205
 206 # Decide if -z separate-code should be enabled in ELF linker by default.
 207 ac_default_ld_z_separate_code=unset
 208 AC_ARG_ENABLE(separate-code,
 209               AS_HELP_STRING([--enable-separate-code],
 210               [enable -z separate-code in ELF linker by default]),
 211 [case "${enableval}" in
 212   yes) ac_default_ld_z_separate_code=1 ;;
 213   no) ac_default_ld_z_separate_code=0 ;;
 214 esac])
 215
 216
 217 # By default warn when an executable stack is created due to object files
 218 # requesting such, not when the user specifies -z execstack.
 219 ac_default_ld_warn_execstack=2
 220 AC_ARG_ENABLE(warn-execstack,
 221               AS_HELP_STRING([--enable-warn-execstack],
 222               [enable warnings when creating an executable stack]),
 223 [case "${enableval}" in
 224   yes) ac_default_ld_warn_execstack=1 ;;
 225   no)  ac_default_ld_warn_execstack=0 ;;
 226 esac])
 227
 228 ac_default_ld_warn_rwx_segments=unset
 229 AC_ARG_ENABLE(warn-rwx-segments,
 230               AS_HELP_STRING([--enable-warn-rwx-segments],
 231               [enable warnings when creating segements with RWX permissions]),
 232 [case "${enableval}" in
 233   yes) ac_default_ld_warn_rwx_segments=1 ;;
 234   no)  ac_default_ld_warn_rwx_segments=0 ;;
 235 esac])
 236
 237 ac_default_ld_default_execstack=unset
 238 AC_ARG_ENABLE(default-execstack,
 239               AS_HELP_STRING([--enable-default-execstack],
 240               [create an executable stack if an input file is missing a .note.GNU-stack section]),
 241 [case "${enableval}" in
 242   yes) ac_default_ld_default_execstack=1 ;;
 243   no)  ac_default_ld_default_execstack=0 ;;
 244 esac])
 245
 246
 247 # Decide if --error-handling-script should be supported.
 248 ac_support_error_handling_script=unset
 249 AC_ARG_ENABLE(error-handling-script,
 250               AS_HELP_STRING([--enable-error-handling-script],
 251               [enable/disable support for the --error-handling-script option]),
 252 [case "${enableval}" in
 253   yes) ac_support_error_handling_script=1 ;;
 254   no)  ac_support_error_handling_script=0 ;;
 255 esac])
 256
 257 # Decide which "--hash-style" to use by default
 258 # Provide a configure time option to override our default.
 259 AC_ARG_ENABLE([default-hash-style],
 260 AS_HELP_STRING([--enable-default-hash-style={sysv,gnu,both}],
 261                [use this default hash style]),
 262 [case "${enable_default_hash_style}" in
 263   sysv | gnu | both) ;;
 264   *) AC_MSG_ERROR([bad value ${enable_default_hash_style} for enable-default-hash-style option]) ;;
 265 esac],
 266 [case "${target}" in
 267   # Enable gnu hash only on GNU targets, but not mips
 268   mips*-*-*) enable_default_hash_style=sysv ;;
 269   *-*-gnu* | *-*-linux* | *-*-nacl*) enable_default_hash_style=both ;;
 270   *) enable_default_hash_style=sysv ;;
 271 esac])
 272
 273 case "${enable_default_hash_style}" in
 274   sysv | both) ac_default_emit_sysv_hash=1 ;;
 275   *) ac_default_emit_sysv_hash=0 ;;
 276 esac
 277
 278 case "${enable_default_hash_style}" in
 279   gnu | both) ac_default_emit_gnu_hash=1 ;;
 280   *) ac_default_emit_gnu_hash=0 ;;
 281 esac
 282
 283 AC_ARG_ENABLE(initfini-array,
 284 [  --disable-initfini-array do not use .init_array/.fini_array sections],
 285 [case "${enableval}" in
 286  yes|no) ;;
 287  *) AC_MSG_ERROR([invalid --enable-initfini-array argument]) ;;
 288  esac], [enable_initfini_array=yes])
 289 AC_SUBST(enable_initfini_array)
 290 if test $enable_initfini_array = yes; then
 291   AC_DEFINE(HAVE_INITFINI_ARRAY, 1,
 292     [Define .init_array/.fini_array sections are available and working.])
 293 fi
 294
 295 GCC_ENABLE([libctf], [yes], [], [Handle .ctf type-info sections])
 296 if test "${enable_libctf}" = yes; then
 297     AC_DEFINE(ENABLE_LIBCTF, 1, [Handle .ctf type-info sections])
 298 fi
 299 AM_CONDITIONAL(ENABLE_LIBCTF, test "${enable_libctf}" = yes)
 300 AC_SUBST(enable_libctf)
 301
 302 # Used to validate --package-metadata= input. Disabled by default.
 303 AC_ARG_ENABLE([jansson],
 304   [AS_HELP_STRING([--enable-jansson],
 305     [enable jansson [default=no]])],
 306   [enable_jansson=$enableval],
 307   [enable_jansson="no"])
 308
 309 AS_IF([test "x$enable_jansson" != "xno"],
 310   [PKG_CHECK_MODULES(JANSSON, [jansson],
 311     [
 312       AC_DEFINE(HAVE_JANSSON, 1, [The jansson library is to be used])
 313       AC_SUBST([JANSSON_CFLAGS])
 314       AC_SUBST([JANSSON_LIBS])
 315     ],
 316     [AC_MSG_ERROR([Cannot find jansson library])])
 317   ])
 318
 319 AM_BINUTILS_WARNINGS
 320
 321 AM_LC_MESSAGES
 322
 323 AC_CONFIG_HEADERS([config.h:config.in])
 324
 325 # PR 14072
 326 AH_VERBATIM([00_CONFIG_H_CHECK],
 327 [/* Check that config.h is #included before system headers
 328    (this works only for glibc, but that should be enough).  */
 329 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
 330 #  error config.h must be #included before system headers
 331 #endif
 332 #define __CONFIG_H__ 1])
 333
 334 if test -z "$target" ; then
 335     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
 336 fi
 337 if test -z "$host" ; then
 338     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
 339 fi
 340
 341 # host-specific stuff:
 342
 343 ALL_LINGUAS="bg da de es fi fr ga id it ja pt_BR ru sr sv tr uk vi zh_CN zh_TW"
 344 ZW_GNU_GETTEXT_SISTER_DIR
 345 AM_PO_SUBDIRS
 346
 347 AC_EXEEXT
 348
 349 AC_PROG_YACC
 350 AM_PROG_LEX
 351
 352 AM_MAINTAINER_MODE
 353 AM_CONDITIONAL(GENINSRC_NEVER, false)
 354 ACX_PROG_CMP_IGNORE_INITIAL
 355
 356 . ${srcdir}/configure.host
 357
 358 AC_SUBST(HDEFINES)
 359 AC_SUBST(NATIVE_LIB_DIRS)
 360
 361 # We use headers from include/ that check various HAVE_*_H macros, thus
 362 # should ensure they are set by configure.  This is true even when C99
 363 # guarantees they are available.
 364 # sha1.h and md4.h test HAVE_LIMITS_H, HAVE_SYS_TYPES_H and HAVE_STDINT_H
 365 # plugin-api.h tests HAVE_STDINT_H and HAVE_INTTYPES_H
 366 # Besides those, we need to check anything used in ld/ not in C99.
 367 AC_CHECK_HEADERS(fcntl.h elf-hints.h limits.h inttypes.h stdint.h \
 368                  sys/file.h sys/mman.h sys/param.h sys/stat.h sys/time.h \
 369                  sys/types.h unistd.h)
 370 AC_CHECK_FUNCS(close glob lseek mkstemp open realpath waitpid)
 371
 372 BFD_BINARY_FOPEN
 373
 374 AC_CHECK_DECLS([asprintf, environ])
 375
 376 AC_FUNC_MMAP
 377
 378 AC_SEARCH_LIBS([dlopen], [dl])
 379
 380 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 381 AC_CACHE_VAL(ld_cv_decl_getopt_unistd_h,
 382 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 383 ld_cv_decl_getopt_unistd_h=yes, ld_cv_decl_getopt_unistd_h=no)])
 384 AC_MSG_RESULT($ld_cv_decl_getopt_unistd_h)
 385 if test $ld_cv_decl_getopt_unistd_h = yes; then
 386   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 387             [Is the prototype for getopt in <unistd.h> in the expected format?])
 388 fi
 389
 390 # Link in zlib/zstd if we can.  This allows us to read and write
 391 # compressed debug sections.
 392 AM_ZLIB
 393 AC_ZSTD
 394
 395 # When converting linker scripts into strings for use in emulation
 396 # files, use astring.sed if the compiler supports ANSI string
 397 # concatenation, or ostring.sed otherwise.  This is to support the
 398 # broken Microsoft MSVC compiler, which limits the length of string
 399 # constants, while still supporting pre-ANSI compilers which do not
 400 # support string concatenation.
 401 AC_MSG_CHECKING([whether ANSI C string concatenation works])
 402 AC_CACHE_VAL(ld_cv_string_concatenation,
 403 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [char *a = "a" "a";])],
 404   ld_cv_string_concatenation=yes,
 405   ld_cv_string_concatenation=no)])
 406 AC_MSG_RESULT($ld_cv_string_concatenation)
 407 if test "$ld_cv_string_concatenation" = "yes"; then
 408   STRINGIFY=astring.sed
 409 else
 410   STRINGIFY=ostring.sed
 411 fi
 412 AC_SUBST(STRINGIFY)
 413
 414 # target-specific stuff:
 415
 416 all_targets=
 417 EMUL=
 418 all_emuls=
 419 all_emul_extras=
 420 all_libpath=
 421 TDIRS=
 422
 423 elf_list_options=false
 424 elf_shlib_list_options=false
 425 elf_plt_unwind_list_options=false
 426 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 427 do
 428   if test "$targ_alias" = "all"; then
 429     all_targets=true
 430     elf_list_options=true
 431     elf_shlib_list_options=true
 432     elf_plt_unwind_list_options=true
 433   else
 434     # Canonicalize the secondary target names.
 435     result=`$ac_config_sub $targ_alias 2>/dev/null`
 436     if test -n "$result"; then
 437         targ=$result
 438     else
 439         targ=$targ_alias
 440     fi
 441
 442     . ${srcdir}/configure.tgt
 443
 444     if test "$targ" = "$target"; then
 445       EMUL=$targ_emul
 446     fi
 447
 448     if test x${enable_64_bit_bfd} = xno; then
 449       . ${srcdir}/../bfd/config.bfd
 450     fi
 451
 452     if test x${enable_64_bit_bfd} = xyes; then
 453       targ_extra_emuls="$targ_extra_emuls $targ64_extra_emuls"
 454       targ_extra_libpath="$targ_extra_libpath $targ64_extra_libpath"
 455     fi
 456
 457     for i in $targ_emul $targ_extra_emuls $targ_extra_libpath; do
 458         case " $all_emuls " in
 459         *" e${i}.o "*) ;;
 460         *)
 461           all_emuls="$all_emuls e${i}.o"
 462           eval result=\$tdir_$i
 463           test -z "$result" && result=$targ_alias
 464           TDIRS="$TDIRS
 465 tdir_$i=$result"
 466           case "${i}" in
 467           *elf*)
 468             elf_list_options=true
 469             ;;
 470           *)
 471             if $GREP "TEMPLATE_NAME=elf" ${srcdir}/emulparams/${i}.sh >/dev/null 2>/dev/null; then
 472               elf_list_options=true
 473             fi
 474             ;;
 475           esac
 476           if test "$elf_list_options" = "true"; then
 477             source_sh()
 478             {
 479               . $1
 480             }
 481             source_sh ${srcdir}/emulparams/${i}.sh
 482             if test x${GENERATE_SHLIB_SCRIPT} = xyes; then
 483               elf_shlib_list_options=true
 484             fi
 485             if test x${PLT_UNWIND} = xyes; then
 486               elf_plt_unwind_list_options=true
 487             fi
 488           fi
 489           ;;
 490         esac
 491     done
 492
 493     for i in $targ_emul $targ_extra_libpath; do
 494         case " $all_libpath " in
 495         *" ${i} "*) ;;
 496         *)
 497           if test -z "$all_libpath"; then
 498             all_libpath=${i}
 499           else
 500             all_libpath="$all_libpath ${i}"
 501           fi
 502           ;;
 503         esac
 504     done
 505
 506     for i in $targ_extra_ofiles; do
 507         case " $all_emul_extras " in
 508         *" ${i} "*) ;;
 509         *)
 510           all_emul_extras="$all_emul_extras ${i}"
 511           ;;
 512         esac
 513     done
 514
 515   fi
 516 done
 517
 518 if test x$ac_default_compressed_debug_sections = xyes ; then
 519   AC_DEFINE(DEFAULT_FLAG_COMPRESS_DEBUG, 1, [Define if you want compressed debug sections by default.])
 520 fi
 521
 522 AC_DEFINE_UNQUOTED(DEFAULT_COMPRESSED_DEBUG_ALGORITHM, $ac_default_compressed_debug_sections_algorithm,
 523                    [Default compression algorithm for --enable-compressed-debug-sections.])
 524
 525 if test "${ac_default_new_dtags}" = unset; then
 526   ac_default_new_dtags=0
 527 fi
 528 AC_DEFINE_UNQUOTED(DEFAULT_NEW_DTAGS,
 529   $ac_default_new_dtags,
 530   [Define to 1 if you want to set DT_RUNPATH instead of DT_RPATH by default.])
 531
 532 if test "${ac_default_ld_z_relro}" = unset; then
 533   ac_default_ld_z_relro=0
 534 fi
 535 AC_DEFINE_UNQUOTED(DEFAULT_LD_Z_RELRO,
 536   $ac_default_ld_z_relro,
 537   [Define to 1 if you want to enable -z relro in ELF linker by default.])
 538
 539 ac_default_ld_textrel_check_warning=0
 540 case "${ac_default_ld_textrel_check}" in
 541   unset|no)
 542     ac_default_ld_textrel_check=textrel_check_none
 543     ;;
 544   yes|warning)
 545     ac_default_ld_textrel_check=textrel_check_warning
 546     ac_default_ld_textrel_check_warning=1
 547     ;;
 548   error)
 549     ac_default_ld_textrel_check=textrel_check_error
 550     ;;
 551 esac
 552 AC_DEFINE_UNQUOTED(DEFAULT_LD_TEXTREL_CHECK,
 553   $ac_default_ld_textrel_check,
 554   [The default method for DT_TEXTREL check in ELF linker.])
 555 AC_DEFINE_UNQUOTED(DEFAULT_LD_TEXTREL_CHECK_WARNING,
 556   $ac_default_ld_textrel_check_warning,
 557   [Define to 1 if DT_TEXTREL check is warning in ELF linker by default.])
 558
 559 if test "${ac_default_ld_z_separate_code}" = unset; then
 560   ac_default_ld_z_separate_code=0
 561 fi
 562 AC_DEFINE_UNQUOTED(DEFAULT_LD_Z_SEPARATE_CODE,
 563   $ac_default_ld_z_separate_code,
 564   [Define to 1 if you want to enable -z separate-code in ELF linker by default.])
 565
 566
 567 AC_DEFINE_UNQUOTED(DEFAULT_LD_WARN_EXECSTACK,
 568   $ac_default_ld_warn_execstack,
 569   [Define to 1 if you want to enable --warn-execstack in ELF linker by default.])
 570
 571 if test "${ac_default_ld_warn_rwx_segments}" = unset; then
 572   ac_default_ld_warn_rwx_segments=1
 573 fi
 574 AC_DEFINE_UNQUOTED(DEFAULT_LD_WARN_RWX_SEGMENTS,
 575   $ac_default_ld_warn_rwx_segments,
 576   [Define to 0 if you want to disable --warn-rwx-segments in ELF linker by default.])
 577
 578 if test "${ac_default_ld_default_execstack}" = unset; then
 579   ac_default_ld_default_execstack=1
 580 fi
 581 AC_DEFINE_UNQUOTED(DEFAULT_LD_EXECSTACK,
 582   $ac_default_ld_default_execstack,
 583   [Define to 0 if you want to disable the generation of an executable stack when a .note-GNU-stack section is missing.])
 584
 585
 586 if test "${ac_support_error_handling_script}" = unset; then
 587   ac_support_error_handling_script=1
 588 fi
 589 AC_DEFINE_UNQUOTED(SUPPORT_ERROR_HANDLING_SCRIPT,
 590   $ac_support_error_handling_script,
 591   [Define to 1 if you want to support the --error-handling-script command line option.])
 592
 593 AC_DEFINE_UNQUOTED([DEFAULT_EMIT_SYSV_HASH],
 594   [$ac_default_emit_sysv_hash],
 595   [Define to 1 if you want to emit sysv hash in the ELF linker by default.])
 596
 597 AC_DEFINE_UNQUOTED([DEFAULT_EMIT_GNU_HASH],
 598   [$ac_default_emit_gnu_hash],
 599   [Define to 1 if you want to emit gnu hash in the ELF linker by default.])
 600
 601 AC_SUBST(elf_list_options)
 602 AC_SUBST(elf_shlib_list_options)
 603 AC_SUBST(elf_plt_unwind_list_options)
 604 AC_SUBST(EMUL)
 605
 606 AC_SUBST(TDIRS)
 607 AM_SUBST_NOTMAKE(TDIRS)
 608
 609 if test x${all_targets} = xtrue; then
 610   if test x${enable_64_bit_bfd} = xyes; then
 611     EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)'
 612     EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES) $(ALL_64_EMUL_EXTRA_OFILES)'
 613   else
 614     EMULATION_OFILES='$(ALL_EMULATIONS)'
 615     EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)'
 616   fi
 617 else
 618   EMULATION_OFILES=$all_emuls
 619   EMUL_EXTRA_OFILES=$all_emul_extras
 620 fi
 621 AC_SUBST(EMULATION_OFILES)
 622 AC_SUBST(EMUL_EXTRA_OFILES)
 623 AC_SUBST(LIB_PATH)
 624
 625 EMULATION_LIBPATH=$all_libpath
 626 AC_SUBST(EMULATION_LIBPATH)
 627
 628 if test x${enable_static} = xno; then
 629   TESTBFDLIB="-Wl,--rpath,../bfd/.libs ../bfd/.libs/libbfd.so"
 630   TESTCTFLIB="-Wl,--rpath,../libctf/.libs ../libctf/.libs/libctf.so"
 631   TESTSFRAMELIB="-Wl,--rpath,../libsframe/.libs ../libsframe/.libs/libsframe.so"
 632 else
 633   TESTBFDLIB="../bfd/.libs/libbfd.a"
 634   TESTCTFLIB="../libctf/.libs/libctf.a"
 635   TESTSFRAMELIB="../libsframe/.libs/libsframe.a"
 636 fi
 637 if test "${enable_libctf}" = no; then
 638     TESTCTFLIB=
 639 fi
 640 AC_SUBST(TESTBFDLIB)
 641 AC_SUBST(TESTCTFLIB)
 642 AC_SUBST(TESTSFRAMELIB)
 643
 644 target_vendor=${target_vendor=$host_vendor}
 645 case "$target_vendor" in
 646   hp) EXTRA_SHLIB_EXTENSION=".sl" ;;
 647   *)  EXTRA_SHLIB_EXTENSION= ;;
 648 esac
 649
 650 case "$target_os" in
 651   lynxos) EXTRA_SHLIB_EXTENSION=".a" ;;
 652 esac
 653
 654 if test x${EXTRA_SHLIB_EXTENSION} != x ; then
 655   AC_DEFINE_UNQUOTED(EXTRA_SHLIB_EXTENSION, "$EXTRA_SHLIB_EXTENSION",
 656    [Additional extension a shared object might have.])
 657 fi
 658
 659 AC_CONFIG_COMMANDS([default],
 660 [[
 661 case "$srcdir" in
 662   .) srcdirpre= ;;
 663   *) srcdirpre='$(srcdir)/' ;;
 664 esac
 665 POFILES=
 666 GMOFILES=
 667 for lang in dummy $OBSOLETE_ALL_LINGUAS; do
 668   if test $lang != dummy; then
 669     POFILES="$POFILES $srcdirpre$lang.po"
 670     GMOFILES="$GMOFILES $srcdirpre$lang.gmo"
 671   fi
 672 done
 673 sed -e '/^SRC-POTFILES =/r po/SRC-POTFILES' \
 674     -e '/^BLD-POTFILES =/r po/BLD-POTFILES' \
 675     -e "s,@POFILES@,$POFILES," \
 676     -e "s,@GMOFILES@,$GMOFILES," \
 677     po/Makefile.in > po/Makefile]],[[]])
 678
 679 dnl Required by html, pdf, install-pdf and install-html
 680 AC_SUBST(datarootdir)
 681 AC_SUBST(docdir)
 682 AC_SUBST(htmldir)
 683 AC_SUBST(pdfdir)
 684
 685 AC_CONFIG_FILES(Makefile po/Makefile.in:po/Make-in)
 686 AC_OUTPUT
 687
 688 GNU_MAKE_JOBSERVER