awesomeConfig.cmake

   1 set(PROJECT_AWE_NAME awesome)
   2
   3 # If ${SOURCE_DIR} is a git repository VERSION is set to
   4 # `git describe` later.
   5 set(VERSION devel)
   6
   7 set(CODENAME "Starlight")
   8
   9 project(${PROJECT_AWE_NAME} C)
  10
  11 set(CMAKE_BUILD_TYPE RELEASE)
  12
  13 option(WITH_DBUS "build with D-BUS" ON)
  14 option(GENERATE_MANPAGES "generate manpages" ON)
  15 option(COMPRESS_MANPAGES "compress manpages" ON)
  16 option(GENERATE_LUADOC "generate luadoc" ON)
  17
  18 # {{{ CFLAGS
  19 add_definitions(-std=gnu99 -ggdb3 -fno-strict-aliasing -Wall -Wextra
  20     -Wchar-subscripts -Wundef -Wshadow -Wcast-align -Wwrite-strings
  21     -Wsign-compare -Wunused -Wno-unused-parameter -Wuninitialized -Winit-self
  22     -Wpointer-arith -Wredundant-decls -Wformat-nonliteral
  23     -Wno-format-zero-length -Wmissing-format-attribute -Wmissing-prototypes
  24     -Wstrict-prototypes)
  25 # }}}
  26
  27 # {{{ Endianness
  28 include(TestBigEndian)
  29 TEST_BIG_ENDIAN(AWESOME_IS_BIG_ENDIAN)
  30 # }}}
  31
  32 # {{{ Find external utilities
  33 macro(a_find_program var prg req)
  34     set(required ${req})
  35     find_program(${var} ${prg})
  36     if(NOT ${var})
  37         message(STATUS "${prg} not found.")
  38         if(required)
  39             message(FATAL_ERROR "${prg} is required to build awesome")
  40         endif()
  41     else()
  42         message(STATUS "${prg} -> ${${var}}")
  43     endif()
  44 endmacro()
  45
  46 a_find_program(CAT_EXECUTABLE cat TRUE)
  47 a_find_program(LN_EXECUTABLE ln TRUE)
  48 a_find_program(GREP_EXECUTABLE grep TRUE)
  49 a_find_program(GIT_EXECUTABLE git FALSE)
  50 a_find_program(HOSTNAME_EXECUTABLE hostname FALSE)
  51 a_find_program(GPERF_EXECUTABLE gperf TRUE)
  52 # programs needed for man pages
  53 a_find_program(ASCIIDOC_EXECUTABLE asciidoc FALSE)
  54 a_find_program(XMLTO_EXECUTABLE xmlto FALSE)
  55 a_find_program(GZIP_EXECUTABLE gzip FALSE)
  56 # lua documentation
  57 a_find_program(LUA_EXECUTABLE lua FALSE)
  58 a_find_program(LUADOC_EXECUTABLE luadoc FALSE)
  59 # theme graphics
  60 a_find_program(CONVERT_EXECUTABLE convert TRUE)
  61 # doxygen
  62 include(FindDoxygen)
  63 # pkg-config
  64 include(FindPkgConfig)
  65 # lua 5.1
  66 include(FindLua51) #Due to a cmake bug, you will see Lua50 on screen
  67 # }}}
  68
  69 # {{{ Check if documentation can be build
  70 if(GENERATE_MANPAGES)
  71     if(NOT ASCIIDOC_EXECUTABLE OR NOT XMLTO_EXECUTABLE OR (COMPRESS_MANPAGES AND NOT GZIP_EXECUTABLE))
  72         if(NOT ASCIIDOC_EXECUTABLE)
  73             SET(missing "asciidoc")
  74         endif()
  75         if(NOT XMLTO_EXECUTABLE)
  76             SET(missing ${missing} " xmlto")
  77         endif()
  78         if(COMPRESS_MANPAGES AND NOT GZIP_EXECUTABLE)
  79             SET(missing ${missing} " gzip")
  80         endif()
  81
  82         message(STATUS "Not generating manpages. Missing: " ${missing})
  83         set(GENERATE_MANPAGES OFF)
  84     endif()
  85 endif()
  86
  87 if(GENERATE_LUADOC)
  88     if(NOT LUADOC_EXECUTABLE)
  89         message(STATUS "Not generating luadoc. Missing: luadoc")
  90         set(GENERATE_LUADOC OFF)
  91     endif()
  92 endif()
  93 # }}}
  94
  95 # {{{ Version stamp
  96 if(EXISTS ${SOURCE_DIR}/.git/HEAD AND GIT_EXECUTABLE)
  97     # get current version
  98     execute_process(
  99         COMMAND ${GIT_EXECUTABLE} describe
 100         WORKING_DIRECTORY ${SOURCE_DIR}
 101         OUTPUT_VARIABLE VERSION
 102         OUTPUT_STRIP_TRAILING_WHITESPACE)
 103     # file the git-version-stamp.sh script will look into
 104     set(VERSION_STAMP_FILE ${BUILD_DIR}/.version_stamp)
 105     file(WRITE ${VERSION_STAMP_FILE} ${VERSION})
 106     # create a version_stamp target later
 107     set(BUILD_FROM_GIT TRUE)
 108 elseif( EXISTS ${SOURCE_DIR}/.version_stamp )
 109     # get version from version stamp
 110     file(READ ${SOURCE_DIR}/.version_stamp VERSION)
 111 endif()
 112 # }}}
 113
 114 # {{{ Get hostname
 115 execute_process(
 116     COMMAND ${HOSTNAME_EXECUTABLE}
 117     WORKING_DIRECTORY ${SOURCE_DIR}
 118     OUTPUT_VARIABLE BUILDHOSTNAME
 119     OUTPUT_STRIP_TRAILING_WHITESPACE)
 120 # }}}
 121
 122 # {{{ Required libraries
 123 #
 124 # this sets up:
 125 # AWESOME_REQUIRED_LDFLAGS
 126 # AWESOME_REQUIRED_INCLUDE_DIRS
 127
 128 # Use pkgconfig to get most of the libraries
 129 pkg_check_modules(AWESOME_COMMON_REQUIRED REQUIRED
 130     xcb>=1.6)
 131
 132 pkg_check_modules(AWESOME_REQUIRED REQUIRED
 133     glib-2.0
 134     cairo
 135     x11
 136     pango>=1.19.3
 137     pangocairo>=1.19.3
 138     xcb-randr
 139     xcb-xtest
 140     xcb-xinerama
 141     xcb-shape
 142     xcb-util>=0.3.8
 143     xcb-keysyms>=0.3.4
 144     xcb-icccm>=0.3.8
 145     xcb-image>=0.3.0
 146     cairo-xcb
 147     libstartup-notification-1.0>=0.10
 148     xproto>=7.0.15
 149     imlib2
 150     libxdg-basedir>=1.0.0)
 151
 152 if(NOT AWESOME_REQUIRED_FOUND OR NOT AWESOME_COMMON_REQUIRED_FOUND)
 153     message(FATAL_ERROR)
 154 endif()
 155
 156 macro(a_find_library variable library)
 157     find_library(${variable} ${library})
 158     if(NOT ${variable})
 159         message(FATAL_ERROR ${library} " library not found.")
 160     endif()
 161 endmacro()
 162
 163 # Check for libev
 164 a_find_library(LIB_EV ev)
 165
 166 # Check for backtrace_symbols()
 167 include(CheckFunctionExists)
 168 check_function_exists(backtrace_symbols HAS_EXECINFO)
 169 if(NOT HAS_EXECINFO)
 170     find_library(LIB_EXECINFO execinfo)
 171     if(LIB_EXECINFO)
 172         set(HAS_EXECINFO 1)
 173         set(AWESOME_REQUIRED_LDFLAGS
 174             ${AWESOME_REQUIRED_LDFLAGS}
 175             ${LIB_EXECINFO})
 176     endif()
 177 endif()
 178 if(HAS_EXECINFO)
 179     message(STATUS "checking for execinfo -- found")
 180 else()
 181     message(STATUS "checking for execinfo -- not found")
 182 endif()
 183
 184 # __builtin_clz is available since gcc 3.4
 185 try_compile(HAS___BUILTIN_CLZ
 186     ${CMAKE_BINARY_DIR}
 187     ${CMAKE_SOURCE_DIR}/build-tests/__builtin_clz.c)
 188 if(HAS___BUILTIN_CLZ)
 189     message(STATUS "checking for __builtin_clz -- yes")
 190 else()
 191     message(STATUS "checking for __builtin_clz -- no")
 192 endif()
 193
 194 # Error check
 195 if(NOT LUA51_FOUND AND NOT LUA50_FOUND) # This is a workaround to a cmake bug
 196     message(FATAL_ERROR "lua library not found")
 197 endif()
 198
 199 set(AWESOME_REQUIRED_LDFLAGS
 200     ${AWESOME_COMMON_REQUIRED_LDFLAGS}
 201     ${AWESOME_REQUIRED_LDFLAGS}
 202     ${LIB_EV}
 203     ${LUA_LIBRARIES})
 204
 205 set(AWESOME_REQUIRED_INCLUDE_DIRS
 206     ${AWESOME_COMMON_REQUIRED_INCLUDE_DIRS}
 207     ${AWESOME_REQUIRED_INCLUDE_DIRS}
 208     ${LUA_INCLUDE_DIR})
 209 # }}}
 210
 211 # {{{ Optional libraries
 212 #
 213 # this sets up:
 214 # AWESOME_OPTIONAL_LDFLAGS
 215 # AWESOME_OPTIONAL_INCLUDE_DIRS
 216
 217 if(WITH_DBUS)
 218     pkg_check_modules(DBUS dbus-1)
 219     if(DBUS_FOUND)
 220         set(AWESOME_OPTIONAL_LDFLAGS ${AWESOME_OPTIONAL_LDFLAGS} ${DBUS_LDFLAGS})
 221         set(AWESOME_OPTIONAL_INCLUDE_DIRS ${AWESOME_OPTIONAL_INCLUDE_DIRS} ${DBUS_INCLUDE_DIRS})
 222     else()
 223         set(WITH_DBUS OFF)
 224         message(STATUS "DBUS not found. Disabled.")
 225     endif()
 226 endif()
 227 # }}}
 228
 229 # {{{ Install path and configuration variables
 230 if(DEFINED PREFIX)
 231     set(PREFIX ${PREFIX} CACHE PATH "install prefix")
 232     set(CMAKE_INSTALL_PREFIX ${PREFIX})
 233 else()
 234     set(PREFIX ${CMAKE_INSTALL_PREFIX} CACHE PATH "install prefix")
 235 endif()
 236
 237 #If a sysconfdir is specified, use it instead
 238 #of the default configuration dir.
 239 if(DEFINED SYSCONFDIR)
 240     set(SYSCONFDIR ${SYSCONFDIR} CACHE PATH "config directory")
 241 else()
 242     set(SYSCONFDIR ${PREFIX}/etc CACHE PATH "config directory")
 243 endif()
 244
 245 #If an XDG Config Dir is specificed, use it instead
 246 #of the default XDG configuration dir.
 247 if(DEFINED XDG_CONFIG_DIR)
 248     set(XDG_CONFIG_DIR ${XDG_CONFIG_DIR} CACHE PATH "xdg config directory")
 249 else()
 250     set(XDG_CONFIG_DIR ${SYSCONFDIR}/xdg CACHE PATH "xdg config directory")
 251 endif()
 252
 253 # setting AWESOME_DOC_PATH
 254 if(DEFINED AWESOME_DOC_PATH)
 255     set(AWESOME_DOC_PATH ${AWESOME_DOC_PATH} CACHE PATH "awesome docs directory")
 256 else()
 257     set(AWESOME_DOC_PATH ${PREFIX}/share/doc/${PROJECT_AWE_NAME} CACHE PATH "awesome docs directory")
 258 endif()
 259
 260 # setting AWESOME_XSESSION_PATH
 261 if(DEFINED AWESOME_XSESSION_PATH)
 262     set(AWESOME_XSESSION_PATH ${AWESOME_XSESSION_PATH} CACHE PATH "awesome xsessions directory")
 263 else()
 264     set(AWESOME_XSESSION_PATH ${PREFIX}/share/xsessions CACHE PATH "awesome xsessions directory")
 265 endif()
 266
 267 # set man path
 268 if(DEFINED AWESOME_MAN_PATH)
 269    set(AWESOME_MAN_PATH ${AWESOME_MAN_PATH} CACHE PATH "awesome manpage directory")
 270 else()
 271    set(AWESOME_MAN_PATH ${PREFIX}/share/man CACHE PATH "awesome manpage directory")
 272 endif()
 273
 274 # Hide to avoid confusion
 275 mark_as_advanced(CMAKE_INSTALL_PREFIX)
 276
 277 set(AWESOME_VERSION          ${VERSION})
 278 set(AWESOME_COMPILE_MACHINE  ${CMAKE_SYSTEM_PROCESSOR})
 279 set(AWESOME_COMPILE_HOSTNAME ${BUILDHOSTNAME})
 280 set(AWESOME_COMPILE_BY       $ENV{USER})
 281 set(AWESOME_RELEASE          ${CODENAME})
 282 set(AWESOME_SYSCONFDIR       ${XDG_CONFIG_DIR}/${PROJECT_AWE_NAME})
 283 set(AWESOME_DATA_PATH        ${PREFIX}/share/${PROJECT_AWE_NAME})
 284 set(AWESOME_LUA_LIB_PATH     ${AWESOME_DATA_PATH}/lib)
 285 set(AWESOME_ICON_PATH        ${AWESOME_DATA_PATH}/icons)
 286 set(AWESOME_THEMES_PATH      ${AWESOME_DATA_PATH}/themes)
 287 # }}}
 288
 289 # {{{ Configure files
 290 file(GLOB_RECURSE awesome_lua_configure_files RELATIVE ${SOURCE_DIR} ${SOURCE_DIR}/lib/*.lua.in ${SOURCE_DIR}/themes/*/*.lua.in)
 291 set(AWESOME_CONFIGURE_FILES
 292     ${awesome_lua_configure_files}
 293     config.h.in
 294     awesomerc.lua.in
 295     awesome-version-internal.h.in
 296     awesome.doxygen.in)
 297
 298 macro(a_configure_file file)
 299     string(REGEX REPLACE ".in\$" "" outfile ${file})
 300     message(STATUS "Configuring ${outfile}")
 301     configure_file(${SOURCE_DIR}/${file}
 302                    ${BUILD_DIR}/${outfile}
 303                    ESCAPE_QUOTE
 304                    @ONLY)
 305 endmacro()
 306
 307 foreach(file ${AWESOME_CONFIGURE_FILES})
 308     a_configure_file(${file})
 309 endforeach()
 310 #}}}
 311
 312 # vim: filetype=cmake:expandtab:shiftwidth=4:tabstop=8:softtabstop=4:textwidth=80