configure.in

   1 AC_INIT
   2 AC_CONFIG_MACRO_DIR([m4])
   3 AM_INIT_AUTOMAKE(barvinok, 0.32.1)
   4 AC_PROG_CC
   5
   6 AC_PROG_CXX
   7 AM_PROG_LEX
   8 AC_PROG_YACC
   9 AC_SUBST(versioninfo)
  10 versioninfo=21:1:1
  11
  12 AC_CANONICAL_HOST
  13 AC_LIBTOOL_WIN32_DLL
  14 AC_SUBST(BV_LDFLAGS)
  15 case $host in
  16         *-*-cygwin* | *-*-mingw* | *-*-pw32* | *-*-os2*)
  17         if test "$enable_shared" = yes; then
  18                 BV_LDFLAGS="-no-undefined"
  19         fi
  20         ;;
  21 esac
  22
  23 AC_PROG_LIBTOOL
  24
  25 PKG_PROG_PKG_CONFIG
  26
  27 AC_CHECK_HEADERS(getopt.h)
  28 AC_CHECK_HEADERS(sys/times.h)
  29
  30 AC_MSG_CHECKING(whether to build shared libbarvinok)
  31 AC_ARG_ENABLE(shared_barvinok,
  32         AS_HELP_STRING([--enable-shared-barvinok],
  33                        [build shared barvinok library]),
  34         [bv_cv_shared_barvinok=$enableval], [bv_cv_shared_barvinok="no"])
  35 AC_MSG_RESULT($bv_cv_shared_barvinok)
  36 if test "x$bv_cv_shared_barvinok" != "xyes" ; then
  37         BV_LDFLAGS="$BV_LDFLAGS -static"
  38 fi
  39
  40 AC_CXX_GNUCXX_HASHMAP
  41
  42 AC_ARG_WITH(default-prefix,
  43         AS_HELP_STRING([--with-default-prefix=DIR],
  44             [Default installation prefix of optional packages]))
  45 if test "${with_default_prefix+set}" = set; then
  46         if test "${with_libgmp+set}" != set -a \
  47            -f "$with_default_prefix/include/gmp.h"; then
  48                 with_libgmp=$with_default_prefix
  49         fi
  50         if test "${with_ntl+set}" != set -a \
  51            -f "$with_default_prefix/include/NTL/ZZ.h"; then
  52                 with_ntl=$with_default_prefix
  53         fi
  54         if test "${with_cddlib+set}" != set -a \
  55            -f "$with_default_prefix/include/cddmp.h"; then
  56                 with_cddlib=$with_default_prefix
  57         fi
  58         if test "${with_glpk+set}" != set -a \
  59            -f "$with_default_prefix/include/glpk.h"; then
  60                 with_glpk=$with_default_prefix
  61         fi
  62         if test "${with_topcom+set}" != set -a \
  63            -f "$with_default_prefix/bin/points2triangs"; then
  64                 with_topcom=$with_default_prefix
  65         fi
  66 fi
  67
  68 dnl Check for GMP library
  69 AC_MSG_CHECKING(whether to use GMP)
  70 AC_ARG_WITH(libgmp,
  71         [  --with-libgmp           DIR Location of the GMP Distribution],
  72         gmp_package=$withval, gmp_package=yes)
  73 if test "x$gmp_package" = "xno"; then
  74         AC_MSG_RESULT(no)
  75         AC_MSG_ERROR(Need gmp)
  76 else
  77         AC_MSG_RESULT(yes)
  78         if test "x$gmp_package" = "xyes"; then
  79                 bv_configure_args="$bv_configure_args --with-libgmp --with-gmp"
  80         else
  81             bv_configure_args="$bv_configure_args --with-libgmp=$gmp_package"
  82             bv_configure_args="$bv_configure_args --with-gmp-prefix=$gmp_package"
  83             GMP_DIR=$gmp_package
  84             if test ! -d "$GMP_DIR"; then
  85                 AC_ERROR(Directory given for GMP Distribution is not a directory)
  86             fi
  87             CPPFLAGS="-I$GMP_DIR/include $CPPFLAGS"
  88             LDFLAGS="-L$GMP_DIR/lib $LDFLAGS"
  89         fi
  90         poly_cv_gmpfatal="no"
  91         AC_CHECK_HEADER(gmp.h,
  92                 [AC_CHECK_LIB(gmp,main,
  93                     [],
  94                     [poly_cv_gmpfatal="yes"])],
  95                 [poly_cv_gmpfatal="yes"])
  96         if test "$poly_cv_gmpfatal" = "yes"; then
  97                 AC_MSG_ERROR([GMP not found])
  98         fi
  99 fi
 100 AC_CHECK_DECL(mpz_divisible_p,[],[AC_LIBOBJ(mpz_divisible_p)],[#include <gmp.h>])
 101
 102 AX_SUBMODULE(polylib,build|bundled|system,bundled)
 103
 104 AC_SUBST(POLYLIB_CPPFLAGS)
 105 AC_SUBST(POLYLIB_LDFLAGS)
 106 AC_SUBST(POLYLIB_LIBS)
 107 case "$with_polylib" in
 108 bundled)
 109         bv_configure_args="$bv_configure_args --with-polylib-builddir=../polylib"
 110         POLYLIB_CPPFLAGS="-I\$(top_builddir)/polylib/include -I\$(top_srcdir)/polylib/include"
 111         ;;
 112 build)
 113         with_polylib_builddir=`echo @abs_builddir@ | $with_polylib_builddir/config.status --file=-`
 114         POLYLIB_CPPFLAGS="-I$polylib_srcdir/include -I$with_polylib_builddir/include"
 115         POLYLIB_LIBS="$with_polylib_builddir/libpolylibgmp.la"
 116         ;;
 117 system)
 118         POLYLIB_LIBS="-lpolylibgmp"
 119         if test "x$with_polylib_prefix" != "x"; then
 120                 POLYLIB_CPPFLAGS="-I$with_polylib_prefix/include"
 121                 POLYLIB_LDFLAGS="-L$with_polylib_prefix/lib"
 122         fi
 123         SAVE_CPPFLAGS="$CPPFLAGS"
 124         CPPFLAGS="$POLYLIB_CPPFLAGS $CPPFLAGS"
 125         AC_CHECK_HEADERS([polylib/polylibgmp.h], [], [
 126                 AC_MSG_ERROR(Need PolyLib)
 127         ])
 128         CPPFLAGS="$SAVE_CPPFLAGS"
 129 esac
 130
 131 AM_CONDITIONAL(BUNDLED_POLYLIB, test $with_polylib = bundled)
 132
 133 AX_SUBMODULE(piplib,no|bundled|system,bundled)
 134
 135 AC_SUBST(PIPLIB_CPPFLAGS)
 136 AC_SUBST(PIPLIB_LDFLAGS)
 137 AC_SUBST(PIPLIB_LIBS)
 138 have_piplib=false
 139 case "$with_piplib" in
 140 bundled)
 141         have_piplib=true
 142         bv_configure_args="$bv_configure_args --with-piplib-builddir=../piplib"
 143         bv_configure_args="$bv_configure_args --with-bits=gmp"
 144         PIPLIB_CPPFLAGS="-I$srcdir/piplib/include"
 145         ;;
 146 system)
 147         PIPLIB_LIBS="-lpiplibMP"
 148         if test "x$with_piplib_prefix" != "x"; then
 149                 PIPLIB_CPPFLAGS="-I$with_piplib_prefix/include"
 150                 PIPLIB_LDFLAGS="-L$with_piplib_prefix/lib"
 151         fi
 152         SAVE_CPPFLAGS="$CPPFLAGS"
 153         SAVE_LDFLAGS="$LDFLAGS"
 154         CPPFLAGS="$PIPLIB_CPPFLAGS $CPPFLAGS"
 155         LDFLAGS="$PIPLIB_LDFLAGS $LDFLAGS"
 156         AC_CHECK_LIB(piplibMP, pip_solve,[
 157             AC_CHECK_MEMBER(PipOptions.Urs_parms, [have_piplib=true], [
 158                 AC_MSG_ERROR([Piplib too old; please install version 1.3.6 or newer])
 159             ],[#include <stdio.h>
 160                #include <piplib/piplibMP.h>])
 161         ],[
 162             AC_MSG_WARN([Piplib not found])
 163         ])
 164         CPPFLAGS="$SAVE_CPPFLAGS"
 165         LDFLAGS="$SAVE_LDFLAGS"
 166         ;;
 167 esac
 168 if test "$have_piplib" = true; then
 169         AC_DEFINE(HAVE_PIPLIB,[],[use piplib])
 170 fi
 171 AM_CONDITIONAL(HAVE_PIPLIB, test x$have_piplib = xtrue)
 172 AM_CONDITIONAL(BUNDLED_PIPLIB, test $with_piplib = bundled)
 173
 174 AX_SUBMODULE(isl,build|bundled|system,bundled)
 175
 176 AC_SUBST(ISL_CFLAGS)
 177 AC_SUBST(ISL_LIBS)
 178 AC_SUBST(ISL_BUILDDIR)
 179 case "$with_isl" in
 180 bundled)
 181         ISL_CFLAGS="-I\$(top_srcdir)/isl/include -I\$(top_builddir)/isl/include"
 182         bv_configure_args="$bv_configure_args --with-isl-builddir=../isl"
 183         PACKAGE_CFLAGS_ISL='-I${prefix}/include/isl'
 184         ;;
 185 build)
 186         ISL_BUILDDIR=`echo @abs_builddir@ | $with_isl_builddir/config.status --file=-`
 187         ISL_CFLAGS="-I$isl_srcdir/include -I$ISL_BUILDDIR/include"
 188         PACKAGE_CFLAGS_ISL='-I${prefix}/include/isl'
 189         ;;
 190 system)
 191         PKG_CHECK_MODULES([ISL], [isl])
 192         PACKAGE_CFLAGS_ISL="$ISL_CFLAGS"
 193 esac
 194 AM_CONDITIONAL(BUNDLED_ISL, test $with_isl = bundled)
 195 AM_CONDITIONAL(BUILD_ISL, test $with_isl = build)
 196
 197 AX_SUBMODULE(isl-polylib,build|bundled|system,bundled)
 198
 199 AC_SUBST(ISL_POLYLIB_CFLAGS)
 200 AC_SUBST(ISL_POLYLIB_LIBS)
 201 case "$with_isl_polylib" in
 202 bundled)
 203         ISL_POLYLIB_CFLAGS="-I\$(top_srcdir)/isl-polylib/include -I\$(top_builddir)/isl-polylib/include"
 204         ;;
 205 build)
 206         ISL_POLYLIB_CFLAGS="-I$isl_polylib_srcdir/include -I$with_isl_polylib_builddir/include"
 207         ISL_POLYLIB_LIBS="$with_isl_polylib_builddir/libisl-polylib.la"
 208         ;;
 209 system)
 210         PKG_CHECK_MODULES([ISL_POLYLIB], [isl-polylib])
 211 esac
 212 AM_CONDITIONAL(BUNDLED_ISL_POLYLIB, test $with_isl_polylib = bundled)
 213
 214 AC_MSG_CHECKING(if the fractional representation should be used)
 215 AC_ARG_ENABLE(fractional, [AS_HELP_STRING([--disable-fractional],
 216                                           [Don't use fractional representation])],
 217             [bv_cv_fractional=$enableval], [bv_cv_fractional="yes"])
 218 AC_ARG_ENABLE(modulo, [AS_HELP_STRING([--disable-modulo],
 219                                       [Don't use fractional representation])],
 220             [bv_cv_modulo=$enableval], [bv_cv_modulo="$bv_cv_fractional"])
 221 AC_MSG_RESULT($bv_cv_modulo)
 222 if test "x$bv_cv_modulo" != "xno" ; then
 223         AC_DEFINE(USE_MODULO,[], [Use fractional representation])
 224 fi
 225
 226 AC_MSG_CHECKING(whether to use incremental algorithm)
 227 AC_ARG_ENABLE(incremental,
 228         [AS_HELP_STRING([--enable-incremental@<:@=bf|df@:>@],
 229                         [Enable incremental algorithm [bf]])],
 230         [bv_cv_incremental=$enableval], [bv_cv_incremental="no"])
 231 AC_MSG_RESULT($bv_cv_incremental)
 232 case $bv_cv_incremental in
 233         yes | bf)
 234                 AC_DEFINE(USE_INCREMENTAL_BF,[],
 235                           [Use breadth-first incremental algorithm])
 236         ;;
 237         df)
 238                 AC_DEFINE(USE_INCREMENTAL_DF,[],
 239                           [Use depth-first incremental algorithm])
 240         ;;
 241 esac
 242
 243 AC_ARG_WITH(ntl,
 244             [  --with-ntl=DIR          DIR Location of NTL],
 245             [ echo "Package ntl : $withval" && ntl_package=$withval],
 246             [ ntl_package=yes ])
 247
 248 if test "$ntl_package" = "no"; then
 249     AC_MSG_ERROR(Need ntl)
 250 fi
 251
 252 AC_SUBST(NTL_CPPFLAGS)
 253 AC_SUBST(NTL_LDFLAGS)
 254 if test "$ntl_package" != "yes"; then
 255     NTL_CPPFLAGS="-I$ntl_package/include"
 256     NTL_LDFLAGS="-L$ntl_package/lib"
 257 fi
 258
 259 SAVE_CPPFLAGS="$CPPFLAGS"
 260 SAVE_LDFLAGS="$LDFLAGS"
 261 CPPFLAGS="$NTL_CPPFLAGS $CPPFLAGS"
 262 LDFLAGS="$NTL_LDFLAGS $LDFLAGS"
 263 AC_EGREP_CPP(yes, [
 264     #include <NTL/ZZ.h>
 265     #ifdef NTL_GMP_LIP
 266     yes
 267     #endif
 268     ],:,AC_MSG_ERROR(ntl not compiled with gmp support))
 269
 270 AC_CHECK_LIB(ntl, main,[],[
 271     AC_MSG_ERROR(Need ntl)
 272 ])
 273 CPPFLAGS="$SAVE_CPPFLAGS"
 274 LDFLAGS="$SAVE_LDFLAGS"
 275
 276 AC_SUBST(bv_cone_hilbert_basis)
 277 AC_MSG_CHECKING(whether to compile zsolve)
 278 AC_ARG_WITH(zsolve,
 279             [AS_HELP_STRING([--without-zsolve],[do not compile zsolve])],
 280             [ with_zsolve=$withval],  [ with_zsolve=yes ])
 281 AC_MSG_RESULT($with_zsolve)
 282
 283 use_zsolve=false
 284 if test "$with_zsolve" != "no"; then
 285         if test "$GCC" = "yes"; then
 286                 $CC --version |
 287                 sed -e 's/.* \(@<:@0-9@:>@@<:@0-9@:>@*\)\.\(@<:@0-9@:>@@<:@0-9@:>@*\).*/\1 \2/' |
 288                 (read major minor
 289                         if test $major -gt 3; then
 290                                 exit 0
 291                         fi
 292                         if test $major -eq 3 -a $minor -ge 4; then
 293                                 exit 0
 294                         fi
 295                         exit 1
 296                 ) && use_zsolve=true
 297         fi
 298         if test "$use_zsolve" = false; then
 299                 AC_MSG_WARN(gcc 3.4 required to compile zsolve)
 300         else
 301                 AC_DEFINE(USE_ZSOLVE,[],[use zsolve])
 302                 bv_cone_hilbert_basis="cone_hilbert_basis\$(EXEEXT)"
 303         fi
 304 fi
 305 AM_CONDITIONAL(USE_ZSOLVE, test x$use_zsolve = xtrue)
 306
 307 AX_SUBMODULE(omega,no|bundled|system,no)
 308
 309 AC_SUBST(OMEGA_CPPFLAGS)
 310 AC_SUBST(OMEGA_LDFLAGS)
 311 AC_SUBST(OMEGA_LIBS)
 312 AC_SUBST(OMEGA_CODEGEN_LIBS)
 313 have_omega=false
 314 have_codegen=false
 315 case "$with_omega" in
 316 bundled)
 317         have_omega=true
 318         have_codegen=true
 319         OMEGA_CPPFLAGS="-I\$(top_srcdir)/omega/omega_lib/include"
 320         OMEGA_CPPFLAGS="$OMEGA_CPPFLAGS -I\$(top_srcdir)/omega/basic/include"
 321         OMEGA_CPPFLAGS="$OMEGA_CPPFLAGS -I\$(top_srcdir)/omega/code_gen/include"
 322         OMEGA_CPPFLAGS="$OMEGA_CPPFLAGS -I\$(top_srcdir)/omega/omega_calc/include"
 323         ;;
 324 system)
 325     if test "x$omega_package" != "xyes"; then
 326         OMEGA_CPPFLAGS="-I$omega_package/include/omega"
 327         OMEGA_LDFLAGS="-L$omega_package/lib"
 328     else
 329         for i in /usr/include /usr/local/include; do
 330             if test -f $i/omega/omega.h; then
 331                 OMEGA_CPPFLAGS="-I$i/omega"
 332             fi
 333         done
 334     fi
 335
 336     AC_LANG_PUSH(C++)
 337     SAVE_CPPFLAGS="$CPPFLAGS"
 338     SAVE_LDFLAGS="$LDFLAGS"
 339     CPPFLAGS="$OMEGA_CPPFLAGS $CPPFLAGS"
 340     LDFLAGS="$OMEGA_LDFLAGS $LDFLAGS"
 341     AC_CHECK_HEADERS([omega.h],[
 342         OMEGA_LIBS="-lomega"
 343         AC_CHECK_LIB(code_gen,main,[
 344                 OMEGA_CODEGEN_LIBS="-lcode_gen -lomega"
 345                 have_codegen=true
 346         ])
 347         have_omega=true
 348     ],[AC_MSG_WARN(Omega not found)])
 349     CPPFLAGS="$SAVE_CPPFLAGS"
 350     LDFLAGS="$SAVE_LDFLAGS"
 351     AC_LANG_POP
 352     ;;
 353 esac
 354 if test "$have_omega" = true; then
 355         AC_DEFINE(HAVE_OMEGA,[],[use omega])
 356 fi
 357 AM_CONDITIONAL(HAVE_OMEGA, test x$have_omega = xtrue)
 358 AM_CONDITIONAL(BUNDLED_OMEGA, test $with_omega = bundled)
 359
 360 use_parker=false
 361 AC_MSG_CHECKING(whether to compile parker)
 362 AC_ARG_WITH(parker,
 363             [AS_HELP_STRING([--without-zsolve],[do not compile zsolve])],
 364             [ with_parker=$withval],  [ with_parker=yes ])
 365 AC_MSG_RESULT($with_parker)
 366
 367 if test "$with_parker" != "no"; then
 368         AC_MSG_CHECKING(for mona)
 369         AC_ARG_WITH(mona,
 370                 [AS_HELP_STRING([--with-mona=DIR],[mona *source* directory])],
 371                                 [], [AC_MSG_RESULT(not specified)])
 372
 373         if test "x$with_mona" != "x"; then
 374                 AC_SUBST(MONAPATH)
 375                 MONAPATH=$with_mona
 376                 AC_MSG_RESULT($MONAPATH)
 377                 use_parker=true
 378                 AC_DEFINE(USE_PARKER,[],[use parker])
 379         fi
 380
 381         if test "x$with_mona" = "x"; then
 382                 AC_MSG_WARN(mona source directory required to compile parker)
 383                 AC_MSG_WARN(http://www.brics.dk/mona/download)
 384         fi
 385 fi
 386 AM_CONDITIONAL(USE_PARKER, test x$use_parker = xtrue)
 387
 388 AC_MSG_CHECKING(whether to use cddlib)
 389 AC_ARG_WITH(cddlib, [AS_HELP_STRING([--with-cddlib=DIR],[DIR Location of cddlib])],
 390             [ cddlib_package=$withval],  [ cddlib_package=yes ])
 391 AC_MSG_RESULT($cddlib_package)
 392
 393 have_cddlib=false
 394 if test "$cddlib_package" != "no"; then
 395     if test "x$cddlib_package" != "xyes"; then
 396         CPPFLAGS="-I$cddlib_package/include $CPPFLAGS"
 397         LDFLAGS="-L$cddlib_package/lib $LDFLAGS"
 398     fi
 399     AC_TRY_LINK([
 400 #define GMPRATIONAL
 401 #include <setoper.h>
 402 #include <cddmp.h>
 403 ], [
 404     mytype a;
 405     dd_init(a); ], [
 406         have_cddlib=true
 407         AC_CHECK_LIB(cddgmp, main,[
 408                 SAVE_LIBS="$LIBS"
 409                 LIBS="-lcddgmp $LIBS"
 410                 AC_DEFINE_UNQUOTED([SRCDIR], ["$srcdir"], [srcdir])
 411                 AC_LANG_PUSH(C++)
 412                 AC_RUN_IFELSE(AC_LANG_PROGRAM([[#define GMPRATIONAL
 413 #include <setoper.h>
 414 #include <cdd.h>]],
 415                 [[
 416         const char *filename = SRCDIR"/cdd94e-test";
 417         FILE *f;
 418         dd_MatrixPtr M;
 419         dd_LPType *lp;
 420         dd_ErrorType err = dd_NoError;
 421
 422         dd_set_global_constants();
 423
 424         f = fopen(filename, "r");
 425         M = dd_PolyFile2Matrix(f, &err);
 426         lp = dd_Matrix2LP(M, &err);
 427         dd_LPSolve(lp, dd_DualSimplex, &err);
 428         return lp->LPS == dd_Inconsistent;
 429                 ]]),[
 430                         AC_DEFINE(HAVE_LIBCDDGMP, [], [Define to 1 if you have the `cddgmp' library (-lcddgmp).])
 431                 ],[
 432                         AC_MSG_WARN(please upgrade cddlib to 0.94e or later)
 433                         LIBS="$SAVE_LIBS"
 434                         have_cddlib=false
 435                 ])
 436                 AC_LANG_POP
 437         ],[have_cddlib=false])
 438     ])
 439 fi
 440 AM_CONDITIONAL(HAVE_CDDLIB, test x$have_cddlib = xtrue)
 441
 442
 443
 444 AC_MSG_CHECKING(whether to use GLPK)
 445 AC_ARG_WITH(glpk, [AS_HELP_STRING([--with-glpk=DIR],[DIR Location of GLPK])],
 446             [ glpk_package=$withval],  [ glpk_package=yes ])
 447 AC_MSG_RESULT($glpk_package)
 448
 449 have_glpk=false
 450 if test "$glpk_package" != "no"; then
 451     if test "x$glpk_package" != "xyes"; then
 452         CPPFLAGS="-I$glpk_package/include $CPPFLAGS"
 453         LDFLAGS="-L$glpk_package/lib $LDFLAGS"
 454     fi
 455     AC_CHECK_HEADERS([glpk.h],[
 456         have_glpk=true
 457         AC_CHECK_LIB(glpk, main,[],[have_glpk=false])
 458     ])
 459 fi
 460 AM_CONDITIONAL(HAVE_GLPK, test x$have_glpk = xtrue)
 461
 462 AC_MSG_CHECKING(location of TOPCOM)
 463 AC_ARG_WITH(topcom, [AS_HELP_STRING([--with-topcom=DIR],[Location of TOPCOM])],
 464             [topcom_package=$withval], [topcom_package=unspecified])
 465 AC_MSG_RESULT($topcom_package)
 466 have_topcom=false
 467 if test "$topcom_package" != no; then
 468         topcom_path="$PATH"
 469         if test "$topcom_package" != unspecified; then
 470                 topcom_path="$topcom_package/bin"
 471         fi
 472         AC_PATH_PROG([POINTS2TRIANGS], [points2triangs], [], [$topcom_path])
 473         if test -n "$POINTS2TRIANGS"; then
 474                 have_topcom=true
 475                 AC_DEFINE_UNQUOTED(POINTS2TRIANGS_PATH, ["$POINTS2TRIANGS"],
 476                                     [Path of points2triangs])
 477         fi
 478 fi
 479 AM_CONDITIONAL(HAVE_TOPCOM, test x$have_topcom = xtrue)
 480
 481 AX_SUBMODULE(cloog,no|build|system,no)
 482
 483 AC_SUBST(CLOOG_LDFLAGS)
 484 AC_SUBST(CLOOG_CFLAGS)
 485 AC_SUBST(CLOOG_LIBS)
 486 CLOOG_CFLAGS="-DCLOOG_INT_GMP=1"
 487 case "$with_cloog" in
 488 build)
 489         with_cloog_builddir=`echo @abs_builddir@ | $with_cloog_builddir/config.status --file=-`
 490         CLOOG_CFLAGS="$CLOOG_CFLAGS -I$cloog_srcdir/include -I$with_cloog_builddir/include"
 491         CLOOG_LIBS="$with_cloog_builddir/libcloog-isl.la"
 492         AC_DEFINE(HAVE_CLOOG,[],[use CLooG])
 493         ;;
 494 system)
 495         if test "x$with_cloog_prefix" != "x"; then
 496                 CLOOG_CFLAGS="$CLOOG_CFLAGS -I$with_cloog_prefix/include"
 497         fi
 498         if test "x$with_cloog_exec_prefix" != "x"; then
 499                 CLOOG_LDFLAGS="-L$with_cloog_exec_prefix/lib"
 500         fi
 501         CLOOG_LIBS="-lcloog-isl"
 502         AC_DEFINE(HAVE_CLOOG,[],[use CLooG])
 503 esac
 504
 505 AC_SUBST(GIT_HEAD_ID)
 506 AC_SUBST(GIT_HEAD)
 507 AC_SUBST(GIT_HEAD_VERSION)
 508 if test -f $srcdir/.git/HEAD; then
 509     GIT_HEAD="$srcdir/.git/index"
 510     GIT_REPO="$srcdir/.git"
 511     GIT_HEAD_ID=`GIT_DIR=$GIT_REPO git describe`
 512 elif test -f $srcdir/GIT_HEAD_ID; then
 513     GIT_HEAD_ID=`cat $srcdir/GIT_HEAD_ID`
 514 else
 515     mysrcdir=`(cd $srcdir; pwd)`
 516     head=`basename $mysrcdir | sed -e 's/.*-//'`
 517     head2=`echo $head | sed -e 's/[^0-9a-f]//'`
 518     head3=`echo $head2 | sed -e 's/........................................//'`
 519     base=`basename $mysrcdir | sed -e 's/-.*//'`
 520     if test "x$head3" = "x" -a "x$head" = "x$head2"; then
 521         GIT_HEAD_ID="barvinok-$VERSION-$head
 522     elif test "x$base" = "xbarvinok-$VERSION" -a "x$head" != "x"; then
 523         GIT_HEAD_ID="barvinok-$VERSION-$head
 524     else
 525         GIT_HEAD_ID="UNKNOWN"
 526     fi
 527 fi
 528 if test -z "$GIT_REPO" ; then
 529     GIT_HEAD_VERSION="$GIT_HEAD_ID"
 530 else
 531     GIT_HEAD_VERSION="\`GIT_DIR=$GIT_REPO git describe\`"
 532 fi
 533 echo '#define GIT_HEAD_ID "'$GIT_HEAD_ID'"' > version.h
 534
 535 AC_LANG_PUSH(C++)
 536 AC_TRY_COMPILE([
 537                 #include <set>
 538                 void negate();
 539         ], [negate()],
 540         suffix="normal", suffix="broken")
 541 AC_CONFIG_COMMANDS([barvinok/set.h],
 542                    [cp $srcdir/barvinok/set.h.$suffix barvinok/set.h],
 543                    [suffix="$suffix"])
 544 AC_CONFIG_COMMANDS([barvinok/NTL.h],
 545                    [cp $srcdir/barvinok/NTL.h.$suffix barvinok/NTL.h],
 546                    [suffix="$suffix"])
 547 use_fdstream=false
 548 SAVE_CPPFLAGS="$CPPFLAGS"
 549 CPPFLAGS="-I$srcdir $CPPFLAGS"
 550 AC_TRY_COMPILE([#include "fdstream.h"],[],
 551         [AC_DEFINE(USE_FDSTREAM,[],[use fdstream])
 552         use_fdstream=true])
 553 CPPFLAGS="$SAVE_CPPFLAGS"
 554 AC_LANG_POP
 555 AM_CONDITIONAL(USE_FDSTREAM, [test "$use_fdstream" = true])
 556
 557 PACKAGE_CFLAGS="$PACKAGE_CFLAGS_ISL"
 558 PACKAGE_LIBS="-lbarvinok $EXTRA_PACKAGE_LIBS -lisl-polylib -lpolylibgmp -lpiplibMP -lisl"
 559 AX_CREATE_PKGCONFIG_INFO
 560
 561 AC_CONFIG_HEADERS(config.h)
 562 AC_CONFIG_FILES(Makefile zsolve/Makefile doc/Makefile)
 563 AC_CONFIG_FILES(parker/Makefile)
 564 if test $with_polylib = bundled; then
 565         AC_CONFIG_SUBDIRS(polylib)
 566 fi
 567 if test $with_piplib = bundled; then
 568         AC_CONFIG_SUBDIRS(piplib)
 569 fi
 570 if test $with_isl = bundled; then
 571         AC_CONFIG_SUBDIRS(isl)
 572 fi
 573 if test $with_isl_polylib = bundled; then
 574         AC_CONFIG_SUBDIRS(isl-polylib)
 575 fi
 576 if test $with_omega = bundled; then
 577         AC_CONFIG_SUBDIRS(omega)
 578 fi
 579 AC_CONFIG_COMMANDS_POST([
 580         dnl pass on arguments to subdir configures, but don't
 581         dnl add them to config.status
 582         ac_configure_args="$ac_configure_args $bv_configure_args"
 583 ])
 584 AC_OUTPUT