configure.ac

   1 AC_INIT([barvinok], [0.41.6], [isl-development@googlegroups.com])
   2 AC_CONFIG_MACRO_DIR([m4])
   3 AM_INIT_AUTOMAKE([foreign subdir-objects])
   4 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
   5 AC_PROG_CC
   6
   7 AC_PROG_CXX
   8 AC_PROG_GREP
   9 AC_PROG_SED
  10 AC_SUBST(versioninfo)
  11 versioninfo=23:11:0
  12
  13 AC_CANONICAL_HOST
  14 AC_LIBTOOL_WIN32_DLL
  15 AC_SUBST(BV_LIB_LDFLAGS)
  16 case $host in
  17         *-*-cygwin* | *-*-mingw* | *-*-pw32* | *-*-os2*)
  18         if test "$enable_shared" = yes; then
  19                 BV_LIB_LDFLAGS="-no-undefined"
  20         fi
  21         ;;
  22 esac
  23
  24 AC_PROG_LIBTOOL
  25
  26 PKG_PROG_PKG_CONFIG
  27
  28 AC_CHECK_HEADERS(getopt.h)
  29 AC_CHECK_HEADERS(sys/times.h)
  30 AC_CHECK_FUNCS(sigaction)
  31
  32 AC_MSG_CHECKING(whether to build shared libbarvinok)
  33 AC_ARG_ENABLE(shared_barvinok,
  34         AS_HELP_STRING([--enable-shared-barvinok],
  35                        [build shared barvinok library]),
  36         [bv_cv_shared_barvinok=$enableval], [bv_cv_shared_barvinok="no"])
  37 AC_MSG_RESULT($bv_cv_shared_barvinok)
  38 if test "x$bv_cv_shared_barvinok" != "xyes" ; then
  39         BV_LIB_LDFLAGS="$BV_LIB_LDFLAGS -static"
  40 fi
  41
  42 AC_SUBST(BV_LDFLAGS)
  43 AC_MSG_CHECKING(whether to build static executables)
  44 AC_ARG_ENABLE(all_static,
  45         AS_HELP_STRING([--enable-all-static],
  46                        [build static executables]),
  47         [bv_cv_all_static=$enableval], [bv_cv_all_static="no"])
  48 AC_MSG_RESULT($bv_cv_all_static)
  49 if test "x$bv_cv_all_static" = "xyes" ; then
  50         BV_LDFLAGS="$BV_LDFLAGS -all-static"
  51 fi
  52
  53 AX_C___ATTRIBUTE__
  54 AX_UNORDERED_MAP
  55 AC_CXX_GNUCXX_HASHMAP
  56
  57 AC_ARG_WITH(default-prefix,
  58         AS_HELP_STRING([--with-default-prefix=DIR],
  59             [Default installation prefix of optional packages]))
  60 if test "${with_default_prefix+set}" = set; then
  61         if test "${with_libgmp+set}" != set -a \
  62            -f "$with_default_prefix/include/gmp.h"; then
  63                 with_gmp_prefix=$with_default_prefix
  64         fi
  65         if test "${with_ntl+set}" != set -a \
  66            "${with_ntl_prefix+set}" != set -a \
  67            -f "$with_default_prefix/include/NTL/ZZ.h"; then
  68                 with_ntl_prefix=$with_default_prefix
  69         fi
  70         if test "${with_cddlib+set}" != set -a \
  71            -f "$with_default_prefix/include/cddmp.h"; then
  72                 with_cddlib=$with_default_prefix
  73         fi
  74         if test "${with_glpk+set}" != set -a \
  75            -f "$with_default_prefix/include/glpk.h"; then
  76                 with_glpk=$with_default_prefix
  77         fi
  78         if test "${with_topcom+set}" != set -a \
  79            -f "$with_default_prefix/bin/points2triangs"; then
  80                 with_topcom=$with_default_prefix
  81         fi
  82 fi
  83
  84 AX_SUBMODULE(gmp,system|build,system)
  85
  86 case "$with_gmp" in
  87 build)
  88         with_gmp_builddir=`echo @abs_builddir@ | \
  89                            $with_gmp_builddir/config.status --file=-`
  90         CPPFLAGS="-I$with_gmp_builddir $CPPFLAGS"
  91         LDFLAGS="-L$with_gmp_builddir/$lt_cv_objdir $LDFLAGS"
  92         bv_extra="--with-gmp --with-gmp-builddir=$with_gmp_builddir"
  93         bv_configure_args="$bv_configure_args $bv_extra"
  94         ;;
  95 system)
  96         if test "x$with_gmp_prefix" != "x"; then
  97                 bv_extra="--with-libgmp=$with_gmp_prefix"
  98                 bv_configure_args="$bv_configure_args $bv_extra"
  99                 CPPFLAGS="-I$with_gmp_prefix/include $CPPFLAGS"
 100                 LDFLAGS="-L$with_gmp_prefix/lib $LDFLAGS"
 101         else
 102                 bv_configure_args="$bv_configure_args --with-libgmp --with-gmp"
 103         fi
 104         ;;
 105 esac
 106
 107 poly_cv_gmpfatal="no"
 108 AC_CHECK_HEADER(gmp.h,
 109         [AC_CHECK_LIB(gmp,main,
 110             [],
 111             [poly_cv_gmpfatal="yes"])],
 112         [poly_cv_gmpfatal="yes"])
 113 if test "$poly_cv_gmpfatal" = "yes"; then
 114         AC_MSG_ERROR([GMP not found])
 115 fi
 116 AC_CHECK_DECL(mpz_divisible_p,[],[AC_LIBOBJ(mpz_divisible_p)],[#include <gmp.h>])
 117
 118 AX_SUBMODULE(polylib,build|bundled|system,bundled)
 119
 120 AC_SUBST(POLYLIB_CPPFLAGS)
 121 AC_SUBST(POLYLIB_LDFLAGS)
 122 AC_SUBST(POLYLIB_LIBS)
 123 case "$with_polylib" in
 124 bundled)
 125         bv_configure_args="$bv_configure_args --with-polylib-builddir=../polylib"
 126         POLYLIB_CPPFLAGS="-I\$(top_builddir)/polylib/include -I\$(top_srcdir)/polylib/include"
 127         ;;
 128 build)
 129         with_polylib_builddir=`echo @abs_builddir@ | $with_polylib_builddir/config.status --file=-`
 130         POLYLIB_CPPFLAGS="-I$polylib_srcdir/include -I$with_polylib_builddir/include"
 131         POLYLIB_LIBS="$with_polylib_builddir/libpolylibgmp.la"
 132         ;;
 133 system)
 134         POLYLIB_LIBS="-lpolylibgmp"
 135         if test "x$with_polylib_prefix" != "x"; then
 136                 POLYLIB_CPPFLAGS="-I$with_polylib_prefix/include"
 137                 POLYLIB_LDFLAGS="-L$with_polylib_prefix/lib"
 138         fi
 139         SAVE_CPPFLAGS="$CPPFLAGS"
 140         CPPFLAGS="$POLYLIB_CPPFLAGS $CPPFLAGS"
 141         AC_CHECK_HEADERS([polylib/polylibgmp.h], [], [
 142                 AC_MSG_ERROR(Need PolyLib)
 143         ])
 144         CPPFLAGS="$SAVE_CPPFLAGS"
 145 esac
 146
 147 AM_CONDITIONAL(BUNDLED_POLYLIB, test $with_polylib = bundled)
 148
 149 AX_SUBMODULE(isl,build|bundled|system,bundled)
 150
 151 AC_SUBST(ISL_CFLAGS)
 152 AC_SUBST(ISL_LIBS)
 153 AC_SUBST(ISL_SRCDIR)
 154 AC_SUBST(ISL_BUILDDIR)
 155 case "$with_isl" in
 156 bundled)
 157         ISL_SRCDIR="$srcdir/isl"
 158         ISL_BUILDDIR=isl
 159         ISL_CFLAGS="-I\$(top_srcdir)/isl/include -I\$(top_builddir)/isl/include"
 160         bv_configure_args="$bv_configure_args --with-isl=build"
 161         bv_configure_args="$bv_configure_args --with-isl-builddir=../isl"
 162         PACKAGE_CFLAGS_ISL='-I${prefix}/include'
 163         ;;
 164 build)
 165         ISL_SRCDIR="$isl_srcdir"
 166         ISL_BUILDDIR=`echo @abs_builddir@ | $with_isl_builddir/config.status --file=-`
 167         bv_configure_args="$bv_configure_args --with-isl-builddir=$ISL_BUILDDIR"
 168         ISL_CFLAGS="-I$isl_srcdir/include -I$ISL_BUILDDIR/include"
 169         PACKAGE_CFLAGS_ISL='-I${prefix}/include'
 170         ;;
 171 system)
 172         PKG_CHECK_MODULES([ISL], [isl])
 173         PACKAGE_CFLAGS_ISL="$ISL_CFLAGS"
 174 esac
 175 AM_CONDITIONAL(BUNDLED_ISL, test $with_isl = bundled)
 176 AM_CONDITIONAL(BUILD_ISL, test $with_isl = build)
 177 AM_CONDITIONAL(HAVE_ISL_BUILDDIR, test "x$ISL_BUILDDIR" != "x")
 178
 179 AX_SUBMODULE(pet,bundled|build|system|no,no)
 180 AC_SUBST(PET_CFLAGS)
 181 AC_SUBST(PET_LIBS)
 182 AC_SUBST(PET_BUILDDIR)
 183 pet_suffix="top.pet"
 184 case "$with_pet" in
 185 bundled)
 186         PET_CFLAGS="-I\$(top_srcdir)/pet/include"
 187         AC_DEFINE(HAVE_PET,[],[use Pet])
 188         ;;
 189 build)
 190         PET_BUILDDIR=`echo @abs_builddir@ | $with_pet_builddir/config.status --file=-`
 191         PET_CFLAGS="-I$pet_srcdir/include"
 192         AC_DEFINE(HAVE_PET,[],[use Pet])
 193         ;;
 194 system)
 195         PKG_CHECK_MODULES([PET], [pet])
 196         AC_DEFINE(HAVE_PET,[],[use Pet])
 197         ;;
 198 no)
 199         pet_suffix="top.no_pet"
 200         ;;
 201 esac
 202 AM_CONDITIONAL(BUNDLED_PET, test $with_pet = bundled)
 203 AM_CONDITIONAL(BUILD_PET, test $with_pet = build)
 204
 205 AC_MSG_CHECKING(whether to use incremental algorithm)
 206 AC_ARG_ENABLE(incremental,
 207         [AS_HELP_STRING([--enable-incremental@<:@=bf|df@:>@],
 208                         [Enable incremental algorithm [bf]])],
 209         [bv_cv_incremental=$enableval], [bv_cv_incremental="no"])
 210 AC_MSG_RESULT($bv_cv_incremental)
 211 case $bv_cv_incremental in
 212         yes | bf)
 213                 AC_DEFINE(USE_INCREMENTAL_BF,[],
 214                           [Use breadth-first incremental algorithm])
 215         ;;
 216         df)
 217                 AC_DEFINE(USE_INCREMENTAL_DF,[],
 218                           [Use depth-first incremental algorithm])
 219         ;;
 220 esac
 221
 222 AC_ARG_WITH(ntl,
 223             [AC_HELP_STRING([--with-ntl=system|build],
 224                             [Which NTL to use [default=system]])])
 225
 226 AC_ARG_WITH(ntl-prefix,
 227             [AC_HELP_STRING([--with-ntl-prefix=DIR],
 228                             [Prefix of NTL installation])])
 229
 230 AC_ARG_WITH(ntl-builddir,
 231             [AC_HELP_STRING([--with-ntl-builddir=DIR],
 232                             [Prefix of NTL root build directory
 233                              containing include and src subdirectories])])
 234
 235 if test "x$with_ntl_builddir" != "x"; then
 236         if test "x$with_ntl" != "xbuild" -a "x$with_ntl" != "x"; then
 237                 AC_MSG_ERROR(m4_normalize([Setting --with-ntl-builddir implies
 238                                            use of build NTL]))
 239         fi
 240         with_ntl="build"
 241 fi
 242
 243 if test "x$with_ntl_prefix" != "x"; then
 244         if test "x$with_ntl" != "xsystem" -a "x$with_ntl" != "x"; then
 245                 AC_MSG_ERROR(m4_normalize([Setting --with-ntl-prefix implies
 246                                            use of system NTL]))
 247         fi
 248         with_ntl="system"
 249 fi
 250
 251 case "$with_ntl" in
 252 build|system)
 253         ;;
 254 *)
 255         with_ntl="system"
 256         ;;
 257 esac
 258 AC_MSG_CHECKING([which NTL to use])
 259 AC_MSG_RESULT($with_ntl)
 260
 261 AC_SUBST(NTL_CPPFLAGS)
 262 AC_SUBST(NTL_LDFLAGS)
 263 case "$with_ntl" in
 264 build)
 265         ntl_include="$with_ntl_builddir/include"
 266         NTL_LDFLAGS="-L$with_ntl_builddir/src/$lt_cv_objdir"
 267         ntl_builddir_found=false
 268         AC_CHECK_FILE(["$with_ntl_builddir/src/ZZ.c"],
 269                       [ntl_builddir_found=true],[])
 270         if test "x$ntl_builddir_found" != "xtrue"; then
 271                 if test -f "$with_ntl_builddir/ZZ.c"; then
 272                         ntl_builddir=`dirname $with_ntl_builddir`
 273                         AC_MSG_ERROR(m4_normalize(
 274                               [NTL source directory src/ specified as builddir.
 275                                Use root directory instead as
 276                                --with-ntl-builddir=$ntl_builddir]))
 277                 else
 278                         AC_MSG_ERROR([Could not find NTL in the builddir])
 279                 fi
 280         fi
 281         ;;
 282 system)
 283         if test "x$with_ntl_prefix" != "x"; then
 284                 ntl_include="$with_ntl_prefix/include"
 285                 NTL_LDFLAGS="-L$with_ntl_prefix/lib"
 286         fi
 287         ;;
 288 esac
 289 if test "x$ntl_include" != "x"; then
 290         NTL_CPPFLAGS="-I$ntl_include"
 291 else
 292         for path in /usr/local /usr; do
 293                 if test -f "$path/include/NTL/ZZ.h"; then
 294                         ntl_include="$path/include"
 295                         break;
 296                 fi
 297         done
 298 fi
 299 # Look for compiler/linker options needed for linking against NTL
 300 ntl_configlog="$ntl_include/NTL/ConfigLog.h"
 301 if test -f "$ntl_configlog"; then
 302         AC_MSG_CHECKING([for compiler options in $ntl_configlog])
 303         eval $($GREP "^CXXAUTOFLAGS" $ntl_configlog | $SED -e 's/^/NTL_/')
 304         AC_MSG_RESULT([$NTL_CXXAUTOFLAGS])
 305         NTL_CPPFLAGS="$NTL_CPPFLAGS $NTL_CXXAUTOFLAGS"
 306         NTL_LDFLAGS="$NTL_LDFLAGS $NTL_CXXAUTOFLAGS"
 307 fi
 308
 309 AX_CHECK_NTL
 310
 311 AC_SUBST(bv_cone_hilbert_basis)
 312 AC_MSG_CHECKING(whether to compile zsolve)
 313 AC_ARG_WITH(zsolve,
 314             [AS_HELP_STRING([--without-zsolve],[do not compile zsolve])],
 315             [ with_zsolve=$withval],  [ with_zsolve=yes ])
 316 AC_MSG_RESULT($with_zsolve)
 317
 318 use_zsolve=false
 319 if test "$with_zsolve" != "no"; then
 320         if test "$GCC" = "yes"; then
 321                 $CC --version |
 322                 $SED -e 's/.* \(@<:@0-9@:>@@<:@0-9@:>@*\)\.\(@<:@0-9@:>@@<:@0-9@:>@*\).*/\1 \2/' |
 323                 (read major minor
 324                         if test $major -gt 3; then
 325                                 exit 0
 326                         fi
 327                         if test $major -eq 3 -a $minor -ge 4; then
 328                                 exit 0
 329                         fi
 330                         exit 1
 331                 ) && use_zsolve=true
 332         fi
 333         if test "$use_zsolve" = false; then
 334                 AC_MSG_WARN(gcc 3.4 required to compile zsolve)
 335         else
 336                 AC_DEFINE(USE_ZSOLVE,[],[use zsolve])
 337                 bv_cone_hilbert_basis="cone_hilbert_basis\$(EXEEXT)"
 338         fi
 339 fi
 340 AM_CONDITIONAL(USE_ZSOLVE, test x$use_zsolve = xtrue)
 341
 342 AX_SUBMODULE(omega,no|system,no)
 343
 344 AC_SUBST(OMEGA_CPPFLAGS)
 345 AC_SUBST(OMEGA_LDFLAGS)
 346 AC_SUBST(OMEGA_LIBS)
 347 AC_SUBST(OMEGA_CODEGEN_LIBS)
 348 have_omega=false
 349 have_codegen=false
 350 case "$with_omega" in
 351 system)
 352     if test "x$with_omega_prefix" != "xyes"; then
 353         OMEGA_CPPFLAGS="-I$with_omega_prefix/include/omega"
 354         OMEGA_LDFLAGS="-L$with_omega_prefix/lib"
 355     else
 356         for i in /usr/include /usr/local/include; do
 357             if test -f $i/omega/omega.h; then
 358                 OMEGA_CPPFLAGS="-I$i/omega"
 359             fi
 360         done
 361     fi
 362
 363     AC_LANG_PUSH(C++)
 364     SAVE_CPPFLAGS="$CPPFLAGS"
 365     SAVE_LDFLAGS="$LDFLAGS"
 366     CPPFLAGS="$OMEGA_CPPFLAGS $CPPFLAGS"
 367     LDFLAGS="$OMEGA_LDFLAGS $LDFLAGS"
 368     AC_CHECK_HEADERS([omega.h],[
 369         OMEGA_LIBS="-lomega"
 370         AC_CHECK_LIB(code_gen,main,[
 371                 OMEGA_CODEGEN_LIBS="-lcode_gen -lomega"
 372                 have_codegen=true
 373         ])
 374         have_omega=true
 375     ],[AC_MSG_WARN(Omega not found)])
 376     CPPFLAGS="$SAVE_CPPFLAGS"
 377     LDFLAGS="$SAVE_LDFLAGS"
 378     AC_LANG_POP
 379     ;;
 380 esac
 381 if test "$have_omega" = true; then
 382         AC_DEFINE(HAVE_OMEGA,[],[use omega])
 383 fi
 384 AM_CONDITIONAL(HAVE_OMEGA, test x$have_omega = xtrue)
 385
 386 use_parker=false
 387 AC_MSG_CHECKING(whether to compile parker)
 388 AC_ARG_WITH(parker,
 389             [AS_HELP_STRING([--without-zsolve],[do not compile zsolve])],
 390             [ with_parker=$withval],  [ with_parker=yes ])
 391 AC_MSG_RESULT($with_parker)
 392
 393 if test "$with_parker" != "no"; then
 394         AC_MSG_CHECKING(for mona)
 395         AC_ARG_WITH(mona,
 396                 [AS_HELP_STRING([--with-mona=DIR],[mona *source* directory])],
 397                                 [], [AC_MSG_RESULT(not specified)])
 398
 399         if test "x$with_mona" != "x"; then
 400                 AC_SUBST(MONAPATH)
 401                 MONAPATH=$with_mona
 402                 AC_MSG_RESULT($MONAPATH)
 403                 use_parker=true
 404                 AC_DEFINE(USE_PARKER,[],[use parker])
 405         fi
 406
 407         if test "x$with_mona" = "x"; then
 408                 AC_MSG_WARN(mona source directory required to compile parker)
 409                 AC_MSG_WARN(http://www.brics.dk/mona/download)
 410         fi
 411 fi
 412 AM_CONDITIONAL(USE_PARKER, test x$use_parker = xtrue)
 413
 414 AC_MSG_CHECKING(whether to use cddlib)
 415 AC_ARG_WITH(cddlib, [AS_HELP_STRING([--with-cddlib=DIR],[DIR Location of cddlib])],
 416             [ cddlib_package=$withval],  [ cddlib_package=yes ])
 417 AC_MSG_RESULT($cddlib_package)
 418
 419 have_cddlib=false
 420 if test "$cddlib_package" != "no"; then
 421     if test "x$cddlib_package" != "xyes"; then
 422         CPPFLAGS="-I$cddlib_package/include $CPPFLAGS"
 423         LDFLAGS="-L$cddlib_package/lib $LDFLAGS"
 424     fi
 425     AC_TRY_LINK([
 426 #define GMPRATIONAL
 427 #include <setoper.h>
 428 #include <cddmp.h>
 429 ], [
 430     mytype a;
 431     dd_init(a); ], [
 432         have_cddlib=true
 433         AC_CHECK_LIB(cddgmp, main,[
 434                 SAVE_LIBS="$LIBS"
 435                 LIBS="-lcddgmp $LIBS"
 436                 AC_DEFINE_UNQUOTED([SRCDIR], ["$srcdir"], [srcdir])
 437                 AC_LANG_PUSH(C++)
 438                 AC_RUN_IFELSE([AC_LANG_PROGRAM([[#define GMPRATIONAL
 439 #include <setoper.h>
 440 #include <cdd.h>]],
 441                 [[
 442         const char *filename = SRCDIR"/cdd94e-test";
 443         FILE *f;
 444         dd_MatrixPtr M;
 445         dd_LPType *lp;
 446         dd_ErrorType err = dd_NoError;
 447
 448         dd_set_global_constants();
 449
 450         f = fopen(filename, "r");
 451         M = dd_PolyFile2Matrix(f, &err);
 452         lp = dd_Matrix2LP(M, &err);
 453         dd_LPSolve(lp, dd_DualSimplex, &err);
 454         return lp->LPS == dd_Inconsistent;
 455                 ]])],[
 456                         AC_DEFINE(HAVE_LIBCDDGMP, [], [Define to 1 if you have the `cddgmp' library (-lcddgmp).])
 457                 ],[
 458                         AC_MSG_WARN(please upgrade cddlib to 0.94e or later)
 459                         LIBS="$SAVE_LIBS"
 460                         have_cddlib=false
 461                 ])
 462                 AC_LANG_POP
 463         ],[have_cddlib=false])
 464     ])
 465 fi
 466 AM_CONDITIONAL(HAVE_CDDLIB, test x$have_cddlib = xtrue)
 467
 468
 469
 470 AC_MSG_CHECKING(whether to use GLPK)
 471 AC_ARG_WITH(glpk, [AS_HELP_STRING([--with-glpk=DIR],[DIR Location of GLPK])],
 472             [ glpk_package=$withval],  [ glpk_package=yes ])
 473 AC_MSG_RESULT($glpk_package)
 474
 475 have_glpk=false
 476 if test "$glpk_package" != "no"; then
 477     if test "x$glpk_package" != "xyes"; then
 478         CPPFLAGS="-I$glpk_package/include $CPPFLAGS"
 479         LDFLAGS="-L$glpk_package/lib $LDFLAGS"
 480     fi
 481     AC_CHECK_HEADERS([glpk.h],[
 482         have_glpk=true
 483         AC_CHECK_LIB(glpk, [glp_simplex],[],[have_glpk=false])
 484     ])
 485 fi
 486 AM_CONDITIONAL(HAVE_GLPK, test x$have_glpk = xtrue)
 487
 488 AC_MSG_CHECKING(location of TOPCOM)
 489 AC_ARG_WITH(topcom, [AS_HELP_STRING([--with-topcom=DIR],[Location of TOPCOM])],
 490             [topcom_package=$withval], [topcom_package=unspecified])
 491 AC_MSG_RESULT($topcom_package)
 492 have_topcom=false
 493 if test "$topcom_package" != no; then
 494         topcom_path="$PATH"
 495         if test "$topcom_package" != unspecified; then
 496                 topcom_path="$topcom_package/bin"
 497         fi
 498         AC_PATH_PROG([POINTS2TRIANGS], [points2triangs], [], [$topcom_path])
 499         if test -n "$POINTS2TRIANGS"; then
 500                 have_topcom=true
 501                 AC_DEFINE_UNQUOTED(POINTS2TRIANGS_PATH, ["$POINTS2TRIANGS"],
 502                                     [Path of points2triangs])
 503         fi
 504 fi
 505 AM_CONDITIONAL(HAVE_TOPCOM, test x$have_topcom = xtrue)
 506
 507 AX_DETECT_GIT_HEAD
 508 echo '#define GIT_HEAD_ID "'$GIT_HEAD_ID'"' > version.h
 509
 510 AC_LANG_PUSH(C++)
 511 AC_TRY_COMPILE([
 512                 #include <set>
 513                 void negate();
 514         ], [negate()],
 515         suffix="normal", suffix="broken")
 516 AC_CONFIG_COMMANDS([barvinok/set.h],
 517                    [cp $srcdir/barvinok/set.h.$suffix barvinok/set.h],
 518                    [suffix="$suffix"])
 519 AC_CONFIG_COMMANDS([barvinok/NTL.h],
 520                    [cp $srcdir/barvinok/NTL.h.$suffix barvinok/NTL.h],
 521                    [suffix="$suffix"])
 522 use_fdstream=false
 523 SAVE_CPPFLAGS="$CPPFLAGS"
 524 CPPFLAGS="-I$srcdir $CPPFLAGS"
 525 AC_TRY_COMPILE([#include "fdstream.h"],[],
 526         [AC_DEFINE(USE_FDSTREAM,[],[use fdstream])
 527         use_fdstream=true])
 528 CPPFLAGS="$SAVE_CPPFLAGS"
 529 AC_LANG_POP
 530 AM_CONDITIONAL(USE_FDSTREAM, [test "$use_fdstream" = true])
 531
 532 AC_CONFIG_COMMANDS([interface/isl.py.top],
 533                  [cp $srcdir/interface/isl.py.$pet_suffix interface/isl.py.top],
 534                  [pet_suffix="$pet_suffix"])
 535
 536 PACKAGE_CFLAGS="$PACKAGE_CFLAGS_ISL"
 537 PACKAGE_LIBS="-lbarvinok $EXTRA_PACKAGE_LIBS -lpolylibgmp -lisl"
 538 AX_CREATE_PKGCONFIG_INFO
 539
 540 AH_BOTTOM([#include "config_post.h"])
 541 AC_CONFIG_HEADERS(config.h)
 542 AC_CONFIG_FILES(Makefile zsolve/Makefile doc/Makefile)
 543 AC_CONFIG_FILES(parker/Makefile)
 544 if test $with_polylib = bundled; then
 545         AC_CONFIG_SUBDIRS(polylib)
 546 fi
 547 if test $with_isl = bundled; then
 548         AC_CONFIG_SUBDIRS(isl)
 549 fi
 550 if test $with_pet = bundled; then
 551         AC_CONFIG_SUBDIRS(pet)
 552 fi
 553 AC_CONFIG_COMMANDS_POST([
 554         dnl pass on arguments to subdir configures, but don't
 555         dnl add them to config.status
 556         ac_configure_args="$ac_configure_args $bv_configure_args"
 557 ])
 558 AC_OUTPUT