src/main/target/KISSFCV2F7/stm32_flash_f722_kissfcv2f7.ld

   1 /*
   2 *****************************************************************************
   3 **
   4 **  File        : stm32_flash_f722.ld
   5 **
   6 **  Abstract    : Linker script for STM32F722RETx Device with
   7 **                512KByte FLASH, 256KByte RAM
   8 **
   9 *****************************************************************************
  10 */
  11
  12 /* Entry Point */
  13 ENTRY(Reset_Handler)
  14
  15 /*
  16 0x08000000 to 0x0807FFFF  512K full flash
  17 0x08000000 to 0x08003FFF   16K KISS bootloader
  18 0x08004000 to 0x08007FFF   16K config
  19 0x08008000 to 0x0807FFFF  480K ISR vector, firmware
  20 */
  21
  22 /* Specify the memory areas */
  23 MEMORY
  24 {
  25     ITCM_RAM (rx)           : ORIGIN = 0x00000000, LENGTH = 16K
  26
  27     /* config occupies the entire flash sector 1 for the ease of erasure, 16K on F72x */
  28     ITCM_FLASH_CONFIG (r)   : ORIGIN = 0x00204000, LENGTH = 16K
  29     ITCM_FLASH (rx)         : ORIGIN = 0x00208000, LENGTH = 480K
  30
  31     AXIM_FLASH_CUSTOM_DEFAULTS (r) : ORIGIN = 0x08002800, LENGTH = 6K
  32     AXIM_FLASH_CONFIG (r)   : ORIGIN = 0x08004000, LENGTH = 16K
  33     AXIM_FLASH (rx)         : ORIGIN = 0x08008000, LENGTH = 480K
  34
  35     DTCM_RAM (rwx)          : ORIGIN = 0x20000000, LENGTH = 64K
  36     SRAM1 (rwx)             : ORIGIN = 0x20010000, LENGTH = 176K
  37     SRAM2 (rwx)             : ORIGIN = 0x2003C000, LENGTH = 16K
  38     MEMORY_B1 (rx)          : ORIGIN = 0x60000000, LENGTH = 0K
  39 }
  40
  41 REGION_ALIAS("FLASH", AXIM_FLASH)
  42 REGION_ALIAS("WRITABLE_FLASH", AXIM_FLASH)
  43 REGION_ALIAS("FLASH_CONFIG", AXIM_FLASH_CONFIG)
  44 REGION_ALIAS("FLASH1", AXIM_FLASH)
  45 REGION_ALIAS("FLASH_CUSTOM_DEFAULTS", AXIM_FLASH_CUSTOM_DEFAULTS)
  46 REGION_ALIAS("WRITABLE_FLASH1", AXIM_FLASH)
  47
  48 REGION_ALIAS("STACKRAM", DTCM_RAM)
  49 REGION_ALIAS("FASTRAM", DTCM_RAM)
  50 REGION_ALIAS("RAM", SRAM1)
  51
  52 /* Put various bits and bobs of data into the free space after the vector table in sector 0 to save flash space. */
  53 REGION_ALIAS("MOVABLE_FLASH", AXIM_FLASH)
  54
  55 INCLUDE "stm32_flash_f7_split.ld"