configure.in

   1 AC_INIT
   2 AM_INIT_AUTOMAKE(barvinok, 0.19)
   3 AC_PROG_CXX
   4 AM_PROG_LEX
   5 AC_PROG_YACC
   6 AC_SUBST(versioninfo)
   7 versioninfo=10:1:0
   8
   9 AC_CANONICAL_HOST
  10 AC_LIBTOOL_WIN32_DLL
  11 AC_SUBST(BV_LDFLAGS)
  12 case $host in
  13         *-*-cygwin* | *-*-mingw* | *-*-pw32* | *-*-os2*)
  14         if test "$enable_shared" = yes; then
  15                 BV_LDFLAGS="-no-undefined"
  16         fi
  17         ;;
  18 esac
  19
  20 AC_PROG_LIBTOOL
  21
  22 AC_CHECK_HEADERS(getopt.h)
  23 AC_CHECK_HEADERS(sys/times.h)
  24
  25 dnl Check for GMP library
  26 AC_MSG_CHECKING(whether to use GMP)
  27 AC_ARG_WITH(libgmp,
  28         [  --with-libgmp           DIR Location of the GMP Distribution],
  29         gmp_package=$withval, gmp_package=yes)
  30 if test "x$gmp_package" = "xno"; then
  31         AC_MSG_RESULT(no)
  32         AC_MSG_ERROR(Need gmp)
  33 else
  34         AC_MSG_RESULT(yes)
  35         if test "x$gmp_package" != "xyes"; then
  36             GMP_DIR=$gmp_package
  37             if test ! -d "$GMP_DIR"; then
  38                 AC_ERROR(Directory given for GMP Distribution is not a directory)
  39             fi
  40             CPPFLAGS="-I$GMP_DIR/include $CPPFLAGS"
  41             LDFLAGS="-L$GMP_DIR/lib $LDFLAGS"
  42         fi
  43         poly_cv_gmpfatal="no"
  44         AC_CHECK_HEADER(gmp.h,
  45                 [AC_CHECK_LIB(gmp,main,
  46                     [],
  47                     [poly_cv_gmpfatal="yes"])],
  48                 [poly_cv_gmpfatal="yes"])
  49         if test "$poly_cv_gmpfatal" = "yes"; then
  50                 AC_MSG_ERROR([GMP not found])
  51         fi
  52 fi
  53 AC_CHECK_DECL(mpz_divisible_p,[],[AC_LIBOBJ(mpz_divisible_p)],[#include <gmp.h>])
  54
  55 AC_ARG_WITH(polylib,
  56             [  --with-polylib=DIR      DIR Location of PolyLib],
  57             [ echo "Package polylib : $withval" && polylib_package=$withval],
  58             [ polylib_package=yes ])
  59
  60 if test "$polylib_package" = "no"; then
  61     AC_MSG_ERROR(Need polylib)
  62 fi
  63
  64 if test "$polylib_package" != "yes"; then
  65     CPPFLAGS="-I$polylib_package/include $CPPFLAGS"
  66     LDFLAGS="-L$polylib_package/lib $LDFLAGS"
  67     LD_LIBRARY_PATH="$polylib_package/lib:$LD_LIBRARY_PATH"
  68     export LD_LIBRARY_PATH
  69 fi
  70
  71 AC_CHECK_LIB(polylibgmp, PolyhedronTSort,[],[
  72     AC_MSG_ERROR(Need polylib)
  73 ])
  74 AC_CHECK_FUNCS(Enumeration_Free)
  75 AC_CHECK_FUNCS(compress_parms)
  76 AC_SUBST(bv_extra_programs)
  77 AC_CHECK_FUNCS(LexSmaller,[
  78         bv_extra_programs="verify_lexsmaller $bv_extra_programs"
  79     ])
  80 AC_REPLACE_FUNCS(DomainConstraintSimplify)
  81 AC_TRY_RUN([
  82 #include <polylib/polylibgmp.h>
  83
  84 int main()
  85 {
  86     int i, j;
  87     Polyhedron *P;
  88     Matrix *M = Matrix_Alloc(6,5);
  89     for (i = 0; i < 6; ++i) {
  90         value_set_si(M->p[i][0], 1);
  91         for (j = 1; j < 4; ++j)
  92             value_set_si(M->p[i][j], (j-1 == i/2) * (1-2*(i%2)));
  93         value_set_si(M->p[i][4], i%2);
  94     }
  95     P = Constraints2Polyhedron(M, 6);
  96     return !(P->NbRays == 8);
  97 }
  98 ],
  99 [AC_DEFINE(HAVE_GROWING_CHERNIKOVA,[],
 100           [PolyLib automatically grows the Chernikova table space])],
 101 AC_MSG_WARN([This version of PolyLib does not automatically])
 102 AC_MSG_WARN([enlarge the Chernikova table space]),
 103 AC_MSG_WARN([Unable to determine whether PolyLib automatically])
 104 AC_MSG_WARN([grows the Chernikova table space]))
 105
 106 AC_TRY_RUN([
 107 #include <polylib/polylibgmp.h>
 108
 109 int main()
 110 {
 111     enode *en = new_enode(polynomial, 1, 1);
 112     return !(en->arr[0].x.p == NULL);
 113 }
 114 ],,
 115 AC_MSG_WARN([This version of polylib leaks]),[true])
 116
 117 AC_TRY_RUN([
 118 #include <stdio.h>
 119 #include <polylib/polylibgmp.h>
 120
 121 int main()
 122 {
 123     Matrix *M;
 124     Polyhedron *P, *C;
 125     Param_Polyhedron *PP;
 126     int i;
 127     Param_Vertices *V;
 128
 129     freopen("$srcdir/tests/ehrhart/t12.in", "r", stdin);
 130     M = Matrix_Read();
 131     P = Constraints2Polyhedron(M, 1024);
 132     M = Matrix_Read();
 133     C = Constraints2Polyhedron(M, 1024);
 134     PP = Polyhedron2Param_SimplifiedDomain(&P, C, 1024, NULL, NULL);
 135     for (i = 0, V = PP->V; V; ++i, V = V->next)
 136         ;
 137     return !(i == 10);
 138 }
 139 ],
 140 [AC_DEFINE(HAVE_CORRECT_VERTICES,[],
 141           [PolyLib computes correct vertices])],
 142 AC_MSG_WARN([This version of polylib produces incorrect vertices.]),
 143 AC_MSG_WARN([Unable to determine whether PolyLib computes correct vertices]))
 144
 145 AC_MSG_CHECKING([number of arguments of Polyhedron_Enumerate])
 146 AC_TRY_COMPILE([#include <polylib/polylibgmp.h>],
 147                [Polyhedron_Enumerate(NULL,NULL,0,NULL)],
 148                [AC_MSG_RESULT(4)
 149                 AC_DEFINE(HAVE_ENUMERATE4,[],
 150                           [Polyhedron_Enumerate takes four arguments])],
 151                [AC_MSG_RESULT(3)])
 152
 153 AC_MSG_CHECKING([number of arguments of count_points])
 154 AC_TRY_COMPILE([#include <polylib/polylibgmp.h>],
 155                [count_points(0,NULL,NULL,NULL)],
 156                [AC_MSG_RESULT(4)
 157                 AC_DEFINE(HAVE_COUNT_POINTS4,[],
 158                           [count_points takes four arguments])],
 159                [AC_MSG_RESULT(3)])
 160
 161 AC_MSG_CHECKING([for value_subtract macro])
 162 AC_EGREP_CPP(yes, [
 163     #include <polylib/polylibgmp.h>
 164     #ifdef value_subtract
 165     yes
 166     #endif
 167     ],[AC_MSG_RESULT(yes)],
 168     [AC_MSG_RESULT(no)
 169      AC_DEFINE(value_subtract,value_substract,
 170                 [define to value_substract if missing from PolyLib])])
 171
 172 AC_ARG_WITH(piplib,
 173             [  --with-piplib=DIR       DIR Location of PIP],
 174             [ echo "Package piplib : $withval" && piplib_package=$withval],
 175             [ piplib_package=yes ])
 176
 177 if test "$piplib_package" != "no"; then
 178     if test "$piplib_package" != "yes"; then
 179         CPPFLAGS="-I$piplib_package/include $CPPFLAGS"
 180         LDFLAGS="-L$piplib_package/lib $LDFLAGS"
 181     fi
 182
 183     AC_CHECK_LIB(piplibMP, pip_solve,[
 184         AC_DEFINE(HAVE_PIPLIB,[],[use piplib])
 185         LIBS="-lpiplibMP $LIBS"
 186         AC_LIBOBJ(piputil)
 187         bv_extra_programs="piptest $bv_extra_programs"
 188     ],[
 189         AC_MSG_WARN([Piplib not found])
 190     ])
 191 fi
 192
 193 AC_MSG_CHECKING(whether to use Omega)
 194 AC_ARG_WITH(omega, [AS_HELP_STRING([--with-omega=DIR],[DIR Location of Omega])],
 195             [ omega_package=$withval],  [ omega_package=yes ])
 196 AC_MSG_RESULT($omega_package)
 197
 198 AC_SUBST(OMEGA_CPPFLAGS)
 199 AC_SUBST(OMEGA_LDFLAGS)
 200 AC_SUBST(bv_omega_programs)
 201 if test "$omega_package" != "no"; then
 202     if test "x$omega_package" != "xyes"; then
 203         OMEGA_CPPFLAGS="-I$omega_package/include/omega $CPPFLAGS"
 204         OMEGA_LDFLAGS="-L$omega_package/lib $LDFLAGS"
 205     else
 206         for i in /usr/include /usr/local/include; do
 207             if test -f $i/omega/omega.h; then
 208                 OMEGA_CPPFLAGS="-I$i/omega $CPPFLAGS"
 209             fi
 210         done
 211     fi
 212
 213     AC_LANG_PUSH(C++)
 214     SAVE_CPPFLAGS="$CPPFLAGS"
 215     CPPFLAGS="$OMEGA_CPPFLAGS"
 216     AC_CHECK_HEADERS([omega.h],[
 217         bv_omega_programs="occ $bv_omega_programs"
 218     ],[AC_MSG_WARN(Omega not found)])
 219     CPPFLAGS="$SAVE_CPPFLAGS"
 220     AC_LANG_POP
 221 fi
 222
 223 AC_MSG_CHECKING(if --enable-fractional option specified)
 224 AC_ARG_ENABLE(fractional,
 225             [  --enable-fractional     Use fractional representation],
 226             [bv_cv_fractional=$enableval], [bv_cv_fractional="no"])
 227 AC_MSG_RESULT($bv_cv_fractional)
 228 AC_MSG_CHECKING(if --enable-modulo option specified)
 229 AC_ARG_ENABLE(modulo,
 230             [  --enable-modulo         Use fractional representation],
 231             [bv_cv_modulo=$enableval], [bv_cv_modulo="no"])
 232 AC_MSG_RESULT($bv_cv_modulo)
 233 if test "x$bv_cv_modulo" != "xno" -o "x$bv_cv_fractional" != "xno"; then
 234         AC_DEFINE(USE_MODULO,[], [Use fractional representation])
 235 fi
 236
 237 AC_MSG_CHECKING(whether to use incremental algorithm)
 238 AC_ARG_ENABLE(incremental,
 239         [AS_HELP_STRING([--enable-incremental@<:@=bf|df@:>@],
 240                         [Enable incremental algorithm [bf]])],
 241         [bv_cv_incremental=$enableval], [bv_cv_incremental="no"])
 242 AC_MSG_RESULT($bv_cv_incremental)
 243 case $bv_cv_incremental in
 244         yes | bf)
 245                 AC_DEFINE(USE_INCREMENTAL_BF,[],
 246                           [Use breadth-first incremental algorithm])
 247         ;;
 248         df)
 249                 AC_DEFINE(USE_INCREMENTAL_DF,[],
 250                           [Use depth-first incremental algorithm])
 251         ;;
 252 esac
 253
 254 AC_ARG_WITH(ntl,
 255             [  --with-ntl=DIR          DIR Location of NTL],
 256             [ echo "Package ntl : $withval" && ntl_package=$withval],
 257             [ ntl_package=yes ])
 258
 259 if test "$ntl_package" = "no"; then
 260     AC_MSG_ERROR(Need ntl)
 261 fi
 262
 263 if test "$ntl_package" != "yes"; then
 264     CPPFLAGS="-I$ntl_package/include $CPPFLAGS"
 265     LDFLAGS="-L$ntl_package/lib $LDFLAGS"
 266 fi
 267
 268 AC_EGREP_CPP(yes, [
 269     #include <NTL/ZZ.h>
 270     #ifdef NTL_GMP_LIP
 271     yes
 272     #endif
 273     ],:,AC_MSG_ERROR(ntl not compiled with gmp support))
 274
 275 AC_CHECK_LIB(ntl, main,[],[
 276     AC_MSG_ERROR(Need ntl)
 277 ])
 278
 279 AC_SUBST(GIT_HEAD_ID)
 280 AC_SUBST(GIT_HEAD)
 281 AC_SUBST(GIT_HEAD_VERSION)
 282 if test -f $srcdir/.git/HEAD; then
 283     GIT_HEAD="$srcdir/.git/index"
 284     GIT_REPO="$srcdir/.git"
 285     GIT_HEAD_ID=`GIT_DIR=$GIT_REPO git rev-parse HEAD`
 286 elif test -f $srcdir/GIT_HEAD_ID; then
 287     GIT_HEAD_ID=`cat $srcdir/GIT_HEAD_ID`
 288 else
 289     mysrcdir=`(cd $srcdir; pwd)`
 290     head=`basename $mysrcdir | sed -e 's/.*-//'`
 291     head2=`echo $head | sed -e 's/[^0-9a-f]//'`
 292     head3=`echo $head2 | sed -e 's/........................................//'`
 293     if test "x$head3" = "x" -a "x$head" = "x$head2"; then
 294         GIT_HEAD_ID="$head"
 295     else
 296         GIT_HEAD_ID="UNKNOWN"
 297     fi
 298 fi
 299 if test -z "$GIT_REPO" ; then
 300     GIT_HEAD_VERSION="$GIT_HEAD_ID"
 301 else
 302     GIT_HEAD_VERSION="\`GIT_DIR=$GIT_REPO git rev-parse HEAD\`"
 303 fi
 304 echo '#define GIT_HEAD_ID "'$GIT_HEAD_ID'"' > version.h
 305
 306 AX_CREATE_PKGCONFIG_INFO
 307
 308 AC_CONFIG_HEADERS(config.h)
 309 AC_OUTPUT(Makefile omega/Makefile)