CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6.0)
   2 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS  TRUE)
   3
   4 if(COMMAND cmake_policy)
   5     cmake_policy(VERSION 2.6)
   6 endif()
   7
   8 set(SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
   9 set(BUILD_DIR ${CMAKE_CURRENT_BINARY_DIR})
  10
  11 if(NOT EXISTS ${SOURCE_DIR}/awesomeConfig.cmake)
  12     message(FATAL_ERROR "Please provide awesomeConfig.cmake")
  13 endif()
  14
  15 include(awesomeConfig.cmake)
  16
  17 include_directories(
  18     ${SOURCE_DIR}
  19     ${BUILD_DIR}
  20     ${BUILD_DIR}/common
  21     ${AWESOME_COMMON_REQUIRED_INCLUDE_DIRS}
  22     ${AWESOME_REQUIRED_INCLUDE_DIRS}
  23     ${AWESOME_OPTIONAL_INCLUDE_DIRS})
  24
  25 file(GLOB_RECURSE AWE_LUA_FILES ${BUILD_DIR}/lib/*.lua)
  26
  27 set(AWE_CONF_FILE_DEFAULT ${BUILD_DIR}/awesomerc.lua)
  28 set(AWE_CONF_FILE rc.lua)
  29
  30 set(AWE_ICON_DIR ${SOURCE_DIR}/icons)
  31 set(AWE_THEMES_DIR ${SOURCE_DIR}/themes)
  32
  33 set(AWE_DOC_FILES
  34     ${SOURCE_DIR}/AUTHORS
  35     ${SOURCE_DIR}/BUGS
  36     ${SOURCE_DIR}/README
  37     ${SOURCE_DIR}/LICENSE)
  38
  39 set(AWE_SRCS
  40     ${SOURCE_DIR}/awesome.c
  41     ${SOURCE_DIR}/client.c
  42     ${SOURCE_DIR}/dbus.c
  43     ${SOURCE_DIR}/root.c
  44     ${SOURCE_DIR}/event.c
  45     ${SOURCE_DIR}/property.c
  46     ${SOURCE_DIR}/ewmh.c
  47     ${SOURCE_DIR}/key.c
  48     ${SOURCE_DIR}/keygrabber.c
  49     ${SOURCE_DIR}/mousegrabber.c
  50     ${SOURCE_DIR}/layout.c
  51     ${SOURCE_DIR}/luaa.c
  52     ${SOURCE_DIR}/spawn.c
  53     ${SOURCE_DIR}/hooks.c
  54     ${SOURCE_DIR}/mouse.c
  55     ${SOURCE_DIR}/button.c
  56     ${SOURCE_DIR}/screen.c
  57     ${SOURCE_DIR}/stack.c
  58     ${SOURCE_DIR}/selection.c
  59     ${SOURCE_DIR}/wibox.c
  60     ${SOURCE_DIR}/systray.c
  61     ${SOURCE_DIR}/tag.c
  62     ${SOURCE_DIR}/titlebar.c
  63     ${SOURCE_DIR}/widget.c
  64     ${SOURCE_DIR}/window.c
  65     ${SOURCE_DIR}/image.c
  66     ${SOURCE_DIR}/draw.c
  67     ${SOURCE_DIR}/color.c
  68     ${SOURCE_DIR}/swindow.c
  69     ${SOURCE_DIR}/common/buffer.c
  70     ${SOURCE_DIR}/common/atoms.c
  71     ${SOURCE_DIR}/common/util.c
  72     ${SOURCE_DIR}/common/version.c
  73     ${SOURCE_DIR}/common/xembed.c
  74     ${SOURCE_DIR}/common/xutil.c
  75     ${SOURCE_DIR}/common/xcursor.c
  76     ${SOURCE_DIR}/common/backtrace.c
  77     ${SOURCE_DIR}/widgets/graph.c
  78     ${SOURCE_DIR}/widgets/progressbar.c
  79     ${SOURCE_DIR}/widgets/textbox.c
  80     ${SOURCE_DIR}/widgets/systray.c
  81     ${SOURCE_DIR}/widgets/imagebox.c)
  82
  83 set(AWE_MAN_SRCS
  84     ${SOURCE_DIR}/manpages/awesome.1.txt
  85     ${SOURCE_DIR}/manpages/awsetbg.1.txt
  86     ${SOURCE_DIR}/manpages/awesome-client.1.txt
  87     ${SOURCE_DIR}/manpages/awesomerc.5.txt)
  88
  89 add_executable(${PROJECT_AWE_NAME}
  90     ${AWE_SRCS}
  91     ${BUILD_DIR}/common/tokenize.c)
  92
  93 set_target_properties(${PROJECT_AWE_NAME}
  94     PROPERTIES
  95     LINK_FLAGS -export-dynamic)
  96
  97 target_link_libraries(${PROJECT_AWE_NAME}
  98     ${AWESOME_COMMON_REQUIRED_LIBRARIES}
  99     ${AWESOME_REQUIRED_LIBRARIES}
 100     ${AWESOME_OPTIONAL_LIBRARIES})
 101
 102 # {{{ Generated sources
 103 add_custom_command(
 104     COMMAND ${SOURCE_DIR}/build-utils/widgetgen.sh
 105     ARGS    > ${BUILD_DIR}/widgetgen.h
 106     OUTPUT  ${BUILD_DIR}/widgetgen.h
 107     WORKING_DIRECTORY ${SOURCE_DIR}
 108     DEPENDS ${SOURCE_DIR}/widget.h
 109     COMMENT "Generating widgetgen.h"
 110     VERBATIM)
 111
 112 # atoms
 113 file(MAKE_DIRECTORY ${BUILD_DIR}/common)
 114 add_custom_command(
 115     COMMAND ${SOURCE_DIR}/build-utils/atoms-ext.sh ${SOURCE_DIR}/common/atoms.list
 116     ARGS    > ${BUILD_DIR}/common/atoms-extern.h
 117     OUTPUT  ${BUILD_DIR}/common/atoms-extern.h
 118     WORKING_DIRECTORY ${SOURCE_DIR}
 119     DEPENDS ${SOURCE_DIR}/common/atoms.list
 120     COMMENT "Generating atoms-extern.h"
 121     VERBATIM)
 122
 123 add_custom_command(
 124     COMMAND ${SOURCE_DIR}/build-utils/atoms-int.sh ${SOURCE_DIR}/common/atoms.list
 125     ARGS    > ${BUILD_DIR}/common/atoms-intern.h
 126     OUTPUT  ${BUILD_DIR}/common/atoms-intern.h
 127     WORKING_DIRECTORY ${SOURCE_DIR}
 128     DEPENDS ${SOURCE_DIR}/common/atoms.list
 129     COMMENT "Generating atoms-intern.h"
 130     VERBATIM)
 131
 132 # gperf
 133 add_custom_command(
 134     COMMAND ${SOURCE_DIR}/build-utils/gperf.sh
 135     ARGS    ${SOURCE_DIR}/common/tokenize.gperf
 136             ${BUILD_DIR}/common/tokenize.h
 137     OUTPUT  ${BUILD_DIR}/common/tokenize.h
 138     DEPENDS ${SOURCE_DIR}/common/tokenize.gperf
 139             ${SOURCE_DIR}/build-utils/gperf.sh
 140     COMMENT "Generating common/tokenize.h")
 141
 142 add_custom_command(
 143     COMMAND ${SOURCE_DIR}/build-utils/gperf.sh
 144     ARGS    ${SOURCE_DIR}/common/tokenize.gperf
 145             ${BUILD_DIR}/common/tokenize.c
 146     OUTPUT  ${BUILD_DIR}/common/tokenize.c
 147     DEPENDS ${SOURCE_DIR}/common/tokenize.gperf
 148             ${SOURCE_DIR}/build-utils/gperf.sh
 149     COMMENT "Generating common/tokenize.c")
 150
 151 add_custom_target(generated_sources
 152     DEPENDS ${BUILD_DIR}/widgetgen.h
 153             ${BUILD_DIR}/common/atoms-intern.h
 154             ${BUILD_DIR}/common/atoms-extern.h
 155             ${BUILD_DIR}/common/tokenize.c
 156             ${BUILD_DIR}/common/tokenize.h)
 157
 158 # Default theme directory
 159 file(MAKE_DIRECTORY ${BUILD_DIR}/themes/default)
 160 file(MAKE_DIRECTORY ${BUILD_DIR}/themes/sky)
 161 add_dependencies(${PROJECT_AWE_NAME} generated_sources)
 162 # }}}
 163
 164 # {{{ Version stamp
 165 if(BUILD_FROM_GIT)
 166     add_custom_target(version_stamp ALL
 167         COMMAND ${SOURCE_DIR}/build-utils/git-version-stamp.sh
 168                 ${VERSION_STAMP_FILE}
 169                 ${BUILD_DIR}/awesome-version-internal.h
 170         WORKING_DIRECTORY ${SOURCE_DIR})
 171
 172     add_dependencies(${PROJECT_AWE_NAME} version_stamp)
 173 endif()
 174 # }}}
 175
 176 # {{{ Manpages
 177 if(GENERATE_MANPAGES)
 178     if(NOT BUILD_DIR STREQUAL SOURCE_DIR)
 179         file(MAKE_DIRECTORY ${BUILD_DIR}/manpages)
 180     endif()
 181     foreach(txtfile ${AWE_MAN_SRCS})
 182         string(REGEX REPLACE ".txt\$" ".xml" xmlfile ${txtfile})
 183         string(REPLACE ${SOURCE_DIR}
 184                        ${BUILD_DIR} xmlfile ${xmlfile})
 185         string(REGEX REPLACE ".xml\$" ".gz" gzfile ${xmlfile})
 186         string(REGEX REPLACE ".gz\$" "" manfile ${gzfile})
 187
 188         add_custom_command(
 189             COMMAND ${ASCIIDOC_EXECUTABLE} -d manpage -b docbook -o ${xmlfile} - < ${txtfile}
 190             WORKING_DIRECTORY ${BUILD_DIR}/manpages
 191             OUTPUT  ${xmlfile}
 192             DEPENDS ${txtfile}
 193             VERBATIM)
 194         add_custom_command(
 195             COMMAND ${XMLTO_EXECUTABLE} man ${xmlfile}
 196             OUTPUT  ${manfile}
 197             WORKING_DIRECTORY ${BUILD_DIR}/manpages
 198             DEPENDS ${xmlfile})
 199         add_custom_command(
 200             COMMAND ${GZIP_EXECUTABLE} < ${manfile} > ${gzfile}
 201             OUTPUT  ${gzfile}
 202             WORKING_DIRECTORY ${BUILD_DIR}/manpages
 203             DEPENDS ${manfile}
 204             VERBATIM)
 205
 206         set(MAN_FILES ${MAN_FILES} ${gzfile})
 207
 208         # figure out in what section to install to from filename
 209         string(REGEX REPLACE "^.*\\.([0-9])\\.gz\$" "\\1" section ${gzfile})
 210         set(AWE_MAN${section}_FILES ${AWE_MAN${section}_FILES} ${gzfile})
 211     endforeach()
 212
 213     add_custom_target(man ALL DEPENDS ${MAN_FILES})
 214 endif()
 215 # }}}
 216
 217 # {{{ Doxygen
 218 if(DOXYGEN_EXECUTABLE)
 219     add_custom_target(doc
 220         COMMAND ${DOXYGEN_EXECUTABLE} awesome.doxygen
 221         WORKING_DIRECTORY ${BUILD_DIR})
 222 endif()
 223 # }}}
 224
 225 # {{{ Lua API Documentation
 226 if(GENERATE_LUADOC)
 227
 228     set(capi_lua ${BUILD_DIR}/lib/capi.lua)
 229
 230     if(NOT BUILD_DIR STREQUAL SOURCE_DIR)
 231         file(MAKE_DIRECTORY ${BUILD_DIR}/lib)
 232     endif()
 233
 234     # {{{ setup a command for ${capi_lua}
 235     macro(a_file_match infile regex result_var)
 236         file(STRINGS ${infile} match REGEX ${regex} LIMIT_COUNT 1)
 237         if(match)
 238             set(${result_var} TRUE)
 239         else()
 240             set(${result_var} FALSE)
 241         endif()
 242     endmacro()
 243
 244     set(luadoc_c_srcs "")
 245
 246     # find .c files exporting lua functions
 247     foreach(cfile ${AWE_SRCS})
 248         a_file_match(${cfile} "const struct luaL_reg" result)
 249         if(result)
 250             set(luadoc_c_srcs ${luadoc_c_srcs} ${cfile})
 251         else()
 252             a_file_match(${cfile} "luaA_.*_index" result)
 253             if(result)
 254                 set(luadoc_c_srcs ${luadoc_c_srcs} ${cfile})
 255         endif()
 256         endif()
 257     endforeach()
 258
 259     # create fake lua source file to process by luadoc
 260     add_custom_command(
 261         COMMAND ${CAT_EXECUTABLE} ${luadoc_c_srcs}
 262                 | ${LUA_EXECUTABLE} ${SOURCE_DIR}/build-utils/fake-lua-src.lua
 263                 > ${capi_lua}
 264         OUTPUT  ${capi_lua}
 265         DEPENDS ${luadoc_c_srcs}
 266         COMMENT "Generating fake lua source."
 267         VERBATIM)
 268     # }}}
 269
 270     # Generate documentation of lib//0lua
 271     file(GLOB_RECURSE lua_lib_files ${BUILD_DIR}/lib/*.lua)
 272     foreach(filename ${lua_lib_files})
 273         file(RELATIVE_PATH filename ${BUILD_DIR}/lib ${filename})
 274         set(luadoc_srcs ${luadoc_srcs} ${filename})
 275     endforeach()
 276
 277     add_custom_target(luadoc ALL
 278         COMMAND ${LUADOC_EXECUTABLE} ${luadoc_srcs} -d ${BUILD_DIR}/luadoc
 279         WORKING_DIRECTORY ${BUILD_DIR}/lib
 280         DEPENDS ${AWE_LUA_FILES} ${capi_lua})
 281 endif()
 282 # }}}
 283
 284 # {{{ Theme icons
 285 file(GLOB icon_sources ${SOURCE_DIR}/themes/*/titlebar/*.png)
 286 set(ALL_ICONS ${icon_sources})
 287
 288 macro(a_icon_convert match replacement input)
 289     string(REPLACE ${match} ${replacement} output ${input})
 290
 291     if(NOT ${input} STREQUAL ${output})
 292         if(NOT ${output} MATCHES ${BUILD_DIR})
 293             string(REPLACE ${SOURCE_DIR} ${BUILD_DIR} output ${output})
 294         endif()
 295
 296         set(ALL_ICONS ${ALL_ICONS} ${output})
 297
 298         get_filename_component(output_path ${output} PATH)
 299         file(MAKE_DIRECTORY ${output_path})
 300
 301         add_custom_command(
 302             COMMAND ${CONVERT_EXECUTABLE} ${input} ${ARGN} ${output}
 303             OUTPUT  ${output}
 304             DEPENDS ${input}
 305             VERBATIM)
 306     endif()
 307 endmacro()
 308
 309 foreach(icon ${ALL_ICONS})
 310     # Make unfocused icons translucent
 311     a_icon_convert("_focus" "_normal" ${icon}
 312         -gamma 0.6 -channel A -evaluate Multiply 0.4)
 313 endforeach()
 314
 315 foreach(icon ${ALL_ICONS})
 316     # Make inactive icons grayscale
 317     a_icon_convert("_active" "_inactive" ${icon}
 318         -colorspace Gray)
 319 endforeach()
 320
 321 add_custom_target(generated_icons ALL DEPENDS ${ALL_ICONS})
 322 # }}}
 323
 324 # {{{ Dist tarball
 325 if(BUILD_FROM_GIT)
 326     add_custom_target(dist
 327         COMMAND ${SOURCE_DIR}/build-utils/dist.sh ${VERSION}
 328         WORKING_DIRECTORY ${SOURCE_DIR})
 329 endif()
 330 # }}}
 331
 332 # {{{ Installation
 333 install(TARGETS ${PROJECT_AWE_NAME} RUNTIME DESTINATION bin)
 334 install(FILES "utils/awsetbg" DESTINATION bin PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE)
 335 install(FILES "utils/awesome-client" DESTINATION bin PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE)
 336 install(DIRECTORY ${BUILD_DIR}/lib DESTINATION ${AWESOME_DATA_PATH})
 337 install(FILES ${AWE_CONF_FILE_DEFAULT} DESTINATION ${AWESOME_SYSCONFDIR}
 338         RENAME ${AWE_CONF_FILE})
 339 if(GENERATE_MANPAGES)
 340     install(FILES ${AWE_MAN1_FILES} DESTINATION ${AWESOME_MAN_PATH}/man1)
 341     install(FILES ${AWE_MAN5_FILES} DESTINATION ${AWESOME_MAN_PATH}/man5)
 342 endif()
 343 install(DIRECTORY ${AWE_ICON_DIR} DESTINATION ${AWESOME_DATA_PATH})
 344 install(DIRECTORY ${BUILD_DIR}/themes DESTINATION ${AWESOME_DATA_PATH})
 345 install(DIRECTORY ${SOURCE_DIR}/themes DESTINATION ${AWESOME_DATA_PATH}
 346     PATTERN "*.in" EXCLUDE)
 347 install(FILES ${AWE_DOC_FILES} DESTINATION ${AWESOME_DOC_PATH})
 348 install(FILES "awesome.desktop" DESTINATION ${AWESOME_XSESSION_PATH})
 349 if(GENERATE_LUADOC)
 350     install(DIRECTORY ${BUILD_DIR}/luadoc DESTINATION ${AWESOME_DOC_PATH})
 351 endif()
 352 # }}}
 353
 354 # vim: filetype=cmake:expandtab:shiftwidth=4:tabstop=8:softtabstop=4:encoding=utf-8:textwidth=80