CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.0)
   2 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS  TRUE)
   3
   4 if(COMMAND cmake_policy)
   5     cmake_policy(VERSION 2.6)
   6 endif()
   7
   8 set(SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
   9 set(BUILD_DIR ${CMAKE_CURRENT_BINARY_DIR})
  10
  11 if(NOT EXISTS ${SOURCE_DIR}/awesomeConfig.cmake)
  12     message(FATAL_ERROR "Please provide awesomeConfig.cmake")
  13 endif()
  14
  15 include(awesomeConfig.cmake)
  16
  17 include_directories(
  18     ${SOURCE_DIR}
  19     ${BUILD_DIR}
  20     ${AWESOME_COMMON_REQUIRED_INCLUDE_DIRS}
  21     ${AWESOME_REQUIRED_INCLUDE_DIRS}
  22     ${AWESOME_OPTIONAL_INCLUDE_DIRS})
  23
  24 set(AWE_CONF_FILE_DEFAULT ${BUILD_DIR}/awesomerc.lua)
  25 set(AWE_CONF_FILE rc.lua)
  26
  27 set(AWE_ICON_DIR ${SOURCE_DIR}/icons)
  28 set(AWE_THEMES_DIR ${SOURCE_DIR}/themes)
  29
  30 set(AWE_DOC_FILES
  31     ${SOURCE_DIR}/AUTHORS
  32     ${SOURCE_DIR}/BUGS
  33     ${SOURCE_DIR}/README
  34     ${SOURCE_DIR}/LICENSE)
  35
  36 set(AWE_SRCS
  37     ${SOURCE_DIR}/awesome.c
  38     ${SOURCE_DIR}/banning.c
  39     ${SOURCE_DIR}/color.c
  40     ${SOURCE_DIR}/dbus.c
  41     ${SOURCE_DIR}/draw.c
  42     ${SOURCE_DIR}/event.c
  43     ${SOURCE_DIR}/ewmh.c
  44     ${SOURCE_DIR}/keygrabber.c
  45     ${SOURCE_DIR}/keyresolv.c
  46     ${SOURCE_DIR}/luaa.c
  47     ${SOURCE_DIR}/mouse.c
  48     ${SOURCE_DIR}/mousegrabber.c
  49     ${SOURCE_DIR}/property.c
  50     ${SOURCE_DIR}/root.c
  51     ${SOURCE_DIR}/selection.c
  52     ${SOURCE_DIR}/spawn.c
  53     ${SOURCE_DIR}/stack.c
  54     ${SOURCE_DIR}/strut.c
  55     ${SOURCE_DIR}/systray.c
  56     ${SOURCE_DIR}/xwindow.c
  57     ${SOURCE_DIR}/common/atoms.c
  58     ${SOURCE_DIR}/common/backtrace.c
  59     ${SOURCE_DIR}/common/buffer.c
  60     ${SOURCE_DIR}/common/luaclass.c
  61     ${SOURCE_DIR}/common/lualib.c
  62     ${SOURCE_DIR}/common/luaobject.c
  63     ${SOURCE_DIR}/common/util.c
  64     ${SOURCE_DIR}/common/version.c
  65     ${SOURCE_DIR}/common/xcursor.c
  66     ${SOURCE_DIR}/common/xembed.c
  67     ${SOURCE_DIR}/common/xutil.c
  68     ${SOURCE_DIR}/objects/button.c
  69     ${SOURCE_DIR}/objects/client.c
  70     ${SOURCE_DIR}/objects/drawable.c
  71     ${SOURCE_DIR}/objects/drawin.c
  72     ${SOURCE_DIR}/objects/key.c
  73     ${SOURCE_DIR}/objects/screen.c
  74     ${SOURCE_DIR}/objects/tag.c
  75     ${SOURCE_DIR}/objects/timer.c
  76     ${SOURCE_DIR}/objects/window.c)
  77
  78 set(AWE_MAN_SRCS
  79     ${SOURCE_DIR}/manpages/awesome.1.txt
  80     ${SOURCE_DIR}/manpages/awesome-client.1.txt
  81     ${SOURCE_DIR}/manpages/awesomerc.5.txt)
  82 set(AWE_MAN_LANGS it es fr de ru)
  83
  84 # Don't strip RPATH if compiling on Solaris
  85 if (${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
  86     set(CMAKE_SKIP_BUILD_RPATH FALSE)
  87     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
  88     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
  89 endif()
  90
  91 add_executable(${PROJECT_AWE_NAME}
  92     ${AWE_SRCS})
  93
  94 # FreeBSD requires dynamic linking
  95 if(${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD")
  96     set_target_properties(${PROJECT_AWE_NAME}
  97         PROPERTIES
  98         LINK_FLAGS -export-dynamic)
  99 endif()
 100
 101 target_link_libraries(${PROJECT_AWE_NAME}
 102     ${AWESOME_COMMON_REQUIRED_LDFLAGS}
 103     ${AWESOME_REQUIRED_LDFLAGS}
 104     ${AWESOME_OPTIONAL_LDFLAGS})
 105
 106 # check for lgi and the needed gobject introspection files
 107 add_custom_target(lgi-check ALL
 108     COMMAND ${SOURCE_DIR}/build-utils/lgi-check.sh)
 109
 110 # atoms
 111 file(MAKE_DIRECTORY ${BUILD_DIR}/common)
 112 add_custom_command(
 113     COMMAND ${SOURCE_DIR}/build-utils/atoms-ext.sh ${SOURCE_DIR}/common/atoms.list
 114     ARGS    > ${BUILD_DIR}/common/atoms-extern.h
 115     OUTPUT  ${BUILD_DIR}/common/atoms-extern.h
 116     WORKING_DIRECTORY ${SOURCE_DIR}
 117     DEPENDS ${SOURCE_DIR}/common/atoms.list
 118     COMMENT "Generating atoms-extern.h"
 119     VERBATIM)
 120
 121 add_custom_command(
 122     COMMAND ${SOURCE_DIR}/build-utils/atoms-int.sh ${SOURCE_DIR}/common/atoms.list
 123     ARGS    > ${BUILD_DIR}/common/atoms-intern.h
 124     OUTPUT  ${BUILD_DIR}/common/atoms-intern.h
 125     WORKING_DIRECTORY ${SOURCE_DIR}
 126     DEPENDS ${SOURCE_DIR}/common/atoms.list
 127     COMMENT "Generating atoms-intern.h"
 128     VERBATIM)
 129
 130 add_custom_target(generated_sources
 131     DEPENDS ${BUILD_DIR}/common/atoms-intern.h
 132             ${BUILD_DIR}/common/atoms-extern.h)
 133
 134 # Default theme directory
 135 file(MAKE_DIRECTORY ${BUILD_DIR}/themes/default)
 136 file(MAKE_DIRECTORY ${BUILD_DIR}/themes/sky)
 137 file(MAKE_DIRECTORY ${BUILD_DIR}/themes/zenburn)
 138 add_dependencies(${PROJECT_AWE_NAME} generated_sources)
 139 # }}}
 140
 141 # {{{ Version stamp
 142 if(BUILD_FROM_GIT)
 143     add_custom_target(version_stamp ALL
 144         COMMAND ${SOURCE_DIR}/build-utils/git-version-stamp.sh
 145                 ${VERSION_STAMP_FILE}
 146                 ${BUILD_DIR}/awesome-version-internal.h
 147         WORKING_DIRECTORY ${SOURCE_DIR})
 148
 149     add_dependencies(${PROJECT_AWE_NAME} version_stamp)
 150 endif()
 151 # }}}
 152
 153 # {{{ Manpages
 154 if(GENERATE_MANPAGES)
 155     if(NOT BUILD_DIR STREQUAL SOURCE_DIR)
 156         file(MAKE_DIRECTORY ${BUILD_DIR}/manpages)
 157     endif()
 158
 159     # add the default translation to the list of languages
 160     set(AWE_MAN_LANGS default ${AWE_MAN_LANGS})
 161
 162     foreach(lang ${AWE_MAN_LANGS})
 163
 164         foreach(txtfile ${AWE_MAN_SRCS})
 165             # figure the base name of the file (ie "awesome.1")
 166             GET_FILENAME_COMPONENT(tmpname ${txtfile} NAME)
 167             string(REGEX REPLACE ".txt\$" "" basename ${tmpname})
 168
 169             # figure the relative path of the file
 170             GET_FILENAME_COMPONENT(tmppath ${txtfile} PATH)
 171             string(REPLACE ${SOURCE_DIR}/ "" relpath ${tmppath})
 172
 173             # figure the manpage section to install to from filename
 174             string(REGEX REPLACE "^.*\\.([0-9])$" "\\1" section ${basename})
 175
 176             # construct the language specific versions of the basename and path
 177             if (lang STREQUAL default)
 178                 set(basename2 ${basename})
 179                 set(relpath2 ${relpath}/man${section})
 180             else()
 181                 set(basename2 ${basename}.${lang})
 182                 set(relpath2 ${relpath}/${lang}/man${section})
 183             endif()
 184
 185             # create the build directory (if it does not exist)
 186             file(MAKE_DIRECTORY ${BUILD_DIR}/${relpath2})
 187
 188             # set the final filenames
 189             set(txtfile ${SOURCE_DIR}/${relpath}/${basename2}.txt)
 190             set(xmlfile ${BUILD_DIR}/${relpath2}/${basename}.xml)
 191             set(gzfile  ${BUILD_DIR}/${relpath2}/${basename}.gz)
 192             set(manfile ${BUILD_DIR}/${relpath2}/${basename})
 193
 194             add_custom_command(
 195                 COMMAND ${ASCIIDOC_EXECUTABLE} -d manpage -b docbook -o ${xmlfile} - < ${txtfile}
 196                 WORKING_DIRECTORY ${BUILD_DIR}/${relpath2}
 197                 OUTPUT  ${xmlfile}
 198                 DEPENDS ${txtfile}
 199                 VERBATIM)
 200             add_custom_command(
 201                 COMMAND ${XMLTO_EXECUTABLE} man ${xmlfile}
 202                 OUTPUT  ${manfile}
 203                 WORKING_DIRECTORY ${BUILD_DIR}/${relpath2}
 204                 DEPENDS ${xmlfile})
 205
 206             if(COMPRESS_MANPAGES)
 207                 add_custom_command(
 208                     COMMAND ${GZIP_EXECUTABLE} < ${manfile} > ${gzfile}
 209                     OUTPUT  ${gzfile}
 210                     WORKING_DIRECTORY ${BUILD_DIR}/${relpath2}
 211                     DEPENDS ${manfile}
 212                     VERBATIM)
 213
 214                 set(MAN_FILES ${MAN_FILES} ${gzfile})
 215             else()
 216                 set(MAN_FILES ${MAN_FILES} ${manfile})
 217             endif()
 218         endforeach()
 219
 220     endforeach()
 221
 222     add_custom_target(man ALL DEPENDS ${MAN_FILES})
 223 endif()
 224 # }}}
 225
 226 # {{{ Doxygen
 227 if(DOXYGEN_EXECUTABLE)
 228     add_custom_target(doc
 229         COMMAND ${DOXYGEN_EXECUTABLE} awesome.doxygen
 230         WORKING_DIRECTORY ${BUILD_DIR})
 231 endif()
 232 # }}}
 233
 234 # {{{ Lua API Documentation
 235 if(GENERATE_DOC)
 236     if(NOT BUILD_DIR STREQUAL SOURCE_DIR)
 237         file(MAKE_DIRECTORY ${BUILD_DIR}/lib)
 238     endif()
 239
 240     file(GLOB_RECURSE AWE_LUA_FILES ${BUILD_DIR}/lib/*.lua ${BUILD_DIR}/luadoc/*.lua)
 241
 242     add_custom_target(ldoc ALL
 243         COMMAND ${LDOC_EXECUTABLE} .
 244         WORKING_DIRECTORY ${BUILD_DIR}
 245         DEPENDS ${AWE_LUA_FILES})
 246 endif()
 247 # }}}
 248
 249 # {{{ Theme icons
 250 file(GLOB icon_sources RELATIVE ${SOURCE_DIR} ${SOURCE_DIR}/themes/*/titlebar/*.png)
 251
 252 foreach(icon ${icon_sources})
 253     # Copy all icons to the build dir to simplify the following code.
 254     # Source paths are interpreted relative to ${SOURCE_DIR}, target paths
 255     # relative to ${BUILD_DIR}.
 256     get_filename_component(icon_path ${icon} PATH)
 257     get_filename_component(icon_name ${icon} NAME)
 258     file(COPY ${icon} DESTINATION ${icon_path})
 259     set(ALL_ICONS ${ALL_ICONS} "${icon_path}/${icon_name}")
 260 endforeach()
 261
 262 macro(a_icon_convert match replacement input)
 263     string(REPLACE ${match} ${replacement} output ${input})
 264
 265     if(NOT ${input} STREQUAL ${output})
 266         set(ALL_ICONS ${ALL_ICONS} ${output})
 267
 268         add_custom_command(
 269             COMMAND ${CONVERT_EXECUTABLE} ${input} ${ARGN} ${output}
 270             OUTPUT  ${output}
 271             DEPENDS ${input}
 272             VERBATIM)
 273     endif()
 274 endmacro()
 275
 276 foreach(icon ${ALL_ICONS})
 277     # Make unfocused icons translucent
 278     a_icon_convert("_focus" "_normal" ${icon}
 279         -colorspace rgb -gamma 0.6 -channel A -evaluate Multiply 0.4)
 280 endforeach()
 281
 282 foreach(icon ${ALL_ICONS})
 283     # Make inactive icons grayscale
 284     a_icon_convert("_active" "_inactive" ${icon}
 285         -colorspace Gray)
 286 endforeach()
 287
 288 add_custom_target(generated_icons ALL DEPENDS ${ALL_ICONS})
 289 # }}}
 290
 291 # {{{ Dist tarball
 292 if(BUILD_FROM_GIT)
 293     add_custom_target(dist
 294         COMMAND ${SOURCE_DIR}/build-utils/dist.sh ${VERSION}
 295         WORKING_DIRECTORY ${SOURCE_DIR})
 296 endif()
 297 # }}}
 298
 299 # {{{ Installation
 300 install(TARGETS ${PROJECT_AWE_NAME} RUNTIME DESTINATION bin)
 301 install(FILES "utils/awesome-client" DESTINATION bin PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE)
 302 install(DIRECTORY ${BUILD_DIR}/lib DESTINATION ${AWESOME_DATA_PATH}
 303     PATTERN "*.in" EXCLUDE)
 304 install(FILES ${AWE_CONF_FILE_DEFAULT} DESTINATION ${AWESOME_SYSCONFDIR}
 305         RENAME ${AWE_CONF_FILE})
 306 if(GENERATE_MANPAGES)
 307     if(COMPRESS_MANPAGES)
 308         set(regex "\\.(xml|txt|[0-9])$")
 309     else()
 310         set(regex "\\.(xml|txt|gz)$")
 311     endif()
 312     install(DIRECTORY ${BUILD_DIR}/${relpath}/ DESTINATION ${AWESOME_MAN_PATH}
 313             REGEX ${regex} EXCLUDE )
 314 endif()
 315 install(DIRECTORY ${AWE_ICON_DIR} DESTINATION ${AWESOME_DATA_PATH})
 316 install(DIRECTORY ${BUILD_DIR}/themes DESTINATION ${AWESOME_DATA_PATH}
 317     PATTERN "*.in" EXCLUDE)
 318 install(DIRECTORY ${SOURCE_DIR}/themes DESTINATION ${AWESOME_DATA_PATH}
 319     PATTERN "*.in" EXCLUDE)
 320 install(FILES ${AWE_DOC_FILES} DESTINATION ${AWESOME_DOC_PATH})
 321 install(FILES "awesome.desktop" DESTINATION ${AWESOME_XSESSION_PATH})
 322 if(GENERATE_DOC)
 323     install(DIRECTORY ${BUILD_DIR}/doc DESTINATION ${AWESOME_DOC_PATH})
 324 endif()
 325 # }}}
 326
 327 # vim: filetype=cmake:expandtab:shiftwidth=4:tabstop=8:softtabstop=4:textwidth=80