CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.0)
   2 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS  TRUE)
   3
   4 if(COMMAND cmake_policy)
   5     cmake_policy(VERSION 2.6)
   6 endif()
   7
   8 set(SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
   9 set(BUILD_DIR ${CMAKE_CURRENT_BINARY_DIR})
  10
  11 if(NOT EXISTS ${SOURCE_DIR}/awesomeConfig.cmake)
  12     message(FATAL_ERROR "Please provide awesomeConfig.cmake")
  13 endif()
  14
  15 include(awesomeConfig.cmake)
  16
  17 include_directories(
  18     ${SOURCE_DIR}
  19     ${BUILD_DIR}
  20     ${AWESOME_COMMON_REQUIRED_INCLUDE_DIRS}
  21     ${AWESOME_REQUIRED_INCLUDE_DIRS}
  22     ${AWESOME_OPTIONAL_INCLUDE_DIRS})
  23
  24 set(AWE_CONF_FILE_DEFAULT ${BUILD_DIR}/awesomerc.lua)
  25 set(AWE_CONF_FILE rc.lua)
  26
  27 set(AWE_ICON_DIR ${SOURCE_DIR}/icons)
  28 set(AWE_THEMES_DIR ${SOURCE_DIR}/themes)
  29
  30 set(AWE_DOC_FILES
  31     ${SOURCE_DIR}/AUTHORS
  32     ${SOURCE_DIR}/BUGS
  33     ${SOURCE_DIR}/README
  34     ${SOURCE_DIR}/LICENSE)
  35
  36 set(AWE_SRCS
  37     ${SOURCE_DIR}/awesome.c
  38     ${SOURCE_DIR}/banning.c
  39     ${SOURCE_DIR}/color.c
  40     ${SOURCE_DIR}/dbus.c
  41     ${SOURCE_DIR}/draw.c
  42     ${SOURCE_DIR}/event.c
  43     ${SOURCE_DIR}/ewmh.c
  44     ${SOURCE_DIR}/keygrabber.c
  45     ${SOURCE_DIR}/keyresolv.c
  46     ${SOURCE_DIR}/luaa.c
  47     ${SOURCE_DIR}/mouse.c
  48     ${SOURCE_DIR}/mousegrabber.c
  49     ${SOURCE_DIR}/property.c
  50     ${SOURCE_DIR}/root.c
  51     ${SOURCE_DIR}/screen.c
  52     ${SOURCE_DIR}/selection.c
  53     ${SOURCE_DIR}/spawn.c
  54     ${SOURCE_DIR}/stack.c
  55     ${SOURCE_DIR}/strut.c
  56     ${SOURCE_DIR}/systray.c
  57     ${SOURCE_DIR}/xwindow.c
  58     ${SOURCE_DIR}/common/atoms.c
  59     ${SOURCE_DIR}/common/backtrace.c
  60     ${SOURCE_DIR}/common/buffer.c
  61     ${SOURCE_DIR}/common/luaclass.c
  62     ${SOURCE_DIR}/common/lualib.c
  63     ${SOURCE_DIR}/common/luaobject.c
  64     ${SOURCE_DIR}/common/util.c
  65     ${SOURCE_DIR}/common/version.c
  66     ${SOURCE_DIR}/common/xcursor.c
  67     ${SOURCE_DIR}/common/xembed.c
  68     ${SOURCE_DIR}/common/xutil.c
  69     ${SOURCE_DIR}/objects/button.c
  70     ${SOURCE_DIR}/objects/client.c
  71     ${SOURCE_DIR}/objects/drawable.c
  72     ${SOURCE_DIR}/objects/drawin.c
  73     ${SOURCE_DIR}/objects/key.c
  74     ${SOURCE_DIR}/objects/tag.c
  75     ${SOURCE_DIR}/objects/timer.c
  76     ${SOURCE_DIR}/objects/window.c)
  77
  78 set(AWE_MAN_SRCS
  79     ${SOURCE_DIR}/manpages/awesome.1.txt
  80     ${SOURCE_DIR}/manpages/awesome-client.1.txt
  81     ${SOURCE_DIR}/manpages/awesomerc.5.txt)
  82 set(AWE_MAN_LANGS it es fr de ru)
  83
  84 # Don't strip RPATH if compiling on Solaris
  85 if (${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
  86     set(CMAKE_SKIP_BUILD_RPATH FALSE)
  87     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
  88     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
  89 endif()
  90
  91 add_executable(${PROJECT_AWE_NAME}
  92     ${AWE_SRCS})
  93
  94 # FreeBSD requires dynamic linking
  95 if(${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD")
  96     set_target_properties(${PROJECT_AWE_NAME}
  97         PROPERTIES
  98         LINK_FLAGS -export-dynamic)
  99 endif()
 100
 101 target_link_libraries(${PROJECT_AWE_NAME}
 102     ${AWESOME_COMMON_REQUIRED_LDFLAGS}
 103     ${AWESOME_REQUIRED_LDFLAGS}
 104     ${AWESOME_OPTIONAL_LDFLAGS})
 105
 106 # atoms
 107 file(MAKE_DIRECTORY ${BUILD_DIR}/common)
 108 add_custom_command(
 109     COMMAND ${SOURCE_DIR}/build-utils/atoms-ext.sh ${SOURCE_DIR}/common/atoms.list
 110     ARGS    > ${BUILD_DIR}/common/atoms-extern.h
 111     OUTPUT  ${BUILD_DIR}/common/atoms-extern.h
 112     WORKING_DIRECTORY ${SOURCE_DIR}
 113     DEPENDS ${SOURCE_DIR}/common/atoms.list
 114     COMMENT "Generating atoms-extern.h"
 115     VERBATIM)
 116
 117 add_custom_command(
 118     COMMAND ${SOURCE_DIR}/build-utils/atoms-int.sh ${SOURCE_DIR}/common/atoms.list
 119     ARGS    > ${BUILD_DIR}/common/atoms-intern.h
 120     OUTPUT  ${BUILD_DIR}/common/atoms-intern.h
 121     WORKING_DIRECTORY ${SOURCE_DIR}
 122     DEPENDS ${SOURCE_DIR}/common/atoms.list
 123     COMMENT "Generating atoms-intern.h"
 124     VERBATIM)
 125
 126 add_custom_target(generated_sources
 127     DEPENDS ${BUILD_DIR}/common/atoms-intern.h
 128             ${BUILD_DIR}/common/atoms-extern.h)
 129
 130 # Default theme directory
 131 file(MAKE_DIRECTORY ${BUILD_DIR}/themes/default)
 132 file(MAKE_DIRECTORY ${BUILD_DIR}/themes/sky)
 133 file(MAKE_DIRECTORY ${BUILD_DIR}/themes/zenburn)
 134 add_dependencies(${PROJECT_AWE_NAME} generated_sources)
 135 # }}}
 136
 137 # {{{ Version stamp
 138 if(BUILD_FROM_GIT)
 139     add_custom_target(version_stamp ALL
 140         COMMAND ${SOURCE_DIR}/build-utils/git-version-stamp.sh
 141                 ${VERSION_STAMP_FILE}
 142                 ${BUILD_DIR}/awesome-version-internal.h
 143         WORKING_DIRECTORY ${SOURCE_DIR})
 144
 145     add_dependencies(${PROJECT_AWE_NAME} version_stamp)
 146 endif()
 147 # }}}
 148
 149 # {{{ Manpages
 150 if(GENERATE_MANPAGES)
 151     if(NOT BUILD_DIR STREQUAL SOURCE_DIR)
 152         file(MAKE_DIRECTORY ${BUILD_DIR}/manpages)
 153     endif()
 154
 155     # add the default translation to the list of languages
 156     set(AWE_MAN_LANGS default ${AWE_MAN_LANGS})
 157
 158     foreach(lang ${AWE_MAN_LANGS})
 159
 160         foreach(txtfile ${AWE_MAN_SRCS})
 161             # figure the base name of the file (ie "awesome.1")
 162             GET_FILENAME_COMPONENT(tmpname ${txtfile} NAME)
 163             string(REGEX REPLACE ".txt\$" "" basename ${tmpname})
 164
 165             # figure the relative path of the file
 166             GET_FILENAME_COMPONENT(tmppath ${txtfile} PATH)
 167             string(REPLACE ${SOURCE_DIR}/ "" relpath ${tmppath})
 168
 169             # figure the manpage section to install to from filename
 170             string(REGEX REPLACE "^.*\\.([0-9])$" "\\1" section ${basename})
 171
 172             # construct the language specific versions of the basename and path
 173             if (lang STREQUAL default)
 174                 set(basename2 ${basename})
 175                 set(relpath2 ${relpath}/man${section})
 176             else()
 177                 set(basename2 ${basename}.${lang})
 178                 set(relpath2 ${relpath}/${lang}/man${section})
 179             endif()
 180
 181             # create the build directory (if it does not exist)
 182             file(MAKE_DIRECTORY ${BUILD_DIR}/${relpath2})
 183
 184             # set the final filenames
 185             set(txtfile ${SOURCE_DIR}/${relpath}/${basename2}.txt)
 186             set(xmlfile ${BUILD_DIR}/${relpath2}/${basename}.xml)
 187             set(gzfile  ${BUILD_DIR}/${relpath2}/${basename}.gz)
 188             set(manfile ${BUILD_DIR}/${relpath2}/${basename})
 189
 190             add_custom_command(
 191                 COMMAND ${ASCIIDOC_EXECUTABLE} -d manpage -b docbook -o ${xmlfile} - < ${txtfile}
 192                 WORKING_DIRECTORY ${BUILD_DIR}/${relpath2}
 193                 OUTPUT  ${xmlfile}
 194                 DEPENDS ${txtfile}
 195                 VERBATIM)
 196             add_custom_command(
 197                 COMMAND ${XMLTO_EXECUTABLE} man ${xmlfile}
 198                 OUTPUT  ${manfile}
 199                 WORKING_DIRECTORY ${BUILD_DIR}/${relpath2}
 200                 DEPENDS ${xmlfile})
 201
 202             if(COMPRESS_MANPAGES)
 203                 add_custom_command(
 204                     COMMAND ${GZIP_EXECUTABLE} < ${manfile} > ${gzfile}
 205                     OUTPUT  ${gzfile}
 206                     WORKING_DIRECTORY ${BUILD_DIR}/${relpath2}
 207                     DEPENDS ${manfile}
 208                     VERBATIM)
 209
 210                 set(MAN_FILES ${MAN_FILES} ${gzfile})
 211             else()
 212                 set(MAN_FILES ${MAN_FILES} ${manfile})
 213             endif()
 214         endforeach()
 215
 216     endforeach()
 217
 218     add_custom_target(man ALL DEPENDS ${MAN_FILES})
 219 endif()
 220 # }}}
 221
 222 # {{{ Doxygen
 223 if(DOXYGEN_EXECUTABLE)
 224     add_custom_target(doc
 225         COMMAND ${DOXYGEN_EXECUTABLE} awesome.doxygen
 226         WORKING_DIRECTORY ${BUILD_DIR})
 227 endif()
 228 # }}}
 229
 230 # {{{ Lua API Documentation
 231 if(GENERATE_DOC)
 232     if(NOT BUILD_DIR STREQUAL SOURCE_DIR)
 233         file(MAKE_DIRECTORY ${BUILD_DIR}/lib)
 234     endif()
 235
 236     file(GLOB_RECURSE AWE_LUA_FILES ${BUILD_DIR}/lib/*.lua ${BUILD_DIR}/luadoc/*.lua)
 237
 238     add_custom_target(ldoc ALL
 239         COMMAND ${LDOC_EXECUTABLE} .
 240         WORKING_DIRECTORY ${BUILD_DIR}
 241         DEPENDS ${AWE_LUA_FILES})
 242 endif()
 243 # }}}
 244
 245 # {{{ Theme icons
 246 file(GLOB icon_sources RELATIVE ${SOURCE_DIR} ${SOURCE_DIR}/themes/*/titlebar/*.png)
 247
 248 foreach(icon ${icon_sources})
 249     # Copy all icons to the build dir to simplify the following code.
 250     # Source paths are interpreted relative to ${SOURCE_DIR}, target paths
 251     # relative to ${BUILD_DIR}.
 252     get_filename_component(icon_path ${icon} PATH)
 253     get_filename_component(icon_name ${icon} NAME)
 254     file(COPY ${icon} DESTINATION ${icon_path})
 255     set(ALL_ICONS ${ALL_ICONS} "${icon_path}/${icon_name}")
 256 endforeach()
 257
 258 macro(a_icon_convert match replacement input)
 259     string(REPLACE ${match} ${replacement} output ${input})
 260
 261     if(NOT ${input} STREQUAL ${output})
 262         set(ALL_ICONS ${ALL_ICONS} ${output})
 263
 264         add_custom_command(
 265             COMMAND ${CONVERT_EXECUTABLE} ${input} ${ARGN} ${output}
 266             OUTPUT  ${output}
 267             DEPENDS ${input}
 268             VERBATIM)
 269     endif()
 270 endmacro()
 271
 272 foreach(icon ${ALL_ICONS})
 273     # Make unfocused icons translucent
 274     a_icon_convert("_focus" "_normal" ${icon}
 275         -colorspace rgb -gamma 0.6 -channel A -evaluate Multiply 0.4)
 276 endforeach()
 277
 278 foreach(icon ${ALL_ICONS})
 279     # Make inactive icons grayscale
 280     a_icon_convert("_active" "_inactive" ${icon}
 281         -colorspace Gray)
 282 endforeach()
 283
 284 add_custom_target(generated_icons ALL DEPENDS ${ALL_ICONS})
 285 # }}}
 286
 287 # {{{ Dist tarball
 288 if(BUILD_FROM_GIT)
 289     add_custom_target(dist
 290         COMMAND ${SOURCE_DIR}/build-utils/dist.sh ${VERSION}
 291         WORKING_DIRECTORY ${SOURCE_DIR})
 292 endif()
 293 # }}}
 294
 295 # {{{ Installation
 296 install(TARGETS ${PROJECT_AWE_NAME} RUNTIME DESTINATION bin)
 297 install(FILES "utils/awesome-client" DESTINATION bin PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE)
 298 install(DIRECTORY ${BUILD_DIR}/lib DESTINATION ${AWESOME_DATA_PATH}
 299     PATTERN "*.in" EXCLUDE)
 300 install(FILES ${AWE_CONF_FILE_DEFAULT} DESTINATION ${AWESOME_SYSCONFDIR}
 301         RENAME ${AWE_CONF_FILE})
 302 if(GENERATE_MANPAGES)
 303     if(COMPRESS_MANPAGES)
 304         set(regex "\\.(xml|txt|[0-9])$")
 305     else()
 306         set(regex "\\.(xml|txt|gz)$")
 307     endif()
 308     install(DIRECTORY ${BUILD_DIR}/${relpath}/ DESTINATION ${AWESOME_MAN_PATH}
 309             REGEX ${regex} EXCLUDE )
 310 endif()
 311 install(DIRECTORY ${AWE_ICON_DIR} DESTINATION ${AWESOME_DATA_PATH})
 312 install(DIRECTORY ${BUILD_DIR}/themes DESTINATION ${AWESOME_DATA_PATH}
 313     PATTERN "*.in" EXCLUDE)
 314 install(DIRECTORY ${SOURCE_DIR}/themes DESTINATION ${AWESOME_DATA_PATH}
 315     PATTERN "*.in" EXCLUDE)
 316 install(FILES ${AWE_DOC_FILES} DESTINATION ${AWESOME_DOC_PATH})
 317 install(FILES "awesome.desktop" DESTINATION ${AWESOME_XSESSION_PATH})
 318 if(GENERATE_DOC)
 319     install(DIRECTORY ${BUILD_DIR}/doc DESTINATION ${AWESOME_DOC_PATH})
 320 endif()
 321 # }}}
 322
 323 # vim: filetype=cmake:expandtab:shiftwidth=4:tabstop=8:softtabstop=4:textwidth=80