awesomeConfig.cmake

   1 set(PROJECT_AWE_NAME awesome)
   2
   3 # If ${SOURCE_DIR} is a git repository VERSION is set to
   4 # `git describe` later.
   5 set(VERSION devel)
   6
   7 set(CODENAME "Closing In")
   8
   9 project(${PROJECT_AWE_NAME} C)
  10
  11 set(CMAKE_BUILD_TYPE RELEASE)
  12
  13 option(WITH_DBUS "build with D-BUS" ON)
  14 option(GENERATE_MANPAGES "generate manpages" ON)
  15 option(COMPRESS_MANPAGES "compress manpages" ON)
  16 option(GENERATE_LUADOC "generate luadoc" ON)
  17
  18 # {{{ CFLAGS
  19 add_definitions(-std=gnu99 -ggdb3 -rdynamic -fno-strict-aliasing -Wall -Wextra
  20     -Wchar-subscripts -Wundef -Wshadow -Wcast-align -Wwrite-strings
  21     -Wsign-compare -Wunused -Wno-unused-parameter -Wuninitialized -Winit-self
  22     -Wpointer-arith -Wredundant-decls -Wformat-nonliteral
  23     -Wno-format-zero-length -Wmissing-format-attribute -Wmissing-prototypes
  24     -Wstrict-prototypes)
  25 # }}}
  26
  27 # {{{ Endianness
  28 include(TestBigEndian)
  29 TEST_BIG_ENDIAN(AWESOME_IS_BIG_ENDIAN)
  30 # }}}
  31
  32 # {{{ Find external utilities
  33 macro(a_find_program var prg req)
  34     set(required ${req})
  35     find_program(${var} ${prg})
  36     if(NOT ${var})
  37         message(STATUS "${prg} not found.")
  38         if(required)
  39             message(FATAL_ERROR "${prg} is required to build awesome")
  40         endif()
  41     else()
  42         message(STATUS "${prg} -> ${${var}}")
  43     endif()
  44 endmacro()
  45
  46 a_find_program(CAT_EXECUTABLE cat TRUE)
  47 a_find_program(LN_EXECUTABLE ln TRUE)
  48 a_find_program(GREP_EXECUTABLE grep TRUE)
  49 a_find_program(GIT_EXECUTABLE git FALSE)
  50 a_find_program(HOSTNAME_EXECUTABLE hostname FALSE)
  51 # programs needed for man pages
  52 a_find_program(ASCIIDOC_EXECUTABLE asciidoc FALSE)
  53 a_find_program(XMLTO_EXECUTABLE xmlto FALSE)
  54 a_find_program(GZIP_EXECUTABLE gzip FALSE)
  55 # lua documentation
  56 a_find_program(LUA_EXECUTABLE lua FALSE)
  57 a_find_program(LUADOC_EXECUTABLE luadoc FALSE)
  58 # theme graphics
  59 a_find_program(CONVERT_EXECUTABLE convert TRUE)
  60 # doxygen
  61 include(FindDoxygen)
  62 # pkg-config
  63 include(FindPkgConfig)
  64 # lua 5.1
  65 include(FindLua51) #Due to a cmake bug, you will see Lua50 on screen
  66 # }}}
  67
  68 # {{{ Check if documentation can be build
  69 if(GENERATE_MANPAGES)
  70     if(NOT ASCIIDOC_EXECUTABLE OR NOT XMLTO_EXECUTABLE OR (COMPRESS_MANPAGES AND NOT GZIP_EXECUTABLE))
  71         if(NOT ASCIIDOC_EXECUTABLE)
  72             SET(missing "asciidoc")
  73         endif()
  74         if(NOT XMLTO_EXECUTABLE)
  75             SET(missing ${missing} " xmlto")
  76         endif()
  77         if(COMPRESS_MANPAGES AND NOT GZIP_EXECUTABLE)
  78             SET(missing ${missing} " gzip")
  79         endif()
  80
  81         message(STATUS "Not generating manpages. Missing: " ${missing})
  82         set(GENERATE_MANPAGES OFF)
  83     endif()
  84 endif()
  85
  86 if(GENERATE_LUADOC)
  87     if(NOT LUADOC_EXECUTABLE)
  88         message(STATUS "Not generating luadoc. Missing: luadoc")
  89         set(GENERATE_LUADOC OFF)
  90     endif()
  91 endif()
  92 # }}}
  93
  94 # {{{ Version stamp
  95 if(EXISTS ${SOURCE_DIR}/.git/HEAD AND GIT_EXECUTABLE)
  96     # get current version
  97     execute_process(
  98         COMMAND ${GIT_EXECUTABLE} describe
  99         WORKING_DIRECTORY ${SOURCE_DIR}
 100         OUTPUT_VARIABLE VERSION
 101         OUTPUT_STRIP_TRAILING_WHITESPACE)
 102     # file the git-version-stamp.sh script will look into
 103     set(VERSION_STAMP_FILE ${BUILD_DIR}/.version_stamp)
 104     file(WRITE ${VERSION_STAMP_FILE} ${VERSION})
 105     # create a version_stamp target later
 106     set(BUILD_FROM_GIT TRUE)
 107 elseif( EXISTS ${SOURCE_DIR}/.version_stamp )
 108     # get version from version stamp
 109     file(READ ${SOURCE_DIR}/.version_stamp VERSION)
 110 endif()
 111 # }}}
 112
 113 # {{{ Get hostname
 114 execute_process(
 115     COMMAND ${HOSTNAME_EXECUTABLE}
 116     WORKING_DIRECTORY ${SOURCE_DIR}
 117     OUTPUT_VARIABLE BUILDHOSTNAME
 118     OUTPUT_STRIP_TRAILING_WHITESPACE)
 119 # }}}
 120
 121 # {{{ Required libraries
 122 #
 123 # this sets up:
 124 # AWESOME_REQUIRED_LDFLAGS
 125 # AWESOME_REQUIRED_INCLUDE_DIRS
 126
 127 # Use pkgconfig to get most of the libraries
 128 pkg_check_modules(AWESOME_COMMON_REQUIRED REQUIRED
 129     xcb>=1.6)
 130
 131 pkg_check_modules(AWESOME_REQUIRED REQUIRED
 132     glib-2.0
 133     cairo
 134     x11
 135     oocairo
 136     oopango
 137     xcb-randr
 138     xcb-xtest
 139     xcb-xinerama
 140     xcb-util>=0.3.8
 141     xcb-keysyms>=0.3.4
 142     xcb-icccm>=0.3.8
 143     xcb-image>=0.3.0
 144     cairo-xcb
 145     libstartup-notification-1.0>=0.10
 146     xproto>=7.0.15
 147     imlib2
 148     libxdg-basedir>=1.0.0)
 149
 150 if(NOT AWESOME_REQUIRED_FOUND OR NOT AWESOME_COMMON_REQUIRED_FOUND)
 151     message(FATAL_ERROR)
 152 endif()
 153
 154 macro(a_find_library variable library)
 155     find_library(${variable} ${library})
 156     if(NOT ${variable})
 157         message(FATAL_ERROR ${library} " library not found.")
 158     endif()
 159 endmacro()
 160
 161 # Check for libev
 162 a_find_library(LIB_EV ev)
 163
 164 # Check for backtrace_symbols()
 165 include(CheckFunctionExists)
 166 check_function_exists(backtrace_symbols HAS_EXECINFO)
 167 if(NOT HAS_EXECINFO)
 168     find_library(LIB_EXECINFO execinfo)
 169     if(LIB_EXECINFO)
 170         set(HAS_EXECINFO 1)
 171         set(AWESOME_REQUIRED_LDFLAGS
 172             ${AWESOME_REQUIRED_LDFLAGS}
 173             ${LIB_EXECINFO})
 174     endif()
 175 endif()
 176 if(HAS_EXECINFO)
 177     message(STATUS "checking for execinfo -- found")
 178 else()
 179     message(STATUS "checking for execinfo -- not found")
 180 endif()
 181
 182 # __builtin_clz is available since gcc 3.4
 183 try_compile(HAS___BUILTIN_CLZ
 184     ${CMAKE_BINARY_DIR}
 185     ${CMAKE_SOURCE_DIR}/build-tests/__builtin_clz.c)
 186 if(HAS___BUILTIN_CLZ)
 187     message(STATUS "checking for __builtin_clz -- yes")
 188 else()
 189     message(STATUS "checking for __builtin_clz -- no")
 190 endif()
 191
 192 # Error check
 193 if(NOT LUA51_FOUND AND NOT LUA50_FOUND) # This is a workaround to a cmake bug
 194     message(FATAL_ERROR "lua library not found")
 195 endif()
 196
 197 set(AWESOME_REQUIRED_LDFLAGS
 198     ${AWESOME_COMMON_REQUIRED_LDFLAGS}
 199     ${AWESOME_REQUIRED_LDFLAGS}
 200     ${LIB_EV}
 201     ${LUA_LIBRARIES})
 202
 203 set(AWESOME_REQUIRED_INCLUDE_DIRS
 204     ${AWESOME_COMMON_REQUIRED_INCLUDE_DIRS}
 205     ${AWESOME_REQUIRED_INCLUDE_DIRS}
 206     ${LUA_INCLUDE_DIR})
 207 # }}}
 208
 209 # {{{ Optional libraries
 210 #
 211 # this sets up:
 212 # AWESOME_OPTIONAL_LDFLAGS
 213 # AWESOME_OPTIONAL_INCLUDE_DIRS
 214
 215 if(WITH_DBUS)
 216     pkg_check_modules(DBUS dbus-1)
 217     if(DBUS_FOUND)
 218         set(AWESOME_OPTIONAL_LDFLAGS ${AWESOME_OPTIONAL_LDFLAGS} ${DBUS_LDFLAGS})
 219         set(AWESOME_OPTIONAL_INCLUDE_DIRS ${AWESOME_OPTIONAL_INCLUDE_DIRS} ${DBUS_INCLUDE_DIRS})
 220     else()
 221         set(WITH_DBUS OFF)
 222         message(STATUS "DBUS not found. Disabled.")
 223     endif()
 224 endif()
 225 # }}}
 226
 227 # {{{ Install path and configuration variables
 228 if(DEFINED PREFIX)
 229     set(PREFIX ${PREFIX} CACHE PATH "install prefix")
 230     set(CMAKE_INSTALL_PREFIX ${PREFIX})
 231 else()
 232     set(PREFIX ${CMAKE_INSTALL_PREFIX} CACHE PATH "install prefix")
 233 endif()
 234
 235 #If a sysconfdir is specified, use it instead
 236 #of the default configuration dir.
 237 if(DEFINED SYSCONFDIR)
 238     set(SYSCONFDIR ${SYSCONFDIR} CACHE PATH "config directory")
 239 else()
 240     set(SYSCONFDIR ${PREFIX}/etc CACHE PATH "config directory")
 241 endif()
 242
 243 #If an XDG Config Dir is specificed, use it instead
 244 #of the default XDG configuration dir.
 245 if(DEFINED XDG_CONFIG_DIR)
 246     set(XDG_CONFIG_DIR ${XDG_CONFIG_DIR} CACHE PATH "xdg config directory")
 247 else()
 248     set(XDG_CONFIG_DIR ${SYSCONFDIR}/xdg CACHE PATH "xdg config directory")
 249 endif()
 250
 251 # setting AWESOME_DOC_PATH
 252 if(DEFINED AWESOME_DOC_PATH)
 253     set(AWESOME_DOC_PATH ${AWESOME_DOC_PATH} CACHE PATH "awesome docs directory")
 254 else()
 255     set(AWESOME_DOC_PATH ${PREFIX}/share/doc/${PROJECT_AWE_NAME} CACHE PATH "awesome docs directory")
 256 endif()
 257
 258 # setting AWESOME_XSESSION_PATH
 259 if(DEFINED AWESOME_XSESSION_PATH)
 260     set(AWESOME_XSESSION_PATH ${AWESOME_XSESSION_PATH} CACHE PATH "awesome xsessions directory")
 261 else()
 262     set(AWESOME_XSESSION_PATH ${PREFIX}/share/xsessions CACHE PATH "awesome xsessions directory")
 263 endif()
 264
 265 # set man path
 266 if(DEFINED AWESOME_MAN_PATH)
 267    set(AWESOME_MAN_PATH ${AWESOME_MAN_PATH} CACHE PATH "awesome manpage directory")
 268 else()
 269    set(AWESOME_MAN_PATH ${PREFIX}/share/man CACHE PATH "awesome manpage directory")
 270 endif()
 271
 272 # Hide to avoid confusion
 273 mark_as_advanced(CMAKE_INSTALL_PREFIX)
 274
 275 set(AWESOME_VERSION          ${VERSION})
 276 set(AWESOME_COMPILE_MACHINE  ${CMAKE_SYSTEM_PROCESSOR})
 277 set(AWESOME_COMPILE_HOSTNAME ${BUILDHOSTNAME})
 278 set(AWESOME_COMPILE_BY       $ENV{USER})
 279 set(AWESOME_RELEASE          ${CODENAME})
 280 set(AWESOME_SYSCONFDIR       ${XDG_CONFIG_DIR}/${PROJECT_AWE_NAME})
 281 set(AWESOME_DATA_PATH        ${PREFIX}/share/${PROJECT_AWE_NAME})
 282 set(AWESOME_LUA_LIB_PATH     ${AWESOME_DATA_PATH}/lib)
 283 set(AWESOME_ICON_PATH        ${AWESOME_DATA_PATH}/icons)
 284 set(AWESOME_THEMES_PATH      ${AWESOME_DATA_PATH}/themes)
 285 # }}}
 286
 287 # {{{ Configure files
 288 file(GLOB_RECURSE awesome_lua_configure_files RELATIVE ${SOURCE_DIR} ${SOURCE_DIR}/lib/*.lua.in ${SOURCE_DIR}/themes/*/*.lua.in)
 289 set(AWESOME_CONFIGURE_FILES
 290     ${awesome_lua_configure_files}
 291     config.h.in
 292     awesomerc.lua.in
 293     awesome-version-internal.h.in
 294     awesome.doxygen.in)
 295
 296 macro(a_configure_file file)
 297     string(REGEX REPLACE ".in\$" "" outfile ${file})
 298     message(STATUS "Configuring ${outfile}")
 299     configure_file(${SOURCE_DIR}/${file}
 300                    ${BUILD_DIR}/${outfile}
 301                    ESCAPE_QUOTE
 302                    @ONLY)
 303 endmacro()
 304
 305 foreach(file ${AWESOME_CONFIGURE_FILES})
 306     a_configure_file(${file})
 307 endforeach()
 308 #}}}
 309
 310 # vim: filetype=cmake:expandtab:shiftwidth=4:tabstop=8:softtabstop=4:textwidth=80