awesomeConfig.cmake

   1 set(PROJECT_AWE_NAME awesome)
   2
   3 # If ${SOURCE_DIR} is a git repository VERSION is set to
   4 # `git describe` later.
   5 set(VERSION devel)
   6
   7 set(CODENAME "Ruby Tuesday")
   8
   9 project(${PROJECT_AWE_NAME} C)
  10
  11 set(CMAKE_BUILD_TYPE RELEASE)
  12
  13 option(WITH_DBUS "build with D-BUS" ON)
  14 option(GENERATE_MANPAGES "generate manpages" ON)
  15 option(COMPRESS_MANPAGES "compress manpages" ON)
  16 option(GENERATE_DOC "generate API documentation" ON)
  17
  18 # {{{ CFLAGS
  19 add_definitions(-O1 -std=gnu99 -ggdb3 -rdynamic -fno-strict-aliasing -Wall -Wextra
  20     -Wchar-subscripts -Wundef -Wshadow -Wcast-align -Wwrite-strings
  21     -Wsign-compare -Wunused -Wno-unused-parameter -Wuninitialized -Winit-self
  22     -Wpointer-arith -Wformat-nonliteral
  23     -Wno-format-zero-length -Wmissing-format-attribute -Wmissing-prototypes
  24     -Wstrict-prototypes)
  25 # }}}
  26
  27 # {{{ Endianness
  28 include(TestBigEndian)
  29 TEST_BIG_ENDIAN(AWESOME_IS_BIG_ENDIAN)
  30 # }}}
  31
  32 # {{{ Find external utilities
  33 macro(a_find_program var prg req)
  34     set(required ${req})
  35     find_program(${var} ${prg})
  36     if(NOT ${var})
  37         message(STATUS "${prg} not found.")
  38         if(required)
  39             message(FATAL_ERROR "${prg} is required to build awesome")
  40         endif()
  41     else()
  42         message(STATUS "${prg} -> ${${var}}")
  43     endif()
  44 endmacro()
  45
  46 a_find_program(CAT_EXECUTABLE cat TRUE)
  47 a_find_program(LN_EXECUTABLE ln TRUE)
  48 a_find_program(GREP_EXECUTABLE grep TRUE)
  49 a_find_program(GIT_EXECUTABLE git FALSE)
  50 a_find_program(HOSTNAME_EXECUTABLE hostname FALSE)
  51 # programs needed for man pages
  52 a_find_program(ASCIIDOC_EXECUTABLE asciidoc FALSE)
  53 a_find_program(XMLTO_EXECUTABLE xmlto FALSE)
  54 a_find_program(GZIP_EXECUTABLE gzip FALSE)
  55 # lua documentation
  56 a_find_program(LUA_EXECUTABLE lua FALSE)
  57 a_find_program(LDOC_EXECUTABLE ldoc.lua FALSE)
  58 # theme graphics
  59 a_find_program(CONVERT_EXECUTABLE convert TRUE)
  60 # doxygen
  61 include(FindDoxygen)
  62 # pkg-config
  63 include(FindPkgConfig)
  64 # lua 5.1
  65 include(FindLua51)
  66 # }}}
  67
  68 # {{{ Check if documentation can be build
  69 if(GENERATE_MANPAGES)
  70     if(NOT ASCIIDOC_EXECUTABLE OR NOT XMLTO_EXECUTABLE OR (COMPRESS_MANPAGES AND NOT GZIP_EXECUTABLE))
  71         if(NOT ASCIIDOC_EXECUTABLE)
  72             SET(missing "asciidoc")
  73         endif()
  74         if(NOT XMLTO_EXECUTABLE)
  75             SET(missing ${missing} " xmlto")
  76         endif()
  77         if(COMPRESS_MANPAGES AND NOT GZIP_EXECUTABLE)
  78             SET(missing ${missing} " gzip")
  79         endif()
  80
  81         message(STATUS "Not generating manpages. Missing: " ${missing})
  82         set(GENERATE_MANPAGES OFF)
  83     endif()
  84 endif()
  85
  86 if(GENERATE_DOC)
  87     if(NOT LDOC_EXECUTABLE)
  88         message(STATUS "Not generating API documentation. Missing: ldoc")
  89         set(GENERATE_DOC OFF)
  90     endif()
  91 endif()
  92 # }}}
  93
  94 # {{{ Version stamp
  95 if(EXISTS ${SOURCE_DIR}/.git/HEAD AND GIT_EXECUTABLE)
  96     # get current version
  97     execute_process(
  98         COMMAND ${GIT_EXECUTABLE} describe
  99         WORKING_DIRECTORY ${SOURCE_DIR}
 100         OUTPUT_VARIABLE VERSION
 101         OUTPUT_STRIP_TRAILING_WHITESPACE)
 102     # file the git-version-stamp.sh script will look into
 103     set(VERSION_STAMP_FILE ${BUILD_DIR}/.version_stamp)
 104     file(WRITE ${VERSION_STAMP_FILE} ${VERSION})
 105     # create a version_stamp target later
 106     set(BUILD_FROM_GIT TRUE)
 107 elseif( EXISTS ${SOURCE_DIR}/.version_stamp )
 108     # get version from version stamp
 109     file(READ ${SOURCE_DIR}/.version_stamp VERSION)
 110 endif()
 111 # }}}
 112
 113 # {{{ Get hostname
 114 execute_process(
 115     COMMAND ${HOSTNAME_EXECUTABLE}
 116     WORKING_DIRECTORY ${SOURCE_DIR}
 117     OUTPUT_VARIABLE BUILDHOSTNAME
 118     OUTPUT_STRIP_TRAILING_WHITESPACE)
 119 # }}}
 120
 121 # {{{ Required libraries
 122 #
 123 # this sets up:
 124 # AWESOME_REQUIRED_LDFLAGS
 125 # AWESOME_REQUIRED_INCLUDE_DIRS
 126
 127 # Use pkgconfig to get most of the libraries
 128 pkg_check_modules(AWESOME_COMMON_REQUIRED REQUIRED
 129     xcb>=1.6)
 130
 131 pkg_check_modules(AWESOME_REQUIRED REQUIRED
 132     glib-2.0
 133     gdk-pixbuf-2.0
 134     cairo
 135     x11
 136     x11-xcb
 137     xcursor
 138     xcb-randr
 139     xcb-xtest
 140     xcb-xinerama
 141     xcb-shape
 142     xcb-util>=0.3.8
 143     xcb-keysyms>=0.3.4
 144     xcb-icccm>=0.3.8
 145     xcb-image>=0.3.0
 146     cairo-xcb
 147     libstartup-notification-1.0>=0.10
 148     xproto>=7.0.15
 149     libxdg-basedir>=1.0.0)
 150
 151 if(NOT AWESOME_REQUIRED_FOUND OR NOT AWESOME_COMMON_REQUIRED_FOUND)
 152     message(FATAL_ERROR)
 153 endif()
 154
 155 macro(a_find_library variable library)
 156     find_library(${variable} ${library})
 157     if(NOT ${variable})
 158         message(FATAL_ERROR ${library} " library not found.")
 159     endif()
 160 endmacro()
 161
 162 # Check for backtrace_symbols()
 163 include(CheckFunctionExists)
 164 check_function_exists(backtrace_symbols HAS_EXECINFO)
 165 if(NOT HAS_EXECINFO)
 166     find_library(LIB_EXECINFO execinfo)
 167     if(LIB_EXECINFO)
 168         set(HAS_EXECINFO 1)
 169         set(AWESOME_REQUIRED_LDFLAGS
 170             ${AWESOME_REQUIRED_LDFLAGS}
 171             ${LIB_EXECINFO})
 172     endif()
 173 endif()
 174 if(HAS_EXECINFO)
 175     message(STATUS "checking for execinfo -- found")
 176 else()
 177     message(STATUS "checking for execinfo -- not found")
 178 endif()
 179
 180 # __builtin_clz is available since gcc 3.4
 181 try_compile(HAS___BUILTIN_CLZ
 182     ${CMAKE_BINARY_DIR}
 183     ${CMAKE_SOURCE_DIR}/build-tests/__builtin_clz.c)
 184 if(HAS___BUILTIN_CLZ)
 185     message(STATUS "checking for __builtin_clz -- yes")
 186 else()
 187     message(STATUS "checking for __builtin_clz -- no")
 188 endif()
 189
 190 # Error check
 191 if(NOT LUA51_FOUND AND NOT LUA50_FOUND) # This is a workaround to a cmake bug
 192     message(FATAL_ERROR "lua library not found")
 193 endif()
 194
 195 set(AWESOME_REQUIRED_LDFLAGS
 196     ${AWESOME_COMMON_REQUIRED_LDFLAGS}
 197     ${AWESOME_REQUIRED_LDFLAGS}
 198     ${LUA_LIBRARIES})
 199
 200 set(AWESOME_REQUIRED_INCLUDE_DIRS
 201     ${AWESOME_COMMON_REQUIRED_INCLUDE_DIRS}
 202     ${AWESOME_REQUIRED_INCLUDE_DIRS}
 203     ${LUA_INCLUDE_DIR})
 204 # }}}
 205
 206 # {{{ Optional libraries
 207 #
 208 # this sets up:
 209 # AWESOME_OPTIONAL_LDFLAGS
 210 # AWESOME_OPTIONAL_INCLUDE_DIRS
 211
 212 if(WITH_DBUS)
 213     pkg_check_modules(DBUS dbus-1)
 214     if(DBUS_FOUND)
 215         set(AWESOME_OPTIONAL_LDFLAGS ${AWESOME_OPTIONAL_LDFLAGS} ${DBUS_LDFLAGS})
 216         set(AWESOME_OPTIONAL_INCLUDE_DIRS ${AWESOME_OPTIONAL_INCLUDE_DIRS} ${DBUS_INCLUDE_DIRS})
 217     else()
 218         set(WITH_DBUS OFF)
 219         message(STATUS "DBUS not found. Disabled.")
 220     endif()
 221 endif()
 222 # }}}
 223
 224 # {{{ Install path and configuration variables
 225 #If a sysconfdir is specified, use it instead
 226 #of the default configuration dir.
 227 if(DEFINED SYSCONFDIR)
 228     set(SYSCONFDIR ${SYSCONFDIR} CACHE PATH "config directory")
 229 else()
 230     set(SYSCONFDIR ${CMAKE_INSTALL_PREFIX}/etc CACHE PATH "config directory")
 231 endif()
 232
 233 #If an XDG Config Dir is specificed, use it instead
 234 #of the default XDG configuration dir.
 235 if(DEFINED XDG_CONFIG_DIR)
 236     set(XDG_CONFIG_DIR ${XDG_CONFIG_DIR} CACHE PATH "xdg config directory")
 237 else()
 238     set(XDG_CONFIG_DIR ${SYSCONFDIR}/xdg CACHE PATH "xdg config directory")
 239 endif()
 240
 241 # setting AWESOME_DOC_PATH
 242 if(DEFINED AWESOME_DOC_PATH)
 243     set(AWESOME_DOC_PATH ${AWESOME_DOC_PATH} CACHE PATH "awesome docs directory")
 244 else()
 245     set(AWESOME_DOC_PATH ${CMAKE_INSTALL_PREFIX}/share/doc/${PROJECT_AWE_NAME} CACHE PATH "awesome docs directory")
 246 endif()
 247
 248 # setting AWESOME_XSESSION_PATH
 249 if(DEFINED AWESOME_XSESSION_PATH)
 250     set(AWESOME_XSESSION_PATH ${AWESOME_XSESSION_PATH} CACHE PATH "awesome xsessions directory")
 251 else()
 252     set(AWESOME_XSESSION_PATH ${CMAKE_INSTALL_PREFIX}/share/xsessions CACHE PATH "awesome xsessions directory")
 253 endif()
 254
 255 # set man path
 256 if(DEFINED AWESOME_MAN_PATH)
 257    set(AWESOME_MAN_PATH ${AWESOME_MAN_PATH} CACHE PATH "awesome manpage directory")
 258 else()
 259    set(AWESOME_MAN_PATH ${CMAKE_INSTALL_PREFIX}/share/man CACHE PATH "awesome manpage directory")
 260 endif()
 261
 262 # Hide to avoid confusion
 263 mark_as_advanced(CMAKE_INSTALL_CMAKE_INSTALL_PREFIX)
 264
 265 set(AWESOME_VERSION          ${VERSION})
 266 set(AWESOME_COMPILE_MACHINE  ${CMAKE_SYSTEM_PROCESSOR})
 267 set(AWESOME_COMPILE_HOSTNAME ${BUILDHOSTNAME})
 268 set(AWESOME_COMPILE_BY       $ENV{USER})
 269 set(AWESOME_RELEASE          ${CODENAME})
 270 set(AWESOME_SYSCONFDIR       ${XDG_CONFIG_DIR}/${PROJECT_AWE_NAME})
 271 set(AWESOME_DATA_PATH        ${CMAKE_INSTALL_PREFIX}/share/${PROJECT_AWE_NAME})
 272 set(AWESOME_LUA_LIB_PATH     ${AWESOME_DATA_PATH}/lib)
 273 set(AWESOME_ICON_PATH        ${AWESOME_DATA_PATH}/icons)
 274 set(AWESOME_THEMES_PATH      ${AWESOME_DATA_PATH}/themes)
 275 # }}}
 276
 277 # {{{ Configure files
 278 file(GLOB_RECURSE awesome_lua_configure_files RELATIVE ${SOURCE_DIR} ${SOURCE_DIR}/lib/*.lua.in ${SOURCE_DIR}/themes/*/*.lua.in)
 279 set(AWESOME_CONFIGURE_FILES
 280     ${awesome_lua_configure_files}
 281     config.h.in
 282     config.ld.in
 283     awesomerc.lua.in
 284     awesome-version-internal.h.in
 285     awesome.doxygen.in)
 286
 287 macro(a_configure_file file)
 288     string(REGEX REPLACE ".in\$" "" outfile ${file})
 289     message(STATUS "Configuring ${outfile}")
 290     configure_file(${SOURCE_DIR}/${file}
 291                    ${BUILD_DIR}/${outfile}
 292                    ESCAPE_QUOTE
 293                    @ONLY)
 294 endmacro()
 295
 296 foreach(file ${AWESOME_CONFIGURE_FILES})
 297     a_configure_file(${file})
 298 endforeach()
 299 #}}}
 300
 301 # vim: filetype=cmake:expandtab:shiftwidth=4:tabstop=8:softtabstop=4:textwidth=80