configure.ac

   1 AC_INIT([barvinok], [0.37], [isl-development@googlegroups.com])
   2 AC_CONFIG_MACRO_DIR([m4])
   3 AM_INIT_AUTOMAKE([foreign])
   4 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
   5 AC_PROG_CC
   6
   7 AC_PROG_CXX
   8 AM_PROG_LEX
   9 AC_PROG_YACC
  10 AC_SUBST(versioninfo)
  11 versioninfo=23:2:0
  12
  13 AC_CANONICAL_HOST
  14 AC_LIBTOOL_WIN32_DLL
  15 AC_SUBST(BV_LDFLAGS)
  16 case $host in
  17         *-*-cygwin* | *-*-mingw* | *-*-pw32* | *-*-os2*)
  18         if test "$enable_shared" = yes; then
  19                 BV_LDFLAGS="-no-undefined"
  20         fi
  21         ;;
  22 esac
  23
  24 AC_PROG_LIBTOOL
  25
  26 PKG_PROG_PKG_CONFIG
  27
  28 AC_CHECK_HEADERS(getopt.h)
  29 AC_CHECK_HEADERS(sys/times.h)
  30 AC_CHECK_FUNCS(sigaction)
  31
  32 AC_MSG_CHECKING(whether to build shared libbarvinok)
  33 AC_ARG_ENABLE(shared_barvinok,
  34         AS_HELP_STRING([--enable-shared-barvinok],
  35                        [build shared barvinok library]),
  36         [bv_cv_shared_barvinok=$enableval], [bv_cv_shared_barvinok="no"])
  37 AC_MSG_RESULT($bv_cv_shared_barvinok)
  38 if test "x$bv_cv_shared_barvinok" != "xyes" ; then
  39         BV_LDFLAGS="$BV_LDFLAGS -static"
  40 fi
  41
  42 AC_CXX_GNUCXX_HASHMAP
  43
  44 AC_ARG_WITH(default-prefix,
  45         AS_HELP_STRING([--with-default-prefix=DIR],
  46             [Default installation prefix of optional packages]))
  47 if test "${with_default_prefix+set}" = set; then
  48         if test "${with_libgmp+set}" != set -a \
  49            -f "$with_default_prefix/include/gmp.h"; then
  50                 with_gmp_prefix=$with_default_prefix
  51         fi
  52         if test "${with_ntl+set}" != set -a \
  53            "${with_ntl_prefix+set}" != set -a \
  54            -f "$with_default_prefix/include/NTL/ZZ.h"; then
  55                 with_ntl_prefix=$with_default_prefix
  56         fi
  57         if test "${with_cddlib+set}" != set -a \
  58            -f "$with_default_prefix/include/cddmp.h"; then
  59                 with_cddlib=$with_default_prefix
  60         fi
  61         if test "${with_glpk+set}" != set -a \
  62            -f "$with_default_prefix/include/glpk.h"; then
  63                 with_glpk=$with_default_prefix
  64         fi
  65         if test "${with_topcom+set}" != set -a \
  66            -f "$with_default_prefix/bin/points2triangs"; then
  67                 with_topcom=$with_default_prefix
  68         fi
  69 fi
  70
  71 AX_SUBMODULE(gmp,system|build,system)
  72
  73 case "$with_gmp" in
  74 build)
  75         with_gmp_builddir=`echo @abs_builddir@ | \
  76                            $with_gmp_builddir/config.status --file=-`
  77         CPPFLAGS="-I$with_gmp_builddir $CPPFLAGS"
  78         LDFLAGS="-L$with_gmp_builddir/$lt_cv_objdir $LDFLAGS"
  79         bv_extra="--with-gmp --with-gmp-builddir=$with_gmp_builddir"
  80         bv_configure_args="$bv_configure_args $bv_extra"
  81         ;;
  82 system)
  83         if test "x$with_gmp_prefix" != "x"; then
  84                 bv_extra="--with-libgmp=$with_gmp_prefix"
  85                 bv_configure_args="$bv_configure_args $bv_extra"
  86                 CPPFLAGS="-I$with_gmp_prefix/include $CPPFLAGS"
  87                 LDFLAGS="-L$with_gmp_prefix/lib $LDFLAGS"
  88         else
  89                 bv_configure_args="$bv_configure_args --with-libgmp --with-gmp"
  90         fi
  91         ;;
  92 esac
  93
  94 poly_cv_gmpfatal="no"
  95 AC_CHECK_HEADER(gmp.h,
  96         [AC_CHECK_LIB(gmp,main,
  97             [],
  98             [poly_cv_gmpfatal="yes"])],
  99         [poly_cv_gmpfatal="yes"])
 100 if test "$poly_cv_gmpfatal" = "yes"; then
 101         AC_MSG_ERROR([GMP not found])
 102 fi
 103 AC_CHECK_DECL(mpz_divisible_p,[],[AC_LIBOBJ(mpz_divisible_p)],[#include <gmp.h>])
 104
 105 AX_SUBMODULE(polylib,build|bundled|system,bundled)
 106
 107 AC_SUBST(POLYLIB_CPPFLAGS)
 108 AC_SUBST(POLYLIB_LDFLAGS)
 109 AC_SUBST(POLYLIB_LIBS)
 110 case "$with_polylib" in
 111 bundled)
 112         bv_configure_args="$bv_configure_args --with-polylib-builddir=../polylib"
 113         POLYLIB_CPPFLAGS="-I\$(top_builddir)/polylib/include -I\$(top_srcdir)/polylib/include"
 114         ;;
 115 build)
 116         with_polylib_builddir=`echo @abs_builddir@ | $with_polylib_builddir/config.status --file=-`
 117         POLYLIB_CPPFLAGS="-I$polylib_srcdir/include -I$with_polylib_builddir/include"
 118         POLYLIB_LIBS="$with_polylib_builddir/libpolylibgmp.la"
 119         ;;
 120 system)
 121         POLYLIB_LIBS="-lpolylibgmp"
 122         if test "x$with_polylib_prefix" != "x"; then
 123                 POLYLIB_CPPFLAGS="-I$with_polylib_prefix/include"
 124                 POLYLIB_LDFLAGS="-L$with_polylib_prefix/lib"
 125         fi
 126         SAVE_CPPFLAGS="$CPPFLAGS"
 127         CPPFLAGS="$POLYLIB_CPPFLAGS $CPPFLAGS"
 128         AC_CHECK_HEADERS([polylib/polylibgmp.h], [], [
 129                 AC_MSG_ERROR(Need PolyLib)
 130         ])
 131         CPPFLAGS="$SAVE_CPPFLAGS"
 132 esac
 133
 134 AM_CONDITIONAL(BUNDLED_POLYLIB, test $with_polylib = bundled)
 135
 136 AX_SUBMODULE(isl,build|bundled|system,bundled)
 137
 138 AC_SUBST(ISL_CFLAGS)
 139 AC_SUBST(ISL_LIBS)
 140 AC_SUBST(ISL_BUILDDIR)
 141 case "$with_isl" in
 142 bundled)
 143         ISL_BUILDDIR=isl
 144         ISL_CFLAGS="-I\$(top_srcdir)/isl/include -I\$(top_builddir)/isl/include"
 145         bv_configure_args="$bv_configure_args --with-isl-builddir=../isl"
 146         PACKAGE_CFLAGS_ISL='-I${prefix}/include'
 147         ;;
 148 build)
 149         ISL_BUILDDIR=`echo @abs_builddir@ | $with_isl_builddir/config.status --file=-`
 150         bv_configure_args="$bv_configure_args --with-isl-builddir=$ISL_BUILDDIR"
 151         ISL_CFLAGS="-I$isl_srcdir/include -I$ISL_BUILDDIR/include"
 152         PACKAGE_CFLAGS_ISL='-I${prefix}/include'
 153         ;;
 154 system)
 155         PKG_CHECK_MODULES([ISL], [isl])
 156         PACKAGE_CFLAGS_ISL="$ISL_CFLAGS"
 157 esac
 158 AM_CONDITIONAL(BUNDLED_ISL, test $with_isl = bundled)
 159 AM_CONDITIONAL(BUILD_ISL, test $with_isl = build)
 160
 161 AX_SUBMODULE(pet,bundled|build|system|no,no)
 162 AC_SUBST(PET_CFLAGS)
 163 AC_SUBST(PET_LIBS)
 164 AC_SUBST(PET_BUILDDIR)
 165 case "$with_pet" in
 166 bundled)
 167         PET_CFLAGS="-I\$(top_srcdir)/pet/include"
 168         AC_DEFINE(HAVE_PET,[],[use Pet])
 169         ;;
 170 build)
 171         PET_BUILDDIR=`echo @abs_builddir@ | $with_pet_builddir/config.status --file=-`
 172         PET_CFLAGS="-I$pet_srcdir/include"
 173         AC_DEFINE(HAVE_PET,[],[use Pet])
 174         ;;
 175 system)
 176         PKG_CHECK_MODULES([PET], [pet])
 177         AC_DEFINE(HAVE_PET,[],[use Pet])
 178 esac
 179 AM_CONDITIONAL(BUNDLED_PET, test $with_pet = bundled)
 180 AM_CONDITIONAL(BUILD_PET, test $with_pet = build)
 181
 182 AC_MSG_CHECKING(if the fractional representation should be used)
 183 AC_ARG_ENABLE(fractional, [AS_HELP_STRING([--disable-fractional],
 184                                           [Don't use fractional representation])],
 185             [bv_cv_fractional=$enableval], [bv_cv_fractional="yes"])
 186 AC_ARG_ENABLE(modulo, [AS_HELP_STRING([--disable-modulo],
 187                                       [Don't use fractional representation])],
 188             [bv_cv_modulo=$enableval], [bv_cv_modulo="$bv_cv_fractional"])
 189 AC_MSG_RESULT($bv_cv_modulo)
 190 if test "x$bv_cv_modulo" != "xno" ; then
 191         AC_DEFINE(USE_MODULO,[], [Use fractional representation])
 192 fi
 193
 194 AC_MSG_CHECKING(whether to use incremental algorithm)
 195 AC_ARG_ENABLE(incremental,
 196         [AS_HELP_STRING([--enable-incremental@<:@=bf|df@:>@],
 197                         [Enable incremental algorithm [bf]])],
 198         [bv_cv_incremental=$enableval], [bv_cv_incremental="no"])
 199 AC_MSG_RESULT($bv_cv_incremental)
 200 case $bv_cv_incremental in
 201         yes | bf)
 202                 AC_DEFINE(USE_INCREMENTAL_BF,[],
 203                           [Use breadth-first incremental algorithm])
 204         ;;
 205         df)
 206                 AC_DEFINE(USE_INCREMENTAL_DF,[],
 207                           [Use depth-first incremental algorithm])
 208         ;;
 209 esac
 210
 211 AC_ARG_WITH(ntl,
 212             [AC_HELP_STRING([--with-ntl=system|build],
 213                             [Which NTL to use [default=system]])])
 214
 215 AC_ARG_WITH(ntl-prefix,
 216             [AC_HELP_STRING([--with-ntl-prefix=DIR],
 217                             [Prefix of NTL installation])])
 218
 219 AC_ARG_WITH(ntl-builddir,
 220             [AC_HELP_STRING([--with-ntl-builddir=DIR],
 221                             [Prefix of NTL root build directory
 222                              containing include and src subdirectories])])
 223
 224 if test "x$with_ntl_builddir" != "x"; then
 225         if test "x$with_ntl" != "xbuild" -a "x$with_ntl" != "x"; then
 226                 AC_MSG_ERROR(m4_normalize([Setting --with-ntl-builddir implies
 227                                            use of build NTL]))
 228         fi
 229         with_ntl="build"
 230 fi
 231
 232 if test "x$with_ntl_prefix" != "x"; then
 233         if test "x$with_ntl" != "xsystem" -a "x$with_ntl" != "x"; then
 234                 AC_MSG_ERROR(m4_normalize([Setting --with-ntl-prefix implies
 235                                            use of system NTL]))
 236         fi
 237         with-ntl="system"
 238 fi
 239
 240 case "$with_ntl" in
 241 build|system)
 242         ;;
 243 *)
 244         with_ntl="system"
 245         ;;
 246 esac
 247 AC_MSG_CHECKING([which NTL to use])
 248 AC_MSG_RESULT($with_ntl)
 249
 250 AC_SUBST(NTL_CPPFLAGS)
 251 AC_SUBST(NTL_LDFLAGS)
 252 case "$with_ntl" in
 253 build)
 254         NTL_CPPFLAGS="-I$with_ntl_builddir/include"
 255         NTL_LDFLAGS="-L$with_ntl_builddir/src/$lt_cv_objdir"
 256         ntl_builddir_found=false
 257         AC_CHECK_FILE(["$with_ntl_builddir/src/ZZ.c"],
 258                       [ntl_builddir_found=true],[])
 259         if test "x$ntl_builddir_found" != "xtrue"; then
 260                 if test -f "$with_ntl_builddir/ZZ.c"; then
 261                         ntl_builddir=`dirname $with_ntl_builddir`
 262                         AC_MSG_ERROR(m4_normalize(
 263                               [NTL source directory src/ specified as builddir.
 264                                Use root directory instead as
 265                                --with-ntl-builddir=$ntl_builddir]))
 266                 else
 267                         AC_MSG_ERROR([Could not find NTL in the builddir])
 268                 fi
 269         fi
 270         ;;
 271 system)
 272         if test "x$with_ntl_prefix" != "x"; then
 273                 NTL_CPPFLAGS="-I$with_ntl_prefix/include"
 274                 NTL_LDFLAGS="-L$with_ntl_prefix/lib"
 275         fi
 276         ;;
 277 esac
 278
 279 bv_no_ntl=false
 280 SAVE_CPPFLAGS="$CPPFLAGS"
 281 SAVE_LDFLAGS="$LDFLAGS"
 282 CPPFLAGS="$NTL_CPPFLAGS $CPPFLAGS"
 283 LDFLAGS="$NTL_LDFLAGS $LDFLAGS"
 284 AC_LANG_PUSH(C++)
 285 AC_CHECK_HEADER([NTL/ZZ.h],[],[bv_no_ntl=true])
 286 AC_EGREP_CPP(yes, [
 287     #include <NTL/ZZ.h>
 288     #ifdef NTL_GMP_LIP
 289     yes
 290     #endif
 291     ],:,AC_MSG_ERROR(ntl not compiled with gmp support))
 292 AC_LANG_POP
 293
 294 AC_CHECK_LIB(ntl, main,[],[bv_no_ntl=true])
 295 if test "$bv_no_ntl" = "true"; then
 296     AC_MSG_ERROR(Need ntl)
 297 fi
 298 CPPFLAGS="$SAVE_CPPFLAGS"
 299 LDFLAGS="$SAVE_LDFLAGS"
 300
 301 AC_SUBST(bv_cone_hilbert_basis)
 302 AC_MSG_CHECKING(whether to compile zsolve)
 303 AC_ARG_WITH(zsolve,
 304             [AS_HELP_STRING([--without-zsolve],[do not compile zsolve])],
 305             [ with_zsolve=$withval],  [ with_zsolve=yes ])
 306 AC_MSG_RESULT($with_zsolve)
 307
 308 use_zsolve=false
 309 if test "$with_zsolve" != "no"; then
 310         if test "$GCC" = "yes"; then
 311                 $CC --version |
 312                 sed -e 's/.* \(@<:@0-9@:>@@<:@0-9@:>@*\)\.\(@<:@0-9@:>@@<:@0-9@:>@*\).*/\1 \2/' |
 313                 (read major minor
 314                         if test $major -gt 3; then
 315                                 exit 0
 316                         fi
 317                         if test $major -eq 3 -a $minor -ge 4; then
 318                                 exit 0
 319                         fi
 320                         exit 1
 321                 ) && use_zsolve=true
 322         fi
 323         if test "$use_zsolve" = false; then
 324                 AC_MSG_WARN(gcc 3.4 required to compile zsolve)
 325         else
 326                 AC_DEFINE(USE_ZSOLVE,[],[use zsolve])
 327                 bv_cone_hilbert_basis="cone_hilbert_basis\$(EXEEXT)"
 328         fi
 329 fi
 330 AM_CONDITIONAL(USE_ZSOLVE, test x$use_zsolve = xtrue)
 331
 332 AX_SUBMODULE(omega,no|system,no)
 333
 334 AC_SUBST(OMEGA_CPPFLAGS)
 335 AC_SUBST(OMEGA_LDFLAGS)
 336 AC_SUBST(OMEGA_LIBS)
 337 AC_SUBST(OMEGA_CODEGEN_LIBS)
 338 have_omega=false
 339 have_codegen=false
 340 case "$with_omega" in
 341 system)
 342     if test "x$with_omega_prefix" != "xyes"; then
 343         OMEGA_CPPFLAGS="-I$with_omega_prefix/include/omega"
 344         OMEGA_LDFLAGS="-L$with_omega_prefix/lib"
 345     else
 346         for i in /usr/include /usr/local/include; do
 347             if test -f $i/omega/omega.h; then
 348                 OMEGA_CPPFLAGS="-I$i/omega"
 349             fi
 350         done
 351     fi
 352
 353     AC_LANG_PUSH(C++)
 354     SAVE_CPPFLAGS="$CPPFLAGS"
 355     SAVE_LDFLAGS="$LDFLAGS"
 356     CPPFLAGS="$OMEGA_CPPFLAGS $CPPFLAGS"
 357     LDFLAGS="$OMEGA_LDFLAGS $LDFLAGS"
 358     AC_CHECK_HEADERS([omega.h],[
 359         OMEGA_LIBS="-lomega"
 360         AC_CHECK_LIB(code_gen,main,[
 361                 OMEGA_CODEGEN_LIBS="-lcode_gen -lomega"
 362                 have_codegen=true
 363         ])
 364         have_omega=true
 365     ],[AC_MSG_WARN(Omega not found)])
 366     CPPFLAGS="$SAVE_CPPFLAGS"
 367     LDFLAGS="$SAVE_LDFLAGS"
 368     AC_LANG_POP
 369     ;;
 370 esac
 371 if test "$have_omega" = true; then
 372         AC_DEFINE(HAVE_OMEGA,[],[use omega])
 373 fi
 374 AM_CONDITIONAL(HAVE_OMEGA, test x$have_omega = xtrue)
 375
 376 use_parker=false
 377 AC_MSG_CHECKING(whether to compile parker)
 378 AC_ARG_WITH(parker,
 379             [AS_HELP_STRING([--without-zsolve],[do not compile zsolve])],
 380             [ with_parker=$withval],  [ with_parker=yes ])
 381 AC_MSG_RESULT($with_parker)
 382
 383 if test "$with_parker" != "no"; then
 384         AC_MSG_CHECKING(for mona)
 385         AC_ARG_WITH(mona,
 386                 [AS_HELP_STRING([--with-mona=DIR],[mona *source* directory])],
 387                                 [], [AC_MSG_RESULT(not specified)])
 388
 389         if test "x$with_mona" != "x"; then
 390                 AC_SUBST(MONAPATH)
 391                 MONAPATH=$with_mona
 392                 AC_MSG_RESULT($MONAPATH)
 393                 use_parker=true
 394                 AC_DEFINE(USE_PARKER,[],[use parker])
 395         fi
 396
 397         if test "x$with_mona" = "x"; then
 398                 AC_MSG_WARN(mona source directory required to compile parker)
 399                 AC_MSG_WARN(http://www.brics.dk/mona/download)
 400         fi
 401 fi
 402 AM_CONDITIONAL(USE_PARKER, test x$use_parker = xtrue)
 403
 404 AC_MSG_CHECKING(whether to use cddlib)
 405 AC_ARG_WITH(cddlib, [AS_HELP_STRING([--with-cddlib=DIR],[DIR Location of cddlib])],
 406             [ cddlib_package=$withval],  [ cddlib_package=yes ])
 407 AC_MSG_RESULT($cddlib_package)
 408
 409 have_cddlib=false
 410 if test "$cddlib_package" != "no"; then
 411     if test "x$cddlib_package" != "xyes"; then
 412         CPPFLAGS="-I$cddlib_package/include $CPPFLAGS"
 413         LDFLAGS="-L$cddlib_package/lib $LDFLAGS"
 414     fi
 415     AC_TRY_LINK([
 416 #define GMPRATIONAL
 417 #include <setoper.h>
 418 #include <cddmp.h>
 419 ], [
 420     mytype a;
 421     dd_init(a); ], [
 422         have_cddlib=true
 423         AC_CHECK_LIB(cddgmp, main,[
 424                 SAVE_LIBS="$LIBS"
 425                 LIBS="-lcddgmp $LIBS"
 426                 AC_DEFINE_UNQUOTED([SRCDIR], ["$srcdir"], [srcdir])
 427                 AC_LANG_PUSH(C++)
 428                 AC_RUN_IFELSE([AC_LANG_PROGRAM([[#define GMPRATIONAL
 429 #include <setoper.h>
 430 #include <cdd.h>]],
 431                 [[
 432         const char *filename = SRCDIR"/cdd94e-test";
 433         FILE *f;
 434         dd_MatrixPtr M;
 435         dd_LPType *lp;
 436         dd_ErrorType err = dd_NoError;
 437
 438         dd_set_global_constants();
 439
 440         f = fopen(filename, "r");
 441         M = dd_PolyFile2Matrix(f, &err);
 442         lp = dd_Matrix2LP(M, &err);
 443         dd_LPSolve(lp, dd_DualSimplex, &err);
 444         return lp->LPS == dd_Inconsistent;
 445                 ]])],[
 446                         AC_DEFINE(HAVE_LIBCDDGMP, [], [Define to 1 if you have the `cddgmp' library (-lcddgmp).])
 447                 ],[
 448                         AC_MSG_WARN(please upgrade cddlib to 0.94e or later)
 449                         LIBS="$SAVE_LIBS"
 450                         have_cddlib=false
 451                 ])
 452                 AC_LANG_POP
 453         ],[have_cddlib=false])
 454     ])
 455 fi
 456 AM_CONDITIONAL(HAVE_CDDLIB, test x$have_cddlib = xtrue)
 457
 458
 459
 460 AC_MSG_CHECKING(whether to use GLPK)
 461 AC_ARG_WITH(glpk, [AS_HELP_STRING([--with-glpk=DIR],[DIR Location of GLPK])],
 462             [ glpk_package=$withval],  [ glpk_package=yes ])
 463 AC_MSG_RESULT($glpk_package)
 464
 465 have_glpk=false
 466 if test "$glpk_package" != "no"; then
 467     if test "x$glpk_package" != "xyes"; then
 468         CPPFLAGS="-I$glpk_package/include $CPPFLAGS"
 469         LDFLAGS="-L$glpk_package/lib $LDFLAGS"
 470     fi
 471     AC_CHECK_HEADERS([glpk.h],[
 472         have_glpk=true
 473         AC_CHECK_LIB(glpk, [glp_simplex],[],[have_glpk=false])
 474     ])
 475 fi
 476 AM_CONDITIONAL(HAVE_GLPK, test x$have_glpk = xtrue)
 477
 478 AC_MSG_CHECKING(location of TOPCOM)
 479 AC_ARG_WITH(topcom, [AS_HELP_STRING([--with-topcom=DIR],[Location of TOPCOM])],
 480             [topcom_package=$withval], [topcom_package=unspecified])
 481 AC_MSG_RESULT($topcom_package)
 482 have_topcom=false
 483 if test "$topcom_package" != no; then
 484         topcom_path="$PATH"
 485         if test "$topcom_package" != unspecified; then
 486                 topcom_path="$topcom_package/bin"
 487         fi
 488         AC_PATH_PROG([POINTS2TRIANGS], [points2triangs], [], [$topcom_path])
 489         if test -n "$POINTS2TRIANGS"; then
 490                 have_topcom=true
 491                 AC_DEFINE_UNQUOTED(POINTS2TRIANGS_PATH, ["$POINTS2TRIANGS"],
 492                                     [Path of points2triangs])
 493         fi
 494 fi
 495 AM_CONDITIONAL(HAVE_TOPCOM, test x$have_topcom = xtrue)
 496
 497 AX_DETECT_GIT_HEAD
 498 echo '#define GIT_HEAD_ID "'$GIT_HEAD_ID'"' > version.h
 499
 500 AC_LANG_PUSH(C++)
 501 AC_TRY_COMPILE([
 502                 #include <set>
 503                 void negate();
 504         ], [negate()],
 505         suffix="normal", suffix="broken")
 506 AC_CONFIG_COMMANDS([barvinok/set.h],
 507                    [cp $srcdir/barvinok/set.h.$suffix barvinok/set.h],
 508                    [suffix="$suffix"])
 509 AC_CONFIG_COMMANDS([barvinok/NTL.h],
 510                    [cp $srcdir/barvinok/NTL.h.$suffix barvinok/NTL.h],
 511                    [suffix="$suffix"])
 512 use_fdstream=false
 513 SAVE_CPPFLAGS="$CPPFLAGS"
 514 CPPFLAGS="-I$srcdir $CPPFLAGS"
 515 AC_TRY_COMPILE([#include "fdstream.h"],[],
 516         [AC_DEFINE(USE_FDSTREAM,[],[use fdstream])
 517         use_fdstream=true])
 518 CPPFLAGS="$SAVE_CPPFLAGS"
 519 AC_LANG_POP
 520 AM_CONDITIONAL(USE_FDSTREAM, [test "$use_fdstream" = true])
 521
 522 PACKAGE_CFLAGS="$PACKAGE_CFLAGS_ISL"
 523 PACKAGE_LIBS="-lbarvinok $EXTRA_PACKAGE_LIBS -lpolylibgmp -lisl"
 524 AX_CREATE_PKGCONFIG_INFO
 525
 526 AC_CONFIG_HEADERS(config.h)
 527 AC_CONFIG_FILES(Makefile zsolve/Makefile doc/Makefile)
 528 AC_CONFIG_FILES(parker/Makefile)
 529 if test $with_polylib = bundled; then
 530         AC_CONFIG_SUBDIRS(polylib)
 531 fi
 532 if test $with_isl = bundled; then
 533         AC_CONFIG_SUBDIRS(isl)
 534 fi
 535 if test $with_pet = bundled; then
 536         AC_CONFIG_SUBDIRS(pet)
 537 fi
 538 AC_CONFIG_COMMANDS_POST([
 539         dnl pass on arguments to subdir configures, but don't
 540         dnl add them to config.status
 541         ac_configure_args="$ac_configure_args $bv_configure_args"
 542 ])
 543 AC_OUTPUT