bcu/ldscripts/bcu_0012.link

   1 /*
   2     BCU SDK bcu development enviroment
   3     Copyright (C) 2005-2007 Martin Koegler <mkoegler@auto.tuwien.ac.at>
   4
   5     This program is free software; you can redistribute it and/or modify
   6     it under the terms of the GNU General Public License as published by
   7     the Free Software Foundation; either version 2 of the License, or
   8     (at your option) any later version.
   9
  10     In addition to the permissions in the GNU General Public License,
  11     you may link the compiled version of this file into combinations
  12     with other programs, and distribute those combinations without any
  13     restriction coming from the use of this file. (The General Public
  14     License restrictions do apply in other respects; for example, they
  15     cover modification of the file, and distribution when not linked into
  16     a combine executable.)
  17
  18     This program is distributed in the hope that it will be useful,
  19     but WITHOUT ANY WARRANTY; without even the implied warranty of
  20     MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21     GNU General Public License for more details.
  22
  23     You should have received a copy of the GNU General Public License
  24     along with this program; if not, write to the Free Software
  25     Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  26 */
  27
  28 /* BCU 1 */
  29
  30 SECTIONS
  31 {
  32 . = 0xCE;
  33
  34 _bss_start = . ;
  35 .ram : {
  36         *(.debounce)
  37         *(.timerval)
  38         *(.register)
  39         *(.ramflags)
  40         *(.ram)
  41 }
  42 .bss : {
  43         *(.bss.*)
  44          }
  45 _bss_end = . ;
  46 _bss_size = _bss_end - _bss_start ;
  47
  48 . = 0x100;
  49
  50 _eeprom_start = . ;
  51
  52 .text : {
  53         _text_start = . ;
  54         *(.bcuconfig)
  55         *(.addrtab)
  56         *(.assoctab)
  57         *(.commobjs)
  58         *(.ratelimit)
  59         *(.init)
  60         *(.timerptr)
  61         *(.init.1)
  62         *(.text)
  63         *(.timer)
  64         *(.loconst)
  65         *(.rodata)
  66         _text_end = . ;
  67         }
  68 _text_size = _text_end - _text_start ;
  69
  70 .data (_bss_end) : AT (_text_end) {
  71         _data_start = . ;
  72         *(.data.*)
  73         _data_end = . ;
  74         }
  75 _data_size = _data_end - _data_start ;
  76
  77 . = _text_end + _data_size ;
  78 _end_readonly = . ;
  79 .parameter : {
  80         *(.eeprom)
  81         *(.parameter)
  82 }
  83
  84 _eeprom_end = . ;
  85 _eeprom_size = _eeprom_end - _eeprom_start ;
  86
  87 _stack_size = SPBASE + SPINIT - _data_end ;
  88
  89 .loadcontrol 0x900000 : {
  90         *(.loadcontrol)
  91         SHORT(10)
  92         SHORT(2)
  93         SHORT(_eeprom_size)
  94         SHORT(_stack_size)
  95         SHORT(_data_size)
  96         SHORT(_bss_size)
  97         }
  98
  99 }
 100