configure.in

   1 AC_INIT
   2 AM_INIT_AUTOMAKE(barvinok, 0.26)
   3 AC_PROG_CC
   4 gl_EARLY
   5
   6 AC_PROG_CXX
   7 AM_PROG_LEX
   8 AC_PROG_YACC
   9 AC_SUBST(versioninfo)
  10 versioninfo=16:0:3
  11
  12 AC_CANONICAL_HOST
  13 AC_LIBTOOL_WIN32_DLL
  14 AC_SUBST(BV_LDFLAGS)
  15 case $host in
  16         *-*-cygwin* | *-*-mingw* | *-*-pw32* | *-*-os2*)
  17         if test "$enable_shared" = yes; then
  18                 BV_LDFLAGS="-no-undefined"
  19         fi
  20         ;;
  21 esac
  22
  23 AC_PROG_LIBTOOL
  24
  25 gl_MODULES(argp progname)
  26 gl_INIT
  27
  28 PKG_PROG_PKG_CONFIG
  29
  30 AC_CHECK_HEADERS(getopt.h)
  31 AC_CHECK_HEADERS(sys/times.h)
  32
  33 AC_MSG_CHECKING(whether to build shared libbarvinok)
  34 AC_ARG_ENABLE(shared_barvinok,
  35         AS_HELP_STRING([--enable-shared-barvinok],
  36                        [build shared barvinok library]),
  37         [bv_cv_shared_barvinok=$enableval], [bv_cv_shared_barvinok="no"])
  38 AC_MSG_RESULT($bv_cv_shared_barvinok)
  39 if test "x$bv_cv_shared_barvinok" != "xyes" ; then
  40         BV_LDFLAGS="$BV_LDFLAGS -static"
  41 fi
  42
  43 AC_ARG_WITH(default-prefix,
  44         AS_HELP_STRING([--with-default-prefix=DIR],
  45             [Default installation prefix of optional packages]))
  46 if test "${with_default_prefix+set}" = set; then
  47         if test "${with_ginac_prefix+set}" != set -a \
  48            -f "$with_default_prefix/lib/pkgconfig/ginac.pc"; then
  49                 with_ginac_prefix=$with_default_prefix
  50         fi
  51         if test "${with_libgmp+set}" != set -a \
  52            -f "$with_default_prefix/include/gmp.h"; then
  53                 with_libgmp=$with_default_prefix
  54         fi
  55         if test "${with_ntl+set}" != set -a \
  56            -f "$with_default_prefix/include/NTL/ZZ.h"; then
  57                 with_ntl=$with_default_prefix
  58         fi
  59         if test "${with_omega+set}" != set -a \
  60            -f "$with_default_prefix/include/omega/omega.h"; then
  61                 with_omega=$with_default_prefix
  62         fi
  63         if test "${with_cddlib+set}" != set -a \
  64            -f "$with_default_prefix/include/cddmp.h"; then
  65                 with_cddlib=$with_default_prefix
  66         fi
  67         if test "${with_glpk+set}" != set -a \
  68            -f "$with_default_prefix/include/glpk.h"; then
  69                 with_glpk=$with_default_prefix
  70         fi
  71         if test "${with_topcom+set}" != set -a \
  72            -f "$with_default_prefix/bin/points2triangs"; then
  73                 with_topcom=$with_default_prefix
  74         fi
  75 fi
  76
  77 dnl Check for GMP library
  78 AC_MSG_CHECKING(whether to use GMP)
  79 AC_ARG_WITH(libgmp,
  80         [  --with-libgmp           DIR Location of the GMP Distribution],
  81         gmp_package=$withval, gmp_package=yes)
  82 if test "x$gmp_package" = "xno"; then
  83         AC_MSG_RESULT(no)
  84         AC_MSG_ERROR(Need gmp)
  85 else
  86         AC_MSG_RESULT(yes)
  87         if test "x$gmp_package" = "xyes"; then
  88                 bv_configure_args="$bv_configure_args --with-libgmp --with-gmp"
  89         else
  90             bv_configure_args="$bv_configure_args --with-libgmp=$gmp_package"
  91             bv_configure_args="$bv_configure_args --with-gmp=$gmp_package"
  92             GMP_DIR=$gmp_package
  93             if test ! -d "$GMP_DIR"; then
  94                 AC_ERROR(Directory given for GMP Distribution is not a directory)
  95             fi
  96             CPPFLAGS="-I$GMP_DIR/include $CPPFLAGS"
  97             LDFLAGS="-L$GMP_DIR/lib $LDFLAGS"
  98         fi
  99         poly_cv_gmpfatal="no"
 100         AC_CHECK_HEADER(gmp.h,
 101                 [AC_CHECK_LIB(gmp,main,
 102                     [],
 103                     [poly_cv_gmpfatal="yes"])],
 104                 [poly_cv_gmpfatal="yes"])
 105         if test "$poly_cv_gmpfatal" = "yes"; then
 106                 AC_MSG_ERROR([GMP not found])
 107         fi
 108 fi
 109 AC_CHECK_DECL(mpz_divisible_p,[],[AC_LIBOBJ(mpz_divisible_p)],[#include <gmp.h>])
 110
 111 # BV_SUBMODULE(SUBMODULE)
 112 AC_DEFUN([BV_SUBMODULE],[
 113         case "$with_$1" in
 114         no)
 115                 AC_MSG_ERROR(Need $1)
 116                 ;;
 117         bundled|system)
 118                 ;;
 119         *)
 120                 if test -d $srcdir/.git -a \
 121                         ! -d $srcdir/$1/.git; then
 122                         AC_MSG_WARN(
 123 [git repo detected, but submodule $1 not initialized])
 124                         AC_MSG_WARN([You may want to run])
 125                         AC_MSG_WARN([   git submodule init])
 126                         AC_MSG_WARN([   git submodule update])
 127                         AC_MSG_WARN([   sh autogen.sh])
 128                 fi
 129                 if test -f $srcdir/$1/configure; then
 130                         with_$1="bundled"
 131                 else
 132                         with_$1="system"
 133                 fi
 134                 ;;
 135         esac
 136 ])
 137
 138 AC_ARG_WITH(polylib,
 139         [AS_HELP_STRING([--with-polylib=bundled|system],[Which PolyLib to use])])
 140 AC_ARG_WITH(polylib_prefix,
 141         [AS_HELP_STRING([--with-polylib-prefix=DIR],[Location of system PolyLib])])
 142
 143 if test "x$with_polylib_prefix" != "x"; then
 144         with_polylib="system"
 145 fi
 146 BV_SUBMODULE(polylib)
 147 AC_MSG_CHECKING([which PolyLib to use])
 148 AC_MSG_RESULT($with_polylib)
 149
 150 AC_SUBST(POLYLIB_CPPFLAGS)
 151 AC_SUBST(POLYLIB_LDFLAGS)
 152 AC_SUBST(POLYLIB_LIBS)
 153 if test "$with_polylib" = "bundled"; then
 154         bv_configure_args="$bv_configure_args --with-polylib-builddir=../polylib"
 155         POLYLIB_CPPFLAGS="-Ipolylib/include -I$srcdir/polylib/include"
 156 else
 157         POLYLIB_LIBS="-lpolylibgmp"
 158         if test "x$with_polylib_prefix" != "x"; then
 159                 POLYLIB_CPPFLAGS="-I$with_polylib_prefix/include"
 160                 POLYLIB_LDFLAGS="-L$with_polylib_prefix/lib"
 161         fi
 162         SAVE_CPPFLAGS="$CPPFLAGS"
 163         CPPFLAGS="$POLYLIB_CPPFLAGS $CPPFLAGS"
 164         AC_CHECK_HEADERS([polylib/polylibgmp.h], [], [
 165                 AC_MSG_ERROR(Need PolyLib)
 166         ])
 167         CPPFLAGS="$SAVE_CPPFLAGS"
 168 fi
 169
 170 AM_CONDITIONAL(BUNDLED_POLYLIB, test $with_polylib = bundled)
 171
 172 AC_ARG_WITH(piplib,
 173         [AS_HELP_STRING([--with-piplib=bundled|system],[Which piplib to use])])
 174 AC_ARG_WITH(piplib_prefix,
 175         [AS_HELP_STRING([--with-piplib-prefix=DIR],[Location of system piplib])])
 176
 177 if test "x$with_piplib_prefix" != "x"; then
 178         with_piplib="system"
 179 fi
 180 BV_SUBMODULE(piplib)
 181 AC_MSG_CHECKING([which piplib to use])
 182 AC_MSG_RESULT($with_piplib)
 183
 184 AC_SUBST(PIPLIB_CPPFLAGS)
 185 AC_SUBST(PIPLIB_LDFLAGS)
 186 AC_SUBST(PIPLIB_LIBS)
 187 if test "$with_piplib" = "bundled"; then
 188         bv_configure_args="$bv_configure_args --with-piplib-builddir=../piplib"
 189         bv_configure_args="$bv_configure_args --enable-mp-version"
 190         PIPLIB_CPPFLAGS="-I$srcdir/piplib/include"
 191 else
 192         PIPLIB_LIBS="-lpiplibMP"
 193         if test "x$with_piplib_prefix" != "x"; then
 194                 PIPLIB_CPPFLAGS="-I$with_piplib_prefix/include"
 195                 PIPLIB_LDFLAGS="-L$with_piplib_prefix/lib"
 196         fi
 197         SAVE_CPPFLAGS="$CPPFLAGS"
 198         SAVE_LDFLAGS="$LDFLAGS"
 199         CPPFLAGS="$PIPLIB_CPPFLAGS $CPPFLAGS"
 200         LDFLAGS="$PIPLIB_LDFLAGS $LDFLAGS"
 201         AC_CHECK_LIB(piplibMP, pip_solve,[
 202             AC_CHECK_MEMBER(PipOptions.Urs_parms, [], [
 203                 AC_MSG_ERROR([Piplib too old; please install version 1.3.6 or newer])
 204             ],[#include <stdio.h>
 205                #include <piplib/piplibMP.h>])
 206         ],[
 207             AC_MSG_ERROR([Piplib not found])
 208         ])
 209         CPPFLAGS="$SAVE_CPPFLAGS"
 210         LDFLAGS="$SAVE_LDFLAGS"
 211 fi
 212 AM_CONDITIONAL(BUNDLED_PIPLIB, test $with_piplib = bundled)
 213
 214 AC_MSG_CHECKING(if the fractional representation should be used)
 215 AC_ARG_ENABLE(fractional, [AS_HELP_STRING([--disable-fractional],
 216                                           [Don't use fractional representation])],
 217             [bv_cv_fractional=$enableval], [bv_cv_fractional="yes"])
 218 AC_ARG_ENABLE(modulo, [AS_HELP_STRING([--disable-modulo],
 219                                       [Don't use fractional representation])],
 220             [bv_cv_modulo=$enableval], [bv_cv_modulo="$bv_cv_fractional"])
 221 AC_MSG_RESULT($bv_cv_modulo)
 222 if test "x$bv_cv_modulo" != "xno" ; then
 223         AC_DEFINE(USE_MODULO,[], [Use fractional representation])
 224 fi
 225
 226 AC_MSG_CHECKING(whether to use incremental algorithm)
 227 AC_ARG_ENABLE(incremental,
 228         [AS_HELP_STRING([--enable-incremental@<:@=bf|df@:>@],
 229                         [Enable incremental algorithm [bf]])],
 230         [bv_cv_incremental=$enableval], [bv_cv_incremental="no"])
 231 AC_MSG_RESULT($bv_cv_incremental)
 232 case $bv_cv_incremental in
 233         yes | bf)
 234                 AC_DEFINE(USE_INCREMENTAL_BF,[],
 235                           [Use breadth-first incremental algorithm])
 236         ;;
 237         df)
 238                 AC_DEFINE(USE_INCREMENTAL_DF,[],
 239                           [Use depth-first incremental algorithm])
 240         ;;
 241 esac
 242
 243 AC_ARG_WITH(ntl,
 244             [  --with-ntl=DIR          DIR Location of NTL],
 245             [ echo "Package ntl : $withval" && ntl_package=$withval],
 246             [ ntl_package=yes ])
 247
 248 if test "$ntl_package" = "no"; then
 249     AC_MSG_ERROR(Need ntl)
 250 fi
 251
 252 if test "$ntl_package" != "yes"; then
 253     CPPFLAGS="-I$ntl_package/include $CPPFLAGS"
 254     LDFLAGS="-L$ntl_package/lib $LDFLAGS"
 255 fi
 256
 257 AC_EGREP_CPP(yes, [
 258     #include <NTL/ZZ.h>
 259     #ifdef NTL_GMP_LIP
 260     yes
 261     #endif
 262     ],:,AC_MSG_ERROR(ntl not compiled with gmp support))
 263
 264 AC_CHECK_LIB(ntl, main,[],[
 265     AC_MSG_ERROR(Need ntl)
 266 ])
 267
 268 AC_SUBST(bv_cone_hilbert_basis)
 269 AC_MSG_CHECKING(whether to compile zsolve)
 270 AC_ARG_WITH(bernstein,
 271             [AS_HELP_STRING([--without-zsolve],[do not compile zsolve])],
 272             [ with_zsolve=$withval],  [ with_zsolve=yes ])
 273 AC_MSG_RESULT($with_zsolve)
 274
 275 use_zsolve=false
 276 if test "$with_zsolve" != "no"; then
 277         if test "$GCC" = "yes"; then
 278                 $CC --version |
 279                 sed -e 's/.* \(@<:@0-9@:>@@<:@0-9@:>@*\)\.\(@<:@0-9@:>@@<:@0-9@:>@*\).*/\1 \2/' |
 280                 (read major minor
 281                         if test $major -gt 3; then
 282                                 exit 0
 283                         fi
 284                         if test $major -eq 3 -a $minor -ge 4; then
 285                                 exit 0
 286                         fi
 287                         exit 1
 288                 ) && use_zsolve=true
 289         fi
 290         if test "$use_zsolve" = false; then
 291                 AC_MSG_WARN(gcc 3.4 required to compile zsolve)
 292         else
 293                 AC_DEFINE(USE_ZSOLVE,[],[use zsolve])
 294                 bv_cone_hilbert_basis="cone_hilbert_basis\$(EXEEXT)"
 295         fi
 296 fi
 297 AM_CONDITIONAL(USE_ZSOLVE, test x$use_zsolve = xtrue)
 298
 299 AC_MSG_CHECKING(whether to compile bernstein)
 300 AC_ARG_WITH(bernstein,
 301             [AS_HELP_STRING([--without-bernstein],[do not compile bernstein])],
 302             [ with_bernstein=$withval],  [ with_bernstein=yes ])
 303 AC_MSG_RESULT($with_bernstein)
 304
 305 AC_ARG_WITH(ginac_prefix,
 306         [AS_HELP_STRING([--with-ginac-prefix=DIR],[Installation prefix of GiNaC])])
 307 if test "x$with_ginac_prefix" != "x"; then
 308         export PKG_CONFIG_PATH=$with_ginac_prefix/lib/pkgconfig:$PKG_CONFIG_PATH
 309 fi
 310
 311 AC_SUBST(bv_barvinok_maximize)
 312 have_ginac=false
 313 if test "$with_bernstein" != "no"; then
 314         PKG_CHECK_EXISTS([ginac], [
 315                 PKG_CHECK_MODULES(ginac, ginac)
 316                 have_ginac=true
 317                 AC_DEFINE(HAVE_GINAC,[],[use GiNaC])
 318                 EXTRA_PACKAGE_LIBS="-lbernstein $EXTRA_PACKAGE_LIBS"
 319                 bv_barvinok_maximize="barvinok_maximize\$(EXEEXT)"
 320         ])
 321 fi
 322 AM_CONDITIONAL(HAVE_GINAC, test x$have_ginac = xtrue)
 323
 324 AC_MSG_CHECKING(whether to use Omega)
 325 AC_ARG_WITH(omega, [AS_HELP_STRING([--with-omega=DIR],[DIR Location of Omega])],
 326             [ omega_package=$withval],  [ omega_package=yes ])
 327 AC_MSG_RESULT($omega_package)
 328
 329 AC_SUBST(OMEGA_CPPFLAGS)
 330 AC_SUBST(OMEGA_LDFLAGS)
 331 AC_SUBST(OMEGA_LIBS)
 332 AC_SUBST(bv_omega_programs)
 333 have_omega=false
 334 if test "$omega_package" != "no"; then
 335     if test "x$omega_package" != "xyes"; then
 336         OMEGA_CPPFLAGS="-I$omega_package/include/omega"
 337         OMEGA_LDFLAGS="-L$omega_package/lib"
 338     else
 339         for i in /usr/include /usr/local/include; do
 340             if test -f $i/omega/omega.h; then
 341                 OMEGA_CPPFLAGS="-I$i/omega"
 342             fi
 343         done
 344     fi
 345
 346     AC_LANG_PUSH(C++)
 347     SAVE_CPPFLAGS="$CPPFLAGS"
 348     CPPFLAGS="$OMEGA_CPPFLAGS $CPPFLAGS"
 349     AC_CHECK_HEADERS([omega.h],[
 350         if test x$have_ginac = xtrue; then
 351                 AC_CHECK_LIB(code_gen,main,[
 352                         bv_omega_programs="occ $bv_omega_programs"
 353                 ])
 354         fi
 355         AC_DEFINE(HAVE_OMEGA,[],[use omega])
 356         OMEGA_LIBS="-lomega"
 357         have_omega=true
 358     ],[AC_MSG_WARN(Omega not found)])
 359     CPPFLAGS="$SAVE_CPPFLAGS"
 360     AC_LANG_POP
 361 fi
 362 AM_CONDITIONAL(HAVE_OMEGA, test x$have_omega = xtrue)
 363
 364
 365 AC_MSG_CHECKING(whether to use cddlib)
 366 AC_ARG_WITH(cddlib, [AS_HELP_STRING([--with-cddlib=DIR],[DIR Location of cddlib])],
 367             [ cddlib_package=$withval],  [ cddlib_package=yes ])
 368 AC_MSG_RESULT($cddlib_package)
 369
 370 have_cddlib=false
 371 if test "$cddlib_package" != "no"; then
 372     if test "x$cddlib_package" != "xyes"; then
 373         CPPFLAGS="-I$cddlib_package/include $CPPFLAGS"
 374         LDFLAGS="-L$cddlib_package/lib $LDFLAGS"
 375     fi
 376     AC_TRY_LINK([
 377 #define GMPRATIONAL
 378 #include <setoper.h>
 379 #include <cddmp.h>
 380 ], [
 381     mytype a;
 382     dd_init(a); ], [
 383         have_cddlib=true
 384         AC_CHECK_LIB(cddgmp, main,[
 385                 SAVE_LIBS="$LIBS"
 386                 LIBS="-lcddgmp $LIBS"
 387                 AC_DEFINE_UNQUOTED([SRCDIR], ["$srcdir"], [srcdir])
 388                 AC_LANG_PUSH(C++)
 389                 AC_RUN_IFELSE(AC_LANG_PROGRAM([[#define GMPRATIONAL
 390 #include <setoper.h>
 391 #include <cdd.h>]],
 392                 [[
 393         const char *filename = SRCDIR"/cdd94e-test";
 394         FILE *f;
 395         dd_MatrixPtr M;
 396         dd_LPType *lp;
 397         dd_ErrorType err = dd_NoError;
 398
 399         dd_set_global_constants();
 400
 401         f = fopen(filename, "r");
 402         M = dd_PolyFile2Matrix(f, &err);
 403         lp = dd_Matrix2LP(M, &err);
 404         dd_LPSolve(lp, dd_DualSimplex, &err);
 405         return lp->LPS == dd_Inconsistent;
 406                 ]]),[
 407                         AC_DEFINE(HAVE_LIBCDDGMP, [], [Define to 1 if you have the `cddgmp' library (-lcddgmp).])
 408                 ],[
 409                         AC_MSG_WARN(please upgrade cddlib to 0.94e or later)
 410                         LIBS="$SAVE_LIBS"
 411                         have_cddlib=false
 412                 ])
 413                 AC_LANG_POP
 414         ],[have_cddlib=false])
 415     ])
 416 fi
 417 AM_CONDITIONAL(HAVE_CDDLIB, test x$have_cddlib = xtrue)
 418
 419
 420
 421 AC_MSG_CHECKING(whether to use GLPK)
 422 AC_ARG_WITH(glpk, [AS_HELP_STRING([--with-glpk=DIR],[DIR Location of GLPK])],
 423             [ glpk_package=$withval],  [ glpk_package=yes ])
 424 AC_MSG_RESULT($glpk_package)
 425
 426 have_glpk=false
 427 if test "$glpk_package" != "no"; then
 428     if test "x$glpk_package" != "xyes"; then
 429         CPPFLAGS="-I$glpk_package/include $CPPFLAGS"
 430         LDFLAGS="-L$glpk_package/lib $LDFLAGS"
 431     fi
 432     AC_CHECK_HEADERS([glpk.h],[
 433         have_glpk=true
 434         AC_CHECK_LIB(glpk, main,[],[have_glpk=false])
 435     ])
 436 fi
 437 AM_CONDITIONAL(HAVE_GLPK, test x$have_glpk = xtrue)
 438
 439 AC_MSG_CHECKING(location of TOPCOM)
 440 AC_ARG_WITH(topcom, [AS_HELP_STRING([--with-topcom=DIR],[Location of TOPCOM])],
 441             [topcom_package=$withval], [topcom_package=unspecified])
 442 AC_MSG_RESULT($topcom_package)
 443 have_topcom=false
 444 if test "$topcom_package" != no; then
 445         topcom_path="$PATH"
 446         if test "$topcom_package" != unspecified; then
 447                 topcom_path="$topcom_package/bin"
 448         fi
 449         AC_PATH_PROG([POINTS2TRIANGS], [points2triangs], [], [$topcom_path])
 450         if test -n "$POINTS2TRIANGS"; then
 451                 have_topcom=true
 452                 AC_DEFINE_UNQUOTED(POINTS2TRIANGS_PATH, ["$POINTS2TRIANGS"],
 453                                     [Path of points2triangs])
 454         fi
 455 fi
 456 AM_CONDITIONAL(HAVE_TOPCOM, test x$have_topcom = xtrue)
 457
 458 AC_SUBST(GIT_HEAD_ID)
 459 AC_SUBST(GIT_HEAD)
 460 AC_SUBST(GIT_HEAD_VERSION)
 461 if test -f $srcdir/.git/HEAD; then
 462     GIT_HEAD="$srcdir/.git/index"
 463     GIT_REPO="$srcdir/.git"
 464     GIT_HEAD_ID=`GIT_DIR=$GIT_REPO git describe`
 465 elif test -f $srcdir/GIT_HEAD_ID; then
 466     GIT_HEAD_ID=`cat $srcdir/GIT_HEAD_ID`
 467 else
 468     mysrcdir=`(cd $srcdir; pwd)`
 469     head=`basename $mysrcdir | sed -e 's/.*-//'`
 470     head2=`echo $head | sed -e 's/[^0-9a-f]//'`
 471     head3=`echo $head2 | sed -e 's/........................................//'`
 472     base=`basename $mysrcdir | sed -e 's/-.*//'`
 473     if test "x$head3" = "x" -a "x$head" = "x$head2"; then
 474         GIT_HEAD_ID="barvinok-$VERSION-$head
 475     elif test "x$base" = "xbarvinok-$VERSION" -a "x$head" != "x"; then
 476         GIT_HEAD_ID="barvinok-$VERSION-$head
 477     else
 478         GIT_HEAD_ID="UNKNOWN"
 479     fi
 480 fi
 481 if test -z "$GIT_REPO" ; then
 482     GIT_HEAD_VERSION="$GIT_HEAD_ID"
 483 else
 484     GIT_HEAD_VERSION="\`GIT_DIR=$GIT_REPO git describe\`"
 485 fi
 486 echo '#define GIT_HEAD_ID "'$GIT_HEAD_ID'"' > version.h
 487
 488 AC_LANG_PUSH(C++)
 489 AC_TRY_COMPILE([
 490                 #include <set>
 491                 void negate();
 492         ], [negate()],
 493         suffix="normal", suffix="broken")
 494 AC_CONFIG_COMMANDS([barvinok/set.h],
 495                    [cp $srcdir/barvinok/set.h.$suffix barvinok/set.h],
 496                    [suffix="$suffix"])
 497 AC_CONFIG_COMMANDS([barvinok/NTL.h],
 498                    [cp $srcdir/barvinok/NTL.h.$suffix barvinok/NTL.h],
 499                    [suffix="$suffix"])
 500 use_fdstream=false
 501 SAVE_CPPFLAGS="$CPPFLAGS"
 502 CPPFLAGS="-I$srcdir $CPPFLAGS"
 503 AC_TRY_COMPILE([#include "fdstream.h"],[],
 504         [AC_DEFINE(USE_FDSTREAM,[],[use fdstream])
 505         use_fdstream=true])
 506 CPPFLAGS="$SAVE_CPPFLAGS"
 507 AC_LANG_POP
 508 AM_CONDITIONAL(USE_FDSTREAM, [test "$use_fdstream" = true])
 509
 510 PACKAGE_LIBS="-lbarvinok -lbarvinok-core $EXTRA_PACKAGE_LIBS -lpolylibgmp -lpiplibMP"
 511 AX_CREATE_PKGCONFIG_INFO
 512
 513 AC_CONFIG_HEADERS(config.h)
 514 AC_CONFIG_FILES(Makefile lib/Makefile zsolve/Makefile doc/Makefile omega/Makefile)
 515 if test $with_polylib = bundled; then
 516         AC_CONFIG_SUBDIRS(polylib)
 517 fi
 518 if test $with_piplib = bundled; then
 519         AC_CONFIG_SUBDIRS(piplib)
 520 fi
 521 if test x$have_ginac = xtrue; then
 522     AC_CONFIG_SUBDIRS(bernstein)
 523 fi
 524 AC_CONFIG_COMMANDS_POST([
 525         dnl pass on arguments to subdir configures, but don't
 526         dnl add them to config.status
 527         ac_configure_args="$ac_configure_args $bv_configure_args"
 528 ])
 529 AC_OUTPUT