awesomeConfig.cmake

   1 set(PROJECT_AWE_NAME awesome)
   2
   3 # If ${SOURCE_DIR} is a git repository VERSION is set to
   4 # `git describe` later.
   5 set(VERSION devel)
   6
   7 set(CODENAME "Never Know")
   8
   9 project(${PROJECT_AWE_NAME} C)
  10
  11 set(CMAKE_BUILD_TYPE RELEASE)
  12
  13 option(WITH_DBUS "build with D-BUS" ON)
  14 option(GENERATE_MANPAGES "generate manpages" ON)
  15 option(COMPRESS_MANPAGES "compress manpages" ON)
  16 option(GENERATE_LUADOC "generate luadoc" ON)
  17
  18 link_directories(/usr/local/lib)
  19
  20 # {{{ CFLAGS
  21 add_definitions(-std=gnu99 -ggdb3 -fno-strict-aliasing -Wall -Wextra
  22     -Wchar-subscripts -Wundef -Wshadow -Wcast-align -Wwrite-strings
  23     -Wsign-compare -Wunused -Wno-unused-parameter -Wuninitialized -Winit-self
  24     -Wpointer-arith -Wredundant-decls -Wformat-nonliteral
  25     -Wno-format-zero-length -Wmissing-format-attribute -Wmissing-prototypes
  26     -Wstrict-prototypes)
  27 # }}}
  28
  29 # {{{ Endianness
  30 include(TestBigEndian)
  31 TEST_BIG_ENDIAN(AWESOME_IS_BIG_ENDIAN)
  32 # }}}
  33
  34 # {{{ Find external utilities
  35 macro(a_find_program var prg req)
  36     set(required ${req})
  37     find_program(${var} ${prg})
  38     if(NOT ${var})
  39         message(STATUS "${prg} not found.")
  40         if(required)
  41             message(FATAL_ERROR "${prg} is required to build awesome")
  42         endif()
  43     else()
  44         message(STATUS "${prg} -> ${${var}}")
  45     endif()
  46 endmacro()
  47
  48 a_find_program(CAT_EXECUTABLE cat TRUE)
  49 a_find_program(LN_EXECUTABLE ln TRUE)
  50 a_find_program(GREP_EXECUTABLE grep TRUE)
  51 a_find_program(GIT_EXECUTABLE git FALSE)
  52 a_find_program(HOSTNAME_EXECUTABLE hostname FALSE)
  53 a_find_program(GPERF_EXECUTABLE gperf TRUE)
  54 # programs needed for man pages
  55 a_find_program(ASCIIDOC_EXECUTABLE asciidoc FALSE)
  56 a_find_program(XMLTO_EXECUTABLE xmlto FALSE)
  57 a_find_program(GZIP_EXECUTABLE gzip FALSE)
  58 # lua documentation
  59 a_find_program(LUA_EXECUTABLE lua FALSE)
  60 a_find_program(LUADOC_EXECUTABLE luadoc FALSE)
  61 # theme graphics
  62 a_find_program(CONVERT_EXECUTABLE convert TRUE)
  63 # doxygen
  64 include(FindDoxygen)
  65 # pkg-config
  66 include(FindPkgConfig)
  67 # lua 5.1
  68 include(FindLua51) #Due to a cmake bug, you will see Lua50 on screen
  69 # }}}
  70
  71 # {{{ Check if documentation can be build
  72 if(GENERATE_MANPAGES)
  73     if(NOT ASCIIDOC_EXECUTABLE OR NOT XMLTO_EXECUTABLE OR (COMPRESS_MANPAGES AND NOT GZIP_EXECUTABLE))
  74         if(NOT ASCIIDOC_EXECUTABLE)
  75             SET(missing "asciidoc")
  76         endif()
  77         if(NOT XMLTO_EXECUTABLE)
  78             SET(missing ${missing} " xmlto")
  79         endif()
  80         if(COMPRESS_MANPAGES AND NOT GZIP_EXECUTABLE)
  81             SET(missing ${missing} " gzip")
  82         endif()
  83
  84         message(STATUS "Not generating manpages. Missing: " ${missing})
  85         set(GENERATE_MANPAGES OFF)
  86     endif()
  87 endif()
  88
  89 if(GENERATE_LUADOC)
  90     if(NOT LUADOC_EXECUTABLE)
  91         message(STATUS "Not generating luadoc. Missing: luadoc")
  92         set(GENERATE_LUADOC OFF)
  93     endif()
  94 endif()
  95 # }}}
  96
  97 # {{{ Version stamp
  98 if(EXISTS ${SOURCE_DIR}/.git/HEAD AND GIT_EXECUTABLE)
  99     # get current version
 100     execute_process(
 101         COMMAND ${GIT_EXECUTABLE} describe
 102         WORKING_DIRECTORY ${SOURCE_DIR}
 103         OUTPUT_VARIABLE VERSION
 104         OUTPUT_STRIP_TRAILING_WHITESPACE)
 105     # file the git-version-stamp.sh script will look into
 106     set(VERSION_STAMP_FILE ${BUILD_DIR}/.version_stamp)
 107     file(WRITE ${VERSION_STAMP_FILE} ${VERSION})
 108     # create a version_stamp target later
 109     set(BUILD_FROM_GIT TRUE)
 110 elseif( EXISTS ${SOURCE_DIR}/.version_stamp )
 111     # get version from version stamp
 112     file(READ ${SOURCE_DIR}/.version_stamp VERSION)
 113 endif()
 114 # }}}
 115
 116 # {{{ Get hostname
 117 execute_process(
 118     COMMAND ${HOSTNAME_EXECUTABLE}
 119     WORKING_DIRECTORY ${SOURCE_DIR}
 120     OUTPUT_VARIABLE BUILDHOSTNAME
 121     OUTPUT_STRIP_TRAILING_WHITESPACE)
 122 # }}}
 123
 124 # {{{ Required libraries
 125 #
 126 # this sets up:
 127 # AWESOME_REQUIRED_LIBRARIES
 128 # AWESOME_REQUIRED_INCLUDE_DIRS
 129
 130 # Use pkgconfig to get most of the libraries
 131 pkg_check_modules(AWESOME_COMMON_REQUIRED REQUIRED
 132     xcb>=1.4)
 133
 134 pkg_check_modules(AWESOME_REQUIRED REQUIRED
 135     glib-2.0
 136     cairo
 137     x11
 138     pango>=1.19.3
 139     pangocairo>=1.19.3
 140     xcb-randr
 141     xcb-xtest
 142     xcb-xinerama
 143     xcb-shape
 144     xcb-aux>=0.3.0
 145     xcb-atom>=0.3.0
 146     xcb-keysyms>=0.3.4
 147     xcb-icccm>=0.3.6
 148     xcb-image>=0.3.0
 149     cairo-xcb
 150     libstartup-notification-1.0>=0.10
 151     xproto>=7.0.15
 152     imlib2
 153     libxdg-basedir>=1.0.0)
 154
 155 if(NOT AWESOME_REQUIRED_FOUND OR NOT AWESOME_COMMON_REQUIRED_FOUND)
 156     message(FATAL_ERROR)
 157 endif()
 158
 159 macro(a_find_library variable library)
 160     find_library(${variable} ${library})
 161     if(NOT ${variable})
 162         message(FATAL_ERROR ${library} " library not found.")
 163     endif()
 164 endmacro()
 165
 166 # Check for libev
 167 a_find_library(LIB_EV ev)
 168 # GNU libc has <execinfo.h> and backtrace() stuff. If this is not available, we
 169 # need libexecinfo.
 170 message(STATUS "checking for execinfo")
 171 try_compile(HAS_EXECINFO
 172     ${CMAKE_BINARY_DIR}
 173     ${CMAKE_SOURCE_DIR}/build-tests/execinfo.c)
 174 if(NOT HAS_EXECINFO)
 175     find_library(LIB_EXECINFO execinfo)
 176     if(LIB_EXECINFO)
 177         set(HAS_EXECINFO 1)
 178         set(AWESOME_REQUIRED_LIBRARIES
 179             ${AWESOME_REQUIRED_LIBRARIES}
 180             ${LIB_EXECINFO})
 181     endif()
 182 endif()
 183 if(HAS_EXECINFO)
 184     message(STATUS "checking for execinfo -- found")
 185 else()
 186     message(STATUS "checking for execinfo -- not found")
 187 endif()
 188
 189 # Error check
 190 if(NOT LUA51_FOUND AND NOT LUA50_FOUND) # This is a workaround to a cmake bug
 191     message(FATAL_ERROR "lua library not found")
 192 endif()
 193
 194 set(AWESOME_REQUIRED_LIBRARIES
 195     ${AWESOME_COMMON_REQUIRED_LDFLAGS}
 196     ${AWESOME_REQUIRED_LIBRARIES}
 197     ${LIB_EV}
 198     ${LUA_LIBRARIES})
 199
 200 set(AWESOME_REQUIRED_INCLUDE_DIRS
 201     ${AWESOME_COMMON_REQUIRED_INCLUDE_DIRS}
 202     ${AWESOME_REQUIRED_INCLUDE_DIRS}
 203     ${LUA_INCLUDE_DIR})
 204 # }}}
 205
 206 # {{{ Optional libraries
 207 #
 208 # this sets up:
 209 # AWESOME_OPTIONAL_LIBRARIES
 210 # AWESOME_OPTIONAL_INCLUDE_DIRS
 211
 212 if(WITH_DBUS)
 213     pkg_check_modules(DBUS dbus-1)
 214     if(DBUS_FOUND)
 215         set(AWESOME_OPTIONAL_LIBRARIES ${AWESOME_OPTIONAL_LIBRARIES} ${DBUS_LDFLAGS})
 216         set(AWESOME_OPTIONAL_INCLUDE_DIRS ${AWESOME_OPTIONAL_INCLUDE_DIRS} ${DBUS_INCLUDE_DIRS})
 217     else()
 218         set(WITH_DBUS OFF)
 219         message(STATUS "DBUS not found. Disabled.")
 220     endif()
 221 endif()
 222 # }}}
 223
 224 # {{{ Install path and configuration variables
 225 if(DEFINED PREFIX)
 226     set(PREFIX ${PREFIX} CACHE PATH "install prefix")
 227     set(CMAKE_INSTALL_PREFIX ${PREFIX})
 228 else()
 229     set(PREFIX ${CMAKE_INSTALL_PREFIX} CACHE PATH "install prefix")
 230 endif()
 231
 232 #If a sysconfdir is specified, use it instead
 233 #of the default configuration dir.
 234 if(DEFINED SYSCONFDIR)
 235     set(SYSCONFDIR ${SYSCONFDIR} CACHE PATH "config directory")
 236 else()
 237     set(SYSCONFDIR ${PREFIX}/etc CACHE PATH "config directory")
 238 endif()
 239
 240 #If an XDG Config Dir is specificed, use it instead
 241 #of the default XDG configuration dir.
 242 if(DEFINED XDG_CONFIG_DIR)
 243     set(XDG_CONFIG_DIR ${XDG_CONFIG_DIR} CACHE PATH "xdg config directory")
 244 else()
 245     set(XDG_CONFIG_DIR ${SYSCONFDIR}/xdg CACHE PATH "xdg config directory")
 246 endif()
 247
 248 # setting AWESOME_DOC_PATH
 249 if(DEFINED AWESOME_DOC_PATH)
 250     set(AWESOME_DOC_PATH ${AWESOME_DOC_PATH} CACHE PATH "awesome docs directory")
 251 else()
 252     set(AWESOME_DOC_PATH ${PREFIX}/share/doc/${PROJECT_AWE_NAME} CACHE PATH "awesome docs directory")
 253 endif()
 254
 255 # setting AWESOME_XSESSION_PATH
 256 if(DEFINED AWESOME_XSESSION_PATH)
 257     set(AWESOME_XSESSION_PATH ${AWESOME_XSESSION_PATH} CACHE PATH "awesome xsessions directory")
 258 else()
 259     set(AWESOME_XSESSION_PATH ${PREFIX}/share/xsessions CACHE PATH "awesome xsessions directory")
 260 endif()
 261
 262 # set man path
 263 if(DEFINED AWESOME_MAN_PATH)
 264    set(AWESOME_MAN_PATH ${AWESOME_MAN_PATH} CACHE PATH "awesome manpage directory")
 265 else()
 266    set(AWESOME_MAN_PATH ${PREFIX}/share/man CACHE PATH "awesome manpage directory")
 267 endif()
 268
 269 # Hide to avoid confusion
 270 mark_as_advanced(CMAKE_INSTALL_PREFIX)
 271
 272 set(AWESOME_VERSION          ${VERSION})
 273 set(AWESOME_COMPILE_MACHINE  ${CMAKE_SYSTEM_PROCESSOR})
 274 set(AWESOME_COMPILE_HOSTNAME ${BUILDHOSTNAME})
 275 set(AWESOME_COMPILE_BY       $ENV{USER})
 276 set(AWESOME_RELEASE          ${CODENAME})
 277 set(AWESOME_SYSCONFDIR       ${XDG_CONFIG_DIR}/${PROJECT_AWE_NAME})
 278 set(AWESOME_DATA_PATH        ${PREFIX}/share/${PROJECT_AWE_NAME})
 279 set(AWESOME_LUA_LIB_PATH     ${AWESOME_DATA_PATH}/lib)
 280 set(AWESOME_ICON_PATH        ${AWESOME_DATA_PATH}/icons)
 281 set(AWESOME_THEMES_PATH      ${AWESOME_DATA_PATH}/themes)
 282 # }}}
 283
 284 # {{{ Configure files
 285 file(GLOB_RECURSE awesome_lua_configure_files RELATIVE ${SOURCE_DIR} ${SOURCE_DIR}/lib/*.lua.in ${SOURCE_DIR}/themes/*/*.lua.in)
 286 set(AWESOME_CONFIGURE_FILES
 287     ${awesome_lua_configure_files}
 288     config.h.in
 289     awesomerc.lua.in
 290     awesome-version-internal.h.in
 291     awesome.doxygen.in)
 292
 293 macro(a_configure_file file)
 294     string(REGEX REPLACE ".in\$" "" outfile ${file})
 295     message(STATUS "Configuring ${outfile}")
 296     configure_file(${SOURCE_DIR}/${file}
 297                    ${BUILD_DIR}/${outfile}
 298                    ESCAPE_QUOTE
 299                    @ONLY)
 300 endmacro()
 301
 302 foreach(file ${AWESOME_CONFIGURE_FILES})
 303     a_configure_file(${file})
 304 endforeach()
 305 #}}}
 306
 307 # vim: filetype=cmake:expandtab:shiftwidth=4:tabstop=8:softtabstop=4:encoding=utf-8:textwidth=80