bernstein/configure.in

   1 AC_INIT
   2 AC_CONFIG_AUX_DIR(.)
   3 AM_INIT_AUTOMAKE(bernstein, 0.02)
   4 AC_SUBST(versioninfo)
   5 versioninfo=1:0:0
   6
   7 AC_CANONICAL_HOST
   8 AC_PROG_LIBTOOL
   9
  10 AC_ARG_WITH(default-prefix,
  11         AS_HELP_STRING([--with-default-prefix=DIR],
  12             [Default installation prefix of optional packages]))
  13 if test "${with_default_prefix+set}" = set; then
  14         if test "${with_libgmp+set}" != set -a \
  15            -f "$with_default_prefix/include/gmp.h"; then
  16                 with_libgmp=$with_default_prefix
  17         fi
  18 fi
  19
  20 dnl Check for GMP library
  21 AC_MSG_CHECKING(whether to use GMP)
  22 AC_ARG_WITH(libgmp,
  23         [  --with-libgmp           DIR Location of the GMP Distribution],
  24         gmp_package=$withval, gmp_package=yes)
  25 if test "x$gmp_package" = "xno"; then
  26         AC_MSG_RESULT(no)
  27         AC_MSG_ERROR(Need gmp)
  28 else
  29         AC_MSG_RESULT(yes)
  30         if test "x$gmp_package" != "xyes"; then
  31             GMP_DIR=$gmp_package
  32             if test ! -d "$GMP_DIR"; then
  33                 AC_ERROR(Directory given for GMP Distribution is not a directory)
  34             fi
  35             CPPFLAGS="-I$GMP_DIR/include $CPPFLAGS"
  36             LDFLAGS="-L$GMP_DIR/lib $LDFLAGS"
  37         fi
  38         poly_cv_gmpfatal="no"
  39         AC_CHECK_HEADER(gmp.h,
  40                 [AC_CHECK_LIB(gmp,main,
  41                     [],
  42                     [poly_cv_gmpfatal="yes"])],
  43                 [poly_cv_gmpfatal="yes"])
  44         if test "$poly_cv_gmpfatal" = "yes"; then
  45                 AC_MSG_ERROR([GMP not found])
  46         fi
  47 fi
  48
  49 AC_ARG_WITH(polylib_prefix,
  50         [AS_HELP_STRING([--with-polylib-prefix=DIR],
  51                         [Location of PolyLib installation])])
  52 AC_ARG_WITH(polylib_builddir,
  53         [AS_HELP_STRING([--with-polylib-builddir=DIR],
  54                         [Location of PolyLib builddir])])
  55
  56 if test "x$with_polylib_prefix" != "x" -a "x$with_polylib_builddir" != "x"; then
  57         AC_MSG_ERROR(
  58         [--with-polylib-prefix and --with-polylib-builddir are mutually exclusive])
  59 fi
  60
  61 AC_SUBST(POLYLIB_CPPFLAGS)
  62 AC_SUBST(POLYLIB_LDFLAGS)
  63 AC_SUBST(POLYLIB_LIBS)
  64 AC_MSG_CHECKING(for location of PolyLib)
  65 if test "x$with_polylib_builddir" != "x"; then
  66         AC_MSG_RESULT(built in $with_polylib_builddir)
  67         polylib_srcdir=`echo @srcdir@ | $with_polylib_builddir/config.status --file=-`
  68         AC_MSG_NOTICE(PolyLib sources in $polylib_srcdir)
  69         POLYLIB_CPPFLAGS="-I$with_polylib_builddir/include -I$polylib_srcdir/include"
  70         POLYLIB_LIBS="$with_polylib_builddir/libpolylibgmp.la"
  71 else
  72         POLYLIB_LIBS="-lpolylibgmp"
  73         if test "${with_default_prefix+set}" = set -a \
  74             "${with_polylib_prefix+set}" != set -a \
  75             -f "$with_default_prefix/include/polylib/polylibgmp.h"; then
  76                 with_polylib_prefix=$with_default_prefix
  77         fi
  78         if test "x$with_polylib_prefix" != "x"; then
  79                 AC_MSG_RESULT(installed in $with_polylib_prefix)
  80                 POLYLIB_CPPFLAGS="-I$with_polylib_prefix/include"
  81                 POLYLIB_LDFLAGS="-L$with_polylib_prefix/lib"
  82                 LD_LIBRARY_PATH="$with_polylib_prefix/lib:$LD_LIBRARY_PATH"
  83                 export LD_LIBRARY_PATH
  84         else
  85                 AC_MSG_RESULT(installed in standard location)
  86         fi
  87         AC_CHECK_LIB(polylibgmp, PolyhedronTSort,[],[
  88                 AC_MSG_ERROR(Need PolyLib)
  89         ])
  90 fi
  91
  92 AC_LANG_PUSH(C++)
  93 AM_PATH_GINAC(1.3.3, [], [
  94     AC_MSG_ERROR(Need GiNaC)
  95 ])
  96 AC_LANG_POP
  97
  98 AC_CONFIG_HEADERS(config.h)
  99 AC_OUTPUT(Makefile)