configure.ac

   1 AC_INIT([barvinok], [0.39], [isl-development@googlegroups.com])
   2 AC_CONFIG_MACRO_DIR([m4])
   3 AM_INIT_AUTOMAKE([foreign subdir-objects])
   4 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
   5 AC_PROG_CC
   6
   7 AC_PROG_CXX
   8 AM_PROG_LEX
   9 AC_PROG_YACC
  10 AC_SUBST(versioninfo)
  11 versioninfo=23:4:0
  12
  13 AC_CANONICAL_HOST
  14 AC_LIBTOOL_WIN32_DLL
  15 AC_SUBST(BV_LDFLAGS)
  16 case $host in
  17         *-*-cygwin* | *-*-mingw* | *-*-pw32* | *-*-os2*)
  18         if test "$enable_shared" = yes; then
  19                 BV_LDFLAGS="-no-undefined"
  20         fi
  21         ;;
  22 esac
  23
  24 AC_PROG_LIBTOOL
  25
  26 PKG_PROG_PKG_CONFIG
  27
  28 AC_CHECK_HEADERS(getopt.h)
  29 AC_CHECK_HEADERS(sys/times.h)
  30 AC_CHECK_FUNCS(sigaction)
  31
  32 AC_MSG_CHECKING(whether to build shared libbarvinok)
  33 AC_ARG_ENABLE(shared_barvinok,
  34         AS_HELP_STRING([--enable-shared-barvinok],
  35                        [build shared barvinok library]),
  36         [bv_cv_shared_barvinok=$enableval], [bv_cv_shared_barvinok="no"])
  37 AC_MSG_RESULT($bv_cv_shared_barvinok)
  38 if test "x$bv_cv_shared_barvinok" != "xyes" ; then
  39         BV_LDFLAGS="$BV_LDFLAGS -static"
  40 fi
  41
  42 AC_CXX_GNUCXX_HASHMAP
  43
  44 AC_ARG_WITH(default-prefix,
  45         AS_HELP_STRING([--with-default-prefix=DIR],
  46             [Default installation prefix of optional packages]))
  47 if test "${with_default_prefix+set}" = set; then
  48         if test "${with_libgmp+set}" != set -a \
  49            -f "$with_default_prefix/include/gmp.h"; then
  50                 with_gmp_prefix=$with_default_prefix
  51         fi
  52         if test "${with_ntl+set}" != set -a \
  53            "${with_ntl_prefix+set}" != set -a \
  54            -f "$with_default_prefix/include/NTL/ZZ.h"; then
  55                 with_ntl_prefix=$with_default_prefix
  56         fi
  57         if test "${with_cddlib+set}" != set -a \
  58            -f "$with_default_prefix/include/cddmp.h"; then
  59                 with_cddlib=$with_default_prefix
  60         fi
  61         if test "${with_glpk+set}" != set -a \
  62            -f "$with_default_prefix/include/glpk.h"; then
  63                 with_glpk=$with_default_prefix
  64         fi
  65         if test "${with_topcom+set}" != set -a \
  66            -f "$with_default_prefix/bin/points2triangs"; then
  67                 with_topcom=$with_default_prefix
  68         fi
  69 fi
  70
  71 AX_SUBMODULE(gmp,system|build,system)
  72
  73 case "$with_gmp" in
  74 build)
  75         with_gmp_builddir=`echo @abs_builddir@ | \
  76                            $with_gmp_builddir/config.status --file=-`
  77         CPPFLAGS="-I$with_gmp_builddir $CPPFLAGS"
  78         LDFLAGS="-L$with_gmp_builddir/$lt_cv_objdir $LDFLAGS"
  79         bv_extra="--with-gmp --with-gmp-builddir=$with_gmp_builddir"
  80         bv_configure_args="$bv_configure_args $bv_extra"
  81         ;;
  82 system)
  83         if test "x$with_gmp_prefix" != "x"; then
  84                 bv_extra="--with-libgmp=$with_gmp_prefix"
  85                 bv_configure_args="$bv_configure_args $bv_extra"
  86                 CPPFLAGS="-I$with_gmp_prefix/include $CPPFLAGS"
  87                 LDFLAGS="-L$with_gmp_prefix/lib $LDFLAGS"
  88         else
  89                 bv_configure_args="$bv_configure_args --with-libgmp --with-gmp"
  90         fi
  91         ;;
  92 esac
  93
  94 poly_cv_gmpfatal="no"
  95 AC_CHECK_HEADER(gmp.h,
  96         [AC_CHECK_LIB(gmp,main,
  97             [],
  98             [poly_cv_gmpfatal="yes"])],
  99         [poly_cv_gmpfatal="yes"])
 100 if test "$poly_cv_gmpfatal" = "yes"; then
 101         AC_MSG_ERROR([GMP not found])
 102 fi
 103 AC_CHECK_DECL(mpz_divisible_p,[],[AC_LIBOBJ(mpz_divisible_p)],[#include <gmp.h>])
 104
 105 AX_SUBMODULE(polylib,build|bundled|system,bundled)
 106
 107 AC_SUBST(POLYLIB_CPPFLAGS)
 108 AC_SUBST(POLYLIB_LDFLAGS)
 109 AC_SUBST(POLYLIB_LIBS)
 110 case "$with_polylib" in
 111 bundled)
 112         bv_configure_args="$bv_configure_args --with-polylib-builddir=../polylib"
 113         POLYLIB_CPPFLAGS="-I\$(top_builddir)/polylib/include -I\$(top_srcdir)/polylib/include"
 114         ;;
 115 build)
 116         with_polylib_builddir=`echo @abs_builddir@ | $with_polylib_builddir/config.status --file=-`
 117         POLYLIB_CPPFLAGS="-I$polylib_srcdir/include -I$with_polylib_builddir/include"
 118         POLYLIB_LIBS="$with_polylib_builddir/libpolylibgmp.la"
 119         ;;
 120 system)
 121         POLYLIB_LIBS="-lpolylibgmp"
 122         if test "x$with_polylib_prefix" != "x"; then
 123                 POLYLIB_CPPFLAGS="-I$with_polylib_prefix/include"
 124                 POLYLIB_LDFLAGS="-L$with_polylib_prefix/lib"
 125         fi
 126         SAVE_CPPFLAGS="$CPPFLAGS"
 127         CPPFLAGS="$POLYLIB_CPPFLAGS $CPPFLAGS"
 128         AC_CHECK_HEADERS([polylib/polylibgmp.h], [], [
 129                 AC_MSG_ERROR(Need PolyLib)
 130         ])
 131         CPPFLAGS="$SAVE_CPPFLAGS"
 132 esac
 133
 134 AM_CONDITIONAL(BUNDLED_POLYLIB, test $with_polylib = bundled)
 135
 136 AX_SUBMODULE(isl,build|bundled|system,bundled)
 137
 138 AC_SUBST(ISL_CFLAGS)
 139 AC_SUBST(ISL_LIBS)
 140 AC_SUBST(ISL_SRCDIR)
 141 AC_SUBST(ISL_BUILDDIR)
 142 case "$with_isl" in
 143 bundled)
 144         ISL_SRCDIR="$srcdir/isl"
 145         ISL_BUILDDIR=isl
 146         ISL_CFLAGS="-I\$(top_srcdir)/isl/include -I\$(top_builddir)/isl/include"
 147         bv_configure_args="$bv_configure_args --with-isl-builddir=../isl"
 148         PACKAGE_CFLAGS_ISL='-I${prefix}/include'
 149         ;;
 150 build)
 151         ISL_SRCDIR="$isl_srcdir"
 152         ISL_BUILDDIR=`echo @abs_builddir@ | $with_isl_builddir/config.status --file=-`
 153         bv_configure_args="$bv_configure_args --with-isl-builddir=$ISL_BUILDDIR"
 154         ISL_CFLAGS="-I$isl_srcdir/include -I$ISL_BUILDDIR/include"
 155         PACKAGE_CFLAGS_ISL='-I${prefix}/include'
 156         ;;
 157 system)
 158         PKG_CHECK_MODULES([ISL], [isl])
 159         PACKAGE_CFLAGS_ISL="$ISL_CFLAGS"
 160 esac
 161 AM_CONDITIONAL(BUNDLED_ISL, test $with_isl = bundled)
 162 AM_CONDITIONAL(BUILD_ISL, test $with_isl = build)
 163
 164 AX_SUBMODULE(pet,bundled|build|system|no,no)
 165 AC_SUBST(PET_CFLAGS)
 166 AC_SUBST(PET_LIBS)
 167 AC_SUBST(PET_BUILDDIR)
 168 pet_suffix="top.pet"
 169 case "$with_pet" in
 170 bundled)
 171         PET_CFLAGS="-I\$(top_srcdir)/pet/include"
 172         AC_DEFINE(HAVE_PET,[],[use Pet])
 173         ;;
 174 build)
 175         PET_BUILDDIR=`echo @abs_builddir@ | $with_pet_builddir/config.status --file=-`
 176         PET_CFLAGS="-I$pet_srcdir/include"
 177         AC_DEFINE(HAVE_PET,[],[use Pet])
 178         ;;
 179 system)
 180         PKG_CHECK_MODULES([PET], [pet])
 181         AC_DEFINE(HAVE_PET,[],[use Pet])
 182         ;;
 183 no)
 184         pet_suffix="top.no_pet"
 185         ;;
 186 esac
 187 AM_CONDITIONAL(BUNDLED_PET, test $with_pet = bundled)
 188 AM_CONDITIONAL(BUILD_PET, test $with_pet = build)
 189
 190 AC_MSG_CHECKING(whether to use incremental algorithm)
 191 AC_ARG_ENABLE(incremental,
 192         [AS_HELP_STRING([--enable-incremental@<:@=bf|df@:>@],
 193                         [Enable incremental algorithm [bf]])],
 194         [bv_cv_incremental=$enableval], [bv_cv_incremental="no"])
 195 AC_MSG_RESULT($bv_cv_incremental)
 196 case $bv_cv_incremental in
 197         yes | bf)
 198                 AC_DEFINE(USE_INCREMENTAL_BF,[],
 199                           [Use breadth-first incremental algorithm])
 200         ;;
 201         df)
 202                 AC_DEFINE(USE_INCREMENTAL_DF,[],
 203                           [Use depth-first incremental algorithm])
 204         ;;
 205 esac
 206
 207 AC_ARG_WITH(ntl,
 208             [AC_HELP_STRING([--with-ntl=system|build],
 209                             [Which NTL to use [default=system]])])
 210
 211 AC_ARG_WITH(ntl-prefix,
 212             [AC_HELP_STRING([--with-ntl-prefix=DIR],
 213                             [Prefix of NTL installation])])
 214
 215 AC_ARG_WITH(ntl-builddir,
 216             [AC_HELP_STRING([--with-ntl-builddir=DIR],
 217                             [Prefix of NTL root build directory
 218                              containing include and src subdirectories])])
 219
 220 if test "x$with_ntl_builddir" != "x"; then
 221         if test "x$with_ntl" != "xbuild" -a "x$with_ntl" != "x"; then
 222                 AC_MSG_ERROR(m4_normalize([Setting --with-ntl-builddir implies
 223                                            use of build NTL]))
 224         fi
 225         with_ntl="build"
 226 fi
 227
 228 if test "x$with_ntl_prefix" != "x"; then
 229         if test "x$with_ntl" != "xsystem" -a "x$with_ntl" != "x"; then
 230                 AC_MSG_ERROR(m4_normalize([Setting --with-ntl-prefix implies
 231                                            use of system NTL]))
 232         fi
 233         with_ntl="system"
 234 fi
 235
 236 case "$with_ntl" in
 237 build|system)
 238         ;;
 239 *)
 240         with_ntl="system"
 241         ;;
 242 esac
 243 AC_MSG_CHECKING([which NTL to use])
 244 AC_MSG_RESULT($with_ntl)
 245
 246 AC_SUBST(NTL_CPPFLAGS)
 247 AC_SUBST(NTL_LDFLAGS)
 248 case "$with_ntl" in
 249 build)
 250         NTL_CPPFLAGS="-I$with_ntl_builddir/include"
 251         NTL_LDFLAGS="-L$with_ntl_builddir/src/$lt_cv_objdir"
 252         ntl_builddir_found=false
 253         AC_CHECK_FILE(["$with_ntl_builddir/src/ZZ.c"],
 254                       [ntl_builddir_found=true],[])
 255         if test "x$ntl_builddir_found" != "xtrue"; then
 256                 if test -f "$with_ntl_builddir/ZZ.c"; then
 257                         ntl_builddir=`dirname $with_ntl_builddir`
 258                         AC_MSG_ERROR(m4_normalize(
 259                               [NTL source directory src/ specified as builddir.
 260                                Use root directory instead as
 261                                --with-ntl-builddir=$ntl_builddir]))
 262                 else
 263                         AC_MSG_ERROR([Could not find NTL in the builddir])
 264                 fi
 265         fi
 266         ;;
 267 system)
 268         if test "x$with_ntl_prefix" != "x"; then
 269                 NTL_CPPFLAGS="-I$with_ntl_prefix/include"
 270                 NTL_LDFLAGS="-L$with_ntl_prefix/lib"
 271         fi
 272         ;;
 273 esac
 274
 275 AX_CHECK_NTL
 276
 277 AC_SUBST(bv_cone_hilbert_basis)
 278 AC_MSG_CHECKING(whether to compile zsolve)
 279 AC_ARG_WITH(zsolve,
 280             [AS_HELP_STRING([--without-zsolve],[do not compile zsolve])],
 281             [ with_zsolve=$withval],  [ with_zsolve=yes ])
 282 AC_MSG_RESULT($with_zsolve)
 283
 284 use_zsolve=false
 285 if test "$with_zsolve" != "no"; then
 286         if test "$GCC" = "yes"; then
 287                 $CC --version |
 288                 sed -e 's/.* \(@<:@0-9@:>@@<:@0-9@:>@*\)\.\(@<:@0-9@:>@@<:@0-9@:>@*\).*/\1 \2/' |
 289                 (read major minor
 290                         if test $major -gt 3; then
 291                                 exit 0
 292                         fi
 293                         if test $major -eq 3 -a $minor -ge 4; then
 294                                 exit 0
 295                         fi
 296                         exit 1
 297                 ) && use_zsolve=true
 298         fi
 299         if test "$use_zsolve" = false; then
 300                 AC_MSG_WARN(gcc 3.4 required to compile zsolve)
 301         else
 302                 AC_DEFINE(USE_ZSOLVE,[],[use zsolve])
 303                 bv_cone_hilbert_basis="cone_hilbert_basis\$(EXEEXT)"
 304         fi
 305 fi
 306 AM_CONDITIONAL(USE_ZSOLVE, test x$use_zsolve = xtrue)
 307
 308 AX_SUBMODULE(omega,no|system,no)
 309
 310 AC_SUBST(OMEGA_CPPFLAGS)
 311 AC_SUBST(OMEGA_LDFLAGS)
 312 AC_SUBST(OMEGA_LIBS)
 313 AC_SUBST(OMEGA_CODEGEN_LIBS)
 314 have_omega=false
 315 have_codegen=false
 316 case "$with_omega" in
 317 system)
 318     if test "x$with_omega_prefix" != "xyes"; then
 319         OMEGA_CPPFLAGS="-I$with_omega_prefix/include/omega"
 320         OMEGA_LDFLAGS="-L$with_omega_prefix/lib"
 321     else
 322         for i in /usr/include /usr/local/include; do
 323             if test -f $i/omega/omega.h; then
 324                 OMEGA_CPPFLAGS="-I$i/omega"
 325             fi
 326         done
 327     fi
 328
 329     AC_LANG_PUSH(C++)
 330     SAVE_CPPFLAGS="$CPPFLAGS"
 331     SAVE_LDFLAGS="$LDFLAGS"
 332     CPPFLAGS="$OMEGA_CPPFLAGS $CPPFLAGS"
 333     LDFLAGS="$OMEGA_LDFLAGS $LDFLAGS"
 334     AC_CHECK_HEADERS([omega.h],[
 335         OMEGA_LIBS="-lomega"
 336         AC_CHECK_LIB(code_gen,main,[
 337                 OMEGA_CODEGEN_LIBS="-lcode_gen -lomega"
 338                 have_codegen=true
 339         ])
 340         have_omega=true
 341     ],[AC_MSG_WARN(Omega not found)])
 342     CPPFLAGS="$SAVE_CPPFLAGS"
 343     LDFLAGS="$SAVE_LDFLAGS"
 344     AC_LANG_POP
 345     ;;
 346 esac
 347 if test "$have_omega" = true; then
 348         AC_DEFINE(HAVE_OMEGA,[],[use omega])
 349 fi
 350 AM_CONDITIONAL(HAVE_OMEGA, test x$have_omega = xtrue)
 351
 352 use_parker=false
 353 AC_MSG_CHECKING(whether to compile parker)
 354 AC_ARG_WITH(parker,
 355             [AS_HELP_STRING([--without-zsolve],[do not compile zsolve])],
 356             [ with_parker=$withval],  [ with_parker=yes ])
 357 AC_MSG_RESULT($with_parker)
 358
 359 if test "$with_parker" != "no"; then
 360         AC_MSG_CHECKING(for mona)
 361         AC_ARG_WITH(mona,
 362                 [AS_HELP_STRING([--with-mona=DIR],[mona *source* directory])],
 363                                 [], [AC_MSG_RESULT(not specified)])
 364
 365         if test "x$with_mona" != "x"; then
 366                 AC_SUBST(MONAPATH)
 367                 MONAPATH=$with_mona
 368                 AC_MSG_RESULT($MONAPATH)
 369                 use_parker=true
 370                 AC_DEFINE(USE_PARKER,[],[use parker])
 371         fi
 372
 373         if test "x$with_mona" = "x"; then
 374                 AC_MSG_WARN(mona source directory required to compile parker)
 375                 AC_MSG_WARN(http://www.brics.dk/mona/download)
 376         fi
 377 fi
 378 AM_CONDITIONAL(USE_PARKER, test x$use_parker = xtrue)
 379
 380 AC_MSG_CHECKING(whether to use cddlib)
 381 AC_ARG_WITH(cddlib, [AS_HELP_STRING([--with-cddlib=DIR],[DIR Location of cddlib])],
 382             [ cddlib_package=$withval],  [ cddlib_package=yes ])
 383 AC_MSG_RESULT($cddlib_package)
 384
 385 have_cddlib=false
 386 if test "$cddlib_package" != "no"; then
 387     if test "x$cddlib_package" != "xyes"; then
 388         CPPFLAGS="-I$cddlib_package/include $CPPFLAGS"
 389         LDFLAGS="-L$cddlib_package/lib $LDFLAGS"
 390     fi
 391     AC_TRY_LINK([
 392 #define GMPRATIONAL
 393 #include <setoper.h>
 394 #include <cddmp.h>
 395 ], [
 396     mytype a;
 397     dd_init(a); ], [
 398         have_cddlib=true
 399         AC_CHECK_LIB(cddgmp, main,[
 400                 SAVE_LIBS="$LIBS"
 401                 LIBS="-lcddgmp $LIBS"
 402                 AC_DEFINE_UNQUOTED([SRCDIR], ["$srcdir"], [srcdir])
 403                 AC_LANG_PUSH(C++)
 404                 AC_RUN_IFELSE([AC_LANG_PROGRAM([[#define GMPRATIONAL
 405 #include <setoper.h>
 406 #include <cdd.h>]],
 407                 [[
 408         const char *filename = SRCDIR"/cdd94e-test";
 409         FILE *f;
 410         dd_MatrixPtr M;
 411         dd_LPType *lp;
 412         dd_ErrorType err = dd_NoError;
 413
 414         dd_set_global_constants();
 415
 416         f = fopen(filename, "r");
 417         M = dd_PolyFile2Matrix(f, &err);
 418         lp = dd_Matrix2LP(M, &err);
 419         dd_LPSolve(lp, dd_DualSimplex, &err);
 420         return lp->LPS == dd_Inconsistent;
 421                 ]])],[
 422                         AC_DEFINE(HAVE_LIBCDDGMP, [], [Define to 1 if you have the `cddgmp' library (-lcddgmp).])
 423                 ],[
 424                         AC_MSG_WARN(please upgrade cddlib to 0.94e or later)
 425                         LIBS="$SAVE_LIBS"
 426                         have_cddlib=false
 427                 ])
 428                 AC_LANG_POP
 429         ],[have_cddlib=false])
 430     ])
 431 fi
 432 AM_CONDITIONAL(HAVE_CDDLIB, test x$have_cddlib = xtrue)
 433
 434
 435
 436 AC_MSG_CHECKING(whether to use GLPK)
 437 AC_ARG_WITH(glpk, [AS_HELP_STRING([--with-glpk=DIR],[DIR Location of GLPK])],
 438             [ glpk_package=$withval],  [ glpk_package=yes ])
 439 AC_MSG_RESULT($glpk_package)
 440
 441 have_glpk=false
 442 if test "$glpk_package" != "no"; then
 443     if test "x$glpk_package" != "xyes"; then
 444         CPPFLAGS="-I$glpk_package/include $CPPFLAGS"
 445         LDFLAGS="-L$glpk_package/lib $LDFLAGS"
 446     fi
 447     AC_CHECK_HEADERS([glpk.h],[
 448         have_glpk=true
 449         AC_CHECK_LIB(glpk, [glp_simplex],[],[have_glpk=false])
 450     ])
 451 fi
 452 AM_CONDITIONAL(HAVE_GLPK, test x$have_glpk = xtrue)
 453
 454 AC_MSG_CHECKING(location of TOPCOM)
 455 AC_ARG_WITH(topcom, [AS_HELP_STRING([--with-topcom=DIR],[Location of TOPCOM])],
 456             [topcom_package=$withval], [topcom_package=unspecified])
 457 AC_MSG_RESULT($topcom_package)
 458 have_topcom=false
 459 if test "$topcom_package" != no; then
 460         topcom_path="$PATH"
 461         if test "$topcom_package" != unspecified; then
 462                 topcom_path="$topcom_package/bin"
 463         fi
 464         AC_PATH_PROG([POINTS2TRIANGS], [points2triangs], [], [$topcom_path])
 465         if test -n "$POINTS2TRIANGS"; then
 466                 have_topcom=true
 467                 AC_DEFINE_UNQUOTED(POINTS2TRIANGS_PATH, ["$POINTS2TRIANGS"],
 468                                     [Path of points2triangs])
 469         fi
 470 fi
 471 AM_CONDITIONAL(HAVE_TOPCOM, test x$have_topcom = xtrue)
 472
 473 AX_DETECT_GIT_HEAD
 474 echo '#define GIT_HEAD_ID "'$GIT_HEAD_ID'"' > version.h
 475
 476 AC_LANG_PUSH(C++)
 477 AC_TRY_COMPILE([
 478                 #include <set>
 479                 void negate();
 480         ], [negate()],
 481         suffix="normal", suffix="broken")
 482 AC_CONFIG_COMMANDS([barvinok/set.h],
 483                    [cp $srcdir/barvinok/set.h.$suffix barvinok/set.h],
 484                    [suffix="$suffix"])
 485 AC_CONFIG_COMMANDS([barvinok/NTL.h],
 486                    [cp $srcdir/barvinok/NTL.h.$suffix barvinok/NTL.h],
 487                    [suffix="$suffix"])
 488 use_fdstream=false
 489 SAVE_CPPFLAGS="$CPPFLAGS"
 490 CPPFLAGS="-I$srcdir $CPPFLAGS"
 491 AC_TRY_COMPILE([#include "fdstream.h"],[],
 492         [AC_DEFINE(USE_FDSTREAM,[],[use fdstream])
 493         use_fdstream=true])
 494 CPPFLAGS="$SAVE_CPPFLAGS"
 495 AC_LANG_POP
 496 AM_CONDITIONAL(USE_FDSTREAM, [test "$use_fdstream" = true])
 497
 498 AC_CONFIG_COMMANDS([interface/isl.py.top],
 499                  [cp $srcdir/interface/isl.py.$pet_suffix interface/isl.py.top],
 500                  [pet_suffix="$pet_suffix"])
 501
 502 PACKAGE_CFLAGS="$PACKAGE_CFLAGS_ISL"
 503 PACKAGE_LIBS="-lbarvinok $EXTRA_PACKAGE_LIBS -lpolylibgmp -lisl"
 504 AX_CREATE_PKGCONFIG_INFO
 505
 506 AC_CONFIG_HEADERS(config.h)
 507 AC_CONFIG_FILES(Makefile zsolve/Makefile doc/Makefile)
 508 AC_CONFIG_FILES(parker/Makefile)
 509 if test $with_polylib = bundled; then
 510         AC_CONFIG_SUBDIRS(polylib)
 511 fi
 512 if test $with_isl = bundled; then
 513         AC_CONFIG_SUBDIRS(isl)
 514 fi
 515 if test $with_pet = bundled; then
 516         AC_CONFIG_SUBDIRS(pet)
 517 fi
 518 AC_CONFIG_COMMANDS_POST([
 519         dnl pass on arguments to subdir configures, but don't
 520         dnl add them to config.status
 521         ac_configure_args="$ac_configure_args $bv_configure_args"
 522 ])
 523 AC_OUTPUT