CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.0)
   2 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS  TRUE)
   3
   4 if(COMMAND cmake_policy)
   5     cmake_policy(VERSION 2.6)
   6 endif()
   7
   8 set(SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
   9 set(BUILD_DIR ${CMAKE_CURRENT_BINARY_DIR})
  10
  11 if(NOT EXISTS ${SOURCE_DIR}/awesomeConfig.cmake)
  12     message(FATAL_ERROR "Please provide awesomeConfig.cmake")
  13 endif()
  14
  15 include(awesomeConfig.cmake)
  16
  17 include_directories(
  18     ${SOURCE_DIR}
  19     ${BUILD_DIR}
  20     ${AWESOME_COMMON_REQUIRED_INCLUDE_DIRS}
  21     ${AWESOME_REQUIRED_INCLUDE_DIRS}
  22     ${AWESOME_OPTIONAL_INCLUDE_DIRS})
  23
  24 file(GLOB_RECURSE AWE_LUA_FILES ${BUILD_DIR}/lib/*.lua ${BUILD_DIR}/luadoc/*.lua)
  25
  26 set(AWE_CONF_FILE_DEFAULT ${BUILD_DIR}/awesomerc.lua)
  27 set(AWE_CONF_FILE rc.lua)
  28
  29 set(AWE_ICON_DIR ${SOURCE_DIR}/icons)
  30 set(AWE_THEMES_DIR ${SOURCE_DIR}/themes)
  31
  32 set(AWE_DOC_FILES
  33     ${SOURCE_DIR}/AUTHORS
  34     ${SOURCE_DIR}/BUGS
  35     ${SOURCE_DIR}/README
  36     ${SOURCE_DIR}/LICENSE)
  37
  38 set(AWE_SRCS
  39     ${SOURCE_DIR}/awesome.c
  40     ${SOURCE_DIR}/banning.c
  41     ${SOURCE_DIR}/color.c
  42     ${SOURCE_DIR}/dbus.c
  43     ${SOURCE_DIR}/draw.c
  44     ${SOURCE_DIR}/event.c
  45     ${SOURCE_DIR}/ewmh.c
  46     ${SOURCE_DIR}/keygrabber.c
  47     ${SOURCE_DIR}/keyresolv.c
  48     ${SOURCE_DIR}/luaa.c
  49     ${SOURCE_DIR}/mouse.c
  50     ${SOURCE_DIR}/mousegrabber.c
  51     ${SOURCE_DIR}/property.c
  52     ${SOURCE_DIR}/root.c
  53     ${SOURCE_DIR}/screen.c
  54     ${SOURCE_DIR}/selection.c
  55     ${SOURCE_DIR}/spawn.c
  56     ${SOURCE_DIR}/stack.c
  57     ${SOURCE_DIR}/strut.c
  58     ${SOURCE_DIR}/systray.c
  59     ${SOURCE_DIR}/xwindow.c
  60     ${SOURCE_DIR}/common/atoms.c
  61     ${SOURCE_DIR}/common/backtrace.c
  62     ${SOURCE_DIR}/common/buffer.c
  63     ${SOURCE_DIR}/common/luaclass.c
  64     ${SOURCE_DIR}/common/luaobject.c
  65     ${SOURCE_DIR}/common/util.c
  66     ${SOURCE_DIR}/common/version.c
  67     ${SOURCE_DIR}/common/xcursor.c
  68     ${SOURCE_DIR}/common/xembed.c
  69     ${SOURCE_DIR}/common/xutil.c
  70     ${SOURCE_DIR}/objects/button.c
  71     ${SOURCE_DIR}/objects/client.c
  72     ${SOURCE_DIR}/objects/drawin.c
  73     ${SOURCE_DIR}/objects/key.c
  74     ${SOURCE_DIR}/objects/tag.c
  75     ${SOURCE_DIR}/objects/timer.c
  76     ${SOURCE_DIR}/objects/window.c)
  77
  78 set(AWE_MAN_SRCS
  79     ${SOURCE_DIR}/manpages/awesome.1.txt
  80     ${SOURCE_DIR}/manpages/awsetbg.1.txt
  81     ${SOURCE_DIR}/manpages/awesome-client.1.txt
  82     ${SOURCE_DIR}/manpages/awesomerc.5.txt)
  83 set(AWE_MAN_LANGS it es fr de ru)
  84
  85 add_executable(${PROJECT_AWE_NAME}
  86     ${AWE_SRCS})
  87
  88 set_target_properties(${PROJECT_AWE_NAME}
  89     PROPERTIES
  90     LINK_FLAGS -export-dynamic)
  91
  92 target_link_libraries(${PROJECT_AWE_NAME}
  93     ${AWESOME_COMMON_REQUIRED_LDFLAGS}
  94     ${AWESOME_REQUIRED_LDFLAGS}
  95     ${AWESOME_OPTIONAL_LDFLAGS})
  96
  97 # atoms
  98 file(MAKE_DIRECTORY ${BUILD_DIR}/common)
  99 add_custom_command(
 100     COMMAND ${SOURCE_DIR}/build-utils/atoms-ext.sh ${SOURCE_DIR}/common/atoms.list
 101     ARGS    > ${BUILD_DIR}/common/atoms-extern.h
 102     OUTPUT  ${BUILD_DIR}/common/atoms-extern.h
 103     WORKING_DIRECTORY ${SOURCE_DIR}
 104     DEPENDS ${SOURCE_DIR}/common/atoms.list
 105     COMMENT "Generating atoms-extern.h"
 106     VERBATIM)
 107
 108 add_custom_command(
 109     COMMAND ${SOURCE_DIR}/build-utils/atoms-int.sh ${SOURCE_DIR}/common/atoms.list
 110     ARGS    > ${BUILD_DIR}/common/atoms-intern.h
 111     OUTPUT  ${BUILD_DIR}/common/atoms-intern.h
 112     WORKING_DIRECTORY ${SOURCE_DIR}
 113     DEPENDS ${SOURCE_DIR}/common/atoms.list
 114     COMMENT "Generating atoms-intern.h"
 115     VERBATIM)
 116
 117 add_custom_target(generated_sources
 118     DEPENDS ${BUILD_DIR}/common/atoms-intern.h
 119             ${BUILD_DIR}/common/atoms-extern.h)
 120
 121 # Default theme directory
 122 file(MAKE_DIRECTORY ${BUILD_DIR}/themes/default)
 123 file(MAKE_DIRECTORY ${BUILD_DIR}/themes/sky)
 124 file(MAKE_DIRECTORY ${BUILD_DIR}/themes/zenburn)
 125 add_dependencies(${PROJECT_AWE_NAME} generated_sources)
 126 # }}}
 127
 128 # {{{ Version stamp
 129 if(BUILD_FROM_GIT)
 130     add_custom_target(version_stamp ALL
 131         COMMAND ${SOURCE_DIR}/build-utils/git-version-stamp.sh
 132                 ${VERSION_STAMP_FILE}
 133                 ${BUILD_DIR}/awesome-version-internal.h
 134         WORKING_DIRECTORY ${SOURCE_DIR})
 135
 136     add_dependencies(${PROJECT_AWE_NAME} version_stamp)
 137 endif()
 138 # }}}
 139
 140 # {{{ Manpages
 141 if(GENERATE_MANPAGES)
 142     if(NOT BUILD_DIR STREQUAL SOURCE_DIR)
 143         file(MAKE_DIRECTORY ${BUILD_DIR}/manpages)
 144     endif()
 145
 146     # add the default translation to the list of languages
 147     set(AWE_MAN_LANGS default ${AWE_MAN_LANGS})
 148
 149     foreach(lang ${AWE_MAN_LANGS})
 150
 151         foreach(txtfile ${AWE_MAN_SRCS})
 152             # figure the base name of the file (ie "awesome.1")
 153             GET_FILENAME_COMPONENT(tmpname ${txtfile} NAME)
 154             string(REGEX REPLACE ".txt\$" "" basename ${tmpname})
 155
 156             # figure the relative path of the file
 157             GET_FILENAME_COMPONENT(tmppath ${txtfile} PATH)
 158             string(REPLACE ${SOURCE_DIR}/ "" relpath ${tmppath})
 159
 160             # figure the manpage section to install to from filename
 161             string(REGEX REPLACE "^.*\\.([0-9])$" "\\1" section ${basename})
 162
 163             # construct the language specific versions of the basename and path
 164             if (lang STREQUAL default)
 165                 set(basename2 ${basename})
 166                 set(relpath2 ${relpath}/man${section})
 167             else()
 168                 set(basename2 ${basename}.${lang})
 169                 set(relpath2 ${relpath}/${lang}/man${section})
 170             endif()
 171
 172             # create the build directory (if it does not exist)
 173             file(MAKE_DIRECTORY ${BUILD_DIR}/${relpath2})
 174
 175             # set the final filenames
 176             set(txtfile ${SOURCE_DIR}/${relpath}/${basename2}.txt)
 177             set(xmlfile ${BUILD_DIR}/${relpath2}/${basename}.xml)
 178             set(gzfile  ${BUILD_DIR}/${relpath2}/${basename}.gz)
 179             set(manfile ${BUILD_DIR}/${relpath2}/${basename})
 180
 181             add_custom_command(
 182                 COMMAND ${ASCIIDOC_EXECUTABLE} -d manpage -b docbook -o ${xmlfile} - < ${txtfile}
 183                 WORKING_DIRECTORY ${BUILD_DIR}/${relpath2}
 184                 OUTPUT  ${xmlfile}
 185                 DEPENDS ${txtfile}
 186                 VERBATIM)
 187             add_custom_command(
 188                 COMMAND ${XMLTO_EXECUTABLE} man ${xmlfile}
 189                 OUTPUT  ${manfile}
 190                 WORKING_DIRECTORY ${BUILD_DIR}/${relpath2}
 191                 DEPENDS ${xmlfile})
 192
 193             if(COMPRESS_MANPAGES)
 194                 add_custom_command(
 195                     COMMAND ${GZIP_EXECUTABLE} < ${manfile} > ${gzfile}
 196                     OUTPUT  ${gzfile}
 197                     WORKING_DIRECTORY ${BUILD_DIR}/${relpath2}
 198                     DEPENDS ${manfile}
 199                     VERBATIM)
 200
 201                 set(MAN_FILES ${MAN_FILES} ${gzfile})
 202             else()
 203                 set(MAN_FILES ${MAN_FILES} ${manfile})
 204             endif()
 205         endforeach()
 206
 207     endforeach()
 208
 209     add_custom_target(man ALL DEPENDS ${MAN_FILES})
 210 endif()
 211 # }}}
 212
 213 # {{{ Doxygen
 214 if(DOXYGEN_EXECUTABLE)
 215     add_custom_target(doc
 216         COMMAND ${DOXYGEN_EXECUTABLE} awesome.doxygen
 217         WORKING_DIRECTORY ${BUILD_DIR})
 218 endif()
 219 # }}}
 220
 221 # {{{ Lua API Documentation
 222 if(GENERATE_LUADOC)
 223
 224     if(NOT BUILD_DIR STREQUAL SOURCE_DIR)
 225         file(MAKE_DIRECTORY ${BUILD_DIR}/lib)
 226     endif()
 227
 228     set(luadoc_c_srcs "")
 229
 230     # Generate documentation of lib//0lua
 231     file(GLOB_RECURSE lua_lib_files ${BUILD_DIR}/lib/*.lua
 232         ${SOURCE_DIR}/luadoc/*.lua)
 233     foreach(filename ${lua_lib_files})
 234         file(RELATIVE_PATH filename ${BUILD_DIR} ${filename})
 235         set(luadoc_srcs ${luadoc_srcs} ${filename})
 236     endforeach()
 237
 238     add_custom_target(luadoc ALL
 239         COMMAND ${LUADOC_EXECUTABLE} ${luadoc_srcs} -d ${BUILD_DIR}/luadoc --nofiles
 240         WORKING_DIRECTORY ${BUILD_DIR}
 241         DEPENDS ${AWE_LUA_FILES})
 242 endif()
 243 # }}}
 244
 245 # {{{ Theme icons
 246 file(GLOB icon_sources RELATIVE ${SOURCE_DIR} ${SOURCE_DIR}/themes/*/titlebar/*.png)
 247
 248 foreach(icon ${icon_sources})
 249     # Copy all icons to the build dir to simplify the following code.
 250     # Source paths are interpreted relative to ${SOURCE_DIR}, target paths
 251     # relative to ${BUILD_DIR}.
 252     get_filename_component(icon_path ${icon} PATH)
 253     get_filename_component(icon_name ${icon} NAME)
 254     file(COPY ${icon} DESTINATION ${icon_path})
 255     set(ALL_ICONS ${ALL_ICONS} "${icon_path}/${icon_name}")
 256 endforeach()
 257
 258 macro(a_icon_convert match replacement input)
 259     string(REPLACE ${match} ${replacement} output ${input})
 260
 261     if(NOT ${input} STREQUAL ${output})
 262         set(ALL_ICONS ${ALL_ICONS} ${output})
 263
 264         add_custom_command(
 265             COMMAND ${CONVERT_EXECUTABLE} ${input} ${ARGN} ${output}
 266             OUTPUT  ${output}
 267             DEPENDS ${input}
 268             VERBATIM)
 269     endif()
 270 endmacro()
 271
 272 foreach(icon ${ALL_ICONS})
 273     # Make unfocused icons translucent
 274     a_icon_convert("_focus" "_normal" ${icon}
 275         -gamma 0.6 -channel A -evaluate Multiply 0.4)
 276 endforeach()
 277
 278 foreach(icon ${ALL_ICONS})
 279     # Make inactive icons grayscale
 280     a_icon_convert("_active" "_inactive" ${icon}
 281         -colorspace Gray)
 282 endforeach()
 283
 284 add_custom_target(generated_icons ALL DEPENDS ${ALL_ICONS})
 285 # }}}
 286
 287 # {{{ Dist tarball
 288 if(BUILD_FROM_GIT)
 289     add_custom_target(dist
 290         COMMAND ${SOURCE_DIR}/build-utils/dist.sh ${VERSION}
 291         WORKING_DIRECTORY ${SOURCE_DIR})
 292 endif()
 293 # }}}
 294
 295 # {{{ Installation
 296 install(TARGETS ${PROJECT_AWE_NAME} RUNTIME DESTINATION bin)
 297 install(FILES "utils/awsetbg" DESTINATION bin PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE)
 298 install(FILES "utils/awesome-client" DESTINATION bin PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE)
 299 install(DIRECTORY ${BUILD_DIR}/lib DESTINATION ${AWESOME_DATA_PATH}
 300     PATTERN "*.in" EXCLUDE)
 301 install(FILES ${AWE_CONF_FILE_DEFAULT} DESTINATION ${AWESOME_SYSCONFDIR}
 302         RENAME ${AWE_CONF_FILE})
 303 if(GENERATE_MANPAGES)
 304     if(COMPRESS_MANPAGES)
 305         set(regex "\\.(xml|txt|[0-9])$")
 306     else()
 307         set(regex "\\.(xml|txt|gz)$")
 308     endif()
 309     install(DIRECTORY ${BUILD_DIR}/${relpath}/ DESTINATION ${AWESOME_MAN_PATH}
 310             REGEX ${regex} EXCLUDE )
 311 endif()
 312 install(DIRECTORY ${AWE_ICON_DIR} DESTINATION ${AWESOME_DATA_PATH})
 313 install(DIRECTORY ${BUILD_DIR}/themes DESTINATION ${AWESOME_DATA_PATH}
 314     PATTERN "*.in" EXCLUDE)
 315 install(DIRECTORY ${SOURCE_DIR}/themes DESTINATION ${AWESOME_DATA_PATH}
 316     PATTERN "*.in" EXCLUDE)
 317 install(FILES ${AWE_DOC_FILES} DESTINATION ${AWESOME_DOC_PATH})
 318 install(FILES "awesome.desktop" DESTINATION ${AWESOME_XSESSION_PATH})
 319 if(GENERATE_LUADOC)
 320     install(DIRECTORY ${BUILD_DIR}/luadoc DESTINATION ${AWESOME_DOC_PATH})
 321 endif()
 322 # }}}
 323
 324 # vim: filetype=cmake:expandtab:shiftwidth=4:tabstop=8:softtabstop=4:textwidth=80