ld/configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2 dnl
   3 dnl   Copyright (C) 2012-2024 Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9 dnl
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program; see the file COPYING3.  If not see
  17 dnl <http://www.gnu.org/licenses/>.
  18 dnl
  19
  20 m4_include([../bfd/version.m4])
  21 AC_INIT([ld], BFD_VERSION)
  22 AC_CONFIG_SRCDIR(ldmain.c)
  23
  24 AC_CANONICAL_TARGET
  25 AC_CANONICAL_BUILD
  26
  27 AM_INIT_AUTOMAKE
  28 AM_SILENT_RULES([yes])
  29 AM_MAINTAINER_MODE
  30
  31 AC_PROG_CC
  32 AC_PROG_CXX
  33 AC_PROG_GREP
  34 AC_GNU_SOURCE
  35 AC_USE_SYSTEM_EXTENSIONS
  36 AC_PROG_INSTALL
  37 PKG_PROG_PKG_CONFIG
  38
  39 LT_INIT
  40 ACX_LARGEFILE
  41
  42 ac_checking=
  43 . ${srcdir}/../bfd/development.sh
  44 test "$development" = true && ac_checking=yes
  45 AC_ARG_ENABLE(checking,
  46 [  --enable-checking       enable run-time checks],
  47 [case "${enableval}" in
  48   no|none)  ac_checking= ;;
  49   *)        ac_checking=yes ;;
  50 esac])dnl
  51 if test x$ac_checking != x ; then
  52   AC_DEFINE(ENABLE_CHECKING, 1, [Define if you want run-time sanity checks.])
  53 fi
  54
  55 AC_ARG_WITH(lib-path, [  --with-lib-path=dir1:dir2...  set default LIB_PATH],LIB_PATH=$withval)
  56 AC_ARG_ENABLE(targets,
  57 [  --enable-targets        alternative target configurations],
  58 [case "${enableval}" in
  59   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  60             ;;
  61   no)       enable_targets= ;;
  62   *)        enable_targets=$enableval ;;
  63 esac])dnl
  64
  65 BFD_64_BIT
  66
  67 AC_ARG_WITH(sysroot,
  68 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
  69 [
  70  case ${with_sysroot} in
  71  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
  72  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
  73  esac
  74
  75  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
  76  use_sysroot=yes
  77
  78  if test "x$prefix" = xNONE; then
  79   test_prefix=/usr/local
  80  else
  81   test_prefix=$prefix
  82  fi
  83  if test "x$exec_prefix" = xNONE; then
  84   test_exec_prefix=$test_prefix
  85  else
  86   test_exec_prefix=$exec_prefix
  87  fi
  88  case ${TARGET_SYSTEM_ROOT} in
  89  "${test_prefix}"|"${test_prefix}/"*|\
  90  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
  91  '${prefix}'|'${prefix}/'*|\
  92  '${exec_prefix}'|'${exec_prefix}/'*)
  93    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
  94    TARGET_SYSTEM_ROOT_DEFINE="$t"
  95    ;;
  96  esac
  97 ], [
  98  use_sysroot=no
  99  TARGET_SYSTEM_ROOT=
 100  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
 101 ])
 102 AC_SUBST(use_sysroot)
 103 AC_SUBST(TARGET_SYSTEM_ROOT)
 104 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 105
 106 dnl Use --enable-gold to decide if this linker should be the default.
 107 dnl "install_as_default" is set to false if gold is the default linker.
 108 dnl "installed_linker" is the installed BFD linker name.
 109 AC_ARG_ENABLE(gold,
 110 [[  --enable-gold[=ARG]     build gold [ARG={default,yes,no}]]],
 111 [case "${enableval}" in
 112  default)
 113    install_as_default=no
 114    installed_linker=ld.bfd
 115    ;;
 116  yes|no)
 117    install_as_default=yes
 118    installed_linker=ld.bfd
 119    ;;
 120  *)
 121    AC_MSG_ERROR([invalid --enable-gold argument])
 122    ;;
 123  esac],
 124 [install_as_default=yes
 125  installed_linker=ld.bfd])
 126 AC_SUBST(install_as_default)
 127 AC_SUBST(installed_linker)
 128
 129 AC_ARG_ENABLE([got],
 130 AS_HELP_STRING([--enable-got=<type>],
 131                [GOT handling scheme (target, single, negative, multigot)]),
 132 [case "${enableval}" in
 133   target | single | negative | multigot)  got_handling=$enableval ;;
 134   *)  AC_MSG_ERROR(bad value ${enableval} for --enable-got option) ;;
 135 esac],
 136 [got_handling=target])
 137
 138 case "${got_handling}" in
 139   target)
 140     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_TARGET_DEFAULT],
 141               [Define to choose default GOT handling scheme]) ;;
 142   single)
 143     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_SINGLE],
 144               [Define to choose default GOT handling scheme]) ;;
 145   negative)
 146     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_NEGATIVE],
 147               [Define to choose default GOT handling scheme]) ;;
 148   multigot)
 149     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_MULTIGOT],
 150               [Define to choose default GOT handling scheme]) ;;
 151   *)  AC_MSG_ERROR(bad value ${got_handling} for --enable-got option) ;;
 152 esac
 153
 154 # PR gas/19109
 155 # Decide the default method for compressing debug sections.
 156 ac_default_compressed_debug_sections=unset
 157 # Provide a configure time option to override our default.
 158 AC_ARG_ENABLE(compressed_debug_sections,
 159               AS_HELP_STRING([--enable-compressed-debug-sections={all,ld,none}],
 160               [compress debug sections by default])],
 161 [case ,"${enableval}", in
 162   ,yes, | ,all, | *,ld,*) ac_default_compressed_debug_sections=yes ;;
 163   ,no, | ,none,)  ac_default_compressed_debug_sections=no ;;
 164 esac])dnl
 165
 166 # Select default compression algorithm.
 167 ac_default_compressed_debug_sections_algorithm=COMPRESS_DEBUG_GABI_ZLIB
 168 AC_ARG_ENABLE(default_compressed_debug_sections_algorithm,
 169               AS_HELP_STRING([--enable-default-compressed-debug-sections-algorithm={zlib,zstd}],
 170               [Default compression algorithm for --enable-compressed-debug-sections.]),
 171 [case "${enableval}" in
 172    zstd) ac_default_compressed_debug_sections_algorithm=COMPRESS_DEBUG_ZSTD ;;
 173 esac])dnl
 174
 175 # Decide setting DT_RUNPATH instead of DT_RPATH by default
 176 ac_default_new_dtags=unset
 177 # Provide a configure time option to override our default.
 178 AC_ARG_ENABLE(new_dtags,
 179               AS_HELP_STRING([--enable-new-dtags],
 180               [set DT_RUNPATH instead of DT_RPATH by default])],
 181 [case "${enableval}" in
 182   yes) ac_default_new_dtags=1 ;;
 183   no) ac_default_new_dtags=0 ;;
 184 esac])dnl
 185
 186 # Decide if -z relro should be enabled in ELF linker by default.
 187 ac_default_ld_z_relro=unset
 188 # Provide a configure time option to override our default.
 189 AC_ARG_ENABLE(relro,
 190               AS_HELP_STRING([--enable-relro],
 191               [enable -z relro in ELF linker by default]),
 192 [case "${enableval}" in
 193   yes)  ac_default_ld_z_relro=1 ;;
 194   no)  ac_default_ld_z_relro=0 ;;
 195 esac])dnl
 196
 197 # Decide if DT_TEXTREL check should be enabled in ELF linker.
 198 ac_default_ld_textrel_check=unset
 199 AC_ARG_ENABLE([textrel-check],
 200               AC_HELP_STRING([--enable-textrel-check=@<:@yes|no|warning|error@:>@],
 201                              [enable DT_TEXTREL check in ELF linker]),
 202 [case "${enableval}" in
 203   yes|no|warning|error) ac_default_ld_textrel_check=${enableval} ;;
 204 esac])
 205
 206 # Decide if -z separate-code should be enabled in ELF linker by default.
 207 ac_default_ld_z_separate_code=unset
 208 AC_ARG_ENABLE(separate-code,
 209               AS_HELP_STRING([--enable-separate-code],
 210               [enable -z separate-code in ELF linker by default]),
 211 [case "${enableval}" in
 212   yes) ac_default_ld_z_separate_code=1 ;;
 213   no) ac_default_ld_z_separate_code=0 ;;
 214 esac])
 215
 216 # Decide if -z mark-plt should be enabled in ELF x86-64 linker by default.
 217 ac_default_ld_z_mark_plt=unset
 218 AC_ARG_ENABLE(mark-plt,
 219               AS_HELP_STRING([--enable-mark-plt],
 220               [enable -z mark-plt in ELF x86-64 linker by default]),
 221 [case "${enableval}" in
 222   yes) ac_default_ld_z_mark_plt=1 ;;
 223   no) ac_default_ld_z_mark_plt=0 ;;
 224 esac])
 225
 226
 227 # By default warn when an executable stack is created due to object files
 228 # requesting such, not when the user specifies -z execstack.
 229 ac_default_ld_warn_execstack=2
 230 AC_ARG_ENABLE(warn-execstack,
 231               AS_HELP_STRING([--enable-warn-execstack],
 232               [enable warnings when creating an executable stack]),
 233 [case "${enableval}" in
 234   yes) ac_default_ld_warn_execstack=1 ;;
 235   no)  ac_default_ld_warn_execstack=0 ;;
 236 esac])
 237
 238 ac_default_ld_error_execstack=0
 239 AC_ARG_ENABLE(error-execstack,
 240               AS_HELP_STRING([--enable-error-execstack],
 241               [turn executable stack warnings into errors]),
 242 [case "${enableval}" in
 243   yes) ac_default_ld_error_execstack=1 ;;
 244   no)  ac_default_ld_error_execstack=0 ;;
 245 esac])
 246
 247 ac_default_ld_warn_rwx_segments=unset
 248 AC_ARG_ENABLE(warn-rwx-segments,
 249               AS_HELP_STRING([--enable-warn-rwx-segments],
 250               [enable warnings when creating segments with RWX permissions]),
 251 [case "${enableval}" in
 252   yes) ac_default_ld_warn_rwx_segments=1 ;;
 253   no)  ac_default_ld_warn_rwx_segments=0 ;;
 254 esac])
 255
 256 ac_default_ld_error_rwx_segments=0
 257 AC_ARG_ENABLE(error-rwx-segments,
 258               AS_HELP_STRING([--enable-error-rwx-segments],
 259               [turn executable segment warnings into errors]),
 260 [case "${enableval}" in
 261   yes) ac_default_ld_error_rwx_segments=1 ;;
 262   no)  ac_default_ld_error_rwx_segments=0 ;;
 263 esac])
 264
 265 ac_default_ld_default_execstack=unset
 266 AC_ARG_ENABLE(default-execstack,
 267               AS_HELP_STRING([--enable-default-execstack],
 268               [create an executable stack if an input file is missing a .note.GNU-stack section]),
 269 [case "${enableval}" in
 270   yes) ac_default_ld_default_execstack=1 ;;
 271   no)  ac_default_ld_default_execstack=0 ;;
 272 esac])
 273
 274
 275 # Decide if --error-handling-script should be supported.
 276 ac_support_error_handling_script=unset
 277 AC_ARG_ENABLE(error-handling-script,
 278               AS_HELP_STRING([--enable-error-handling-script],
 279               [enable/disable support for the --error-handling-script option]),
 280 [case "${enableval}" in
 281   yes) ac_support_error_handling_script=1 ;;
 282   no)  ac_support_error_handling_script=0 ;;
 283 esac])
 284
 285 # Decide which "--hash-style" to use by default
 286 # Provide a configure time option to override our default.
 287 AC_ARG_ENABLE([default-hash-style],
 288 AS_HELP_STRING([--enable-default-hash-style={sysv,gnu,both}],
 289                [use this default hash style]),
 290 [case "${enable_default_hash_style}" in
 291   sysv | gnu | both) ;;
 292   *) AC_MSG_ERROR([bad value ${enable_default_hash_style} for enable-default-hash-style option]) ;;
 293 esac],
 294 [case "${target}" in
 295   # Enable gnu hash only on GNU targets, but not mips
 296   mips*-*-*) enable_default_hash_style=sysv ;;
 297   *-*-gnu* | *-*-linux* | *-*-nacl*) enable_default_hash_style=both ;;
 298   *) enable_default_hash_style=sysv ;;
 299 esac])
 300
 301 case "${enable_default_hash_style}" in
 302   sysv | both) ac_default_emit_sysv_hash=1 ;;
 303   *) ac_default_emit_sysv_hash=0 ;;
 304 esac
 305
 306 case "${enable_default_hash_style}" in
 307   gnu | both) ac_default_emit_gnu_hash=1 ;;
 308   *) ac_default_emit_gnu_hash=0 ;;
 309 esac
 310
 311 AC_ARG_ENABLE(initfini-array,
 312 [  --disable-initfini-array do not use .init_array/.fini_array sections],
 313 [case "${enableval}" in
 314  yes|no) ;;
 315  *) AC_MSG_ERROR([invalid --enable-initfini-array argument]) ;;
 316  esac], [enable_initfini_array=yes])
 317 AC_SUBST(enable_initfini_array)
 318 if test $enable_initfini_array = yes; then
 319   AC_DEFINE(HAVE_INITFINI_ARRAY, 1,
 320     [Define .init_array/.fini_array sections are available and working.])
 321 fi
 322
 323 GCC_ENABLE([libctf], [yes], [], [Handle .ctf type-info sections])
 324 if test "${enable_libctf}" = yes; then
 325     AC_DEFINE(ENABLE_LIBCTF, 1, [Handle .ctf type-info sections])
 326 fi
 327 AM_CONDITIONAL(ENABLE_LIBCTF, test "${enable_libctf}" = yes)
 328 AC_SUBST(enable_libctf)
 329
 330 # Used to validate --package-metadata= input. Disabled by default.
 331 AC_ARG_ENABLE([jansson],
 332   [AS_HELP_STRING([--enable-jansson],
 333     [enable jansson [default=no]])],
 334   [enable_jansson=$enableval],
 335   [enable_jansson="no"])
 336
 337 AS_IF([test "x$enable_jansson" != "xno"],
 338   [PKG_CHECK_MODULES(JANSSON, [jansson],
 339     [
 340       AC_DEFINE(HAVE_JANSSON, 1, [The jansson library is to be used])
 341       AC_SUBST([JANSSON_CFLAGS])
 342       AC_SUBST([JANSSON_LIBS])
 343     ],
 344     [AC_MSG_ERROR([Cannot find jansson library])])
 345   ])
 346
 347 AM_BINUTILS_WARNINGS
 348
 349 AM_LC_MESSAGES
 350
 351 AC_CONFIG_HEADERS([config.h:config.in])
 352
 353 # PR 14072
 354 AH_VERBATIM([00_CONFIG_H_CHECK],
 355 [/* Check that config.h is #included before system headers
 356    (this works only for glibc, but that should be enough).  */
 357 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
 358 #  error config.h must be #included before system headers
 359 #endif
 360 #define __CONFIG_H__ 1])
 361
 362 if test -z "$target" ; then
 363     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
 364 fi
 365 if test -z "$host" ; then
 366     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
 367 fi
 368
 369 # host-specific stuff:
 370
 371 ALL_LINGUAS="bg da de es fi fr ga id it ja pt_BR ru sr sv tr uk vi zh_CN zh_TW"
 372 ZW_GNU_GETTEXT_SISTER_DIR
 373 AM_PO_SUBDIRS
 374
 375 AC_EXEEXT
 376
 377 AC_PROG_YACC
 378 AM_PROG_LEX
 379
 380 AM_MAINTAINER_MODE
 381 AM_CONDITIONAL(GENINSRC_NEVER, false)
 382 ACX_PROG_CMP_IGNORE_INITIAL
 383
 384 . ${srcdir}/configure.host
 385
 386 AC_SUBST(HDEFINES)
 387 AC_SUBST(NATIVE_LIB_DIRS)
 388
 389 # We use headers from include/ that check various HAVE_*_H macros, thus
 390 # should ensure they are set by configure.  This is true even when C99
 391 # guarantees they are available.
 392 # sha1.h and md4.h test HAVE_LIMITS_H, HAVE_SYS_TYPES_H and HAVE_STDINT_H
 393 # plugin-api.h tests HAVE_STDINT_H and HAVE_INTTYPES_H
 394 # Besides those, we need to check anything used in ld/ not in C99.
 395 AC_CHECK_HEADERS(fcntl.h elf-hints.h limits.h inttypes.h stdint.h \
 396                  sys/file.h sys/mman.h sys/param.h sys/stat.h sys/time.h \
 397                  sys/types.h unistd.h)
 398 AC_CHECK_FUNCS(close glob lseek mkstemp open realpath waitpid)
 399
 400 BFD_BINARY_FOPEN
 401
 402 AC_CHECK_DECLS([asprintf, environ, stpcpy])
 403
 404 GCC_AC_FUNC_MMAP
 405
 406 AC_SEARCH_LIBS([dlopen], [dl])
 407
 408 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 409 AC_CACHE_VAL(ld_cv_decl_getopt_unistd_h,
 410 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 411 ld_cv_decl_getopt_unistd_h=yes, ld_cv_decl_getopt_unistd_h=no)])
 412 AC_MSG_RESULT($ld_cv_decl_getopt_unistd_h)
 413 if test $ld_cv_decl_getopt_unistd_h = yes; then
 414   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 415             [Is the prototype for getopt in <unistd.h> in the expected format?])
 416 fi
 417
 418 # Link in zlib/zstd if we can.  This allows us to read and write
 419 # compressed debug sections.
 420 AM_ZLIB
 421 AC_ZSTD
 422
 423 # target-specific stuff:
 424
 425 all_targets=
 426 EMUL=
 427 all_emuls=
 428 all_emul_extras=
 429 all_libpath=
 430 TDIRS=
 431
 432 elf_list_options=false
 433 elf_shlib_list_options=false
 434 elf_plt_unwind_list_options=false
 435 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 436 do
 437   if test "$targ_alias" = "all"; then
 438     all_targets=true
 439     elf_list_options=true
 440     elf_shlib_list_options=true
 441     elf_plt_unwind_list_options=true
 442   else
 443     # Canonicalize the secondary target names.
 444     result=`$ac_config_sub $targ_alias 2>/dev/null`
 445     if test -n "$result"; then
 446         targ=$result
 447     else
 448         targ=$targ_alias
 449     fi
 450
 451     . ${srcdir}/configure.tgt
 452
 453     if test "$targ" = "$target"; then
 454       EMUL=$targ_emul
 455     fi
 456
 457     if test x${enable_64_bit_bfd} = xno; then
 458       . ${srcdir}/../bfd/config.bfd
 459     fi
 460
 461     if test x${enable_64_bit_bfd} = xyes; then
 462       targ_extra_emuls="$targ_extra_emuls $targ64_extra_emuls"
 463       targ_extra_libpath="$targ_extra_libpath $targ64_extra_libpath"
 464     fi
 465
 466     for i in $targ_emul $targ_extra_emuls $targ_extra_libpath; do
 467         case " $all_emuls " in
 468         *" e${i}.o "*) ;;
 469         *)
 470           all_emuls="$all_emuls e${i}.o"
 471           eval result=\$tdir_$i
 472           test -z "$result" && result=$targ_alias
 473           TDIRS="$TDIRS
 474 tdir_$i=$result"
 475           case "${i}" in
 476           *elf*)
 477             elf_list_options=true
 478             ;;
 479           *)
 480             if $GREP "TEMPLATE_NAME=elf" ${srcdir}/emulparams/${i}.sh >/dev/null 2>/dev/null; then
 481               elf_list_options=true
 482             fi
 483             ;;
 484           esac
 485           if test "$elf_list_options" = "true"; then
 486             source_sh()
 487             {
 488               . $1
 489             }
 490             source_sh ${srcdir}/emulparams/${i}.sh
 491             if test x${GENERATE_SHLIB_SCRIPT} = xyes; then
 492               elf_shlib_list_options=true
 493             fi
 494             if test x${PLT_UNWIND} = xyes; then
 495               elf_plt_unwind_list_options=true
 496             fi
 497           fi
 498           ;;
 499         esac
 500     done
 501
 502     for i in $targ_emul $targ_extra_libpath; do
 503         case " $all_libpath " in
 504         *" ${i} "*) ;;
 505         *)
 506           if test -z "$all_libpath"; then
 507             all_libpath=${i}
 508           else
 509             all_libpath="$all_libpath ${i}"
 510           fi
 511           ;;
 512         esac
 513     done
 514
 515     for i in $targ_extra_ofiles; do
 516         case " $all_emul_extras " in
 517         *" ${i} "*) ;;
 518         *)
 519           all_emul_extras="$all_emul_extras ${i}"
 520           ;;
 521         esac
 522     done
 523
 524   fi
 525 done
 526
 527 if test x$ac_default_compressed_debug_sections = xyes ; then
 528   AC_DEFINE(DEFAULT_FLAG_COMPRESS_DEBUG, 1, [Define if you want compressed debug sections by default.])
 529 fi
 530
 531 AC_DEFINE_UNQUOTED(DEFAULT_COMPRESSED_DEBUG_ALGORITHM, $ac_default_compressed_debug_sections_algorithm,
 532                    [Default compression algorithm for --enable-compressed-debug-sections.])
 533
 534 if test "${ac_default_new_dtags}" = unset; then
 535   ac_default_new_dtags=0
 536 fi
 537 AC_DEFINE_UNQUOTED(DEFAULT_NEW_DTAGS,
 538   $ac_default_new_dtags,
 539   [Define to 1 if you want to set DT_RUNPATH instead of DT_RPATH by default.])
 540
 541 if test "${ac_default_ld_z_relro}" = unset; then
 542   ac_default_ld_z_relro=0
 543 fi
 544 AC_DEFINE_UNQUOTED(DEFAULT_LD_Z_RELRO,
 545   $ac_default_ld_z_relro,
 546   [Define to 1 if you want to enable -z relro in ELF linker by default.])
 547
 548 ac_default_ld_textrel_check_warning=0
 549 case "${ac_default_ld_textrel_check}" in
 550   unset|no)
 551     ac_default_ld_textrel_check=textrel_check_none
 552     ;;
 553   yes|warning)
 554     ac_default_ld_textrel_check=textrel_check_warning
 555     ac_default_ld_textrel_check_warning=1
 556     ;;
 557   error)
 558     ac_default_ld_textrel_check=textrel_check_error
 559     ;;
 560 esac
 561 AC_DEFINE_UNQUOTED(DEFAULT_LD_TEXTREL_CHECK,
 562   $ac_default_ld_textrel_check,
 563   [The default method for DT_TEXTREL check in ELF linker.])
 564 AC_DEFINE_UNQUOTED(DEFAULT_LD_TEXTREL_CHECK_WARNING,
 565   $ac_default_ld_textrel_check_warning,
 566   [Define to 1 if DT_TEXTREL check is warning in ELF linker by default.])
 567
 568 if test "${ac_default_ld_z_separate_code}" = unset; then
 569   ac_default_ld_z_separate_code=0
 570 fi
 571 AC_DEFINE_UNQUOTED(DEFAULT_LD_Z_SEPARATE_CODE,
 572   $ac_default_ld_z_separate_code,
 573   [Define to 1 if you want to enable -z separate-code in ELF linker by default.])
 574
 575 if test "${ac_default_ld_z_mark_plt}" = unset; then
 576   ac_default_ld_z_mark_plt=0
 577 fi
 578 AC_DEFINE_UNQUOTED(DEFAULT_LD_Z_MARK_PLT,
 579   $ac_default_ld_z_mark_plt,
 580   [Define to 1 if you want to enable -z mark-plt in ELF x86-64 linker by default.])
 581
 582
 583 AC_DEFINE_UNQUOTED(DEFAULT_LD_WARN_EXECSTACK,
 584   $ac_default_ld_warn_execstack,
 585   [Define to 1 if you want to enable --warn-execstack in ELF linker by default.])
 586
 587 AC_DEFINE_UNQUOTED(DEFAULT_LD_ERROR_EXECSTACK,
 588   $ac_default_ld_error_execstack,
 589   [Define to 1 if you want to turn executable stack warnings into errors by default.])
 590
 591 if test "${ac_default_ld_warn_rwx_segments}" = unset; then
 592   ac_default_ld_warn_rwx_segments=1
 593 fi
 594 AC_DEFINE_UNQUOTED(DEFAULT_LD_WARN_RWX_SEGMENTS,
 595   $ac_default_ld_warn_rwx_segments,
 596   [Define to 0 if you want to disable --warn-rwx-segments in ELF linker by default.])
 597
 598 AC_DEFINE_UNQUOTED(DEFAULT_LD_ERROR_RWX_SEGMENTS,
 599   $ac_default_ld_error_rwx_segments,
 600   [Define to 1 if you want to turn executable segment warnings into errors by default.])
 601
 602 if test "${ac_default_ld_default_execstack}" = unset; then
 603   ac_default_ld_default_execstack=1
 604 fi
 605 AC_DEFINE_UNQUOTED(DEFAULT_LD_EXECSTACK,
 606   $ac_default_ld_default_execstack,
 607   [Define to 0 if you want to disable the generation of an executable stack when a .note-GNU-stack section is missing.])
 608
 609
 610 if test "${ac_support_error_handling_script}" = unset; then
 611   ac_support_error_handling_script=1
 612 fi
 613 AC_DEFINE_UNQUOTED(SUPPORT_ERROR_HANDLING_SCRIPT,
 614   $ac_support_error_handling_script,
 615   [Define to 1 if you want to support the --error-handling-script command line option.])
 616
 617 AC_DEFINE_UNQUOTED([DEFAULT_EMIT_SYSV_HASH],
 618   [$ac_default_emit_sysv_hash],
 619   [Define to 1 if you want to emit sysv hash in the ELF linker by default.])
 620
 621 AC_DEFINE_UNQUOTED([DEFAULT_EMIT_GNU_HASH],
 622   [$ac_default_emit_gnu_hash],
 623   [Define to 1 if you want to emit gnu hash in the ELF linker by default.])
 624
 625 AC_SUBST(elf_list_options)
 626 AC_SUBST(elf_shlib_list_options)
 627 AC_SUBST(elf_plt_unwind_list_options)
 628 AC_SUBST(EMUL)
 629
 630 AC_SUBST(TDIRS)
 631 AM_SUBST_NOTMAKE(TDIRS)
 632
 633 if test x${all_targets} = xtrue; then
 634   if test x${enable_64_bit_bfd} = xyes; then
 635     EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)'
 636     EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES) $(ALL_64_EMUL_EXTRA_OFILES)'
 637   else
 638     EMULATION_OFILES='$(ALL_EMULATIONS)'
 639     EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)'
 640   fi
 641 else
 642   EMULATION_OFILES=$all_emuls
 643   EMUL_EXTRA_OFILES=$all_emul_extras
 644 fi
 645 AC_SUBST(EMULATION_OFILES)
 646 AC_SUBST(EMUL_EXTRA_OFILES)
 647 AC_SUBST(LIB_PATH)
 648
 649 EMULATION_LIBPATH=$all_libpath
 650 AC_SUBST(EMULATION_LIBPATH)
 651
 652 if test x${enable_static} = xno; then
 653   TESTBFDLIB="-Wl,--rpath,../bfd/.libs ../bfd/.libs/libbfd.so"
 654   TESTCTFLIB="-Wl,--rpath,../libctf/.libs ../libctf/.libs/libctf.so"
 655   TESTSFRAMELIB="-Wl,--rpath,../libsframe/.libs ../libsframe/.libs/libsframe.so"
 656 else
 657   TESTBFDLIB="../bfd/.libs/libbfd.a"
 658   TESTCTFLIB="../libctf/.libs/libctf.a"
 659   TESTSFRAMELIB="../libsframe/.libs/libsframe.a"
 660 fi
 661 if test "${enable_libctf}" = no; then
 662     TESTCTFLIB=
 663 fi
 664 AC_SUBST(TESTBFDLIB)
 665 AC_SUBST(TESTCTFLIB)
 666 AC_SUBST(TESTSFRAMELIB)
 667
 668 target_vendor=${target_vendor=$host_vendor}
 669 case "$target_vendor" in
 670   hp) EXTRA_SHLIB_EXTENSION=".sl" ;;
 671   *)  EXTRA_SHLIB_EXTENSION= ;;
 672 esac
 673
 674 case "$target_os" in
 675   lynxos) EXTRA_SHLIB_EXTENSION=".a" ;;
 676 esac
 677
 678 if test x${EXTRA_SHLIB_EXTENSION} != x ; then
 679   AC_DEFINE_UNQUOTED(EXTRA_SHLIB_EXTENSION, "$EXTRA_SHLIB_EXTENSION",
 680    [Additional extension a shared object might have.])
 681 fi
 682
 683 AC_CONFIG_COMMANDS([default],
 684 [[
 685 case "$srcdir" in
 686   .) srcdirpre= ;;
 687   *) srcdirpre='$(srcdir)/' ;;
 688 esac
 689 POFILES=
 690 GMOFILES=
 691 for lang in dummy $OBSOLETE_ALL_LINGUAS; do
 692   if test $lang != dummy; then
 693     POFILES="$POFILES $srcdirpre$lang.po"
 694     GMOFILES="$GMOFILES $srcdirpre$lang.gmo"
 695   fi
 696 done
 697 sed -e '/^SRC-POTFILES =/r po/SRC-POTFILES' \
 698     -e '/^BLD-POTFILES =/r po/BLD-POTFILES' \
 699     -e "s,@POFILES@,$POFILES," \
 700     -e "s,@GMOFILES@,$GMOFILES," \
 701     po/Makefile.in > po/Makefile]],[[]])
 702
 703 dnl Required by html, pdf, install-pdf and install-html
 704 AC_SUBST(datarootdir)
 705 AC_SUBST(docdir)
 706 AC_SUBST(htmldir)
 707 AC_SUBST(pdfdir)
 708
 709 AC_CONFIG_FILES(Makefile po/Makefile.in:po/Make-in)
 710 AC_OUTPUT
 711
 712 GNU_MAKE_JOBSERVER