configure.ac

   1 AC_INIT([barvinok], [0.41.6], [isl-development@googlegroups.com])
   2 AC_CONFIG_MACRO_DIR([m4])
   3 AM_INIT_AUTOMAKE([foreign subdir-objects])
   4 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
   5 AC_PROG_CC
   6
   7 AC_PROG_CXX
   8 AM_PROG_LEX
   9 AC_PROG_YACC
  10 AC_PROG_GREP
  11 AC_PROG_SED
  12 AC_SUBST(versioninfo)
  13 versioninfo=23:11:0
  14
  15 AC_CANONICAL_HOST
  16 AC_LIBTOOL_WIN32_DLL
  17 AC_SUBST(BV_LIB_LDFLAGS)
  18 case $host in
  19         *-*-cygwin* | *-*-mingw* | *-*-pw32* | *-*-os2*)
  20         if test "$enable_shared" = yes; then
  21                 BV_LIB_LDFLAGS="-no-undefined"
  22         fi
  23         ;;
  24 esac
  25
  26 AC_PROG_LIBTOOL
  27
  28 PKG_PROG_PKG_CONFIG
  29
  30 AC_CHECK_HEADERS(getopt.h)
  31 AC_CHECK_HEADERS(sys/times.h)
  32 AC_CHECK_FUNCS(sigaction)
  33
  34 AC_MSG_CHECKING(whether to build shared libbarvinok)
  35 AC_ARG_ENABLE(shared_barvinok,
  36         AS_HELP_STRING([--enable-shared-barvinok],
  37                        [build shared barvinok library]),
  38         [bv_cv_shared_barvinok=$enableval], [bv_cv_shared_barvinok="no"])
  39 AC_MSG_RESULT($bv_cv_shared_barvinok)
  40 if test "x$bv_cv_shared_barvinok" != "xyes" ; then
  41         BV_LIB_LDFLAGS="$BV_LIB_LDFLAGS -static"
  42 fi
  43
  44 AC_SUBST(BV_LDFLAGS)
  45 AC_MSG_CHECKING(whether to build static executables)
  46 AC_ARG_ENABLE(all_static,
  47         AS_HELP_STRING([--enable-all-static],
  48                        [build static executables]),
  49         [bv_cv_all_static=$enableval], [bv_cv_all_static="no"])
  50 AC_MSG_RESULT($bv_cv_all_static)
  51 if test "x$bv_cv_all_static" = "xyes" ; then
  52         BV_LDFLAGS="$BV_LDFLAGS -all-static"
  53 fi
  54
  55 AX_C___ATTRIBUTE__
  56 AX_UNORDERED_MAP
  57 AC_CXX_GNUCXX_HASHMAP
  58
  59 AC_ARG_WITH(default-prefix,
  60         AS_HELP_STRING([--with-default-prefix=DIR],
  61             [Default installation prefix of optional packages]))
  62 if test "${with_default_prefix+set}" = set; then
  63         if test "${with_libgmp+set}" != set -a \
  64            -f "$with_default_prefix/include/gmp.h"; then
  65                 with_gmp_prefix=$with_default_prefix
  66         fi
  67         if test "${with_ntl+set}" != set -a \
  68            "${with_ntl_prefix+set}" != set -a \
  69            -f "$with_default_prefix/include/NTL/ZZ.h"; then
  70                 with_ntl_prefix=$with_default_prefix
  71         fi
  72         if test "${with_cddlib+set}" != set -a \
  73            -f "$with_default_prefix/include/cddmp.h"; then
  74                 with_cddlib=$with_default_prefix
  75         fi
  76         if test "${with_glpk+set}" != set -a \
  77            -f "$with_default_prefix/include/glpk.h"; then
  78                 with_glpk=$with_default_prefix
  79         fi
  80         if test "${with_topcom+set}" != set -a \
  81            -f "$with_default_prefix/bin/points2triangs"; then
  82                 with_topcom=$with_default_prefix
  83         fi
  84 fi
  85
  86 AX_SUBMODULE(gmp,system|build,system)
  87
  88 case "$with_gmp" in
  89 build)
  90         with_gmp_builddir=`echo @abs_builddir@ | \
  91                            $with_gmp_builddir/config.status --file=-`
  92         CPPFLAGS="-I$with_gmp_builddir $CPPFLAGS"
  93         LDFLAGS="-L$with_gmp_builddir/$lt_cv_objdir $LDFLAGS"
  94         bv_extra="--with-gmp --with-gmp-builddir=$with_gmp_builddir"
  95         bv_configure_args="$bv_configure_args $bv_extra"
  96         ;;
  97 system)
  98         if test "x$with_gmp_prefix" != "x"; then
  99                 bv_extra="--with-libgmp=$with_gmp_prefix"
 100                 bv_configure_args="$bv_configure_args $bv_extra"
 101                 CPPFLAGS="-I$with_gmp_prefix/include $CPPFLAGS"
 102                 LDFLAGS="-L$with_gmp_prefix/lib $LDFLAGS"
 103         else
 104                 bv_configure_args="$bv_configure_args --with-libgmp --with-gmp"
 105         fi
 106         ;;
 107 esac
 108
 109 poly_cv_gmpfatal="no"
 110 AC_CHECK_HEADER(gmp.h,
 111         [AC_CHECK_LIB(gmp,main,
 112             [],
 113             [poly_cv_gmpfatal="yes"])],
 114         [poly_cv_gmpfatal="yes"])
 115 if test "$poly_cv_gmpfatal" = "yes"; then
 116         AC_MSG_ERROR([GMP not found])
 117 fi
 118 AC_CHECK_DECL(mpz_divisible_p,[],[AC_LIBOBJ(mpz_divisible_p)],[#include <gmp.h>])
 119
 120 AX_SUBMODULE(polylib,build|bundled|system,bundled)
 121
 122 AC_SUBST(POLYLIB_CPPFLAGS)
 123 AC_SUBST(POLYLIB_LDFLAGS)
 124 AC_SUBST(POLYLIB_LIBS)
 125 case "$with_polylib" in
 126 bundled)
 127         bv_configure_args="$bv_configure_args --with-polylib-builddir=../polylib"
 128         POLYLIB_CPPFLAGS="-I\$(top_builddir)/polylib/include -I\$(top_srcdir)/polylib/include"
 129         ;;
 130 build)
 131         with_polylib_builddir=`echo @abs_builddir@ | $with_polylib_builddir/config.status --file=-`
 132         POLYLIB_CPPFLAGS="-I$polylib_srcdir/include -I$with_polylib_builddir/include"
 133         POLYLIB_LIBS="$with_polylib_builddir/libpolylibgmp.la"
 134         ;;
 135 system)
 136         POLYLIB_LIBS="-lpolylibgmp"
 137         if test "x$with_polylib_prefix" != "x"; then
 138                 POLYLIB_CPPFLAGS="-I$with_polylib_prefix/include"
 139                 POLYLIB_LDFLAGS="-L$with_polylib_prefix/lib"
 140         fi
 141         SAVE_CPPFLAGS="$CPPFLAGS"
 142         CPPFLAGS="$POLYLIB_CPPFLAGS $CPPFLAGS"
 143         AC_CHECK_HEADERS([polylib/polylibgmp.h], [], [
 144                 AC_MSG_ERROR(Need PolyLib)
 145         ])
 146         CPPFLAGS="$SAVE_CPPFLAGS"
 147 esac
 148
 149 AM_CONDITIONAL(BUNDLED_POLYLIB, test $with_polylib = bundled)
 150
 151 AX_SUBMODULE(isl,build|bundled|system,bundled)
 152
 153 AC_SUBST(ISL_CFLAGS)
 154 AC_SUBST(ISL_LIBS)
 155 AC_SUBST(ISL_SRCDIR)
 156 AC_SUBST(ISL_BUILDDIR)
 157 case "$with_isl" in
 158 bundled)
 159         ISL_SRCDIR="$srcdir/isl"
 160         ISL_BUILDDIR=isl
 161         ISL_CFLAGS="-I\$(top_srcdir)/isl/include -I\$(top_builddir)/isl/include"
 162         bv_configure_args="$bv_configure_args --with-isl=build"
 163         bv_configure_args="$bv_configure_args --with-isl-builddir=../isl"
 164         PACKAGE_CFLAGS_ISL='-I${prefix}/include'
 165         ;;
 166 build)
 167         ISL_SRCDIR="$isl_srcdir"
 168         ISL_BUILDDIR=`echo @abs_builddir@ | $with_isl_builddir/config.status --file=-`
 169         bv_configure_args="$bv_configure_args --with-isl-builddir=$ISL_BUILDDIR"
 170         ISL_CFLAGS="-I$isl_srcdir/include -I$ISL_BUILDDIR/include"
 171         PACKAGE_CFLAGS_ISL='-I${prefix}/include'
 172         ;;
 173 system)
 174         PKG_CHECK_MODULES([ISL], [isl])
 175         PACKAGE_CFLAGS_ISL="$ISL_CFLAGS"
 176 esac
 177 AM_CONDITIONAL(BUNDLED_ISL, test $with_isl = bundled)
 178 AM_CONDITIONAL(BUILD_ISL, test $with_isl = build)
 179 AM_CONDITIONAL(HAVE_ISL_BUILDDIR, test "x$ISL_BUILDDIR" != "x")
 180
 181 AX_SUBMODULE(pet,bundled|build|system|no,no)
 182 AC_SUBST(PET_CFLAGS)
 183 AC_SUBST(PET_LIBS)
 184 AC_SUBST(PET_BUILDDIR)
 185 pet_suffix="top.pet"
 186 case "$with_pet" in
 187 bundled)
 188         PET_CFLAGS="-I\$(top_srcdir)/pet/include"
 189         AC_DEFINE(HAVE_PET,[],[use Pet])
 190         ;;
 191 build)
 192         PET_BUILDDIR=`echo @abs_builddir@ | $with_pet_builddir/config.status --file=-`
 193         PET_CFLAGS="-I$pet_srcdir/include"
 194         AC_DEFINE(HAVE_PET,[],[use Pet])
 195         ;;
 196 system)
 197         PKG_CHECK_MODULES([PET], [pet])
 198         AC_DEFINE(HAVE_PET,[],[use Pet])
 199         ;;
 200 no)
 201         pet_suffix="top.no_pet"
 202         ;;
 203 esac
 204 AM_CONDITIONAL(BUNDLED_PET, test $with_pet = bundled)
 205 AM_CONDITIONAL(BUILD_PET, test $with_pet = build)
 206
 207 AC_MSG_CHECKING(whether to use incremental algorithm)
 208 AC_ARG_ENABLE(incremental,
 209         [AS_HELP_STRING([--enable-incremental@<:@=bf|df@:>@],
 210                         [Enable incremental algorithm [bf]])],
 211         [bv_cv_incremental=$enableval], [bv_cv_incremental="no"])
 212 AC_MSG_RESULT($bv_cv_incremental)
 213 case $bv_cv_incremental in
 214         yes | bf)
 215                 AC_DEFINE(USE_INCREMENTAL_BF,[],
 216                           [Use breadth-first incremental algorithm])
 217         ;;
 218         df)
 219                 AC_DEFINE(USE_INCREMENTAL_DF,[],
 220                           [Use depth-first incremental algorithm])
 221         ;;
 222 esac
 223
 224 AC_ARG_WITH(ntl,
 225             [AC_HELP_STRING([--with-ntl=system|build],
 226                             [Which NTL to use [default=system]])])
 227
 228 AC_ARG_WITH(ntl-prefix,
 229             [AC_HELP_STRING([--with-ntl-prefix=DIR],
 230                             [Prefix of NTL installation])])
 231
 232 AC_ARG_WITH(ntl-builddir,
 233             [AC_HELP_STRING([--with-ntl-builddir=DIR],
 234                             [Prefix of NTL root build directory
 235                              containing include and src subdirectories])])
 236
 237 if test "x$with_ntl_builddir" != "x"; then
 238         if test "x$with_ntl" != "xbuild" -a "x$with_ntl" != "x"; then
 239                 AC_MSG_ERROR(m4_normalize([Setting --with-ntl-builddir implies
 240                                            use of build NTL]))
 241         fi
 242         with_ntl="build"
 243 fi
 244
 245 if test "x$with_ntl_prefix" != "x"; then
 246         if test "x$with_ntl" != "xsystem" -a "x$with_ntl" != "x"; then
 247                 AC_MSG_ERROR(m4_normalize([Setting --with-ntl-prefix implies
 248                                            use of system NTL]))
 249         fi
 250         with_ntl="system"
 251 fi
 252
 253 case "$with_ntl" in
 254 build|system)
 255         ;;
 256 *)
 257         with_ntl="system"
 258         ;;
 259 esac
 260 AC_MSG_CHECKING([which NTL to use])
 261 AC_MSG_RESULT($with_ntl)
 262
 263 AC_SUBST(NTL_CPPFLAGS)
 264 AC_SUBST(NTL_LDFLAGS)
 265 case "$with_ntl" in
 266 build)
 267         ntl_include="$with_ntl_builddir/include"
 268         NTL_LDFLAGS="-L$with_ntl_builddir/src/$lt_cv_objdir"
 269         ntl_builddir_found=false
 270         AC_CHECK_FILE(["$with_ntl_builddir/src/ZZ.c"],
 271                       [ntl_builddir_found=true],[])
 272         if test "x$ntl_builddir_found" != "xtrue"; then
 273                 if test -f "$with_ntl_builddir/ZZ.c"; then
 274                         ntl_builddir=`dirname $with_ntl_builddir`
 275                         AC_MSG_ERROR(m4_normalize(
 276                               [NTL source directory src/ specified as builddir.
 277                                Use root directory instead as
 278                                --with-ntl-builddir=$ntl_builddir]))
 279                 else
 280                         AC_MSG_ERROR([Could not find NTL in the builddir])
 281                 fi
 282         fi
 283         ;;
 284 system)
 285         if test "x$with_ntl_prefix" != "x"; then
 286                 ntl_include="$with_ntl_prefix/include"
 287                 NTL_LDFLAGS="-L$with_ntl_prefix/lib"
 288         fi
 289         ;;
 290 esac
 291 if test "x$ntl_include" != "x"; then
 292         NTL_CPPFLAGS="-I$ntl_include"
 293 else
 294         for path in /usr/local /usr; do
 295                 if test -f "$path/include/NTL/ZZ.h"; then
 296                         ntl_include="$path/include"
 297                         break;
 298                 fi
 299         done
 300 fi
 301 # Look for compiler/linker options needed for linking against NTL
 302 ntl_configlog="$ntl_include/NTL/ConfigLog.h"
 303 if test -f "$ntl_configlog"; then
 304         AC_MSG_CHECKING([for compiler options in $ntl_configlog])
 305         eval $($GREP "^CXXAUTOFLAGS" $ntl_configlog | $SED -e 's/^/NTL_/')
 306         AC_MSG_RESULT([$NTL_CXXAUTOFLAGS])
 307         NTL_CPPFLAGS="$NTL_CPPFLAGS $NTL_CXXAUTOFLAGS"
 308         NTL_LDFLAGS="$NTL_LDFLAGS $NTL_CXXAUTOFLAGS"
 309 fi
 310
 311 AX_CHECK_NTL
 312
 313 AC_SUBST(bv_cone_hilbert_basis)
 314 AC_MSG_CHECKING(whether to compile zsolve)
 315 AC_ARG_WITH(zsolve,
 316             [AS_HELP_STRING([--without-zsolve],[do not compile zsolve])],
 317             [ with_zsolve=$withval],  [ with_zsolve=yes ])
 318 AC_MSG_RESULT($with_zsolve)
 319
 320 use_zsolve=false
 321 if test "$with_zsolve" != "no"; then
 322         if test "$GCC" = "yes"; then
 323                 $CC --version |
 324                 $SED -e 's/.* \(@<:@0-9@:>@@<:@0-9@:>@*\)\.\(@<:@0-9@:>@@<:@0-9@:>@*\).*/\1 \2/' |
 325                 (read major minor
 326                         if test $major -gt 3; then
 327                                 exit 0
 328                         fi
 329                         if test $major -eq 3 -a $minor -ge 4; then
 330                                 exit 0
 331                         fi
 332                         exit 1
 333                 ) && use_zsolve=true
 334         fi
 335         if test "$use_zsolve" = false; then
 336                 AC_MSG_WARN(gcc 3.4 required to compile zsolve)
 337         else
 338                 AC_DEFINE(USE_ZSOLVE,[],[use zsolve])
 339                 bv_cone_hilbert_basis="cone_hilbert_basis\$(EXEEXT)"
 340         fi
 341 fi
 342 AM_CONDITIONAL(USE_ZSOLVE, test x$use_zsolve = xtrue)
 343
 344 AX_SUBMODULE(omega,no|system,no)
 345
 346 AC_SUBST(OMEGA_CPPFLAGS)
 347 AC_SUBST(OMEGA_LDFLAGS)
 348 AC_SUBST(OMEGA_LIBS)
 349 AC_SUBST(OMEGA_CODEGEN_LIBS)
 350 have_omega=false
 351 have_codegen=false
 352 case "$with_omega" in
 353 system)
 354     if test "x$with_omega_prefix" != "xyes"; then
 355         OMEGA_CPPFLAGS="-I$with_omega_prefix/include/omega"
 356         OMEGA_LDFLAGS="-L$with_omega_prefix/lib"
 357     else
 358         for i in /usr/include /usr/local/include; do
 359             if test -f $i/omega/omega.h; then
 360                 OMEGA_CPPFLAGS="-I$i/omega"
 361             fi
 362         done
 363     fi
 364
 365     AC_LANG_PUSH(C++)
 366     SAVE_CPPFLAGS="$CPPFLAGS"
 367     SAVE_LDFLAGS="$LDFLAGS"
 368     CPPFLAGS="$OMEGA_CPPFLAGS $CPPFLAGS"
 369     LDFLAGS="$OMEGA_LDFLAGS $LDFLAGS"
 370     AC_CHECK_HEADERS([omega.h],[
 371         OMEGA_LIBS="-lomega"
 372         AC_CHECK_LIB(code_gen,main,[
 373                 OMEGA_CODEGEN_LIBS="-lcode_gen -lomega"
 374                 have_codegen=true
 375         ])
 376         have_omega=true
 377     ],[AC_MSG_WARN(Omega not found)])
 378     CPPFLAGS="$SAVE_CPPFLAGS"
 379     LDFLAGS="$SAVE_LDFLAGS"
 380     AC_LANG_POP
 381     ;;
 382 esac
 383 if test "$have_omega" = true; then
 384         AC_DEFINE(HAVE_OMEGA,[],[use omega])
 385 fi
 386 AM_CONDITIONAL(HAVE_OMEGA, test x$have_omega = xtrue)
 387
 388 use_parker=false
 389 AC_MSG_CHECKING(whether to compile parker)
 390 AC_ARG_WITH(parker,
 391             [AS_HELP_STRING([--without-zsolve],[do not compile zsolve])],
 392             [ with_parker=$withval],  [ with_parker=yes ])
 393 AC_MSG_RESULT($with_parker)
 394
 395 if test "$with_parker" != "no"; then
 396         AC_MSG_CHECKING(for mona)
 397         AC_ARG_WITH(mona,
 398                 [AS_HELP_STRING([--with-mona=DIR],[mona *source* directory])],
 399                                 [], [AC_MSG_RESULT(not specified)])
 400
 401         if test "x$with_mona" != "x"; then
 402                 AC_SUBST(MONAPATH)
 403                 MONAPATH=$with_mona
 404                 AC_MSG_RESULT($MONAPATH)
 405                 use_parker=true
 406                 AC_DEFINE(USE_PARKER,[],[use parker])
 407         fi
 408
 409         if test "x$with_mona" = "x"; then
 410                 AC_MSG_WARN(mona source directory required to compile parker)
 411                 AC_MSG_WARN(http://www.brics.dk/mona/download)
 412         fi
 413 fi
 414 AM_CONDITIONAL(USE_PARKER, test x$use_parker = xtrue)
 415
 416 AC_MSG_CHECKING(whether to use cddlib)
 417 AC_ARG_WITH(cddlib, [AS_HELP_STRING([--with-cddlib=DIR],[DIR Location of cddlib])],
 418             [ cddlib_package=$withval],  [ cddlib_package=yes ])
 419 AC_MSG_RESULT($cddlib_package)
 420
 421 have_cddlib=false
 422 if test "$cddlib_package" != "no"; then
 423     if test "x$cddlib_package" != "xyes"; then
 424         CPPFLAGS="-I$cddlib_package/include $CPPFLAGS"
 425         LDFLAGS="-L$cddlib_package/lib $LDFLAGS"
 426     fi
 427     AC_TRY_LINK([
 428 #define GMPRATIONAL
 429 #include <setoper.h>
 430 #include <cddmp.h>
 431 ], [
 432     mytype a;
 433     dd_init(a); ], [
 434         have_cddlib=true
 435         AC_CHECK_LIB(cddgmp, main,[
 436                 SAVE_LIBS="$LIBS"
 437                 LIBS="-lcddgmp $LIBS"
 438                 AC_DEFINE_UNQUOTED([SRCDIR], ["$srcdir"], [srcdir])
 439                 AC_LANG_PUSH(C++)
 440                 AC_RUN_IFELSE([AC_LANG_PROGRAM([[#define GMPRATIONAL
 441 #include <setoper.h>
 442 #include <cdd.h>]],
 443                 [[
 444         const char *filename = SRCDIR"/cdd94e-test";
 445         FILE *f;
 446         dd_MatrixPtr M;
 447         dd_LPType *lp;
 448         dd_ErrorType err = dd_NoError;
 449
 450         dd_set_global_constants();
 451
 452         f = fopen(filename, "r");
 453         M = dd_PolyFile2Matrix(f, &err);
 454         lp = dd_Matrix2LP(M, &err);
 455         dd_LPSolve(lp, dd_DualSimplex, &err);
 456         return lp->LPS == dd_Inconsistent;
 457                 ]])],[
 458                         AC_DEFINE(HAVE_LIBCDDGMP, [], [Define to 1 if you have the `cddgmp' library (-lcddgmp).])
 459                 ],[
 460                         AC_MSG_WARN(please upgrade cddlib to 0.94e or later)
 461                         LIBS="$SAVE_LIBS"
 462                         have_cddlib=false
 463                 ])
 464                 AC_LANG_POP
 465         ],[have_cddlib=false])
 466     ])
 467 fi
 468 AM_CONDITIONAL(HAVE_CDDLIB, test x$have_cddlib = xtrue)
 469
 470
 471
 472 AC_MSG_CHECKING(whether to use GLPK)
 473 AC_ARG_WITH(glpk, [AS_HELP_STRING([--with-glpk=DIR],[DIR Location of GLPK])],
 474             [ glpk_package=$withval],  [ glpk_package=yes ])
 475 AC_MSG_RESULT($glpk_package)
 476
 477 have_glpk=false
 478 if test "$glpk_package" != "no"; then
 479     if test "x$glpk_package" != "xyes"; then
 480         CPPFLAGS="-I$glpk_package/include $CPPFLAGS"
 481         LDFLAGS="-L$glpk_package/lib $LDFLAGS"
 482     fi
 483     AC_CHECK_HEADERS([glpk.h],[
 484         have_glpk=true
 485         AC_CHECK_LIB(glpk, [glp_simplex],[],[have_glpk=false])
 486     ])
 487 fi
 488 AM_CONDITIONAL(HAVE_GLPK, test x$have_glpk = xtrue)
 489
 490 AC_MSG_CHECKING(location of TOPCOM)
 491 AC_ARG_WITH(topcom, [AS_HELP_STRING([--with-topcom=DIR],[Location of TOPCOM])],
 492             [topcom_package=$withval], [topcom_package=unspecified])
 493 AC_MSG_RESULT($topcom_package)
 494 have_topcom=false
 495 if test "$topcom_package" != no; then
 496         topcom_path="$PATH"
 497         if test "$topcom_package" != unspecified; then
 498                 topcom_path="$topcom_package/bin"
 499         fi
 500         AC_PATH_PROG([POINTS2TRIANGS], [points2triangs], [], [$topcom_path])
 501         if test -n "$POINTS2TRIANGS"; then
 502                 have_topcom=true
 503                 AC_DEFINE_UNQUOTED(POINTS2TRIANGS_PATH, ["$POINTS2TRIANGS"],
 504                                     [Path of points2triangs])
 505         fi
 506 fi
 507 AM_CONDITIONAL(HAVE_TOPCOM, test x$have_topcom = xtrue)
 508
 509 AX_DETECT_GIT_HEAD
 510 echo '#define GIT_HEAD_ID "'$GIT_HEAD_ID'"' > version.h
 511
 512 AC_LANG_PUSH(C++)
 513 AC_TRY_COMPILE([
 514                 #include <set>
 515                 void negate();
 516         ], [negate()],
 517         suffix="normal", suffix="broken")
 518 AC_CONFIG_COMMANDS([barvinok/set.h],
 519                    [cp $srcdir/barvinok/set.h.$suffix barvinok/set.h],
 520                    [suffix="$suffix"])
 521 AC_CONFIG_COMMANDS([barvinok/NTL.h],
 522                    [cp $srcdir/barvinok/NTL.h.$suffix barvinok/NTL.h],
 523                    [suffix="$suffix"])
 524 use_fdstream=false
 525 SAVE_CPPFLAGS="$CPPFLAGS"
 526 CPPFLAGS="-I$srcdir $CPPFLAGS"
 527 AC_TRY_COMPILE([#include "fdstream.h"],[],
 528         [AC_DEFINE(USE_FDSTREAM,[],[use fdstream])
 529         use_fdstream=true])
 530 CPPFLAGS="$SAVE_CPPFLAGS"
 531 AC_LANG_POP
 532 AM_CONDITIONAL(USE_FDSTREAM, [test "$use_fdstream" = true])
 533
 534 AC_CONFIG_COMMANDS([interface/isl.py.top],
 535                  [cp $srcdir/interface/isl.py.$pet_suffix interface/isl.py.top],
 536                  [pet_suffix="$pet_suffix"])
 537
 538 PACKAGE_CFLAGS="$PACKAGE_CFLAGS_ISL"
 539 PACKAGE_LIBS="-lbarvinok $EXTRA_PACKAGE_LIBS -lpolylibgmp -lisl"
 540 AX_CREATE_PKGCONFIG_INFO
 541
 542 AH_BOTTOM([#include "config_post.h"])
 543 AC_CONFIG_HEADERS(config.h)
 544 AC_CONFIG_FILES(Makefile zsolve/Makefile doc/Makefile)
 545 AC_CONFIG_FILES(parker/Makefile)
 546 if test $with_polylib = bundled; then
 547         AC_CONFIG_SUBDIRS(polylib)
 548 fi
 549 if test $with_isl = bundled; then
 550         AC_CONFIG_SUBDIRS(isl)
 551 fi
 552 if test $with_pet = bundled; then
 553         AC_CONFIG_SUBDIRS(pet)
 554 fi
 555 AC_CONFIG_COMMANDS_POST([
 556         dnl pass on arguments to subdir configures, but don't
 557         dnl add them to config.status
 558         ac_configure_args="$ac_configure_args $bv_configure_args"
 559 ])
 560 AC_OUTPUT