board/pcm030/u-boot.lds.S

   1 /*
   2  * (C) Copyright 2003
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 #include <asm-generic/u-boot.lds.h>
  25
  26 OUTPUT_ARCH("powerpc")
  27 /* Do we need any of these for elf?
  28    __DYNAMIC = 0;    */
  29 SECTIONS
  30 {
  31   . = TEXT_BASE;
  32
  33   /* Read-only sections, merged into text segment: */
  34   .interp : { *(.interp) }
  35   .hash          : { *(.hash)           }
  36   .dynsym        : { *(.dynsym)         }
  37   .dynstr        : { *(.dynstr)         }
  38   .rel.text      : { *(.rel.text)               }
  39   .rela.text     : { *(.rela.text)      }
  40   .rel.data      : { *(.rel.data)               }
  41   .rela.data     : { *(.rela.data)      }
  42   .rel.rodata    : { *(.rel.rodata)     }
  43   .rela.rodata   : { *(.rela.rodata)    }
  44   .rel.got       : { *(.rel.got)                }
  45   .rela.got      : { *(.rela.got)               }
  46   .rel.ctors     : { *(.rel.ctors)      }
  47   .rela.ctors    : { *(.rela.ctors)     }
  48   .rel.dtors     : { *(.rel.dtors)      }
  49   .rela.dtors    : { *(.rela.dtors)     }
  50   .rel.bss       : { *(.rel.bss)                }
  51   .rela.bss      : { *(.rela.bss)               }
  52   .rel.plt       : { *(.rel.plt)                }
  53   .rela.plt      : { *(.rela.plt)               }
  54   .init          : { *(.init)   }
  55   .plt : { *(.plt) }
  56   .text      :
  57   {
  58     arch/ppc/mach-mpc5xxx/start.o       (.text)
  59     *(.text*)
  60     *(.got1*)
  61     . = ALIGN(16);
  62     *(.rodata*)
  63     *(.rodata1*)
  64     *(.rodata.str1.4)
  65   }
  66   .fini      : { *(.fini)    } =0
  67   .ctors     : { *(.ctors)   }
  68   .dtors     : { *(.dtors)   }
  69
  70   /* Read-write section, merged into data segment: */
  71   . = (. + 0x0FFF) & 0xFFFFF000;
  72   _etext = .;
  73   PROVIDE (erotext = .);
  74   .reloc   :
  75   {
  76     *(.got)
  77     _GOT2_TABLE_ = .;
  78     *(.got2)
  79     _FIXUP_TABLE_ = .;
  80     *(.fixup)
  81   }
  82   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >> 2;
  83   __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
  84
  85
  86   .data    :
  87   {
  88     *(.data*)
  89     *(.data1*)
  90     *(.sdata*)
  91     *(.sdata2*)
  92     *(.dynamic*)
  93     CONSTRUCTORS
  94   }
  95   _edata  =  .;
  96   PROVIDE (edata = .);
  97
  98   . = .;
  99   __u_boot_cmd_start = .;
 100   .u_boot_cmd : { U_BOOT_CMDS }
 101   __u_boot_cmd_end = .;
 102
 103   __u_boot_initcalls_start = .;
 104   .u_boot_initcalls : { INITCALLS }
 105   __u_boot_initcalls_end = .;
 106   __initcall_entries = (__u_boot_initcalls_end - __u_boot_initcalls_start) >> 2;
 107
 108   __usymtab_start = .;
 109   __usymtab : { U_BOOT_SYMS }
 110   __usymtab_end = .;
 111
 112   __early_init_data_begin = .;
 113   .early_init_data : { *(.early_init_data) }
 114   __early_init_data_end = .;
 115
 116   __start___ex_table = .;
 117   __ex_table : { *(__ex_table) }
 118   __stop___ex_table = .;
 119
 120   . = ALIGN(4096);
 121   __init_begin = .;
 122   .text.init : { *(.text.init) }
 123   .data.init : { *(.data.init) }
 124   . = ALIGN(4096);
 125   __init_end = .;
 126
 127   __init_size = __init_end - _start;
 128
 129   __bss_start = .;
 130   .bss       :
 131   {
 132    *(.sbss*) *(.scommon*)
 133    *(.dynbss*)
 134    *(.bss*)
 135    *(COMMON)
 136   }
 137   _end = . ;
 138   PROVIDE (end = .);
 139 }